# day two
label day_two:
window hide
with Pause(1)
show text "Day Two" zorder 5 with dissolve
with Pause(2)
hide text with dissolve
window show
show inn zorder 3 with dissolve

if game.town_stability >=1:
    "The day starts uneventfully.  An eclectic group discuss the merits of the Alderman's chosen citizen.  Their main point of contention seems to be how the choice of person was made - unilaterally in a meeting of the Alderman and some of his friends - but all in all they agree that the choice was a good one, however it was made."
else:
    "The start of the day is tense, but ultimately uneventful.  An eclectic group talks in the corner, whispering about the Alderman's chosen citizen.  They're not happy about how the decision of person was made, - unilaterally in a meeting of the Alderman and some of his friends - and they clearly want to do something about it, but they leave before any decisions can be made."
"""
After that it's just cooking, cleaning, and waiting tables.  Then the breakfast rush is over, leaving you staring absent-mindedly across the large room.  

It takes you a few seconds to realise that the voice you are hearing is talking to you.
"""
show elisabettaimg zorder 4 with dissolve:
    xalign 0.05 yalign 0.25
elisabetta "Because that's what I thought at first, but no, the stars are moving exactly how you would expect them to move under normal conditions.  And isn't that odd!"

"Elisabetta, the richest person in town since her land-owning father died a few years ago, beams at you over a tall stack of books and then continues talking as if you were already deep in conversation."

elisabetta """

I'll just have water please, I'm trying to keep my mind clear.  I'm examining the connection between all of the 'supernatural' – for want of a much better word – events that have been noted by our hunters and the like; and the darkness.

Because the two must be linked, mustn't they?  I mean, we've always had a strong tradition of folklore, here in the north, but while some of the earlier accounts are ambiguous, most of the more recent writings seem pretty confident that all the old stories are just fiction.  Some broth if you have it would be lovely!

But 'supernatural' things are definitely happening now.  I mean, we all saw that giant fish, if you have any of that left I'd definitely take it thank you, and that hunter, what was his name, his wounds were definitely claw marks from something that none of us have heard of before.  And burning round the edges too.  Couldn't find anything in my books like that.

It's all so fascinating!  All the beginning of something new!  You think so too don't you?  Oh you must, it's the only thing to think, it's all so exciting!

Not that much of it is happening in town yet, but it will soon I'm sure!  Have you seen anything?
"""
menu:
    "Yes, I think I have.  People have told me stories and afterwards things changed.  And when they're telling me the story, it feels like I have control over it, like I'm them and it was me choosing what they did.":
        $c=1

    "A beautiful stag visited me last night.  Its eyes were like an endless sky, it shone with a light purer than any star and its antlers were crystal." if game.status_stag == "Alive":
        $c=6

        elisabetta "Oh really?  That's fantastic!  What did it do?  When you say that its eyes were like the sky, can you elaborate?  I want to get a sketch of it.  Stay there, never mind the stew, if Henryk gets annoyed I'll have a word with him, I want to know about everything that it did.  This glow, was it white?  Did it leave a shadow?  The antlers, how many prongs?  Did it leave footsteps in the snow?"

        """

        Elisabetta keeps asking questions as she pulls out a quill and a bottle of ink and proceeds to, badly, sketch out the details you can pass her in her occasional pauses.

        Eventually she is satisfied, although most of her questions still go unanswered and she declares that she has much research to do.  Then, with a flurry of old, dry paper, she is gone.

        It is not till much later in the day, the time when you would expect the sky to be as dark as it always is, that something else truly grabs your attention.  A hunter, sitting in a corner of the room and shivering with more than the cold.
        """

        $game.town_stability +=2

        $c=11

    "A doe visited me last night, drooling blood." if game.status_stag == "Dead":
        $c=7
        elisabetta "Oh really?  That's horrifying!  How much blood?  Was it typical of deer blood?  What is typical of deer blood?  The doe, was it unusual?  How tall was it?  Fully grown?  I want to sketch it.  When you say drooling, do you mean a little mixed with saliva, or was it more gushing?  How long did this go on for?  How distressed did it look?  Did it try to attack or run?  Did you help it?"

        """

        Elisabetta keeps asking questions as she pulls out a quill and a bottle of ink and proceeds to, badly, sketch out the details you can pass her in her occasional pauses.

        Eventually she is satisfied, although most of her questions still go unanswered, and she declares that she has much research to do.  Then, with a flurry of old, dry paper, she is gone.

        It is not till much later in the day, the time when you would expect the sky to be as dark as it always is, that something else truly grabs your attention.  A hunter, sitting in a corner of the room and shivering with more than the cold.
        """

        $game.town_stability +=2

        $c=11


    "Yes, I think I have.  People have told me stories and afterwards things changed.":
        $c=8
        elisabetta """

        Oh fascinating!  What kind of things?  Which people?  Where were you when this happened to you?  Has anyone else mentioned a similar phenomenon to you?

        Has anything else strange happened to you?
        """

        "You do not know why she stopped on that question, but it is that one that she leaves hanging."
        menu:
            "*Tell her the full truth, about the way that you feel like you were making choices about other people's stories*":
                $c=1
                
            "No, that's all.":
                elisabetta "That's good, limits the scope of enquiry.  So, tell me all about it!"

                """

                Elisabetta, with many, many interruptions, eventually allows you to tell her an edited version of the last day and a half.  If she guesses that there are details that you are not sharing with her, she makes no sign, taking everything you say simply at face value.

                Eventually, after she has well and truly wrung all the information you are willing to share out of you, she declares that she has much research to do.  Then, with a flurry of old, dry paper, she is gone.

                It is not till much later in the day, the time when you would expect the sky to be as dark as it always is, that something else truly grabs your attention.  A hunter, sitting in a corner of the room and shivering with more than the cold.
                """

                $game.town_stability +=1

                $c=11


    "No, nothing.":
        $c=9
        elisabetta "Oh well, that makes sense.  But it won't be long now, I'm sure of it!  Everything's changing and while I'm doing research into why it's taking longer to reach us here in town, I'm confident that it will!"

        """

        Elisabetta pauses for breath and you take the opportunity to duck away to fetch her food.  By the time you return, only seconds later, she is so absorbed in a book that you are not sure if she even noticed you serve her.

        Eventually, in a flurry of old, dry paper, she leaves and you continue with your work.

        It is not till much later in the day, the time when you would expect the sky to be as dark as it always is, that something else truly grabs your attention.  A hunter, sitting in a corner of the room and shivering with more than the cold.
        """

        $c=11


    "Yes, just yesterday a flock of giant, winged wolves took me to their sky palace and offered me tea.":
        $c=10
        elisabetta "Oh really?  That's incredible!  A flock?  How many?  How did they fly?  Actually, what were their wings like?  Did they have large wingspans or small?  Which would affect how much they would need to flap.  I must sketch them!  And their palace, where was it?  Was it made out of clouds?  Do you believe it is permanent?  And how did they brew the tea, and what type of tea?"

        """

        Elisabetta keeps asking questions as she pulls out a quill and a bottle of ink and proceeds to, badly, sketch out the details you can pass her in her occasional pauses.

        If at any point she realises that everything you are telling her is completely untrue, she never shows it.  She just continues to ask her amazed, earnest questions, even occasionally pausing to allow you to answer one.

        Eventually she is satisfied, although most of her questions still go unanswered and she declares that she has much research to do.  Then, with a flurry of old, dry paper, she is gone.

        It is not till much later in the day, the time when you would expect the sky to be as dark as it always is, that something else truly grabs your attention.  A hunter, sitting in a corner of the room and shivering with more than the cold.
        """

        $game.town_stability -=2

        $c=11


if c == 1:
    "Elisabetta's eyes go wide."

    elisabetta """

    Oh, oh that sounds very significant!  I wonder if it's an illusion or if you are actually magical?  And if you are magical, where does this magic come from?  What could the alteration of the outcome of a story have to do with the darkness?

    And how do we confirm any of this?

    Oh, I've had an idea!  An experiment!  Why don't I tell you about what I did earlier today and we can see if you can do anything different with it.

    So, let me think, I was going for a walk by the riverbank …
    """

    "You are there, you are her, before she finishs her sentence."
    hide elisabettaimg with dissolve
    window hide
    hide inn with dissolve
    with Pause(1)
    show text "Elisabetta" with dissolve
    with Pause(2)
    hide text with dissolve
    window show
    show woods zorder 1 with dissolve
    """

    You're standing by the river, aware on one level that the cold snow is piercing through the thin, decorative fabric of your clothes, but on all other levels too preoccupied with your thoughts to care.

    The night sky is beautiful above you.  It's constant, eternal, predictable.  You let out a long breath, allowing some of the tension that is pulling at your chest to dissipate.

    The night sky looks back, resolute.  You don't let your eyes leave it.  If they look down, you'll see the snow, the dying trees, the dark, emptying town.  You'll see the confusion and fear and death.

    The night sky looks back, unchanging.  It does not weep into its pillow on those nights that it cannot justify its hope.  It does not fear at all.

    The night sky looks back, uncaring.  Isn't that sad?  Because imagine if it does care.  Imagine if something so great, so wondrously stable looked down now and saw you?

    The night sky looks back, unknown.  Why not?

    The night sky looks back, powerful.  Why is it here when the sun is gone?  Of all the changes that have happened, of all the loss and suffering, surely it is the night sky that has won?

    The night sky looks back, victorious.

    You find you have been holding your breath and you let it out, feeling the cold now as you suck air back in.

    You're cold and alone.  Your mind rings and reels, on the edge of something grand.  You need to clear it, push it aside.  Then the truth will win out and the revelation will come to you.

    For now, you need something else.
    """

    $game.occult_connection +=4
    menu:
        "Go back home and sit by the fire.":
            $c=2
            hide woods with dissolve
            show inn zorder 3 with dissolve
            "Young Man"  "Sorry, is the stew ready?"

            "You stare blankly at the young man opposite you.  Elisabetta, and her books, are nowhere to be seen."

            "Young Man"  "It's for Miss Elisabetta.  She said she's thought of something wonderful and doesn't want to leave her house while she's thinking about it.  Is it ready?"

            "You jolt upright and instinct takes over.  In other words, you do your job: you apologise for the confusion and fetch the man his soup."

            $c=5


        "Find some friends to talk to.":
            $c=3
            hide woods with dissolve
            show inn zorder 3 with dissolve
            elisabetta "Oh really!"

            """

            You blink.  Elisabetta laughs loudly at what you presume was some outrageous story some other young person just said.  You don't hear the reply to Elisabetta's outburst.  Her group is sitting too far away from you for you to hear anyone but Elisabetta.

            The books are gone.  When she glances over to see you staring, she pulls a little face to show her awkwardness and confusion and then looks away.

            She doesn't remember.  That much is clear.
            """

            $c=5

        "Go and join one of the work parties doing something actually useful.":
            $c=4
            hide woods with dissolve
            show inn zorder 3 with dissolve
            "Worker"  "Five shots please."

            "You stare blankly at the woman opposite you.  Elisabetta, and her books, are gone."

            "Worker"  "Umm, five shots?  Please?"

            """

            You jolt upright and instinct takes over.  In other words, you do your job: you apologise for the confusion and fetch the woman her shots.  She takes them to a back table, where she hands them out to a group of other workers.  And Elisabetta.

            When Elisabetta glances over to see you staring, she pulls a little face to show her awkwardness and confusion and then looks away.

            She doesn't remember.  That much is clear.
            """

            $game.town_stability +=3
            $c=5
    
    """

    It's real.

    One moment she was standing there, telling you her story and you got a bit ahead of it, imagined what would come next, and then she was gone and it had happened.  Just like with the Nightwatcher and the stag.  Just like the fisher and the statues.  And just like Mik?  Had that also been you?

    Your mind is lost in thought while your body is busy with work.  You hardly speak to your customers and more than once you notice Henryk looking at you with concern.

    It is only towards the end of the day that a customer finally makes you come out of your own thoughts.  A hunter, sitting in a corner of the room and shivering with more than the cold.
    """

    $c=11
hide elisabettaimg with dissolve
"""

Their eyes are pleading when you approach.  You've seen the look before.  You're not sure if it just comes with working behind a bar, or whether Henryk's bar is special, but people come here to talk.  Henryk always listens and it became clear quickly that people expected you to do the same.  

As long as you never tell.  That is the sacred rule.  Literally.  You are sure it was no coincidence that when Henryk made you promise that you wouldn't repeat stories told to you by patrons, he was sitting directly beneath the icon to Alexis beside the bar.

You do not know if this hunter knows about that rule, that promise, but their look tells you instantly that they need to speak to someone, but they do not want anyone to hear.  Given that that's impossible, you are the next best thing.

So you take their order, and ask what's wrong, and with a look of gratitude and very little preamble, they begin.  And you, again, fall straight into the story.
"""

$game.status_manwolf = 'empty'

hide inn with dissolve
call the_manwolf from _call_the_manwolf
show inn zorder 3 with dissolve

if game.status_manwolf == 'saved':
    "The hunter blushes, embarrassed."

    "Hunter"  "I'm sorry, I don't know why I told you that.  I guess, I just had to tell someone, but I know no-one would believe me.  Just forget about it, please?"
    
else:
    "The hunter buries their head in their hands."

    "Hunter"  "I shouldn't have told you.  I shouldn't have told anyone.  What's that … thing, what's it going to do now?  I know only bad will come of this.  I should have kept it to myself."


"""

The hunter gives you a look, one you have also grown to recognise.  The sharing is over, the moment has passed.  You are a server now, nothing more, and the story will go no further.

Or at least, that is what you then believed.

"""
hide inn with dissolve
show bedroom zorder 3 with dissolve
"""

You startle awake from a dream of ice and snow.  In a moment your mind sorts through everything that happened last night: you finished work; you got home; you went to bed.  All normal.

Your eyes have adjusted to the darkness now and the first thing you notice is your front door hanging off one hinge.  The second thing you notice is the eyes staring back at you.

They're at your level and dark in a way that human eyes can't be.  The shadow behind them confirms it: a dog.  Or something slightly larger.

A wolf.

No, not quite.

It is in a different skin since the last time you saw it.  But then again, so are you.

But even so, even as a wolf, you recognise the man you saw naked in the forest.
"""
if game.status_manwolf == 'saved':
    """
    It takes a step backwards when it sees you jolt awake and sits down on its haunches.

    Then it starts to cough, its body strangely still, quite unlike a dog trying to dislodge something from its throat.

    And then it speaks.  It has to say its first sentence multiple times before you realise that it is attempting to form words, but one whine or gurgle or growl at a time, you begin to understand it.
    """

    "Wolf"  """

    I was dead.

    The slaughterer showed me there was no hope.

    Then he showed me that there was.

    But no.  It was all temporally concurrent.  And only the latter happened.  But I {i}know{/i} the other happened.  I can smell its power-scent.

    It led me to you.

    """
    if game.status_stag == 'Alive':
        "Wolf" "It was you.  The shining prey beast knows it too.  He was here, I smell his real-scent and his power-scent.  You are a friend of our kind.  The night born."
    else:
        "Wolf" "It was you.  The blood-filled prey beast knows it too.  She was here, I smell her real-scent and her power-scent.  You were her enemy, but my friend."
    "Wolf" """
    You are like us.  You are night born.  But my body changes and the prey beast's body has changed, but you change everything.

    You remind me that there is more than good and bad.  There is different and same, and there is power and powerlessness.
    """
    
    "The wolf's ears suddenly twitch, hearing something that you can't.  It lets out a few more whines, but it does not have the time to repeat what it is trying to say, so its meaning is lost as it lopes out of your room."

else:
    """
    It starts to growl as soon as it spots that you have jolted awake.  

    Then it starts to cough, its body strangely still, quite unlike a dog trying to dislodge something from its throat.

    And then it speaks.  It has to say its first sentence multiple times before you realise that it is attempting to form words, but one whine or gurgle or growl at a time, you begin to understand it.
    """
    "Wolf"  """

    I was happy.  I had seen that there was meaning.

    The slaughterer showed me that there was meaning.

    Then he showed me that there wasn't.

    But no.  It was all temporally concurrent.  And only the latter happened.  But I {i}know{/i} the other happened.  I can smell its power-scent.

    It led me to you.
    """
    if game.status_stag == 'Alive':
        "Wolf" "It was you.  The shining prey beast knows it too.  He was here, I smell his real-scent and his power-scent.  You are a friend to him, but not to me."
    else:
        "Wolf" "It was you.  The blood-filled prey beast knows it too.  She was here, I smell her real-scent and her power-scent.  You were an enemy to both of us."
    
    "Wolf" """
    You betrayed your nature.  You betrayed your kin when you betrayed me.  I can only think small thoughts of the meaning I should have.  You took it from me.

    But you also reminded me that there is more than good and bad.  There is different and same, and there is power and powerlessness.

    My body changes and the prey beast's body has changed, but you change everything.
    """
    "The wolf's ears suddenly twitch, hearing something that you can't.  It lets out a few more whines, but it does not have the time to repeat what it is trying to say, so its meaning is lost as it lopes out of your room."


hide bedroom wtih dissolve
return