### DAY ONE

label day_one:
image inn = im.Scale("inn_image.png", 3072, 1920)
$inn_name = "The Wolf and Wheel"
window hide
with Pause(1)
show text "Day One" zorder 5 with dissolve
with Pause(2)
hide text with dissolve
window show
"""


The morning's first bell leaves your dream as nothing but a feeling.  A non-physical sense of warmth.  Maybe love.  Maybe success.  

Your eyelids stay closed but you feel no light behind them.  In two weeks, that has become expected.  It's just the way the world is now.

The bells stop ringing.  You live close to the tower, its immobile clock-face frozen since long before the sun stopped making its way across the sky.  You are told that hours still go by, but you no longer see them go.  

Enough of the philosophy.  Your eyes are heavy and the air on your face is much cooler than the air under your sheets.

Nat, the town crier, will be past soon, shouting out the news of the new day for anyone who missed the bell.  Henryk likes you to be at work before Nat's finished.  Breakfast is one of the busiest times of day at [inn_name] and breakfast comes early, what with all the work that must be done by the hunters, gatherers, fishers and, well, everyone.

But it's {i}possible{/i} that you could have slept through the bells.  The feeling of the dream calls for you, its hold on your mind slipping, letting you know that the dream it represents will be gone forever if you don't give in to it now.
"""
menu:
    "Sleep until Nat wakes you up.":
        $c=1
        """

        A world fades, reality becoming images, images becoming sensations, sensations nothing but impressions by the time your eyes have opened.  Nat's hand-bell and high, child-like voice pierce through your thin window.
        """
        show bedroom zorder 3 with dissolve 
        """
        You have no more excuses.  You are dressed in minutes, tying your work apron on under your furs, partly to save time, partly for the slight extra warmth it will provide on the short walk to the inn.  Perhaps the hunters, gatherers and fishers are used to the cold that this unchanging darkness has brought, but you move from your own fireplace to the inn's each day and so the freezing outside air still bites.
        """
        hide bedroom with dissolve
        show inn zorder 3 with dissolve 
        """
        Your boss, Henryk, is, of course, already there when you arrive.  The fire is already roaring and the stove almost hot.  Three early customers stand at the bar, the town's night watch, just relieved from their duty.  In conversation with them, Henryk does nothing more than give you a disappointed glance as you hurriedly shake off your coat and move into the small kitchen.

        There is much to get ready and you do a sloppy job of it.  Still the food, mostly fish and game and not much of either, is hot and more often than not that is all that your customers can ask for.  Henryk frowns at you when he comes through to help you serve, but again, he says nothing.  He knows he doesn't have to.  
        """

        $game.town_stability -=2
        $game.occult_connection +=1

        $c=3


    "Let the dreams go and go to work.":
        $c=2
        show bedroom zorder 3 with dissolve 
        """

        You push the dream away and as soon as you have made the decision it is gone forever.  

        You are dressed in minutes, tying your work apron on under your furs, partly to save time, partly for the slight extra warmth it will provide on the short walk to the inn.  Perhaps the hunters, gatherers and fishers are used to the cold that this unchanging darkness has brought, but you move from your own fireplace to the inn's each day so the freezing outside air still bites.
        """
        hide bedroom with dissolve
        show inn zorder 3 with dissolve 
        """
        Your boss, Henryk, is, of course, already there when you arrive, bending awkwardly over the main fireplace.  He smiles when he sees you and gracefully lets you take the flint from his hands while he moves back to the bar to get ready for the first customers of the day.

        Soon the room is warm and the stove is hot and you have begun cooking the morning's breakfast while Henryk entertains three Nightwatchmen taking a quick drink before bed.

        You hear the people of the town file in while you are putting the finishing touches to the food, mostly fish and game.  You and Henryk serve together.
        """

        $c=3

"""

Then the first wave of the morning rush is over and Henryk is circulating around the busy tables while you are left with the usually empty bar.  Except today it isn't empty.  One of the nightwatch is still here, her scabbed hands encircling a glass of moonshine; her coat, still clogged with white snow, lying on a stool beside her.

Whether it's out of curiosity, friendliness, worry or just because it's your job, you approach her, absent-mindedly wiping the already spotless bar.  'Tough night?' or 'You okay?' or something equally asinine falls from your lips and she looks up.
"""

"Nightwatcher"  "I was on perimeter watch.  I'm not really supposed to go into the forest, but I've done some hunting and … and I thought I saw something."

"""
The nightwatcher's story is immediately gripping.  But it is more than just her words.  You have never felt this before.  You find yourself slipping beyond her voice, beyond anything that she is saying.  Beyond what is around you.

You find yourself there.  Standing in the snow, her hard leather shoes rubbing uncomfortably against your heel.

And then you feel a brief moment of panic as you feel her mind.  Her thoughts.

But then you are there, the Wolf and Wheel gone, and you are standing beneath the trees.
"""



hide inn with dissolve
call thestag from _call_thestag
show inn zorder 3 with dissolve
if game.status_stag == 'Alive':
    "The woman smiles and finishes her mug of herbal tea."

    "Nightwatcher"  "I don't feel at all like sleep, but Tamara will be waiting for me and I can't keep her waiting."

    """
    The Nightwatcher winks at you and then shakes your hand.  Her skin is as soft as velvet.

    Then she is gone and you are staring down at her mug, the feel of her skin against yours vibrating through your nerves.

    You are back.  Suddenly, brutally, yourself again.
    
    Something is wrong.
    """

    henryk "She enjoy her tea?  Usually drinks the hard stuff, nice to see her branching out."

    "It is a passing comment and Henryk is gone before you can question him further.  Then the breakfasters start to leave and you have clearing and washing to fill your attention."
else:
    """
    The woman sighs and knocks back the last of her drink.
    
    You are back.  Suddenly, brutally yourself again.
    
    Something is wrong.
    """

    "Nightwatcher"  "I am sorry about the glass.  And the stool."

    "She pulls a face when she looks between her hands and her coat, both of which are still coated red with glistening, wet blood."

    "Nightwatcher"  "I am sorry.  I'll make sure Mik sends over extra of the meat.  Have a good night!"

    """
    And then she is gone, leaving you rushing to mop up as much blood as you can before it soaks into the wood, wondering how you had not notice it before.

    But you had, hadn't you?  Not the blood but the hands and the coat.  You had looked, hadn't you?  This was wrong, wasn't it?

    You stand up and squeeze the last of the red-stained water into a bucket.  The breakfast crowd is leaving.  Clearing and washing take your attention.
    """
"""
Then the morning rush is gone, along with any sign that they were ever there.  You get the lunch cooking and then serve the few customers who have trickled in after the rush.

A young man, one of the people sent into the forest or off to the river you would guess, sits at the end of the bar, flicking through a book.  You stand opposite him for some time, either intentionally or not, watching at least the diagrams and illustrations on the well-worn pages flip by.  You can't make much sense of them.  Symbols, possibly flags, and geometric shapes with arrows.

Eventually he notices and looks up.  He blushes and his hands twitch as if to snap the book shut, but he hesitates and smiles sheepishly.
"""

"Fisherman"  "Don't worry, I know I'll never be a soldier."

"He obviously sees your confused look, because he clarifies."

"Fisherman"  """

It's a military record.  I think.  I don't really know much about this stuff, but the Alderman's maid lent it to me.  I'm looking for something specific.

It's important!  I think.  Well, I saw something yesterday.  I think.  Listen, I …
"""
"""
His words fade quickly.  The bar fades with them.

Again.  Whatever {i}it{/i} is, it's happening again.

You feel the calluses of his hard worked hands.  You feel the emptiness of his belly, the pain of his frostbitten toe.

You are him, standing on the river bank.
"""


hide inn with dissolve
hide ssnow
call thestatues from _call_thestatues
show inn zorder 3 with dissolve

if game.status_statues == "Bullet":
    $insert = "examining the bullet"
elif game.status_statues == "Egg":
    $insert = "examining the egg"
elif game.status_statues == "Clean":
    $insert = "examining his cut and slightly frostbitten hands"
else:
    $insert = "staring straight ahead of himself, not a single muscle in his body visibly moving"

"""
The man finishes his story and goes back to [insert].

You find yourself blurting out 'What happened to your book?', or something to that effect.  The man turns to you and cocks his head, as if you have said something that he simply can't make sense of.

Maybe you were about to say more, maybe you were going to simply brush it off, but whatever you were planning to do, you are not given the chance to do it.
"""
show natimg zorder 4 with dissolve:
    xalign 0.05 yalign 0.25
nat  "Hello [game.player_name]!  It's quite a pretty night out tonight isn't it?  Sky almost white there are so many stars!"

"You turn to see the town crier, Nat, settling himself onto one of the bar stools.  He smiles at you, but the moment that your eyes meet his he moves back slightly and his face falters.  Like a puppy unsure if what it has done is the right thing or not."

nat  "I'd like to get a bit to eat, if that's okay with you and Mr Henryk?"

"""

You don't have to check: of course it would be alright with Henryk.  You asked permission the first night - or the first day of the night or whatever it is that you're living through - and the emphatic 'Yes, of course, he's a good lad, give him what he wants' felt like permission to continue serving Nat on the house in perpetuity.

Nat, in a way, became a very important person when the sun disappeared.  He was the first to notice that the night didn't come to an end when it should have done.  But it was the reason he knew this, when the rest of the town simply thought he had finally snapped, which has lead to his importance.

He knows the time.  Lotosk has never had a clock; it almost did but the charlatan 'clockmaker' ran back south after doing nothing but putting a clock face into the top of the bell-tower.  Instead it had the sun - the guide that generations of Lotoskans had used without complaint - and Nat.  

While seconds and minutes and hours were little more than concepts for most Lotoskans, Nat had captured them and could give them back with shocking precision.  A day must have thousands of seconds in it, you muse as you stir the stew, but Nat could tell you exactly which one you were in without even thinking.

You bring him his food and he starts eating slowly.  The other man, the fisher, has already left, leaving Nat as the only customer at the bar.  And, by the way that he keeps glancing up at you, you can tell that he would enjoy talking.
"""


hide natimg with dissolve
hide inn with dissolve
hide ssnow
call crier_1 from _call_crier_1
show inn zorder 3 with dissolve
show ssnow zorder 2

if game.status_stag == "Alive":
    $insert2 = "clumsy."
else:
    $insert2 = "unhealthy."

"""

You watch Nat leave and then it's lunch.  The Alderman's 'chosen citizen' - the person the Alderman deputised when the sun disappeared, now, arguably, the most powerful person in Lotosk - comes in with a group of former farmers and you're rushed off your feet trying to serve them as quickly as possible.

The 'chosen citzen' - just a couple of weeks ago a normal member of society, just like everyone else - now can't be waiting a second longer than necessary.  

Henryk has you work the kitchen, and then the tables, and then the kitchen again.

The chosen citzen leaves and the atmosphere in the room noticably calms.

You talk to people, here and there, but as the afternoon turns to evening and the late shifts come in to drink and get warm before bed – all the time the darkness behind the windows remaining unchanged – you think more and more about the book and the nightwatcher's hands.

And then Nat rings the town bell and the day is over.  The customers leave, you and Henryk clean up, and now you are home.
"""
hide inn with dissolve
show bedroom zorder 3 with dissolve
"""  

You are not sure if you were just sleeping or awake.  You're cold and images of statues and snow are flitting through your mind.  And there is something at the door.

It is not quite knocking.  Yes, that is what it is trying to do, or at least, you cannot imagine anything else that it could be.  But the pause between blows is too long and each knock is followed by a scraping sound, as if whoever is on the other side is dragging something heavy across the wood.

The sound is [insert2]  The rest of your dream fades, but the knocking does not cease.  Your mind is clear and something is there.
"""

menu:
    "Open the door.":
        $c=5
        if game.status_stag == "Alive":
            show stagimg zorder 4 with dissolve:
                xalign 0.5 yalign 0.25
            """You open the door and stare into stars.  Swirling, infinite, set in a frame of shining white fur.  

            You and the stag stare at each other for a moment and then it elegantly places one of its front hooves forward, bending over it and presenting you with a deep bow.

            It straightens, fixing you once more with its eternal eyes, its body unmoving but the light it radiates pulsing.  You cannot help but feel that that movement of light is trying to tell you that the beast knows you and it wants you to know something about it in return.
            """
            menu:
                "Reach out and touch the stag.":
                    $c=8
                    """

                    You feel the moisture on its nose.  

                    Morning dew.  

                    You feel the fur, powdered snow and velvet.

                    You gasp.

                    It is just like the nightwatcher said.

                    It is just like the nightwatcher felt.

                    It is just like what you felt.
                    """
                    hide stagimg with dissolve
                    """
                    The next sensation you can fully comprehend is the feeling of your sheets and the realisation that they are rough and cold, yet you feel nothing but softness and warmth from them.

                    And then there is sleep.
                    """

                    $game.occult_connection +=2


                "Let the stag leave.":
                    $c=9
                    """
                    You stand in the glow, dimly aware that your mouth is hanging open, uncontrolled as you lose yourself in the beauty of the beast before you.

                    Then, in a flurry of snow somehow less pure than its coat, it is gone back towards the forest; leaving you only with the certainty that what you just experienced was as far from a dream as anything you have ever seen.
                    """
                    hide stagimg with dissolve
                    $game.occult_connection +=1

        else:
            """Your eyes adjust quickly to the light of the stars and you quickly make out the creature standing before you.

            A doe.  Maybe slightly small, but you are no expert.  Its coat is a dirty white, which you know is unusual, but despite the shining black eyes, the animal's thin and slightly sickly look mean that the only feelings you can really muster for it are pity and disgust.

            The doe does two things simultaneously.  It slowly but firmly leans the front of its head against you and it opens its mouth.

            From your angle, the first thing you are aware of is warmth.

            It soaks into your clothes and runs down your skin.  At first you think it must be spit, but you realise too late that it is flowing too freely.

            You notice the colour of the liquid as it pools around your feet and between your legs.  Dark.  Black, until a star catches it and you see a flash of darkest red.

            The doe makes a choking sound, its body shaking as something warm hits you and the blood coming from its mouth starts to come faster.

            Instinctively you take a step back.  The deer simply stands there, its dark eyes not turning to look at you as blood falls from its mouth.

            You are not sure how much time has passed before it turns and leaves.  It does so without ceremony, it just simply ceases the flow and turns around, leaving nothing but a spreading pool of blood and a set of ruined clothes as signs that it had ever been there.
            """
            $game.occult_connection +=2



    "Look out of the window.":
        $c=4
        if game.status_stag == "Alive":
            show stagimg zorder 4 with dissolve:
                xalign 0.5 yalign 0.25
            """You draw back the curtain and stare into stars.  Swirling, infinite, set in a frame of shining white fur.  

            The stag gently knocks one silver prong of its shining antlers against the glass of your window, filling the air inside your room with a soft tinkling sound.

            You lean forward, your breath almost fogging your view as the great beast turns and elegantly places one of its front hooves forward; bending over it and presenting you with a deep bow.

            It straightens, fixing you once more with its eternal eyes, and then, in a flurry of snow somehow less pure than its coat, it has gone back towards the forest, leaving you with only the certainty that what you just experienced was as far from a dream as anything you have ever seen.
            """
            hide stagimg with dissolve
        else:
            """Your eyes adjust quickly to the light of the stars and you quickly make out the creature standing at your door.

            A doe.  Maybe slightly small, but you are no expert.  Its coat is a dirty white, which you know is unusual, but despite the shining black eyes, the animal's thin and slightly sickly look mean that the only feelings you can really muster for it are pity and disgust.

            After a moment its head twitches and for a second your eyes meet.  Then, with clear effort, it lifts its front leg up and knocks it against your door again.

            You see no intelligence in that infinitely deep, infinitely black eye.  But it is clear nonetheless that the creature is not leaving until you open the door.
            """
            menu:
                "Open the door.":
                    $c=7
                    
                    """

                    You open the door and for a moment you and the doe simply stare at each other.

                    Then it does two things simultaneously.  It slowly but firmly leans the front of its head against you and it opens its mouth.

                    From your angle, the first thing you are aware of is warmth.

                    It soaks into your clothes and runs down your skin.  At first you think it must be spit, but you realise too late that it is flowing too freely.

                    You notice the colour of the liquid as it pools around your feet and between your legs.  Dark.  Black, until a star catches it and you see a flash of darkest red.

                    The doe makes a choking sound, its body shaking as something warm hits you and the blood coming from its mouth starts to come faster.

                    Instinctively you take a step back.  The deer simply stands there, its dark eyes not turning to look at you as blood falls from its mouth.

                    You are not sure how much time has passed before it turns and leaves.  It does so without ceremony, it just simply ceases the flow and turns around, leaving nothing but a spreading pool of blood and a set of ruined clothes as signs that it had ever been there.
                    """
                    $game.occult_connection +=2



                "Go back to bed and try to sleep through the knocking.":
                    $c=6
                    
                    """

                    You wake up tired, the sound of knocking still echoing in your head.

                    No, no that isn't a dream.  The sound is faster and thinner.  It is a person and they are knocking on your window.

                    You get out of bed and pull the curtain aside to see your neighbour, wide-eyed, glancing between you and your front door.

                    When you open it, you see why she looked so concerned.  Long trails of blood have frozen into the wood and pooled into the snow, like a swarm of giant bleeding slugs had slithered down your door from about chest height and melted into clots of blood at its foot.

                    There is so much of it.  More than you could imagine being inside any man.  But there is no sign of a body of any kind.  And, from the hoof tracks that lead both to and from your door, it is clear what left this here.

                    Your neighbour has questions, but, tired and possibly unsettled, you brush them off.  You will be tired and dirty by the time you are done cleaning this all up.  You will be late for work.  But you know you can't leave this here.
                    """

                    $game.occult_connection -=2
                    $game.town_stability -=2



hide bedroom with dissolve

return