Constant STORY "GSimple 2";
Constant HEADLINE "^GWindows Demonstration Program 2: Basic Layout Continued^";
Constant DEMO 2;
Constant PURPOSE
          "This program shows a very simple
           GWindows layout, inverting the standard layout.^";

! GWindows Demo program.
! This demo takes the code from demo 1 and changes it by placing the status
! line at the bottom.

! Include Gwindows Definitions
include "gwindefs";
include "parser";
include "verblib";
! Include GWindows base classes
include "gwincls";
! Include GWindows hooks
include "gwindows";
include "grammar";

! Include GWindows predefined widgets
include "gstatus.h";

! InitGWindows.  This is where you set up the active interface and the
! main window
[ InitGWindows;
 Active_UI=top;
 Main_GWindow=mainwin;
];

! The window model. To emulate the standard layout, we use one windowpair,
! which holds the status window and the main window. To reverse the order
! of the windows, we set stautswin's split_dir to wintype_Below (its default
! is wintype_Above)
WindowPair top;
 Textbuffer -> mainwin;
 GStatusWin -> statuswin
  with split_dir winmethod_Below;


object r1 "Test room"
 with description "This is a primitive room. Its only purpose is to give the
        user somewhere to be while viewing this GWindows Demonstration",
 has light;
[ Initialise;
 location=r1;
 print "^^^Welcome to GWindows demo program ", DEMO, ". ",
        (string) PURPOSE, "^^";

];