The Empire is growing.

From the humble country of Monaire sprang an unexpected and seemingly unstopable force that has consumed the entire eastern portion of the continent.
It's said that at the reigns stands none other than the mortal incarnation of Dain, the God of Success.
Beside him stand three terrifying presences responsible for carrying out his whims. These are the Reavers.

With a powerful and immortal being serving as Emperor, how could the relentless expansion of the Monaire Empire ever be stopped?

*page_break
Resonance

A fantasy ChoiceScript game by Nereida Scales.
*label thestart
*page_break
You stare down at the note that Reaver Harking had sent to your room upon your arrival to the Imperial Palace.

You've never been invited to a meeting with the Emperor before, nor do you particularly have the energy to do so after your long journey.
Still, you don't have much of an option as to whether or not to attend, as you're certain that the two guards standing outside of your door have been ordered to drag you there if they have to.

You are an Executor for the Monaire Empire, Second-in-Command to the prestigious Reaver Gillen Harking.
While your rank is high, Reaver Harking's insistence that you stay out of the public eye has left you with little reputation to show for it.
In fact, you do little more than play messenger between your direct superior here in the palace, and his army's general out near the western borders.

Being an Executor wasn't your choice and you were moved into the position without your prior knowledge or consent, though, there are worse things you could be doing in the Empire.
*page_break
A meeting with a god was never something ever expected to deal with.

While there are tales in the history of this continent of various gods entering the mortal realm, it's not known to be a common occurrence.
Due to Emperor Dain's elusive behavior, rumors have developed implying that he is simply a man pretending to be a god, or that he may not even exist at all.

You, personally, have never seen the man, but it seems that you're about to find out the truth.

*label startgame
You stare at the note again. From the wording, it's very clear that Reaver Harking expects you to attend formally attired.

*choice
  #As a gentleman, I'd be expected in a well tailored coat...
    *set gender "Male"
    *goto choocloth
  #A lady such as myself really ought to wear a fine gown...
    *set gender "Female"
    *set male false
    *set female true
    *set mister "Miss" 
    *set he "she" 
    *set him "her" 
    *set his "her" 
    *set lord "Lady"
    *set guy "girl"
    *set man "woman"
    *set sir "ma'am"
    *goto choocloth
*page_break
*label choocloth

It's clear what's expected of you, but you currently hold the third highest rank in the Empire. It's certainly not impossible for you to get away with a few things here and there.

*choice
  #That's right. I stay in my everyday traveling clothes.
    A comfortable choice, although you're reasonably sure that Reaver Harking won't be happy about this.
    
    You make your way to the palace reception hall.
    *set cloth "norm"
    *set girel %- 10
    *set rebel +5
    *goto dressed
  #I still have my military uniform from when I was actively in the Imperial Combat Forces. That wouldn't be completely improper.
    While an Executor technically isn't part of the Imperial Combat Forces, the Empire remains a martial government.
    
    You get dressed and make your way to the palace reception hall.
    *set cloth "uni"
    *set rebel +2
    *goto dressed
  *if male
    #I'd better stick to the coat. While a bit stuffy, formalities can't just be ignored whenever I feel like it.
      Probably a wise decision.
      *set girel %+ 10
    
      You get dressed and make your way to the palace reception hall.
      *set cloth "maleform"
      *goto dressed
  *if female
    #I'd better stick to the gown. While a bit stuffy, formalities can't just be ignored whenever I feel like it.
      Probably a wise decision.
      *set girel %+ 10
    
      You get dressed and make your way to the palace reception hall. 
      *set cloth "femform"
      *goto dressed
*label dressed
While most of your assignments had you traveling to countries outside of the Empire's borders, you have a reasonable understanding of the palace's layout.

You've been given a small room in the guest wing for the brief periods of time between your assignments. Reaver Harking's quarters and office are on the floor above the guest rooms. You are fairly sure that the opposite side of the palace is used for military training, and the center area near the main entrance hall is used for administrative things. The exact location of the reception hall eludes you, though.

Luckily, you spot Reaver Harking standing near a set of imposing double doors as soon as you step into the entrance hall.
A notably calm and considerate man with strikingly statuesque features, he always seemed rather distant toward you.

As with other Reavers, you've heard stories that he is a terror on the battlefield, however, you've rarely seen the man leave the Imperial Palace, and you've never seen him in combat.
He is rigidly formal and somewhat severe in everything he does, although you've noticed that he is slightly more lenient toward you than anyone else.

*if cloth="norm"
  "Reaver Harking," you greet as his eyes turn to you, "Is-"
  
  "Change. Immediately," he sternly interrupts, brow furrowing.
  
  It's clear from the tone of Harking's voice that he expects you do as he says without argument.
  *choice
    #I don't care what he expects. I silently stand my ground.
      You stubbornly stand there, unspeaking. Reaver Harking, however, doesn't flinch.
      *set rebel +5
      *set rebelcount + 1
      
      *goto meetingbad
    #I argue the point. I didn't want to be here anyway.
      "What does it matter?" you grimly question.
      *set rebel +5
      *set girel %- 5
      *set rebelcount + 1
      
      "It matters because I'm trying to help you," he plainly explains, "I don't understand why you're so intent on making that difficult on me."
      
      "I'm not intent on anything, Reaver Harking," you frown, crossing your arms, "Maybe I just want to do what I want to do without being ordered around for once."
      
      *goto meetingbad
    #I don't want to get in trouble. Maybe I should just do as ordered.
      Silently, you turn right around and return to your room. You've never seen Reaver Harking angry before, but you imagine it wouldn't end pleasantly for whomever was unlucky enough to face his wrath.
      *set rebel -5
      *set girel %+ 5
      
      As you change into something more formal, it occurs to you how little say you actually have had in your own life since you started your service to the Empire. While following the orders handed to you hasn't led you anywhere too horrific, the distinct lack of personal choices or regards to your opinion can be a bit stifling at times. You shake the thought from your head as you quickly return to the reception room's doors.
      
      Reaver Harking says nothing as he opens the door for you, but looks a bit... relieved, maybe? Less aggravated, at least.
      *goto meeting
*elsif ((cloth = "femform") or (cloth = "maleform"))
  "Reaver Harking," you greet as his eyes turn to you, "Is my presence here really needed? I mean-"
  
  "Absolutely," he immediately answers, a small semblance of a smile on his face. "Actually, since this meeting is concerning you, you may want to take a personal interest in it."
  
  "Me? But I'm-"
  
  Reaver Harking opens the large wooden door for you, forcing you to stop speaking lest the Emperor hear anything like a complaint coming from you.
  *goto meeting
*else
  "Reaver Harking" you greet as his eyes turn to you, "Is my presence here really needed? I mean, you did say I should stay out of important Imperial matters..."
  
  He doesn't immediately respond, giving you an appraising look instead. "You do realize you aren't in the Imperial Forces any longer, do you not?" he quietly asks moments later.
  
  "Technically," you respond, "I'm aware."
  
  He pauses again, the slightest look of displeasure easily recognizable to you on his face. "To answer your question, yes, you're needed. It would be better if your situation changed."
  
  "Changed to what?" you inquire, though "better for whom" is probably what you should be more concerned about.
  
  Reaver Harking avoids your question by opening the large wooden door and gesturing for you to enter.
  
*label meeting
*page_break

You enter the reception hall to find that it's significantly smaller than you had expected. The furnishings were tasteful enough, though they seemed lacking considering this was in the palace of the grand Monaire Empire. The first person you notice as you walk through the room is a man in rather flashy black and red armor to your right. He lets a disarming smile show as you glance his way.

Reaver Harking follows in and immediately steps past you. "Dain," he nods toward a second, finely dressed man in the room.

Emperor Dain?

This is the supposed god who started this empire?

You turn your attention toward the Emperor. You've never seen him before, but he looks... human. Normal. Perhaps he really is just a man after all...

"Gillen," the Emperor returns Reaver Harking's greeting.

And since when is someone able to be on a first name basis with the Emperor?

"Please allow me to present my Second," Harking starts gesturing to you, "In ${his} service to me, ${he}'s performed remarkably dutifully. Therefore, I'd like to nominate ${him} for the position of our newest Reaver."

You are slightly taken aback by this statement.

New Reaver? You?

The Reavers of the Monaire Empire were among the most influential and respected people in the continent, and Reaver Harking thought to make you one of them, an equal to himself?

"I..."

You begin to speak, but fall silent when you notice the Emperor's eyes on you. Though you had thought him to look completely normal before, his current expression seems utterly cold and emotionless. It's impossible to tell if he's disappointed, curious, amused, or just doesn't care.

"Objections?" the Emperor asks, shifting his focus to the man to your right.

"Nope," the armored man replies, holding a steady grin.
*goto newtitle
*label meetingbad
"You know I only tell you to do anything if it's in your best interest," he calmly explains, "I wish you wouldn't fight me on-"

His voice dies down as the door next to him quietly clacks open. After a moment, he gestures for you to enter the room, though he is obviously displeased with the situation.
*page_break

You enter the reception hall to find that it's significantly smaller than you had expected. The furnishings were tasteful enough, though they seemed lacking considering this was in the palace of the grand Monaire Empire. The first person you notice as you walk through the room is a man in rather flashy black and red armor to your right. He lets a disarming smile show as you glance his way.

Reaver Harking follows in and immediately steps past you. "Dain," he nods toward a second, finely dressed in the room.

Emperor Dain?

This is the supposed god who started this empire?

You turn your attention toward the Emperor. You've never seen him before, but he looks... human. Normal. Perhaps he really is just a man after all...

"Gillen," the Emperor returns Reaver Harking's greeting.

And since when is someone able to be on a first name basis with the Emperor?

"Please excuse my Second," Harking starts with strained severity, "I had hoped to nominate ${him} as the new Reaver, but ${he} seems uncooperative today."

You are slightly taken aback by this statement.

New Reaver? You?

The Reavers of the Monaire Empire were among the most influential and respected people in the continent, and Reaver Harking thought to make you one of them, an equal to himself?

"I..."

You begin to speak, but fall silent when you notice the Emperor's eyes on you. Though you had thought him to look completely normal before, his current expression seems utterly cold and emotionless. It's impossible to tell if he's disappointed, angry, amused, or just doesn't care.

"Obviously, I can't recommend ${him} in good faith, now," Reaver Harking continues.

"I'll nominate ${him}," you hear the armored man to your right offer.

You shoot a questioning glance at the man who just nominated a total stranger.

"Gillen can't do it because'a his honor, or code, or whatever it is he bases his decisions on," he continues, his explanation clearly directed to you, "But it doesn't bother me what ${he} looks like. If ${he}'s good enough for Gillen to consider nominating, ${he}'s good enough for me."

"Objections?" the Emperor asks, shifting his focus to Reaver Harking.

"None," Harking answers without much consideration.

*goto newtitle
*label newtitle

"Then I believe we have a new Reaver," the Emperor calmly declares.
*set title "Reaver"
*set rank "Reaver"

With those words, the newest chapter in the story of your life begins.

*page_break

After the meeting, on your way back to your room, you think back to the events that brought you into the Monaire Empire in the first place.

*choice
  #I was born here, and joined the Imperial Combat Forces as soon as I was old enough.
    *set origin "Monaire"
    *set combat +10
    *set intel +5
    *set renown +5
    *set inspiring +5
    *set sword +10
    You were born in the eastern country of Monaire, before Emperor Dain took control and evolved it into the superpower it is today.
    
    When the call came for citizens to join the efforts of the Temple of Dain and help unite the war torn continent into a peaceful Empire, you wanted to jump at the chance. Of course you were still young at the time, and had to wait a few years before you were able to join the Imperial Combat Forces. You can still remember how proud you had been the day you were given your first post as an Imperial guard. 
    
    It wasn't until sometime after your promotion to a guard captain that you met Reaver Harking. He was quick to praise your dedicated service to the Empire, and wasted no time in making you his Second. 
    *goto nametime
  #I'm a professor from a continent far across the western ocean. Unfortunately, a shipwreck left me stranded in this foreign land.
    *set origin "Ehl"
    *set intel +25
    *set renown +5
    You were born in the technologically superior Ehl Imperium across the ocean. Being an expert linguist, you were invited to join an envoy that was to make first contact with this continent. It was a stroke of bad luck that caused a violent storm to tear your ship apart and leave you with no knowledge of what happened to your fellow travelers. 
    
    With no way to get back home, you've managed to carve out something of a life in this rustic land. While living in the Monaire Empire was no where near as easy as living in Ehl, you've managed surprisingly well. Many of the cultural practices that you've learned of, however, seem strange and crude to you. Furthermore, it seems that many people don't know what to make of the Ehlish coloration of your skin, causing them to ask odd questions, or outright avoid you in most situations. 
    *goto nametime
  #The Empire is a blight on this continent. Being a part of it was never my choice.
    *set integrate true
    *set rebel +5
    *set inspiring +5
    *set rebelcount + 1
    Oh? Then what was your life like before you were in the Empire?
    *choice
      #I was a Sage of the Temple of Anoe, in the western region of the continent. The Empire completely took over my country and left me with no real "home" to go back to.
        *set origin "Capel"
        *set magic +10
        *set renown +10
        *set intel +10
        *set inspiring +5
        You were born in the country of Capel, under the blessing of the goddess of fate. When it was discovered you had the magical talents of a Sage, you were placed under the care of the Temple for training. What happened to your family during the invasion is unclear, but your Temple lies in ruins, all of it's Sages and priests executed.
        
        All of them except for you. Reaver Harking unexpectedly pardoned you from execution, though he's never told you exactly why you were the only one saved that day. Still, he managed to give you a place in the Empire; first, a relatively safe position as a guard, then as his Second.
        
        Despite lacking a Temple to belong to, those that learn of your status as a Sage are still rather respectful toward you. This has made many things in the Empire much easier for you. 
        *goto nametime
      #I was a painter in the atheistic northern country of Asylia. It was only because of the Empire's "integration" policies that I ended up here.
        *set origin "Asylia"
        *set intel +10
        *set inspiring +5
        You were born in the isolationist country of Asylia, where art and science were valued above all else. As a painter of remarkable talent, you were given the title of "Sirilas", meaning "one who inspires" in the old tongue. The title was held in the highest regard in Asylia, possibly on par with what the polytheistic nations of this continent consider "Sages". 
        
        Perhaps it is because of this unconventional thinking that your people were so brutally massacred by the Empire. Those that survived were forced into the Imperial military as little more than cannon fodder. It was only due to the intervention of Reaver Harking that you were able to escape the mass graves that awaited your people.
        
        While you haven't seen or heard news of your family since the initial invasion, you consider it very likely that someone in the Empire has to know something about what happened to your home. 
        
        Unfortunately, you possess a well known Asylian specific trait, vivid green flecks scattered throughout the coloration of your irises. While not immediately noticeable by most people, this has caused quite a bit of negativity to be hurled your way. 
        *goto nametime
      #I'm an Elf from the Sedel region to the south. I set out to stop the Empire before it could reach our people, but failed.
        *set origin "Sedel"
        *set combat +25
        *set renown -5
        *set inspiring +5
        *set rebel +10
        *set unarmed +1
        *set sword +10
        *set bow +10
        The goddess wasn't with you the day that you faced Reaver Triolo at his camp near Sedel. Despite your best efforts, the man managed to defeat you soundly without much strain on his abilities. By the time you finally came to, you found yourself locked in a dungeon to rot.
        
        It was only by the grace of Reaver Harking that you were spared that miserable fate. In exchange for your allegiance to the Empire, he promised you your freedom and the immunity of your people from the war. While your service to the Empire has hardly been what you'd call "freedom", the Elven lands have remained untouched by this conflict.
        
        While Elves do occasionally leave Sedel, it seems that most humans are surprised by your presence. Their impressions of your kind vary from person to person, but you've had more than your fair share of harsh words flung at you. 
        *goto nametime
*label nametime

I assume they give names in $!{origin}. What's your given name?

*input_text name

*set fullname title & " "
*set fullname fullname & name
And your surname?

*input_text surname

*set fullname fullname & " "
*set fullname fullname & surname
*if ((name = "Ippit") and (surname = "Jones"))
  *set ippitmode true
$!{title} ${name} $!{surname}.

It has a somewhat satisfying ring to it as you say your new title in your head.

Yet... You can't help but feel completely out of place.

*if origin="Monaire"
  In your days with the Imperial Combat Forces, you had never gotten above the rank of a guard captain. Even then, there was nothing that really set you apart from anyone else. Your swordsmanship was adequate, but nothing special. You weren't particularly skilled, nor had you seen much real combat.
  
  It still baffles you as to why Reaver Harking ever wanted to make you his Second. 
  *goto unblv
*elsif origin="Ehl"
  Aside from the fact that you are clearly not from this continent, you have no definable skills for leading anything in the Monaire Empire. Your expertise is in linguistics, which does little good in a land where everyone speaks the same language. 
  
  Even when you took an easy job as a guard for the Empire, you couldn't accomplish much more than to stand there and look as intimidating as possible. Why Reaver Harking thought that you, of all people, should be his Second was beyond you. 
  *goto unblv
*elsif origin="Capel"
  While Sages are generally thought to be powerful wielders of magic, the Sages of your Temple were merely tracers of fate. Seeing someone's future is nowhere near as intimidating or useful as making fire erupt from your hands, or shaping the seas to your whim.
  
  Why Reaver Harking saved you, of all the Sages of the Temple, has perplexed you since the event. To further vex you, not once has anyone in the Empire ever asked you to use your abilities, not even when you were Reaver Harking's Second. 
  *goto unblv
*elsif origin="Asylia"
  Aside from the borderline hostile reactions you receive when people figure out that you're a "godless Asylian", you have no skills that are of any real use to the Empire. 
  
  Sure, back home, your talent in painting had earned you the greatest honor and title in Asylia. With your culture gone however, that title was little more than a meaningless bit of sentimentality.
  
  Reaver Harking had placed you in an out of the way place as a guard for a time, but you were probably the worst guard the Empire had ever been unfortunate enough to have.
  
  No matter how you thought about it, to the Empire, a painter is completely useless. The fact that Reaver Harking found you important enough to not only save from certain death, but to make his Second was definitely... odd. 
  *goto unblv
*else
  Aside from the fact that Elves are generally treated with suspicion outside of Sedel, you aren't exactly regarded as being the most cooperative member of the Empire. If not for Reaver Harking's promise to spare your people in exchange for your service, you would strike down every Imperial you saw. Giving you a position of authority that is only rivaled by the word of the Emperor is rather counterintuitive on their part. 
  
  Perhaps Reaver Harking thought you would grow some attachment to the Empire? Or to him? It's hard to read the man's intentions, but you're fairly certain that this title was not given to you simply for your ability in combat. 
  
  Furthermore, your skills in combat have been bested by Imperials far more loyal than yourself. Why are you more worthy of anything than them?
  *goto unblv
*label unblv

Now, here you are in one of the highest positions of authority in the Empire. The previous Reavers were all legends, terrifying and awesome in their abilities. They were the type of people who you followed, unquestioningly, knowing they were capable of utterly destroying your life.

And here you are, $!{title} $!{surname}, expected to rank among these terrible giants.

*choice
  #It'll take a lot of hard work, but I'll make it my goal to live up to the title.
    An optimistic outlook. Surely all Reavers have been mediocre at some point. It's highly unlikely that Reaver Harking would have volunteered you for something you aren't capable of. 
    *set rebel 0
    *set effort 1.25
    *if origin = "Sedel"
      *set rebel 10
    *goto continueintro
  #I don't know why I was granted the title, but maybe I'm good enough for it the way that I am.
    *set effort 1
    You were granted the title for a reason. While that reason might be a mystery to you, perhaps it'd be wiser to defer to Reaver Harking and the Emperor's judgement on this matter. 
    *goto continueintro
  #Maybe I was chosen for a different reason.
    *set effort 1
    It's possible that you don't seem like the previous Reavers because you aren't supposed to be like them. Whatever Reavers have done in the past, they weren't you. 
    *set intel +5
    *goto continueintro
  #This is... wrong. I don't think I can do this.
    Wrong? That's entirely possible from certain points of view. 
    
    Out of curiosity, what exactly is your problem with this scenario? 
    *choice
      #I don't want to become a tool for this evil, oppressive organization.
        *set effort 0.75
        The Empire is hated by a great many people. It's certainly understandable that you wouldn't want to be associated with it. 
        
        Unfortunately, the Empire's eyes are everywhere, and any attempt at escape will likely result in a long, bloody struggle. 
        
        Although... 
        
        Perhaps the freedom of your new position will provide you with an alternative... 
        *set rebel +5
        *set rebelcount + 1
        *goto continueintro
      #I can't live up to those kinds of expectations.
        *set effort 0.5
        In all reality, no, you probably can't. Not on your own, anyway.
        
        However, keep in mind that no one insisted that you had to do this alone.
        *goto continueintro
*label continueintro

In any case, no one's even told you what you were supposed to be doing as a Reaver. That, however will have to wait until later. The uncertainty of your situation causes sleep to be nearly impossible that night, but somehow you manage. 
*set loyal true
*if rebel = 0
  *set girel %+ 5
*finish Next