Constant Historia "Prueba";
Constant Titular "^";
Include "EParser";
Include "Acciones";

    
Object vacio "Vacío vacuo"
with descripcion "Un lugar vacío. Al norte hay un lugar con objetos 
	    variados, al este un lugar con objetos idénticos 
	    (plurales), al oeste un lugar con objetos de escenario y 
	    al sur un lugar con objetos ambiguos (nombres 
	    parecidos).",
	al_n variados,
	al_e plurales,
	al_o decorados,
	al_s ambiguos,
 has 	luz;

!================================================================
Object 	variados "Lugar de objetos variados"
 with 	descripcion "Al sur vuelves al lugar vacío.",
	al_s vacio,
 has 	luz;

Object -> raton "ratón de ordenador"
 with 	descripcion "Es un ratón serie, compatible Microsoft.",
	nombre 'raton',
	adjetivos 'ordenador',
	;

Object -> papel "papel"
 with	descripcion "Un folio en blanco.",
	nombre 'papel' 'folio',
	nombre_f 'cuartilla' 'hoja',
	genero G_MASCULINO,
	;

Object -> ornitorrinco "ornitorrinco"
 with 	descripcion "Pico de pato, cubierto de pelo... ya sabes.",
	nombre 'ornitorrinco' 'animal',
	describe "Por aquí anda un ornitorrinco.",
 has 	animado;

Object -> bombilla "bombilla"
 with 	descripcion "Una bombilla, con el filamento fundido.",
	nombre_f 'bombilla',
	nombre_m 'filamento',
	genero G_FEMENINO,
	;

!================================================================
Object plurales "Habitación de los objetos plurales"
 with 	descripcion "Hacia el oeste vuelves al lugar vacío.",
	al_o vacio,
 has 	luz;

Class Letra
  with nombre 'letra' 'letras//p',
	adjetivos 'un' 'juego' 'scrabble',
  listar_juntos [;
           if (etapa_inventario==1)
           {   print "las letras ";
               ! Modificamos el estilo temporalmente
               estilo_ac = estilo_ac | ESPANOL_BIT | SINARTICULO_BIT;
               estilo_ac = estilo_ac & (~NUEVALINEA_BIT) & (~INDENTAR_BIT);
           }
           else print " de un juego de Scrabble";
       ],
       nombre_corto [;
           if (listando_junto ofclass Letra) rfalse;
           print "letra ", (object) self;
	   if (~~preguntacualexactamente) print " de un juego de
	       Scrabble";
	   rtrue;
       ],
       articulo "la",
has femenino;

Letra -> "X" with nombre 'x//';
Letra -> "Y" with nombre 'y//';
Letra -> "Q" with nombre 'q//';
Letra -> "F" with nombre 'f//';

Class  MonedaOro
  with nombre 'moneda' 'oro' 'monedas//p',
       nombre_corto "moneda de oro",
       plural "monedas de oro",
has femenino;

Class  MonedaPlata
  with nombre 'moneda' 'bronce' 'monedas//p',
       nombre_corto "moneda de plata",
       plural "monedas de plata",
has femenino;

Class  MonedaBronce
  with nombre 'moneda' 'bronce' 'monedas//p',
       nombre_corto "moneda de bronce",
       plural "monedas de bronce",
has femenino;

Object ->bolsa "bolsa"
 with  nombre 'bolsa',
has recipiente abrible abierta femenino;
MonedaOro ->-> with adjetivos 'oxidada', nombre_corto "moneda de oro oxidada";
MonedaOro ->->;
MonedaOro ->->;
MonedaPlata ->->;    
MonedaPlata ->->;    
MonedaBronce ->->;


!================================================================
Object ambiguos "Lugar de los objetos ambiguos"
 with 	descripcion "Al norte vuelves al lugar vacío.",
	al_n vacio,
 has 	luz;

Object -> telefono "teléfono gris"
 with	nombre 'telefono' 'aparato' 'telefonico',
	adjetivos 'gris',
	descripcion "El cable está cortado.",
 has 	transparente;

Object ->-> auricular "auricular del teléfono"
 with	nombre 'auricular',
	adjetivos 'telefono',
	descripcion "Ya no tiene utilidad.",
	;

Object -> factura "factura de teléfono"
 with 	nombre 'factura',
	adjetivos 'telefono',
	descripcion "Es astronómica. Tal vez por eso han cortado el
	    cable.",
 has 	femenino;

Object 	-> telefonorojo "teléfono rojo"
 with	nombre 'telefono',
	adjetivos 'rojo',
	descripcion "Un teléfono rojo. ¿con quién comunicará?",
	;

Object -> rojo "Rojo"
 with 	nombre 'rojo',
	descripcion "Un diablo gordo.",
 has 	animado propio;


!================================================================
Object 	decorados "Lugar de las decoraciones"
 with 	descripcion "Este lugar está ricamente decorado, a base de
	    tapices, cuadros, candelabros, alfombras y graffiti. Hacia
	    el este vuelves al lugar vacío.",
	al_e vacio,
 has 	luz;


Object -> tapices "tapices"
 with 	descripcion "Los tapices muestran imágenes abstractas.",
	nombre 'tapices',
 has 	escenario nombreplural;

Object -> cuadros "cuadros"
 with 	descripcion "Son cuadros de Tapies, no muy diferentes de los 
	    tapices.",
	nombre 'cuadros' 'tapies',
 has 	escenario nombreplural;

Object -> alfombras "alfombras"
 with 	descripcion "Alfombras persas.",
	nombre 'alfombras',
 has 	escenario nombreplural femenino;

Object  -> candelabros "candelabros"
 with 	descripcion "Candelabros dorados, pero sin luz.",
	nombre 'candelabros',
 has 	escenario nombreplural;

Object -> graffiti "graffiti"
 with 	descripcion "Los huecos entre cuadros y tapices dejan ver la
	    pared, decorada con graffiti.",
	nombre 'graffiti',
 has 	escenario ;


Include "Gramatica";

[ Inicializar;
    localizacion=vacio;
    parser_listo=0;
    
    "^Bienvenido al banco de pruebas del parser...^";
];