Constant Historia "Demo de Decorados";
Constant Titular  "^(c) 2000 Zak^";

Include "EParser";
Include "Decorado";
Include "Acciones";

Object Celda "Celda"
 with	descripcion "Encerrado entre cuatro paredes, sin un triste
	    objeto que llevarte al inventario... Y para colmo, incluso las
	    paredes son mero decorado.",
 has 	luz;


! El objeto decorado, que sirve para condensar en un solo objeto todas
! las palabras "irrelevantes" que el jugador pueda querer examinar,
! pero proporcionando una descripción para cada una.
!
! Observa cómo en la rutina "antes" podemos dar un mensaje prohibiendo
! ciertas acciones. Las que no se cubran en esta rutina "antes"
! obtendrán el mensaje por defecto "Déjalo, es sólo decorado." Si
! quieres cambiar este mensaje por defecto, pon una cláusula default:
! al final de "antes", con el mensaje deseado, como se muestra en el
! comentario.
!
Object	decorado_celda Celda
 class 	decorado
 with  	describir
       	    'pared' "Paredes de ladrillo lugubres y frias" G_FEMENINO
       	    'paredes' "Paredes de ladrillo lugubres y frias"  G_FEMENINO+G_PLURAL
            'ladrillo' "El ladrillo está negro por la humedad" G_MASCULINO
            'ladrillos' "Los ladrillos están negros por la humedad"
	                 G_MASCULINO+G_PLURAL
	    ,
	antes [;
	 Empujar: "Empujar ", (el) self, " no servirá de nada.";
	 Atacar: print_ret (_El) self, " ", (es) self, " demasiado
		dur", (o) self, ".";
            ! Para redefinir el mensaje por defecto:
	    !default: "Deja eso en paz.";  
	];

[ Inicializar ;
    localizacion=Celda;
    "^^Esta demo contiene un objeto de la clase ~decorado~ que permite
    al jugador examinar las paredes, y los ladrillos, pero impide
    cualquier otra acción sobre ellos. Prueba a romperlos.^";
];

Include "Gramatica";