!---------------------------------------------------------|
!      Aquelarre Parte 1- El Legado Abrapampa 1.0         |
!                  para InformATE                         |
!---------------------------------------------------------|
! Autor: Pablo D'Amico                                    |
! Ambientación Original: Ricard Ibañez                    |
! Guión Inspirado en El Pacto de Ricard Ibañez (supongo)  |
!---------------------------------------------------------|
! Esta  es  mi  primer  aventura  conversacional y  elegí |
! hacerla a  partir de una  historia que ya  conocía y me |
! gustaba.  Es la  típica  historia  de  rescatar  a  una |
! doncella pero con algunas  variantes del guión original |
! debido a que tuve que  simplificar la historia en favor |
! de la  programación.  Ojalá le guste a quien la juegue. |
!---------------------------------------------------------|
! Créditos y Dedicatorias:                                |
! * A la gente del CAAD, sin ellos, a través de su página,|
!   no hubiera conocido las aventuras conversacionales.   |
! * A Zak McKraken por su tutorial de Inform e InformATE  |
! * A Ricard Ibañez por haber creado el mágico mundo de   |
!   Aquelarre                                             |
! * A los que de una u otra manera...                 º-) |
!---------------------------------------------------------|

!--------------------------------------------------------
!----------- Inicialización del Programa ----------------
!--------------------------------------------------------

Constant ADMITIR_COMANDO_SALIDAS;
Constant PUNTUACION_MAX 100;
Constant PUNTOS_OBJETO    5;
Constant PUNTOS_LUGAR    10;
Constant HAY_CURIOSIDADES;
Constant LLEVAR_MAX=10;
Global   PuntosDeVida=20;

Constant Historia "^El legado Abrapampa^";
Constant Titular  "^Esta es la historia:^
	 Burgos, Capital de Castilla. 21 de Junio del año 1355 de Nuestro Señor^^
	 Tu eres Esteban, íntimo amigo de Pedro
	 de Abrapampa, sabes que vive de la renta que heredó de sus padres y su 
	 pasatiempo principal es la caza y la alquimia y su vicio las mujeres.
	 Siempre ha sido enamoradizo. Desde hace unos meses no se le conocen 
	 líos amorosos y permanece encerrado en su mansión. El te ha citado 
	 a una cena de camaradas y te ha pedido tu ayuda:^
	 ~Sabed que hace casi un año me enamoré locamente de una mujer casada.
	 Ya se que esto no es nuevo para mí. Pero os juro que esta vez va en serio.
	 Ella se llama Marina de Béjar. La conocía desde hace ya tiempo.
	 Su padre la hizo casarse antes de morir con el caballero Fernando Antúnez,
	 que se hizo cargo así de la Baronía de Incinillas.
	 Ella pasaba muchas temporadas en Burgos y en una de ellas nos conocimos,
	 lo nuestro terminó bruscamente cuando ella quedó embarazada y su marido
	 se la llevó a su castillo. No supe más de ella y traté de olvidarla sin éxito.
	 Hace unos días recibí noticias de que el Barón se ha vuelto loco y tiene a su mujer
	 encerrada en la torre. Tengo miedo de que la mate y quiero ir a rescatarla,
	 Por la fuerza si es preciso. ~^
	 Al día siguiente parten en su búsqueda...^^";

Constant FinBueno "^Has vencido al Barón, mientras ves caer su cuerpo notas como
			  el extraño mago sale volando por la ventana con sus propias alas,
			  mientras se aleja ríe. Tu liberas a Marina y la ayudas a parir a su hijo allí
			  mismo. Unos instantes después del milagro de la vida, la imagen de
			  San Petrolino parece tomar vida y se te acerca, no comprendes bien pero notas
			  pero es Pedro, o mejor dicho su espíritu, y te dice:^
			  - Esteban, te estoy eternamente agradecido, has vengado mi muerte.^
				Toma a Marina, hazla tu esposa. Le pondrás Pablo a mi hijo y lo cuidarás
				como si fuera tuyo, prepáralo para la vida, guíalo por el buen camino.
				^Será él quien un día encontrará al Mago que quiso acabar con 
				nuestras almas, el niño, mi hijo, sabrá vengarnos.^Hasta siempre...^^
				^Así Marina y tu se casan y tu eres el nuevo Barón de estas tierras,
				un buen gobernante y un buen padre, logras hacer del Castillo tu hogar,
				el mismo hogar que algún día verá partir a ese hijo que ha visto crecer
				en busca del destino, claro que esa es otra	historia...^";

Constant FinMalo "^El Barón te hiere mortalmente, sin embargo no te remata. 
			 Tiene reservado un final aún peor para tí y los demás:
			 Formas parte de un extraño rito: a medianoche se hace presente 
			 el mismísimo demonio. El barón ofrece a Marina, su hijo recién 
			 nacido y a ti como profano sacrificio en el altar.^
			 El ser del abismo rechaza el sacrificio:^
			 ~Imbécil, no puedes engañar al señor de las tinieblas, este no es tu hijo!.
			 Ahora morirás, moriran todos bajo las llamas del infierno!.~^
			 Todo el lugar comienza a arder, el extraño mago sale volando por la ventana
			 con sus propias alas y mientras se aleja ríe. Y tú junto con Marina y el Barón
			 mueren a manos del señor de las tinieblas.^";

[ Curiosidades;
	"^He intentado hacer lo más interesante posible la aventura^
	  Para ello puse algunos objetos y situaciones ~especiales~:^
	* Si arrojas la moneda extraña en el aljibe del pueblo tendrás una visión perturbadora
		Si se la das al Jefe de los soldados te mata, el posadero la aceptará.^
	* El amuleto, si esta puesto, es lo único que permite abrir la puerta del castillo.^
	* El Hacha del soldado del castillo también puede usarse para matar al Barón^
	* La antorcha se apagará a los 6 turnos de haberla prendido, no así las velas de la
		torre que nunca se apagan.^
	* La copa del baúl del mago puede llenarse con el vino de la botella de la cocina para
		ganar puntos de vida extra antes de pelear con el Barón.^
	* El cofre de la torre a oscuras se abre con la pluma. En su interior hay un pergamino
		que desata un curioso final si es leído en la capilla ante el Barón.^
	* Hablar con el borracho, primero, y el mago, después, puede dar una idea de lo que
		pasará en el desenlace de la historia.^
	* Los otros finales pueden ser: morir a manos del soldado (poco probable) y 
		por supuesto que el barón llegue a matarte.^^

	Cabe aclarar que esta es la primera parte de una serie de tres aventuras (que quizá
	algún día formen una sola) que completarán esta saga. Sólo puedo adelantar que la 
	historia tendrá como protagonista a Pablo, el hijo de Pedro de Abrapampa.
	Su objetivo en la vida será vencer al oscuro mago que causó la muerte de su padre, 
	sólo que antes deberá aprender cómo vencerlo. Hasta la próxima.^";
];


Include "EParser";
Include "Acciones";
Include "Facilitar";
Include "Gramatica";
Include "fhablaoo.h";

!------------------------------------------
!------------ Habitaciones ----------------
!------------------------------------------

!************* El Camino ******************

Habitacion Comienzo "El Camino"
with descripcion "El camino plantea pocas dificultades, está en buen estado. 
	Atraviesan algunas zonas rurales, recorriendo de Sur a Norte. Por la noche
	acampan bajo las estrellas y recuerdan con Pedro los viejos tiempos.^
	Al amanecer despiertas, pero Pedro ya no se encuentra y tampoco sus cosas
	Sólo puedes ver que se ha marchado, quizá para ganar tiempo^
	Al este está vuestro pequeño campamento, al norte sigue el camino",
 al_e Campamento,
 al_n Camino1;

Habitacion Campamento "El Campamento"
with	irrelevante 'fogata' 'pertenencias' 'camino' 'campamento',
		descripcion "Es el pequeño solar donde habéis pasado la noche, 
			sólo quedan restos de la fogata y lo que comisteis 
			(Una perdiz que habéis cazado). No hay rastros de tu amigo, 
			ni de sus pertenencias.",
		no_puedes_ir "No te confundas, el camino esta al oeste",
 al_o Camino1;

Habitacion Camino1 "El camino"
with descripcion "El camino se muestra más descuidado y parece que hay menos población. 
		El cielo esta despejado y el clima es agradable.^
		Hay poco follaje, sólo algunos arbustos al lado del camino. 
		^El camino sigue hacia el norte",
	 no_puedes_ir "No querrás salirte del camino, puede ser peligroso",
 al_e Campamento,
 al_n Camino2;

Habitacion Camino2 "El camino"
with 	irrelevante 'suelo' 'ruta',
		descripcion "El terreno cambia determinantemente, 
		no se distingue ya la ruta del suelo.^
		Todo es tierra yerma, sólo hay piedras al lado del camino.
		^Hacia el norte puedes ver una arboleda, parecen olivos.",
		no_puedes_ir "No querrás alejarte del camino, puede ser peligroso",
 al_s Camino1,
 al_n Arboleda;

Habitacion Arboleda "Los dominios del Barón"
with 	irrelevante 'soldados' 'frutos' 'cielo',
		descripcion[;
		if(Pueblo hasnt general) "Al pasar por una arboleda puedes ver seis cadáveres colgando
		 de los árboles como frutos macabros. Cinco soldados de aspecto lamentable
		 se encuentran allí también, uno parece ser el Jefe. Afirma que es necesario
		 pagar un tributo de una moneda, para seguir en estas tierras (hacia el norte
		 puedes ver lo que crees es el pueblo).";
		else "Es la arboleda que está antes del Pueblo, los soldados te ignoran, mientras toman el vino
			que han pagado con el dinero de incautos como tú.";],
 al_s camino2,
 al_n[;
		if(Pueblo hasnt general) "~Oye!, No puedes avanzar hasta que me pagues!~";
		else return Pueblo;];

!**************** El Pueblo ****************

Habitacion Pueblo "El Pueblo de Incinillas"
with irrelevante 'arco' 'piedras',
	 descripcion "Es un pueblo pequeño y de aspecto pobre. Esta dominado por 
		la imponente estructura del castillo del Barón que se alza en lo alto 
		de una estriación rocosa.^ Un arco de piedra da la bienvenida a los visitantes. 
		Te encuentras a la entrada, aquí termina el camino^
		Al norte está la plaza o lo que queda de ella",
	 no_puedes_ir "No hay nada interesante por ahí",
 al_n Plaza,
 al_s[;
	if(amuleto notin jugador){
		give self general;
		print "Remontas camino al sur, pasas por la arboleda y sales de los dominios del Barón^";
		JugadorA(Camino1); return true;}
	else "No querrás volver atrás, ya estás muy cerca. Es muy tarde para la cobardía.";],
has valepuntos;

Habitacion Plaza "Plaza"
with irrelevante 'plaza' 'pueblo',
	 descripcion "Es la pequeña plaza del pueblo, carece de vegetación, 
		aquí hay un aljibe antiguo, algunos pequeños puestos de comida y 
		los caballos de alguien amarrados a un palenque frente a la posada.^
		Hay algunas granjas al oeste y una posada al este, 
		hacia el norte un sendero conduce al castillo",
	 no_puedes_ir "Elige: N, S, E u O",
 al_s Pueblo,
 al_o Granjas,
 al_e Posada,
 al_n Sendero;

Habitacion Granjas "Granjas"
with irrelevante 'pobladores' 'senderos' 'camino',
	 descripcion "Los pobladores tienen sus casas junto a 
		pequeños campos de cultivo o quintas.^
		Breves senderos unen las humildes y hasta casi precarias viviendas. 
		Hay pocos animales y están bastante flacos. También hay algunos
		sembrados al lado del camino. Ninguno parece muy floreciente.",
	 no_puedes_ir "No querrás invadir propiedad privada",
 al_e Plaza;

Habitacion Posada "Posada"
with descripcion "Es una posada de pueblo pequeño, sólo un par de mesas, 
		una caldera, algunos barriles, etc.^
		Hay algunos campesinos sentados pero no parecen muy amistosos, también hay un borracho perdido.^
		El posadero saluda: ~Qué hay, forastero!~",
	 no_puedes_ir "No puedes atravesar paredes",
 al_o[;
	  if(cacerola.comido==1)
		"~Oye, paga primero!~";
	  else
		JugadorA(Plaza);
		return true;
	];

Habitacion Sendero "Sendero"
with descripcion "Es un sinuoso sendero que trepa por el risco rumbo al castillo
que se muestra imponente en la cima. ^
			En el extremo superior se encuentra la puerta del Castillo",
		no_puedes_ir "Es muy peligroso salirse del sendero",
 arriba "Ya estás arriba",
 al_s Plaza,
 al_n Puertahierro;

!****************** El Castillo *******************

Objeto Puertahierro "Puerta del Castillo" Sendero
with nombre 'puerta' 'hierro',
	 descripcion "Es una antigua puerta de Hierro, está algo oxidada, 
		aunque parece bastante sólida. Posee un cerrojo muy antiguo.",
	 antes[;
		abrir:if(amuleto hasnt puesto)
				"Es imposible abrirla, debe estar cerrada por dentro";
			  else
				{tate_callao=1;
				<QuitarCerrojo self>;
				tate_callao=0;
				print "^La puerta hace un extraño sonido^";}
		  ],
	 puerta_a Castillo,
	 direcc_puerta al_n,
has femenino escenario puerta abrible cerrojo cerrojoechado ~abierta;

Habitacion Castillo "El castillo - Hall"
with descripcion "El Castillo está tranquilo, parece deshabitado. 
			Te encuentras en el Hall. El lugar se encuentra entre penumbras.
			Al norte se encuentra el patio, a tus costados hay 2 arcos
			de rocas que conducen a otro lugar.",
 al_s "No puedes abrir la puerta, quizá es una señal",
 al_n Patio,
 al_e Capilla,
 al_o Comedor,
has valepuntos;

Habitacion Patio "Patio central"
with irrelevante 'vegetación' 'agonizante' 'antigua',
	 descripcion "El patio, posee una antigua y agonizante vegetación, 
		su única función es	dar paso a las diferentes torres del castillo. 
		Una en cada esquina: NE,NO,SE,SO, algunas tienen puerta",
	 antes[;
		Abrir:"Necesitas las llaves para abrir las puertas, si ya las tienes, 
			dirígete hacia el punto cardinal que le corresponda a esa torre";
		],
 al_s castillo,
 al_ne Torre1,
 al_no [;
		 if(llave1 notin jugador)
				"Necesitas la llave para la puerta";
			  else{
				print "Abres la puerta y entras.^";
				JugadorA(torre2); rtrue;}
	  ],
 al_se Torre3,
 al_so Torre4;

Habitacion Capilla "Capilla"
with descripcion[;
			if(baron notin self)
				"Es una capilla común y corriente, un poco en desuso. 
				Se extiende a lo largo del castillo con ventanas al Patio.";
			else "Es la capilla del castillo, Aquí están el Barón, el extraño Mago
				y Marina, pariendo a su hijo. El barón te dice: ~¿Qué haces aquí!, 
				ahora morirás como el maldito Pedro de Abrapampa!";
				],
		no_puedes_ir "No es posible atravesar las rocas",
 al_o Castillo,
has valepuntos;

Habitacion Comedor "Comedor y cocina"
with descripcion "Es el salón del castillo es grande y espacioso con ventanas al Patio,
			no posee muchos muebles y no tiene nada que ofrecer.",
		no_puedes_ir "No es posible atravesar las rocas",
 al_e Castillo;

Habitacion torre1 "Torre NE - Abajo"
with descripcion "Al cruzar el arco puedes ver que hay una escalera de piedra que sube.",
 arriba escalera,
		no_puedes_ir "No es posible atravesar las rocas",
 al_so Patio;

Habitacion torre1a "Torre NE - Arriba"
with irrelevante 'ventana' 'montaña' 'paredes',
	 descripcion "Hay es una escalera de piedra que baja. Una ventana da a la montaña.",
	 no_puedes_ir "No es posible atravesar las rocas",
 abajo[;
	if(soldado in self)
		"~Oye!, adonde crees que vas?, pelea como hombre!~";
	else return escalera;
	  ],
has valepuntos;

Habitacion torre2 "Torre NO - Abajo"
with descripcion "Al cruzar el arco puedes ver que hay una escalera de piedra que sube.",
 arriba escalera,
		no_puedes_ir "No es posible atravesar las rocas",
 al_se Patio;

Habitacion torre2a "Torre NO - Arriba"
with irrelevante 'ventana' 'montaña' 'paredes',
	 descripcion [;
		if (mago notin self)
			"Hay es una escalera de piedra que baja. Una ventana da a la montaña.";
		else
			"Hay es una escalera de piedra que baja. Una ventana da a la montaña.^
			Está aquí un extraño mago, que te mira atentamente.";
				],
 abajo escalera,
		no_puedes_ir "No es posible atravesar las rocas",
has valepuntos;

Habitacion torre3 "Torre SE - Abajo"
with descripcion "Al cruzar el arco puedes ver que hay una escalera de piedra que sube.",
 arriba escalera,
		no_puedes_ir "No es posible atravesar las rocas",
 al_no Patio;

Habitacion torre3a "Torre SE - Arriba"
with irrelevante 'ventana' 'paredes' 'silla',
	 descripcion "Hay es una escalera de piedra que baja. Una ventana está tapiada.^
			También hay una mesa y una silla.",
		no_puedes_ir "No es posible atravesar las rocas", 
	abajo escalera,
has valepuntos ~luz;

Habitacion torre4 "Torre SO - Abajo"
with descripcion "Al cruzar el arco puedes ver que hay una escalera de piedra que sube.",
 arriba escalera,
		no_puedes_ir "No es posible atravesar las rocas",
 al_ne Patio;

Habitacion torre4a "Torre SO - Arriba"
with irrelevante 'ventana' 'montaña' 'paredes',
	 descripcion "Hay es una escalera de piedra que baja. Una ventana da a la montaña.
	 Al norte de la habitación hay una celda",
		no_puedes_ir "No es posible atravesar las rocas",
 abajo escalera,
 al_n [;
		if (llave2 in jugador){
			print "Abres la cerradura de la celda.^";
			return Celda;}
		else "Necesitas la llave.";
	],
has valepuntos;

Objeto celdalejos "Celda de barrotes" torre4a
with nombre 'celda' 'barrotes' 'cerradura' 'habitacion' 'con',
	 descripcion "Es una hilera de barrotes que dividen la habitación en dos formando
		una celda en la mitad este de la torre, tiene cerradura.",
	 antes[;
		abrir: if(llave2 in jugador) torre4a.al_n();
				else "Necesitas la llave";
		],
has femenino escenario;

Habitacion Celda "Celda de barrotes" 
with descripcion "Es la celda que ocupa la otra mitad de la torre, probablemente tenían
		encerrada aquí a Marina.",
	 antes[;
		salir: JugadorA(torre4a);
			move Baron to Capilla;
			move Mago to Capilla;
			"Oyes un grito proveniente de la Capilla del Castillo";
		],
 al_s [;<<salir>>;],
has femenino;

!===================================|
!============= Objetos =============|
!===================================|

!************ Del Jugador **********
objeto armadura "Armadura Liviana"
with  nombre 'armadura' 'proteccion', 
	  descripcion "Es una armadura liviana, Bastante resistente y además cómoda",
has femenino prenda puesta;

objeto espada "Espada Normal"
with 	nombre 'espada' 'normal' 'arma',
		descripcion "Es tu espada de toda la vida, ha tomado tantas vidas 
			como ha salvado otras",
		antes[;
			Blandir:
				if(hacha has puesta) "Primero enfunda el hacha";
			 ],
has femenino prenda;

objeto yesca "Yesquero"
with 	nombre 'yesca' 'yesquero' 'pedernal' ,
		descripcion "Es el conjunto de yesca y pedernal para prender fuego";

objeto bolsa "la bolsa"
with 	nombre 'bolsa' 'dinero' 'plata',
		descripcion "Es tu bolsa de dinero, donde llevas los duros",
has recipiente femenino abrible abierto propio;

objeto oro "Moneda de oro" bolsa
with 	nombre 'moneda' 'oro' 'maravedi' 'florin' 'escudo',
		descripcion "Es una moneda de oro con la efigie del rey",
has femenino;

objeto plata "Moneda de plata" bolsa
with 	nombre 'moneda' 'plata' 'maravedi' 'croat' 'escudo',
		descripcion "Es una moneda de plata con la efigie del rey",
has femenino;

!**************** Del Camino **********

objeto restos "Sobras de Comida" Campamento
with nombre 'restos' 'sobras' 'comida' 'perdiz',
	 descripcion "Son las sobras de la perdiz que has comido",
	 antes[;
		Comer:
			PuntosDeVida=PuntosDeVida+1;
		],
has comestible nombreplural femenino;

objeto fogata "Fogata" Campamento
with nombre 'fogata' 'restos' 'cenizas' 'carbon',
	 descripcion "Son los restos de la fogata, sólo carbón y cenizas. Nada en particular.",
has escenario femenino;

objeto arbustos "Arbustos del Camino" Camino1
with nombre 'arbustos' 'plantas' 'camino' 'follaje',
	 descripcion "Hay algunos arbustos achaparrados con un compacto follaje.^
				  No parecen ser comestibles, aunque están bastante verdes",
	 despues[;
			if (amuleto notin jugador){
				move amuleto to camino1;
				amuleto.inicial();}
			],
has escenario masculino nombreplural;

objeto amuleto "Amuleto"
with nombre 'amuleto' 'talisman' 'mágico',
	 inicial "Puedes ver entre las ramas un amuleto",
	 descripcion "Parece ser alguna clase de talismán mágico, no sabes para que sirve.^
				  Aunque si te fijas mejor, recuerdas que Pedro llevaba puesto uno así.",
has masculino valepuntos prenda;

objeto piedras "Piedras del Camino" Camino2
with nombre 'piedras' 'rocas' 'camino' 'pedregullo',
	 descripcion "Hay algunas piedras al lado del camino.^
				  Es un pedregullo bastante grueso, esta por todo el lugar.",
	 despues[;
			if (moneda notin jugador){
				move moneda to Camino2;
				moneda.inicial();}
			],
has escenario femenino nombreplural;

objeto moneda "Moneda extraña"
with 	nombre 'moneda' 'extraña' 'maravedi' 'escudo' 'rara',
		descripcion "Es una extraña moneda de ¿plata?, no reconoces de donde sea",
		inicial "Puedes ver entre la tierra una extraña moneda",
has femenino valepuntos;

objeto arboles "Arboles" Arboleda
with nombre 'arbol' 'arboles' 'frutos' 'macabros' 'cuerpos',
	 descripcion "Son un grupo de árboles, colgados de ellos hay varios cuerpos 
			de hombres muertos,	entre ellos puedes ver a Pedro, tu mejor amigo 
			y fiel compañero",
has masculino nombreplural escenario;

objeto hombres "Soldados" Arboleda
with nombre 'soldados' 'matones' 'ladrones',
	 descripcion "Más que soldados parecen vulgares ladrones, sin embargo son bastante
		persuasivos (dan miedo).",
has escenario nombreplural;

!************* Del Pueblo **************

Objeto arco "Arco" Pueblo
with nombre 'arco' 'arcada' 'piedra',
	 descripcion "Es una arcada de piedra un poco gastada. Dice ~Incinillas~.",
has escenario;

Objeto aljibe "Aljibe" Plaza
with nombre 'aljibe' 'pozo' 'agua',
	descripcion "Es un pozo que recolecta el agua de la lluvia, 
		que, al parecer, es un poco escasa",
	antes[;
		recibir: remove uno;
				"Echas la moneda al agua, te pareciera ver en las ondulaciones
				una perturbara imagen, alguna clase de criatura infernal, sólo te parece.";
		],
has escenario recipiente abierto;

Objeto caballos "Caballos" Plaza
with nombre 'caballo' 'caballos' 'equinos',
	descripcion "Son caballos de monta, no tienen alforjas ni montura y lucen algo flacos",
has escenario nombreplural;

Objeto puestos "Puestos de Comida" Plaza
with nombre 'puestos' 'mercado' 'comida' 'puesto' 'negocios' 'tienda',
	descripcion "Algunos puestos de comida forman un pequeño mercado, 
		hay verduras y algunos animales. Sin embargo no parecen demasiado 
		confiables, no tienes donde llevar las cosas así que desistes de visitarlos.",
has escenario nombreplural;

Objeto mesas "Mesas" posada
with nombre 'mesa' 'mesas' 'tabla' 'tablon',
	 descripcion "Son mesas corrientes de Posada. Madera un poco vieja.",
has femenino escenario nombreplural;

Objeto campesinos "Campesinos" Posada
with nombre 'gente' 'campesinos' 'campesino' 'pobladores',
	 descripcion "Son los pobladores de Incinillas, se muestran algo desconfiados,
		son todos gente de campo, con su ropa de trabajo.",
has nombreplural escenario;

Objeto barriles "Barriles" posada
with nombre 'barril' 'barriles' 'tonel' 'toneles' 'vino',
	 descripcion "Viejos toneles de vino. Son de Roble y parecen a punto de desarmarse.",
	 antes[;
		beber, comprar: "No querrás embriagarte, tienes una misión que cumplir";
		],
has escenario nombreplural;

Objeto caldera "Caldera" posada
with nombre 'caldera' 'caldero' 'cocina' 'chimenea',
	 descripcion "La caldera está tallada en la piedra de las paredes. 
		Esta encendida y parece tener un extraño guiso cocinándose.",
has femenino escenario recipiente abierto;

Objeto cacerola "Cacerola" caldera
with nombre 'cacerola' 'cazuela' 'guisado' 'extraño' 'guiso',
	 descripcion "Es una antigua cacerola de Hierro. 
		Tiene adentro un guiso espeso y burbujeante",
	 comido 0,
	 antes[;
			probar:"No querrás hacer eso";
			comprar, comer:
				if(self.comido==1)"Ya has comido, debes pagar";
				else{
				self.comido=1;
				print "Comes una porción del guiso y te sabe muy mal.^";
				move self to caldera;
				if (oro notin posadero)
					"El posadero te dice: ~Ondia! que debes pagar por eso, forastero~";
				else "Come tranquilo, la casa invita!";}
			meter,recibir:"No creo que el guiso mejore con eso";
		  ],
has femenino;

Objeto casas "Casas" Granjas
with nombre 'casa' 'casas' 'granjas',
	 descripcion "Son pequeñas casas de piedra y madera amontonadas sobre la ladera. 
			Están rodeadas de cultivos de diferentes hortalizas.",
has escenario femenino nombreplural;

Objeto campos "Campos" Granjas
with nombre 'campo' 'campos' 'quinta' 'cultivos' 'quintas' 'cultivo' 'sembrados',
	 descripcion "Son simples campos de cultivo. La tierra deja, difícilmente, 
		crecer algunas zanahorias, nabos, repollos, etc.",
has escenario nombreplural;

Objeto animales "Animales" Granjas
with nombre 'animal' 'animales' 'ganado' 'vacas' 'cabras',
	 descripcion "Algo de ganado de granja, algunas vacas y cabras.",
has escenario nombreplural;


!************** Del Castillo **************

!-------------- Del Hall ------------------

Objeto antorcha "Antorcha" castillo
with nombre 'antorcha' 'fuego' 'luz',
	descripcion "Es una antorcha de madera, no parece que vaya a durar mucho",
	describir [;
		if (self hasnt encendida)"Hay una antorcha, Está apagada.";
		else "Hay una antorcha, Está prendida.";
		],
	antes [;
		Quemar: <<Encender self>>;
		Encender:
		if (yesca notin jugador)
			"No tienes con que prenderla";
		else print "Usas tu yesquero^";
		  ],
	despues [;
		Encender:
			give self luz;
			ArrancarDaemon(self);
		Apagar:
			give self ~luz;
			PararDaemon(self);
			],
	contador 0,
	daemon[;
		if (self has luz) self.contador++;
		if (self.contador>6){
			tate_callao=1;
			<Apagar self>;
			tate_callao=0;
			remove antorcha;
			"^Ves como se extingue el fuego de la antorcha";
}
		  ],
has femenino conmutable;

!---------------- Del Patio ------------------------

Objeto escalera "Escalera"
with nombre 'escalera' 'escalon' 'escalones' 'piedra',
	 descripcion "Es una antigua escalera de piedra",
	 puerta_a[;
		switch(localizacion)
		{
			torre1: return torre1a;
			torre1a:return torre1;
			torre2: return torre2a;
			torre2a:return torre2;
			torre3: return torre3a;
			torre3a:return torre3;
			torre4: return torre4a;
			torre4a:return torre4;
			laoscuridad: return torre3;
		}
	 ],
	 direcc_puerta [;
		switch(localizacion)
		{
			torre1: return arriba;
			torre1a:return abajo;
			torre2: return arriba;
			torre2a:return abajo;
			torre3: return arriba;
			torre3a:return abajo;
			torre4: return arriba;
			torre4a:return abajo;
		}
	 ],
	 esta_en torre1 torre1a torre2 torre2a torre3 torre3a torre4 torre4a,
has escenario puerta abierta;

!------------ Puertas del patio/torres --------------

Objeto puertat1 "Puerta de la Torre NO"
with nombre 'puerta' 'madera' 'NO',
	 descripcion "Es una sólida puerta de madera de roble, al NO del patio",
	 esta_en Patio torre2,
has escenario femenino;

Objeto puertat2 "Puerta de la Torre SE"
with nombre 'puerta' 'madera' 'SE',
	 descripcion "Es una sólida puerta de madera de roble, al SE del Patio",
	 esta_en Patio torre3,
has escenario femenino;

!--------- De la Capilla --------------

Objeto altar "Altar" Capilla
with nombre 'altar' 'mesa' 'retablo' 'relieve' 'marmol',
	 descripcion "Es un altar de mármol un poco avejentado. Tiene algunas manchas oscuras.
		Posee en el frente un bajo relieve que representa la última cena.",
has estatico transparente soporte;

Objeto manchas "Manchas" altar
with nombre 'mancha' 'manchas' 'oscuras',
	 descripcion "Son manchas marrones o rojas. Por un instante te parecen de sangre,
		 pero ¿es posible?",
has escenario femenino nombreplural;

Objeto santo "Imagen de San Petrolino" Capilla
with nombre 'imagen' 'san' 'santo' 'petrolino',
	 descripcion "Es una imagen de madera, tamaño natural, muy deteriorada del santo. 
			Le faltan las orejas y la nariz.",
has estatico;

!-------- Del Comedor -----------------

Objeto mesa "Mesa Grande" Comedor
with nombre 'mesa' 'grande' 'madera' 'muebles',
	 descripcion "Es una gran mesa de banquetes. Es de madera sólida. 
		Parece que no fue usada hace mucho tiempo.",
has estatico femenino soporte;

Objeto chimenea "Chimenea" Comedor
with nombre 'caldera' 'caldero' 'cocina' 'chimenea' 'muebles',
	 descripcion "La Chimenea es de piedra y está montada en una pared exterior. 
		Puede ser usada como cocina o calefacción
		No parece haber sido usada recientemente, sólo hay unas pocas cenizas",
has femenino estatico recipiente abierto;

Objeto repisa "Repisa" Comedor
with nombre 'repisa' 'tabla' 'aparador' 'muebles',
	 descripcion "Es una abandonada repisa de madera. Llena de telarañas",
	 superficie,
has estatico femenino transparente recipiente abierto;

Objeto botella "Botella de Cerámica" repisa
with nombre 'botella' 'ceramica',
	 descripcion "Es una botella de cerámica con tapa de corcho. 
		No puede verse su interior",
has recipiente femenino ~abierto valepuntos abrible;

Objeto vino "Vino" botella
with nombre 'vino' 'bebida',
	 descripcion "Es un espeso vino tinto",
	 antes[;
		beber: if(self in copa){
				PuntosDeVida=PuntosDeVida+5;
				remove self;
				"Te sientes más fuerte y valiente ahora";}
			   else "No querrás tomarte la botella, no?";
		  ],
has valepuntos;

!--------- De la torre 1 --------------

objeto hacha "Hacha a dos manos"
with 	nombre 'hacha' 'dos' 'manos' 'a',
		descripcion "Es un hacha a dos manos, un poco vieja pero 
		completamente funcional y letal.",
		antes[;
			Blandir:
				if(espada has puesta) "Primero enfunda la espada";
			 ],
has femenino valepuntos prenda;

Objeto llave1 "Llave del soldado"
with nombre 'llave' 'soldado' 'objeto',
	 descripcion "Es una llave, la llevaba el soldado",
has femenino;

!----------- de la Torre 2 -----------------

Objeto baul "Baúl" torre2a
with nombre 'baul' 'cofre' 'madera',
	 descripcion "Es un gran cofre de madera, no tiene candado",
	 antes[;
		abrir: if (mago notin torre2a)
				self has abierto;
			   else "~Deja eso, no hay nada que te sirva allí~ dice el mago";
			],
has recipiente estatico abrible ~abierto;

Objeto llave2 "Llave del Mago" baul
with nombre 'llave' 'mago',
	 descripcion "Es una llave, pertenece a la torre del Mago",
has femenino;

Objeto copa "Copa de Plata" baul
with nombre 'copa' 'plata' 'magica',
	 descripcion "Es una copa, parece de plata y tiene extraños símbolos dibujados, 
			debe ser mágica",
	 bandera 0, 
	 antes[;
		llenar: if((botella in jugador) && (self.bandera==0)){
				move vino to self;
				self.bandera=1;
				"Llenas la copa con Vino";}
			   else
				"No tienes nada para llenar la copa";
		recibir: "No puedes meter cosas en la copa, solo llenarla con algún liquido";
		],
has femenino recipiente transparente valepuntos abierta;

!-------------- De la torre 3 -------------

Objeto mesatorre "Mesa" torre3a
with nombre 'mesa' 'madera',
	 descripcion "Es una mesa de madera, sin particularidades",
has escenario femenino soporte;

Objeto sillatorre "Silla" torre3a
with nombre 'mesa' 'madera',
	 descripcion "Es una silla de madera, sin particularidades",
has escenario femenino soporte;

Objeto tesoro1 "Cofre Dorado" mesatorre
with nombre 'cofre' 'dorado',
	 descripcion "Es un pequeño y fino cofre de ¿oro?, posee incrustadas pequeñas piedras
		preciosas: esmeraldas, rubíes, zafiros, brillantes. Debe valer mucho.^
		Tiene un pequeño orificio que oficia de cerradura.",
	 despues[;
		quitarcerrojo: <<abrir self>>;
		],
	 con_llave tesoro2,
has recipiente ~abierto abrible cerrojo cerrojoechado;

Objeto pergamino "Pergamino Antiguo" tesoro1
with nombre 'pergamino' 'antiguo' 'magico' 'mortal' 'viejo',
	 descripcion [;
		if(baron in localizacion){
			banderafin=1;
			"Se te ocurre leer en voz alta el pergamino delante del Barón.^
			Inmediatamente vez como él se retuerce de dolor, su cuerpo se consume 
			en el acto. Su alma escapa hacia el infierno.^
			te das cuenta que con ese cobarde asesinato te has condenado.
			~Ja Ja Ja!, Es demasiado tarde, para arrepentirse~ - dice el mago -
			~Te das cuenta que lo has hecho todo como lo planeé~.
			Al instante aparece un oscura criatura de las entrañas de la tierra.
			Te ordena que sacrifiques a Marina y a su hijo recién nacido. 
			Bajo un extraño influjo no puedes negarte y lo haces. 
			El demonio desaparece entre las sombras y el mago se 
			va volando por una ventana. Recién entonces te das cuenta de lo que has hecho.
			No puedes soportarlo: Pedro, Marina, su hijo, todos muertos, por tu culpa.
			Coges la cimitarra del Barón y te suicidas, quizá Dios se apiade de ti 
			y te premie con un largo purgatorio.";}
		else
			"Es un antiguo pergamino, gastado por el tiempo. 
			No te atreves a leerlo en este momento. Está escrito en una
			lengua que no conoces, pero te parece injustificadamente
			que oculta en sus palabras algún oscuro poder infernal,
			un poder que puede llegar a condenarte para siempre.";
		],
has valepuntos;

Objeto tesoro2 "Pluma de Ganso" mesatorre
with nombre 'pluma' 'ganso',
	 descripcion "Una delicada pluma de ganso, usada alguna vez para escribir quien sabe
		que desesperados mensajes"
has femenino;

Objeto tesoro3 "Pergamino en Blanco" mesatorre
with nombre 'pergamino' 'blanco',
	 descripcion "Un pergamino que nunca ha sido usado";

Objeto tesoro4 "Tintero" mesatorre
with nombre 'tintero' 'tinta',
	 descripcion "Un tintero de vidrio, parece tener tinta negra en su interior",
has recipiente ~abierto abrible;

Objeto tesoro5 "Candelabro" torre3a
with nombre 'candelabro' 'luz' 'velas',
	descripcion "Es un candelabro de 3 velas, colocado en una saliente en la pared.
		 tiene velas de color rojo y están nuevas.",
	describir [;
		if (self hasnt luz)"Hay un candelabro apagado.";
		else "Hay un candelabro prendido, las velas parecen no consumirse";
		],
	antes [;
		Quemar: <<Encender self>>;
		Encender:
		if (yesca notin jugador)
			"No tienes con que prenderlas";
		else print "Usas tu yesquero^";
		  ],
	despues [;
		Encender:
			give self luz;
		Apagar:
			give self ~luz;
			],
has conmutable;

!---------------- De la torre 4 --------------

Objeto catre "Catre desvencijado" Celda
with nombre 'catre' 'cama' 'camastro',
	 descripcion "Es un camastro de paja un tanto desvencijado.
	 Parece haber sido usado recientemente. Están revueltas las mantas.",
has soporte escenario;

Objeto mantas "Mantas Revueltas" catre
with nombre 'mantas' 'sabanas' 'revueltas',
	 descripcion "Son unas sábanas y mantas un poco gastadas, aún están calientes.
		Puedes notar que Marina estuvo aquí y a juzgar por ciertas manchas debe estar
		a punto de tener su bebé, el hijo de Pedro.",
	 antes[;
		coger: "No querrás llevartelas, están muy sucias.";
		],
has nombreplural femenino;

Objeto cadenas "Grilletes" torre4a
with nombre 'cadenas' 'grilletes',
	 descripcion "Son unos grilletes con cadenas, están agarrados a la pared de roca",
has nombreplural estatico;

!******************************************
!**************** PNJs ********************
!******************************************

Personaje jefe "Jefe de los Soldados" arboleda
with nombre 'jefe' 'soldado' ,
	 cantidad 0,
	 descripcion "Es el Jefe de los soldados. Posee un gran físico 
		y esta armado hasta los dientes.",
	Enunciado [linea;
	    switch (linea) {
	     0: "¿Qué le pasó a Pedro?";
	     1: "¿A quién hay que pagar tributo?";
	     2: "Me niego a pagar el tributo";
	     3: "¿Quién es el Barón?";
            }
        ],
	Respuesta [linea;
	    switch (linea) {
	     0:	self.QuipOff(0);
	    	"~Tu amigo no quiso pagar y combatió. 
			No pudo contra nosotros, fue un valiente~";
	     1:	self.QuipOff(1);
			self.QuipOn(3);
	    	"~El tributo es para el Barón de estas tierras, Fernando Antunez~";
	     2:	banderafin = 1;
		 "Antes de que te des cuenta estas rodeado de soldados, te cubren, 
		 ya no puedes ver nada. Es el Fin. 
		 Tu cuerpo es otro fruto más de la injusticia del Barón.";
		 3: self.QuipOff(3);
			"~El Barón es nuestro Jefe, mas te vale no meterte con él~";
	    }
	],
	InicializarQuips [;
	    self.QuipsOn(3, 0, 1, 2);
	],	
	vida [;
		Responder: "Ayuda: mejor escribe ~habla con jefe~";
		Preguntar: "Ayuda: mejor escribe ~habla con jefe~";
		Atacar:
			self.cantidad++;
			if(self.cantidad>1){
			 banderafin=1;
			 "Antes de que te des cuenta estas rodeado de soldados, te cubren,
			 ya no puedes ver nada. Es el Fin.
			 Tu cuerpo es otro fruto más de la injusticia del Barón.";}
			else "Yo que tú no lo haría, pero si insistes...";
		Dar:
		switch(uno)
		{
		oro:
			move uno to self;
			print "~Muy bien generoso amigo, puedes pasar~^";
			JugadorA(pueblo,2);rtrue;
		plata:
			move uno to self;
			print "~Bueno, pasa forastero, vete pronto antes que tenga que arrepentirme~^";
			JugadorA(pueblo,2);rtrue;
		moneda:
			move uno to self;
			banderafin=1;		
			"~¡Qué es esto!, te burlas de mí?. Ahora pagaras como tu amigo!~";
		}
	],
has animado escenario;

Personaje posadero "Posadero" Posada
with nombre 'posadero' 'mesero' ,
	 descripcion "Es un hombre bajo y pelirrojo. Un tanto gordo aunque parece simpático.",
	Enunciado [linea;
	    switch (linea) {
	     0: "¿No ha visto a mi amigo Pedro?";
	     1: "¿A cuanto está el guiso?";
	     2: "¿A cuanto está el vino?";
	     3: "No te pagaré";
		 4: "¿Que sabe del Barón?";
		 5: "¿Quién es el borracho?";
            }
        ],
	Respuesta [linea;
	    switch (linea) {
	     0:	self.QuipOff(0);
			self.QuipOn(5);
	    	"~No conozco a ningún Pedro, lo siento~";
	     1:	self.QuipOff(1);
			self.QuipOn(3);
	    	"~El guiso cuesta una moneda de plata, puedes servirte cuanto quieras~";
	     2:	self.QuipOff(2);
			self.QuipOn(3);
		 	"~El vino cuesta una moneda la jarra~";
		 3: self.QuipOff(3);
			self.QuipOff(0);
			self.QuipOff(1);
			self.QuipOff(2);
			self.QuipOff(4);
			self.QuipOff(5);
			"~Aquí no queremos problemas, mejor paga y vete, ni una palabra más~";
		 4: self.QuipOff(4);
			"~Mi señor, el barón de esta comarca es un buen gobernante~";
		 5: self.QuipOff(5);
			"~Ese borracho perdido siempre esta aquí, pero no habla mucho.~";
	    }
	],
	InicializarQuips [;
	    self.QuipsOn(4, 0, 1, 2, 4);
	],	
	vida [;
		Responder: "Ayuda: mejor escribe ~habla con posadero~";
		Preguntar: "Ayuda: mejor escribe ~habla con posadero~";
		Atacar:
				"No querrás iniciar una pelea, verdad?. Claro que no.";
		Dar:
		switch(uno)
		{
		oro:
			cacerola.comido=0;
			move uno to self;
			"~Ondia!, muy bien amigo, aquí tienes comida, bebida y todo lo que quieras!~^";
		plata:
			cacerola.comido=0;
			move uno to self;
			"~Gracias, vuelve pronto!~^";
		moneda:
			cacerola.comido=0;
			move uno to self;
			"~Bien, esto servirá, de momento~";
		}
	],
has animado escenario;

Personaje borracho "Borracho perdido" posada
with nombre 'borracho' 'hombre' 'ebrio' 'perdido' 'muy',
	 descripcion "Es un hombre ~muy~ ebrio, tan ebrio que no puede ni hablar",
	Enunciado [linea;
	    switch (linea) {
	     0: "¿No ha visto a mi amigo Pedro?";
	     1: "¿Qué tal está el vino?";
	     2: "¿Qué sabe del Barón?";
	     3: "¿Qué clase de secretos?";
		 4: "¿Cómo haré para descubrirlos?";
            }
        ],
	Respuesta [linea;
	    switch (linea) {
	     0:	self.QuipOff(0);
	    	"~Los amigos nunca se olvidan, siempre se llevan en el corazón~";
	     1:	self.QuipOff(1);
	    	"~Bien, Claro~";
	     2:	self.QuipOff(2);
			self.QuipOn(3);
		 	"~El Barón esconde oscuros secretos~";
		 3: self.QuipOff(3);
			self.Quipon(4);
			"~De los que cuestan el alma~";
		 4: self.QuipOff(4);
			"~Aparta las tinieblas de tí~";
	    }
	],
	InicializarQuips [;
	    self.QuipsOn(3, 0, 1, 2);
	],
vida[;
	Atacar: "~Déjalo en paz~, te detiene un campesino";
	Responder,Preguntar: "Mejor escribe ~habla con borracho~";
	Dar: "~Pon las cosas en su lugar, no aquí.~ dice el Borracho";
	],
has escenario animado;

Personaje soldado "Soldado" torre1a
with nombre 'soldado' 'enemigo' 'oponente',
	 descripcion "Tiene un hacha y luce peligroso",
	 pvida 3,
	InicializarQuips [;
	    self.QuipsOn(0);
	],
vida [;
	Atacar:
	if (espada in jugador)
		{
			for(:(self.pvida>=1||PuntosDeVida>=1):)
			{
				if (random(100)<=60){
					self.pvida--;
					print "^Impactas al soldado^";}
				else 
					print "^No alcanzas a pegarle^";
				if (random(100)<=45){
					PuntosDeVida=PuntosDeVida-(random(5)+1);
					print"El soldado te impacta^";}
				else 
					print "El soldado no alcanza a pegarte^";
					print "Tus ";
					<res>;
				if (PuntosDeVida<1){
					banderafin=1;
					"^El soldado clava letalmente el hacha en tu corazón^";}
				if (self.pvida<1){
					remove self;
					move hacha to torre1a;
					move llave1 to torre1a;
					move cadaver to torre1a;
					"Ha muerto, puedes ver que deja caer su hacha y
un pequeño objeto metálico^";}
			}
		}
	else
		{
		banderafin=1;
		"No tienes ningún arma.^
		Intentas golpear al soldado, pero él clava letalmente el hacha en tu corazón.";

		}
	Responder,Preguntar,Hablar: "~Morirás Intruso!~ dice el soldado^";
	],
has animado;

Objeto cadaver "Soldado muerto"
with nombre 'soldado' 'muerto',
	 descripcion "Es un soldado muerto, a manos de un valiente",
	 antes[;
		if (accion==##atacar)
			"Ya esta muerto, déjalo en paz^";
		],
has estatico animado;

Personaje mago "Extraño Mago" torre2a
with nombre 'mago' 'extraño' 'hechicero' 'diabolico',
	 descripcion "Es un extraño hombre de piel morena, está cubierto por una túnica negra.^
					parece alguna clase de hechicero diabólico.",
Enunciado [linea;
	    switch (linea) {
	     0: "¿Dónde esta Marina?";
	     1: "¿Quién eres tú?";
	     2: "¿Dónde está el Barón?";
	     3: "¿Porqué perderá el alma?";
		 4: "¿Qué es lo que tú quieres?";
            }
        ],
Respuesta [linea;
	    switch (linea) {
	     0:	self.QuipOff(0);
	    	"~La maldita está en un lugar seguro, no la atraparás jamás~";
	     1:	self.QuipOff(1);
	    	"~La pregunta debería ser qué soy, pero no querrás saberlo~";
	     2:	self.QuipOff(2);
			self.QuipOn(3);
		 	"~El Barón está preparándose para perder su alma~";
		 3: self.QuipOff(3);
			"~Intentará engañar al Amo y Señor de la Mentira~";
		 4: self.QuipOff(4);
			"~Yo sólo sirvo a mi Señor~";
	    }
	],
InicializarQuips [;
	    self.QuipsOn(4, 0, 1, 2, 4);
	],
vida[;
	Atacar:
		if(self notin capilla){
			move self to capilla; 
			"El mago desaparece";}
		else
			"Alguna clase de mano invisible te detiene.^
			 ~Imbécil, no ves que no puedes matarme!~ dice el mago^
			 ~Ahora tu morirás!~ dice el Barón";
	Responder,Preguntar: "Mejor escribe ~habla con mago~";
	Dar: "~No necesito nada de ti.~";
	],
has estatico animado escenario;

Personaje baron "Barón Fernando Antúnez"
with nombre 'baron' 'fernando' 'antunez',
	 descripcion "Es el Barón, el esposo de Marina,
	 el responsable de la muerte de tu amigo Pedro.^
	 Está ataviado de manera extraña: lleva una túnica y una cimitarra grabada.",
	 pvida 20,
	InicializarQuips [;
	    self.QuipsOn(0);
	],
vida [;
	Atacar:
	if (espada in jugador || hacha in jugador)
	{
		if (espada has puesta)
		{
			for(:(self.pvida>=1||PuntosDeVida>=1):){
				if (random(100)<=60){
					self.pvida=self.pvida-(random(8)+1);
					print "^Impactas al Barón^";}
				else 
					print "^No alcanzas a pegarle^";
				if (random(100)<=60){
					PuntosDeVida=PuntosDeVida-(random(5)+1);
					print"El Barón te impacta^";}
				else 
					print "El barón no alcanza a pegarte^";
					print "Tus "; <res>;
				if (PuntosDeVida<1){
					banderafin=1;
					print_ret (string) FinMalo;}
				if (self.pvida<1){
					remove self;
					banderafin=2;
					print_ret (string) FinBueno;}}
		}
		else
		if (hacha has puesta)
		{
			for(:(self.pvida>=1||PuntosDeVida>=1):){
				if (random(100)<=45){
					self.pvida=self.pvida-(random(10)+2);
					print "^Impactas al Barón^";}
				else 
					print "^No alcanzas a pegarle^";
				if (random(100)<=60){
					PuntosDeVida=PuntosDeVida-(random(5)+1);
					print"El Barón te impacta^";}
				else 
					print "El barón no alcanza a pegarte^";
					print "Tus ";
					<res>;
				if (PuntosDeVida<1){
					banderafin=1;
					print_ret (string) FinMalo;}
				if (self.pvida<1){
					remove self;
					banderafin=2;
					print_ret (string) FinBueno;}}
		}
		if (hacha hasnt puesta && espada hasnt puesta) "Debes blandir un arma primero";
	}
	else
	{
		print "Intentas atacar al Barón con tus propias manos, pero no consigues
			acercarte cuando el ya penetra tu cuerpo con su cimitarra";
		banderafin=1;
		print_ret (string) FinMalo;
	}
	Dar,Responder,Preguntar,Hablar: 
		print "~Morirás Infeliz!~ dice el Barón. ^Entran en combate, tu tienes la iniciativa.^";
		<<atacar self>>;
	],
has animado propio escenario;

!--------------------------------------------
!----------------- Rutinas ------------------
!--------------------------------------------

[ Inicializar o;
    localizacion=Comienzo;
	move armadura to jugador;
	move espada to jugador;
	move bolsa to jugador;
	move yesca to jugador;
	modomirar=2;
	box "   AAA    QQQ   U   U  EEEEE  L       AAA   RRRR   RRRR   EEEEE "
		"  A   A  Q   Q  U   U  E      L      A   A  R   R  R   R  E     "
		"  A   A  Q   Q  U   U  E      L      A   A  R   R  R   R  E     "
		"  AAAAA  Q   Q  U   U  EEEE   L      AAAAA  RRRR   RRRR   EEEE  "
		"  A   A  Q Q Q  U   U  E      L      A   A  R   R  R   R  E     "
		"  A   A  Q  QQ  U   U  E      L      A   A  R   R  R   R  E     "
		"  A   A   QQQQ   UUU   EEEEE  LLLLL  A   A  R   R  R   R  EEEEE "
		""
		"                Parte 1 - El legado Abrapampa";
	    print "^";
    Pause();
	modo_notificar=0;
	Portada();
	objectloop (o ofclass Personaje) { o.InicializarQuips(); }
];

[ Portada;
print "^Aquelarre Parte I v1.11^
	Una idea original de Ricard Ibañez^^Realizador: Pablo D'Amico^Copyright (c) 2000^^
	Esta aventura está inspirada en el módulo El Pacto del Manual de Aquelarre.^
	Este es un juego de rol basado en las tradiciones legendarias hispanas, 
	ambientado en la Baja Edad Media española. Pero no todo es como los libros de historia 
	nos cuentan. Coexistiendo con el hombre existe otro mundo más antiguo y sabio... 
	el mundo de la Fantasía, la Leyenda, la Magia, la Locura, de las Criaturas no 
	Humanas y del Diablo.^
	En cualquier momento ingresa AYUDA para conocer el sistema de juego^";
	Pause();
];

[ AyudaSub;
	CLS();
	print "********************************************************************************^
	 A lo largo del juego te vas a encontrar en diferentes lugares, con diferentes 
	 objetos y personas. Para interactuar con tu entorno tienes una serie de comandos
	 llamados ~verbos~ que se usan en imperativo (no reconocerá infinitivos). Estos 
	 son los verbos que puedes usar, aunque quizá algunos no sean útiles para esta
	 aventura(entre paréntesis, la abreviatura):^
	 Ve [punto cardinal]: norte(n), sur(s), este(e), oeste(o) y (ne) (se) (no) (so)^
	 Saca           Pon            Ataca       Arriba  (u)   Abajo   (d) ^
	 Entra          Sal            Mata        Excava        Llena       ^
	 Ponte          Sacate         Reza        Enfunda       Desenfunda  ^
	 Tira           Empuja         Lanza       Ata           Desata      ^
	 Habla con      Pregunta       Escucha     Enciende      Apaga       ^
	 Mira    (m)    Examina        Bebe        Huele         Come        ^
	 Grita          Canta          Prueba      Da            Llena       ^
	 Coge           Deja           Espera      Piensa        Muestra     ^
	 Abre           Cierra         Corta       Besa          Lee         ^
	 ********************************************************************************^
	 Comandos útiles:^
	 Puntuacion     Inventario(i)  Salidas (X) Vida  (v) -muestra puntos-^
	 Pistas -breve ayuda-          Salvar y Recuperar -un juego a disco-^
	 Quit -para salir- (q)
	 ********************************************************************************";
	pause(); print"^^";
	<<Examinar localizacion>>;
];

[ PowerSub;
	"Me parece que te equivocaste de aventura";
];

[ ResSub;
	print "Puntos de vida: ",PuntosDeVida,"^";
];

[ PagarSub;
	"Escribe ~da moneda de [tipo] a [personaje]~";
];

[ PistasSub;
	switch(localizacion)
		{
		Comienzo:"Ve hacia el norte";
		Campamento:"Coge comida";
		Camino1: "Examina la naturaleza";
		Camino2: "Mira lo que hay en el suelo";
		Arboleda:"No hagas enfadar al Jefe";
		Pueblo:  "Ve hacia el norte";
		Plaza:   "Explora bien todo";
		Posada:  "No escuches al posadero";
		Sendero: "Ponte el amuleto";
		Castillo:"Coge lo que puedas";
		Patio:   "Ve a las torres";
		Capilla: "Examina el Altar";
		Comedor: "Te gusta el Vino?, cógelo";
		torre1:  "Sube";
		torre1a: "Mata al soldado";
		torre2:  "Sube";
		torre2a: "Habla al mago";
		torre3:  "Sube";
		torre3a: "Apresúrate a salir de aquí";
		torre4:  "Sube";
		torre4a: "Entra a la celda";
		}
];

[ BlandirSub;
	if(uno has prenda)
	{
		if(uno hasnt puesto)
			{give uno puesto;
			"Blandes ", (el) uno;}
		else 
			"Ya llevas blandiendo ", (el) uno;
	}
	else 
	"No puedes blandir ", (el) uno, " porque no es un arma";
];

[ EnfundarSub;
	if(uno has prenda)
	{
		if(uno hasnt puesto)
			"No puedes porque no estas blandiendo ", (el) uno;
		else 
			{give uno ~puesto;
			"Enfundas ", (el) uno;}
	}
	else 
	"No puedes enfundar ", (el) uno, " porque no es un arma";
];

!--------------------------------------------
!--------------- Verbos Nuevos --------------
!--------------------------------------------

Verb 'ayuda' 'help'
    *					-> Ayuda;

Verb 'xyzzy'
    *					-> Power;

Verb 'v' 'vida'
    *					-> Res;

Verb 'pagar' 'paga'
	*					-> Pagar;

Verb 'pistas'
	*					-> Pistas;

Verb 'blande' 'desenfunda' 
    * noun   			-> Blandir;

Verb 'enfunda' 'guarda'
    * noun   			-> Enfundar;

!--------------------------------------------
!----------- Funciones de pantalla ----------
!--------------------------------------------
[ Pause i width;
    width = 0->33; if (width == 0) width = 80;
    spaces (width - 18);
    font off;print "[ Pulsa Espacio ]"; font on;
    do { @read_char 1 0 0 i; } until (i==32 or 10 or 13);
    CLS();
];

[ CLS ;
    @erase_window -1;
];

!Fin de Archivo!