$include 'knotstandard1.ala'	

Location shop name Knot Shop
	description
	if hero is sighted then 
		"$p$tThe shop still advertises
	instant escapes from life's hitches. Knotters still nimbly
	negotiate with the seriously stuck. A hopelessly knotted adventurer
	remains planted
	in the floorboards. $p$tBut now you can see
	a way out of here,
	an exit to the east."
		else		 
	"$p$tThis bustling venue offers
	instantaneous solutions to life's little entanglements. Nearby, nimble knotters
	knuckle down to their work."
		end if.
	
	exit w to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit nw to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit sw to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit n to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit s to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit se to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.

	exit ne to shop does 
		if hero is not sighted then
	"$p$tYou can't yet see a way out for yourself."
		else
	"$p$tNot that way!  This is not a good start for a would-be adventurer!"
	end if.
	end exit.


	exit e to shop
		check hero is sighted 
			else
		"$p$tYour vision is clouded by the pressing demands of other people's
			problems. You can't yet see a way out for yourself."
		and compass1 in inventory and map1 in inventory
			else
			"$p$tAren't you forgetting something?"		
		 does 
			"$p$tFinally you can follow your dreams! You have become the Body
			Adventura! $p$tAs you leave, you
			bequeath the Knot Shop to the former adventurer stuck in the floor.
			Bending over, you pat him gently on the head,
			and whisper the shop's motto in his ear.$p$p"
			Quit.
	end exit.

	
		
end location shop.

object shop2 name shop name venue at shop
	is not takeable.
	description
	verb examine does only
		if hero is not sighted then 
		"$p$tYou are not currently aware of any way out of the shop."
		else
		"$p$tThe shop still advertises
	instant escapes from life's hitches. Knotters still nimbly
	negotiate with the seriously stuck. A hopelessly knotted adventurer
	remains planted
	in the floorboards. $p$tBut now you can see
	a way out of here,
	an exit to the east."
		end if.
	end verb.
end object.

object knotters name nimble knotters at shop
	is not takeable.
	description
	verb examine does only
	"$p$tThey're all tied up with their work at the moment."
	end verb.
end object.

 
object sign1 name sign at shop
	is not takeable.
	is readable.
	description
		if hero is sighted then
	""
		else
	"There is a sign here."
	end if.

	verb read, examine does only
	"$p$t$t$t$t$t$t* * * * * * * 
$p$t$t$t$t $ $ $ $ $ $ $ $ : Our Prices: $ $ $ $ $ $ $ $p$t$t$t$t$tThough We Do Knot for Less, 
$n$t$t$t$t$tWe Ask Not Naught for a Knot!
	$p$t$t$t$t$t$t * * * * * * * $p$t$t$t$t$t$tOur Motto:$p$t
	$t$t$t$tNo Knot Unties Itself! $p$t$t$t$t$t$t* * * * * * * "
	schedule bodyarrival after 2.
	end verb.
end object.

object toes name toes at shop
	is not takeable.
	description
	verb examine does only
	"$p$tThey're grimy with dungeon dust."
	end verb.
end object.

object head name head at shop
	is not takeable.
	description
	verb examine does only
	"$p$tAdventura's head is examining you too."
	end verb.
end object.

object foot name foot at shop
	is not takeable.
	description
	verb examine does only
	"$p$tThe extended foot is very handy."
	end verb.
end object.

object torso name torso at shop
	is not takeable.
	description
	verb examine does only
	"$p$tBig, brave, bronze."
	end verb.
end object.

object dust1 name dungeon dust at shop
	is not takeable.
	description
end object.

object leg name leg at shop
	is not takeable.
	description
	verb examine does only
	"$p$tHow could he ever get it over his neck like that, you wonder?"
	end verb.
end object.

object scrotum name scrotum at shop
	is not takeable.
	description
	verb examine does only
	"$p$tThat's not very polite."
	end verb.
end object.

object neck name neck at shop
	is not takeable.
	description
end object.

object door name door at shop
	is not takeable.
	description
end object.

object floor name floor at shop
	is not takeable.
	description
end object.

object shoulder name shoulder at shop
	is not takeable.
	description
end object.


object map1 name map in bodya
	is not xed.
	is not normal.
	is readable.
	verb take does only
		if map1 is normal then
			"$p$t""Ah, ah, ah!""  You resecure the map."
			locate map1 in inventory.
		elsif bodya is compasslike and map1 is not normal then
			"$p$tYou slip the map out from between Adventura's now listless toes."
			make map1 normal.
			locate map1 in inventory.
			make hero mapped.
				if hero is compassed and hero is mapped then
					schedule change after 0.
				else
					""
				end if.
		else
			locate map1 in bodya.
			"$p$tHis toes grip more tightly on what must be an important map."
		end if.
	end verb.

	verb read, examine does only
	if bodya is compasslike then
	make map1 xed.
	"$p$tIt's got the look of a fabulous treasure map --
	crinkly, brownish, with snaky lines, arrows, big X's and stuff.
	This could be major."
		if map1 is xed and compass1 is xed then
		schedule end1 after 0.
		end if.
	else
	"$p$tAdventura grips it even tighter with those amazing toes. You can't get
	it away from him."
	end if.
	end verb.
end object.

object compass1 name compass in bodya
	is not xed.
	is not normal.
	is readable.
	verb take does only

	if compass1 is normal then
		"$p$tYou easily take the compass from the helpless Adventura."
		locate compass1 in inventory.
	elsif bodya is compasslike and compass1 is not normal then
		"$p$tAdventura's exhausted toes give up the compass."
		make compass1 normal.
		locate compass1 in inventory.
		make hero compassed.
			if hero is compassed and hero is mapped then
			schedule change after 0.
			else
			""
			end if.
	
	else
		locate compass1 in bodya.
		"$p$tYou'll have to get him to loosen his grip on it."
		end if.
	end verb.
	
	verb read, examine does only
	if bodya is compasslike then
	make compass1 xed.
	"$p$tIt's pointing east! And Adventura has been trying to trick you into
	going west!"
		if map1 is xed and compass1 is xed then
		schedule end1 after 0.
		end if.
	else
	"$p$tIt looks like one of those cheapo silver ones with the rickety
	needle inside. You can't seem to unbend Adventura's baby toe enough to
	wrest it out of his grasp."
	end if.
	end verb.
end object.
	

actor bodya name Body Adventura name body at limbo
	is not arrived.
	is not compasslike.
	 
	container
		Header
		"His toes are gripping"
		else
		"He is empty-toed."	
	is tied.
	description
	if hero is sighted then
	""
	else
	"The Body Adventura is here."
	list bodya.
	end if.
		
	verb examine does only
	if bodya is compasslike then
	"$p$tBody immobile, foot akilter, he looks just like a weather vane, pointing west."
	list bodya.
	else 
	"$p$tFrom the side he looks like a flamingo."
	list bodya.
	end if.
	end verb.
end actor.

event bodyarrival 

	if bodya is not arrived then 
	"$p$tThe door of the shop abruptly
	bangs inward and the Body Adventura crashes in, hopping unsteadily on
	one foot. 
	$n$tEeaagh!  He's somehow gotten himself stuck in a one-legged yogic pretzel
	position. His left leg is jammed up over the back of his neck, so the
	left foot shoots out awkwardly to the side, off his shoulder. Clasped in
	those toes are a map and a compass.$n$t
	""FRAZZIHW! SGNZXYZZY! INPLUGHKY! !! Red Rover, Red Rover let plover
	come over!"" 
	The Body Adventura rants on incoherently -- you can't make
	any sense out of what he's saying. After listening awhile, you  
	suspect that his predicament stems from the gyrations required by
	his love of adventuring. 
	$p$t""Help
	me, please,"" he implores you. ""I'm totally stuck!""" 
	locate bodya at shop.
	make bodya arrived.
	schedule wonder after 1. 
	else "" 
	end if. 
end event.

event wonder
	"$p$t(You begin to wonder why he's gripping that map and compass so
	tightly. What is it that's so important about them? Hmmmm ... could they
	point the way to a life outside of the knot shop, a different life, an
	exciting life?)"
	schedule wonder2 after 1.
end event.

event wonder2
	"$p$t(The more you think about it, the more you realize that you want to
	see the contents of that map. And while you're at it, you might as well
	try to grab that compass as well. Might come in handy, say, in trying
	to find an ice skating rink or a swimming pool.)"
	schedule wonder3 after 2.
end event.

event wonder3
	"$p$t(Something inside you demands that you examine that map and
	compass. In your eyes they now glitter like diamonds.)"
end event.

object hint1 name hint pill name hint in inventory
	is readable.
	is not given.
	description
	verb examine, read does only
	"$p$tIt's just a tiny little hint pill."
	end verb.
	verb give_to does	
	schedule hint2 after 0.	 
	end verb.
end object.

event hint2
	"$p$t""You need to learn to unwind a bit.""
	$n$tHe swallows the hint but the foot stays right where it is."
	locate hint1 at limbo.
	make hint1 given.	 
end event.

object wt1 name walkthrough potion name walkthrough in inventory
	is readable.
	is not given.
	description
	verb examine, read does only
	"$p$tWarning: Give this walkthrough potion only to those who
	do not suffer from
	debilitating Dis-Walkthroughbic Syndrome, wherein the soul suffers
	extreme guilt and angst for taking a peek, so much so that it must
	accuse all Non-Dis-Walkthroughbics of cheating."
	end verb.
	verb give_to does only
	schedule wt2 after 0.
	end verb.

end object.

event wt2 
	"$p$t""The foot bone's connected to the ANKLE bone,$n$t
	the ankle bone's connected to the SHIN bone,$n$t
	the shin bone's connected to the KNEE bone,$n$t
	the knee bone's connected to the THIGH bone,$n$t
	the thigh bone's connected to the HIP bone,$n$t
	the hip bone's connected to the ... $p$t$t$t
	NECK bone?""$p$t
	""I think I've already played through this part,"" Adventura mourns, scratching
	his scrotum (which happily seems to be easier to reach than it used to
	be.) $n$tHe gulps down the potion anyway, but it doesn't seem to help."
	locate wt1 at limbo.
	make wt1 given.
end event.
	
object adv name piece 'of' advice in inventory 
	description 
	verb listen_to does only 
	"$p$t""Wiggle your toes.""$n$tYou wiggle your toes, which feels good, though nothing happens.
	But why are you giving yourself advice?"
	end verb.
	verb examine does only 
	"$p$tGood idea. Always examine advice carefully.
	But maybe it would be better to listen to it?"	
	end verb. 

	verb give_to
		check hint1 is given and wt1 is given
			else
		"$p$tYou usually exhaust the remedies before giving advice."

		does 
		"$p$tIn the absence of further remedies, the Body Adventura begins to wiggle his toes,
	 first tentatively, then faster and faster. $n$tBefore long
	the flapping toes of the extended foot propel him into a
	spin, while the wiggling toes of the
	standing foot drill him slowly into the ground. As he finally grinds to
	a halt, only his upper torso is
	visible, consisting of a head, a neck, and a leg and a foot pointing west."
	locate adv at limbo.
	schedule question after 1.
	make bodya compasslike.
	make map1 takeable.
	make compass1 takeable.	
end verb.

end object.

event question
	"$p$tThe Body Adventura yells at you, ""Now look what you've done!
	You've gotten me more stuck than I was before! A fine knotter you turned
	out to be!""$p$tYou pause for a moment, stunned but elated. As you
	contemplate the potted adventurer in the floor, you realize you don't
	have to
	be Weava Knottersdaughter any longer."
end event.

event change
	"$p$tAnd immediately, you feel great, as though you've bolded, braved and
	bronzed up a bit. Yes! Soon YOU'RE going to be the Body Adventura!"
	
end event.

event end1

	"$p$tSomething about the shop suddenly seems different."
	make hero sighted.
end event.


actor hero Name Weava Knottersdaughter Name me name myself
	is not compassed.
	is not mapped.
	is not sighted.
	container
		 			
	verb examine does only
	if hero is compassed and hero is mapped then
	"$p$tThat's right! You are now the Body Adventura! You'll find that ice
	rink easily now!"
	else   
	"$p$tYou are Weava Knottersdaughter, professional knotter. You've
	unraveled many a line in your day. You're the best. $n$tBut you're not enjoying the thrill of
	knotting the way you used to. Lately you've been thinking about
	taking up synchronized swimming, or ice dancing, or something really
	exciting like that."
	end if.
	end verb.
end actor.
 
 
Start at shop.

"$p$p$p$p$p$t""So I'm sitting here in the shop, working on a Gordian, no less,
ripping away as usual, when this guy comes in with a noose tied securely around his
neck.$p$t ""Hey lady,"" he says, ""can you get this thing off my neck?"""

"$p$tThe other knotters chuckle with spiteful glee, their nimble fingers
plucking on twisted plaits. $p$t""So did you help him out?""
one of them asks. $p$t""Nah, he was a real pain in the you-know-what.""" 


"$p$p$p$p$p$p$t$t$t$t$t$t**KNOT TO BE UNDONE**$p$t$t$t$t$t *(A WackyComp
Production)*$p$t$t$t$t$t$t
            **by Jess Kiddon**
$p$t$t$t$t$t$t (aka Lelah Conrad)

$p$t$t$t$t$t  (Type credits or info for notes)"