[Título]
"SONRISAS... Y LÁGRIMAS"

Section 0 - Título y demás

[Datos de la ficción interactiva]
The story headline is "Una ficción interactiva creada por Santiago Eximeno para Chryshantemum.".
The release number is 1.
The story creation year is 2008.

[Includes]
Include Spanish Localization by Sarganar.
Include Basic Screen Effects by Emily Short.

[NOTAS DEL JUEGO

Juego creado para la II Rapidocomp, con las reglas
-desarrollo rápido
-incluir al menos tres temas de los cinco propuestos. Los escogidos:

*Grylloblattodea
*Eastmancolor
*Concierto para piano nº 3 (Bartók)
*Hijo del Hombre
*Giovanni Lanfranco

]

[=========== Inicio BEGIN =============]

Section 1 - Inicio

Rule for constructing the status line:
     center "[location]" at row 1;
     rule succeeds.

Use no scoring.

Use full-length room descriptions.

Use undo prevention.

Player is in Localizacion.

[INICIO DEL JUEGO]
When play begins:
clear the screen;
     display the boxed quotation
     "SONRISAS... Y LÁGRIMAS, ficción interactiva de Santiago Eximeno";
     show the current quotation;
say "[paragraph break][bold type]Grylloblatto, la criatura [roman type]metamórfica de dos metros de altura que a tus ojos se presenta como una mezcla dispersa -y desproporcionada, aterradoramente desproporcionada- de cucaracha, grillo y campodea sostiene la cámara entre sus zarpas quitinosas mientras realiza los últimos ajustes. Entre sus fauces -un batiburrilo demencial de órganos creados para funciones más allá de tu imaginación- se debaten los restos sin vida de Lucina Lanfranco, [italic type]prima donna [roman type] de la obra [bold type]Hijo del Hombre[roman type].";
say "Es evidente que la película se ha quedado sin su protagonista."; 
say "Mientras Grylloblatto mastica, te hace una señal con una de sus extremidades superiores, indicándote que vuelvas al escenario. Como un perrito acobardado obedeces. Los restos de vómito pegados a tu ropa hacen que te sientas sucio, débil. Las lágrimas se han solidificado en tu rostro, estrías de dolor que no puedes borrar. ¿Cuánto durará esto?";
say "En el escenario los cadáveres mutilados se amontonan en configuraciones aleatorias. Crees descubrir un patrón, pero cuando Grylloblatto escupe el cuerpo de Lucina y te dedica uno de sus aullidos incomprensibles, te vuelves y le miras.";
say "La película debe continuar.";
say "Y Grylloblatto quiere rodarla en Eastmancolor.";
say "Vuelve a empezar -¿cuántas veces van ya?- el concierto para piano número 3 de Bartók y te tiemblan las piernas";
wait for any key;
clear the screen;

[=========== Inicio END =============]


[=========== Localizaciones BEGIN =============]

[Localizaciones
#Define las localizaciones en las que tiene lugar la ficción interactiva
#Define el escenario de fondo
]

Section 2 - Localizaciones

[Sólo tenemos una localización real]
Localizacion is a room. "[if unvisited]Sobre el escenario, temblando como un bebé y rodeado de cadáveres, esperas en silencio a que Grylloblatto hable. Cuando lo hace, empiezas de nuevo a llorar.[end if][if visited]Estás sobre el escenario en el que se representaba la obra Hijo del Hombre. Docenas de cadáveres mutilados te rodean. Grylloblatto, frente a tí, te enfoca con su cámara.[end if]" .

Understand "ex escenario"  or "examina escenario" or "mira escenario" or  "examinar escenario" or "mirar escenario" or "m escenario" as looking.

[Un poco de escenario para ambientar]
EscEscenario is scenery in Localizacion.
Understand "cadaver" or "cuerpo" or "muerto" or "mutilado" or "mano" or "pie" or "tronco" or "cadaveres" or "Jesucristo" or "Jesus" or "troupe" or "actor" or "actores" or "protagonista" as EscEscenario.
The description of EscEscenario is "Sangre. Cadáveres mutiliados por todas partes. Toda la troupe de actores que representaba [bold type]Hijo del Hombre[roman type], masacrados vilmente. Si te fijas puedes descubrir al protagonista, en el papel de Jesucristo, allí. Y allí. Y allí".

Instead of taking some scenery in Localizacion: say "¿Te has vuelto loco? ¡Sonríe!".

[El nombre es un homenaje a tres inventores de máquinas del tiempo]
The printed name of Localizacion is "El escenario de la obra Hijo del Hombre"

EscSangre is scenery in Localizacion.
Understand "sangre" or "manchas de sangre" or "manchas" or "mancha" as EscSangre.
The description of EscSangre is "Hay restos de sangre por todas partes.".

[=========== Localizaciones END =============]


[=========== Plano BEGIN =============]
[Plano
#incluye los enlaces entre las diferentes localizaciones
]

Section 3 - Plano

[En este caso, evidentemente, no tenemos plano]

[=========== Plano END =============]



[=========== Direcciones BEGIN =============]

[Direcciones
#resuelve el movimiento entre las localizaciones para evitar el uso de ir al norte, al sur... Queremos que se abra la puerta, no que nos movamos con una brújula.
]

Section 4 - Direcciones

A room can be ahora or antes or despues or mucho antes or mucho despues.
A room is usually ahora.

Understand "norte" or "n" or "sur" or "s" or "este" or "e" or "o" or "oeste" or "noreste" or "ne" or "sureste" or "se" or "noroeste" or "no" or "suroeste" or "so" as "[direccion]".

Localizacion is ahora.

After reading a command:
If the player's command includes "[direccion]"
begin;
  say "Sólo tienes una salida... ¡Sonríe!";
  reject the player's command;
end if;


[=========== Direcciones END =============]


[=========== Personajes BEGIN =============]

Section 5 - Personajes

[No hemos definido personajes en esta aventura]

[=========== Personajes END =============]

[=========== Objetos BEGIN =============]

Section 6 - Objetos

[ Objetos ]

Grylloblatto is a thing. 
Grylloblatto is fixed in place.
Grylloblatto is male.
Grylloblatto is in Localizacion.
The printed name of Grylloblatto is "Grylloblatto".
The description of Grylloblatto is "Grylloblatto.".
Understand "criatura" or "director" or "cucaracha" or "grillo" or "campodea" as Grylloblatto.

Lucina is a thing. 
Lucina is fixed in place.
Lucina is female.
Lucina is in Localizacion.
The printed name of Lucina is "Lucina".
The description of Lucina is "Lucina.".
Understand "prima donna" or "Lanfranco" as Lucina.

The Camara is a thing.
The Camara is fixed in place.
The Camara is female.
The Camara is in Grylloblatto.
The printed name of Camara is "camaral".
The description of the Camara is "Una cámara de cine.".


[=========== Objetos END =============]



[=========== Acciones de decorado BEGIN =============]

Section 7 - Acciones de Decorado

[General: no mostrar la lista de objetos y personas en la habitación]
Rule for listing nondescript items of a room: stop.

[Escuchar/Oler]
Instead of smelling:
Say "El olor de la sangre es embriagador.";

Instead of listening:
Say "El odioso concierto para piano reverbera en tus oídos. Lo odias.";

Every turn: 
if player has been in Localizacion for exactly 1 turn, say "-Sonríe -dice Grylloblatto-. Hazme ese favor";
if player has been in Localizacion for exactly 3 turns, say "-Sonríe -dice Grylloblatto-. Por favor.";
if player has been in Localizacion for exactly 6 turns, say "-Sonríe -dice Grylloblatto-. Hazlo.";
if player has been in Localizacion for exactly 9 turns, say "-Sonríe -dice Grylloblatto-. Ya.";
if player has been in Localizacion for exactly 10 turns, say "-Sonríe -dice Grylloblatto-. Ahora.";
if player has been in Localizacion for exactly 11 turns 
begin;
say "-Muy bien -dice Grylloblatto-, no sonrías. Muy bien. En fin, creía que eras diferente. Ahora veo que eres como los otros.";
say "Grylloblatto da dos pasos hacia tí. Sientes la orina deslizándose por la pernera de tus pantalones. Gracias al Cielo, esta obra estaba concebida para un público infantil. Así podremos ahorrar al público la descripción de lo que Grylloblatto va a hacerte.";
say line break;
center "FIN";
end the game in death;
end if;

The description of a thing is usually "No tienes fuerza para mirar nada más.";

[=========== Acciones de decorado END =============]


[=========== Acciones y reglas BEGIN =============]

Section 8 - Acciones y reglas

Instead of waiting:
say "¿Qué quieres esperar? ¡Sonríe!";

Instead of examining the player: 
say "Estás horrible. Mejorarías mucho si... ¡sonrieras!";

Instead of examining the camara:
say "Sí, una cámara preciosa, pero... ¿no quieres sonreír?";

Instead of pushing Grylloblatto:
say "¿Es una broma?";

Instead of taking Grylloblatto:
say "Bromeas, ¿verdad?";

Instead of examining Grylloblatto:
say "Grylloblatto sigue tan hermoso y aterrador como hace un instante.";

Instead of rubbing something:
say "Sí, podría ser buena idea limpiar la sangre... Pero ahora mismo no te sientes con fuerza.";

Instead of singing:
say "No te sientes con fuerzas para tararear ninguna pieza de Batók.";

Instead of attacking Grylloblatto:
say "Bromeas, ¿verdad?";

[Reglas para la comunicación con otros PNJs]

Instead of telling someone about something, try asking the noun about it. 
Instead of answering the noun that something, try asking the noun about it. 

[=========== Acciones y reglas END =============]


Section 9 - Inventario

Instead of taking inventory:
	say "No llevas nada encima que te pueda resultar útil en estos momentos.";

Section 10 - Verbos

Sonreing is an action applying to nothing.

Understand "sonrie" or "sonreir" or "sonrio" or "sonrisa" as Sonreing.

Carry out Sonreing:
say "-¡Muy bien! -dice Grylloblatto-. Muy bien. Sigue así, hermosa sonrisa.";
say "Grylloblatto da dos pasos hacia tí. Sientes la orina deslizándose por la pernera de tus pantalones. Gracias al Cielo, esta obra estaba concebida para un público infantil. Así podremos ahorrar al público la descripción de lo que Grylloblatto va a hacerte.";
say line break;
center "FIN";
end the game in death.

Rezing is an action applying to nothing.

Understand "reza" as Rezing.

Carry out Rezing:
say "No, rezar no te servirá de nada, ahora estás más allá de la ayuda divina.";


Saliding is an action applying to nothing.

Understand "salidas" as Saliding.

Carry out Saliding:
say "No vas a poder salir de aquí con vida, ya lo sabes.";

CogerToding is an action applying to nothing.

Understand "coge todo" or "coger todo" as CogerToding.

Carry out CogerToding:
say "¿Todo? Estás loco.";

Rule for printing a parser error when parser error is not a verb I recognise: 
    say "Estás confuso, no tienes demasiado claro qué hacer." instead. 

Section 11 - Muerte

Rule for printing the player's obituary: 
    say paragraph break;
    center "EPÍLOGO"; 
    center "¿Demasiado breve? Ah, es lo que tiene la vida, que es breve.";
    center "Sabías que tras las sonrisas siempre vienen";
    center "las lágrimas.";
    say paragraph break; 
    center "Sonrisas... y lágrimas"; 
    center "una ficción interactiva creada por Santiago Eximeno"; 
    center "(c) 2008 Chryshantemum"; 
    say paragraph break; 
    wait for any key; 
    stop game abruptly; 
    rule succeeds.