"Iraqi Invasion: A Text Misadventure" by Anonymous

[Inform 7 story file Copyright 2008 by Anonymous]

[ATTENTION: The contents of the source file intentionally incorporate text and story elements created by Matthew Baldwin, and which are presumably copyrighted by him as of their publication in early 2006. See

    http://www.defectiveyeti.com/archives/001561.html

for this original material, which is used by permission of Mr. Baldwin. The author strongly recommends you seek additional permission from Mr. Baldwin before making changes that would cause *any* deviation from the standard transcript provided in the URL above.

This story file also incorporates Inform code provided in example 320 of the Inform 7 documentation ("Writing with Inform") as provided in version 5G67. No permission was sought before use of this code, which was presumed to be fair use.]

[
   This program is free software: you can redistribute it and/or modify
    it under the terms of the GNU General Public License as published by
    the Free Software Foundation, either version 3 of the License, or
    (at your option) any later version.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this program.  If not, see <http://www.gnu.org/licenses/>.
]

Include GNU General Public License v3 by Free Software Foundation.

[A complete copy of the GNU GPL license is included in the release materials for this work of interactive fiction. See the text file titled "COPYING".]


Chapter 0 - Ground Rules

Section 1 - Compiler Behavior

Use American dialect.

Section 2 - New Synonyms

Understand "invade [something]" as attacking.

Understand "look [something]" as examining.

Understand "fill [clothing]" as wearing.

Understand "eat [something]" as eating.

Understand "go to [something]" as entering.

Understand "diagnosis" as requesting the score.

Section 3 - New Verbs

Electionhaving is an action applying to nothing. Understand "get reelected" as electionhaving.
	Instead of electionhaving when the election year is not happening now and the United States is not attacked, say "We just had an election. Dick says it's time for some real work -- something about an Energy Task Force?"
	Instead of electionhaving when the election year is not happening now, say "Why would you have an extra election? There's barely enough time to 'prepare' for the next one."
	Instead of electionhaving when the election year is happening now and the player is not in Compassionate Conservatism, say "You need to shift your political stance to something more appealing before you can get re-elected."

Carry out electionhaving:
	say "You get reelected."	

After electionhaving:
	wrap up the election.


Petting is an action applying to one touchable thing. Understand "pet [something]" as petting.

Carry out petting:
	say "You stroke [the noun] gently. Your favorite [noun]."


[APPARENT RULES
1. Match input "give speech" exactly -- this initiates action context for indefspeechgiving.
2. replace text as instructed to "give speech people" -- action context for activities evaluation remains indefspeechgiving
3. Parser tries to match inserted "people", finds two nouns that correspond: American People (by being part of name) and citizens of the world (by forced one-word match via "understand 'people' as citizens of the world" rule)
4. Parser now has to clarify which noun is meant, engages rule about asking which do you mean *and* is prepared to take new text as clarification.

In a more general case, you could add an unusual name (e.g. "Understand 'indefpeople' as citizens of the world. Understand 'indefpeople' as the American People.) to all things you want to have accepted in the prompt following your replacement "asking which do you mean" rule. However, the player will not be given any guidance as to what things are covered by the prompt.]


Indefspeechgiving is an action applying to one thing. Understand "give speech [something]" as indefspeechgiving.

Carry out indefspeechgiving:
	try speechgiving the noun.

After reading a command (this is the watch for two-word give speech command rule):
	if the player's command matches "give speech", replace the player's command with "give speech indefpeople".

Rule for asking which do you mean while indefspeechgiving:
	say "Who do you want to give the speech to?"


Speechgiving is an action applying to one thing. Understand "make speech to [something]" or "make speech [something]" or "deliver speech to [something]" or "deliver speech [something]" or "give speech to [something]" as speechgiving.

Check speechgiving:
	if noun is not an audience begin;
		say "I know public speaking is hard, but practicing on [the noun] probably won't help.";
		stop the action;
	end if;

Carry out speechgiving:
	now the noun is spoken to.

Report speechgiving:
	say "You give a generic speech full of hypocritical platitudes, coded messages to your rabid base, and amusing neural misfires."


Threathyping is an action applying to nothing. Understand "hype threat" as threathyping.

Carry out threathyping:
	if the United States is not attacked begin;
		say "Unfortunately, there is no threat to hype.";
	otherwise;
		say "'The British government has learned that Saddam Hussein recently sought significant quantities of uranium from Africa.'";
		change threat of Al Qaeda to grossly inflated;
	end if;

Fearmongering is an action applying to nothing. Understand "monger fear" as fearmongering.

Carry out fearmongering:
	if the United States is not attacked begin;
		say "Regrettably, there is no fear to monger. Things have been pretty good lately.";
	otherwise;
		say "'Facing clear evidence of peril, we cannot wait for the final proof -- the smoking gun -- that could come in the form of a mushroom cloud ...'";
		change fear of other religions to skillfully mongered;
	end if;

Watermuddying is an action applying to nothing. Understand "muddy water" as watermuddying.

Carry out watermuddying:
	if the United States is not attacked begin;
		say "If only the public were interested in something, you could try to confuse them about it.";
	otherwise;
		say "'We know that Iraq and the al Qaeda terrorist network share a common enemy -- the United States of America. We know that Iraq and al Qaeda have had high-level contacts that go back a decade. And we know that after September the 11th, Saddam Hussein's regime gleefully celebrated the terrorist attacks on America ...'";
		change accurate perception of reality to poisoned by Fox News;
	end if;

Criticpunishing is an action applying to nothing. Understand "punish critics" as criticpunishing.

Carry out criticpunishing:
	if the United States is not attacked begin;
		say "None of your critics matter right now.";
	otherwise;
		say "'Wilson never worked for the CIA, but his wife, Valerie Plame, is an Agency operative on weapons of mass destruction ...'";
		change testimony of administration critics to criminally undermined;
	end if;

Congressrailroading is an action applying to nothing. Understand "railroad congress" as congressrailroading.

Carry out congressrailroading:
	if the United States is not attacked begin;
		say "Surprisingly, they're too stubborn to railroad at the moment.";
	otherwise;
		say "You schedule a vote on the Iraq invasion for just before the 2002 midterm elections. As usual, spineless democrats roll over like an SUV taking a sharp corner.";
		change the Democrat's general attitude to completely panic-struck;
	end if;

Coursestaying is an action applying to one thing. Understand "stay [something]" as coursestaying.
	Carry out coursestaying the course when Iraq is invaded and the insurgents are not in Baghdad:
		say "The situation in Iraq remains unchanged."
	Carry out coursestaying the course when Iraq is invaded and the insurgents are in Baghdad:
		say "The situation in Iraq deteriorates."
	Before coursestaying in the Political Spectrum:
		say "(first returning to [last real place of the player])[command clarification break]";
		move player to the last real place of the player, without printing a room description.

Mistakeadmitting is an action applying to nothing. Understand "admit mistakes" as mistakeadmitting.

Carry out mistakeadmitting:
	if the insurgents are not in Baghdad begin;
		say "You haven't made any mistakes that the public demands an answer for... yet.";
	otherwise;
		say "You are unable to admit mistakes.";
	end if;

Responsibilityaccepting is an action applying to nothing. Understand "accept responsibility" as responsibilityaccepting.

Carry out responsibilityaccepting:
	if the insurgents are not in Baghdad begin;
		say "There's nothing you need to accept responsibility for... yet.";
	otherwise;
		say "You are unable to accept responsibility.";
	end if;

Victorydeclaring is an action applying to nothing. Understand "declare victory" as victorydeclaring.

Report victorydeclaring:
		say "There's nothing to declare victory about at the moment.";

Instead of victorydeclaring when the United States is not attacked, say "Yes! Eat that, Gore!"

Instead of victorydeclaring when the United States is attacked and Afghanistan is not invaded, say "But the battle has just begun!"

Instead of victorydeclaring when the United States is attacked and Afghanistan is invaded and Iraq is not invaded, say "Your real victory still eludes you."

Instead of victorydeclaring when the United States is attacked and Afghanistan is invaded and Iraq is invaded and the insurgents are not in Baghdad, say "USA! USA! USA! This calls for another photo-op. Karl's got something lined up with an aircraft carrier."

Instead of victorydeclaring when the insurgents are in Baghdad and the insurgents are very small, say "It would be unseemly to declare victory until the rioting dies down a bit."

Instead of victorydeclaring when the insurgents are in Baghdad, say "Maybe in another six months or so... we've reached a real turning point!"

Instead of victorydeclaring when the insurgents are in Baghdad and the player is somehow reelected to another term the first time, say "I do not know what you mean by 'victory.'"

Instead of victorydeclaring when the insurgents are in Baghdad and the election survival status of the player is somehow reelected to another term at least twice, say "I do not know what you mean by 'victory'... and neither do you, it seems."


Understand the command "say" as something new.

Speaking is an action applying to one topic. Understand "say [text]" as speaking.

Carry out speaking:
	let PLAYERINPUT be "[the topic understood]" in sentence case;
	let FIRSTCHAR be character number 1 in PLAYERINPUT;
	if FIRSTCHAR is "[quotation mark]" begin;
		let SECONDCHAR be character number 2 in PLAYERINPUT;
		change SECONDCHAR to SECONDCHAR in upper case;
		replace character number 2 in PLAYERINPUT with SECONDCHAR;
		let N be the number of characters in PLAYERINPUT;
		let LASTCHAR be the character number N minus 1 in PLAYERINPUT;
		if LASTCHAR is "." or LASTCHAR is "!" or LASTCHAR is "?" begin;
			say "[PLAYERINPUT][line break]";
		otherwise;
			replace character number N in PLAYERINPUT with ".";
			say "[PLAYERINPUT]'[line break]";
		end if;
	otherwise;
		let N be the number of characters in PLAYERINPUT;
		let SECONDLASTCHAR be the character number N in PLAYERINPUT;
		if SECONDLASTCHAR is not "." and SECONDLASTCHAR is not "!" and SECONDLASTCHAR is not "?" begin;
			say "'[PLAYERINPUT].'";
		otherwise;
			say "'[PLAYERINPUT]'[line break]";
		end if;
	end if;



Section 4 - New Kinds

A country is a kind of backdrop. A country can be invaded or not invaded. A country can be attacked or not attacked. A country is enterable. A country has a room called the associated room. The associated room is usually nothing.
	Instead of entering a country that is not invaded, say "You'd like to 'go' there, but not as a tourist, if you know what I mean."
	After entering a country:
		let the destination be the associated room;
		if the destination is nothing begin;
			say "You can't seem to figure out how to get there.";
		otherwise;
			move player to the destination;
			change last real place of the player to the destination;
		end if;

An audience is a kind of backdrop. An audience can be spoken to. Understand "indefpeople" as an audience.

Clothing is a kind of thing. Clothing is usually wearable.

Food is a kind of thing. Food is usually edible.

Furniture is a kind of thing. 
A well-documented pre-existing goal is a kind of thing. It can be hidden from public view or easily verified online.

A criminal organization is a kind of thing. It can be fruitlessly pursued militarily or dealt with effectively through police action.

A well-connected gang of war profiteers is a kind of person. It is scenery. Understand "contractor" as a well-connected gang of war profiteers.

A chickenhawk is a kind of man. It can be extremely hypocritical. It is usually extremely hypocritical. 


Section 5 - New Rules

A thing can be examined.

last carry out examining something:
	now the noun is examined.

last carry out attacking a country:
	now the noun is invaded.

A procedural rule:
	if the United States is attacked then ignore the block attacking rule.

Instead of swearing obscenely:
	say "'Profanity is the crutch of the conversational cripple,' according to... some dipshit egghead or other."

Rule for writing a paragraph about a person in a room:
	say "[printed name] is here.".

Rule for writing a paragraph about a thing in a room:
	say "There is a [printed name] here."

Check attacking a country that is invaded:
	say "Invade me once...[line break]shame on...[line break]shame on you.[line break]...[line break]If-invaded-me-can't-get-invaded-again!" instead.

Chapter 1 - The Real World

This is the real world movement restrictions rule:
	abide by the Oval Office movement rule;
	abide by the Photo Op movement rule;
	abide by the Afghanistan movement rule;
	abide by the Iraq movement rule.


Section 1 - The Immediate World

The Oval Office is a room. The description of the Oval Office is "[if unvisited]You are standing inside a White House, having just been elected to the presidency of the United States. You knew Scalia would pull through for you.

[end if]There is a large desk here, along with a few chairs and couches. The presidential seal is in the middle of the room and there is a full-length mirror upon the wall.[if unvisited]

What do you want to do now?[end if]". Right from the Oval Office is the Oval Office. Left from the Oval Office is the Oval Office.

Instead of swearing obscenely in the Oval Office:
	say "Such language in a high-class establishment like this!"

Instead of going nowhere from the Oval Office (this is the avoid tourists rule):
	say "You really hate to leave the Oval Office. There are tourists out there sometimes."

Instead of exiting in the Oval Office (this is the photoop hint rule):
	say "You only ever leave the White House when you go to carefully-controlled photo-ops."

This is the Oval Office movement rule:
	abide by the avoid tourists rule;
	abide by the photoop hint rule.

The desk is scenery in the Oval Office. "[if examined]You love this desk. It doesn't look quite the same as when you see it in the movies, but it's very presidential.[otherwise]It is a large, oak desk, with several drawers." Understand "large desk" as the desk. It is a container.
	After examining the desk:
		silently try searching the desk.
	After searching the desk:
		if the bag is in the desk, try taking the bag.

The bag is in the desk. The printed name is "bag of Mr. Salties". The description is "There are still a few pretzels left."
	Before taking the bag:
		if the bag is not handled, say "In one drawer you find a bag of pretzels." 
	Instead of eating the bag:
		say "You know from past experience that eating plastic sounds more fun than it actually is."

Some pretzels are food. They are in the bag. The description is "So delicious.... but they can't be trusted." Understand "pretzel" or "salties" as the pretzels.
	Instead of eating the pretzels:
		say "I don't think the pretzels would agree with you.";
		move the pretzels to the bag.

Rule for implicitly taking the pretzels:
	try silently taking the pretzels.	

To obtain a slightly better man's shoes:
	change Clinton's shoes to found;
	move Clinton's shoes to the location;
	silently try taking Clinton's shoes.

The chairs are furniture in the Oval Office. They are scenery. The chairs are portable. Understand "few chairs" as chairs. The description is "[one of]They are several chairs arranged around the center of the room, along with two couches.[if Clinton's shoes are lost] Under one couch you find Clinton's shoes.[end if][or]People sit in them when they tell you what to say and do.[stopping]". Understand "chair" as chairs.
	Instead of pushing the chairs:
		try taking the chairs.
	Instead of pulling the chairs:
		try taking the chairs.
	Instead of taking the chairs:
		say "You need more people to play musical chairs."
	After examining the chairs when Clinton's shoes are lost:
		obtain a slightly better man's shoes.

The couches are scenery in the Oval Office. "[one of]They are two couches arranged around the center of the room, along with several chairs.[if Clinton's shoes are lost] Under one couch you find Clinton's shoes.[end if][or]Perfect for napping![stopping]". Understand "couch" as couches.
	After examining the couches when Clinton's shoes are lost:
		obtain a slightly better man's shoes.
	Instead of searching the couches when Clinton's shoes are lost:
		say "Under one couch you find Clinton's shoes.";
		obtain a slightly better man's shoes.

The presidential seal is scenery in the Oval Office. "They once gave you a stamp that would put a little version of this on things, but they had to take away. You still get to play with it when you've been very good."
	Instead of petting the seal:
		say "It's not that kind of seal."

The mirror is scenery in the Oval Office.
	Instead of examining the mirror:
		say "Self-reflection is not your strong suit."

The wall is scenery in the Oval Office. "The few, almost unnoticeable crayon marks are a testament to diligence of the White House cleaning staff." Understand "walls" as the wall.

Section 2 - The Outside World

The United States is a country. It is everywhere. Understand "America" as the United States.
	Instead of attacking the United States:
		say "Maybe later."
	Instead of speechgiving the United States:
		try speechgiving the American People.

The American People is an audience that is everywhere. It can be rallied to tough talk.  Understand "public" as the American People. 
	Instead of speechgiving the American People when the United States is not attacked:
		say "Karl and Dick say it's best to stay out of the spotlight, for now."
	After speechgiving the American People when the United States has been attacked:
		say "You give the speech to the American people. Critics wonder if your use of the word 'crusade' was deliberate."

The citizens of the world are an audience that is everywhere. Understand "everyone" or "people" or "people of the world" as the citizens of the world.
	Instead of speechgiving the citizens of the world:
		say "You don't care about the opinion of the rest of the world, so why try to manipulate it?"

Afghanistan is a country. It is everywhere. The associated room is Mountains of Afghanistan. Understand "the nation of Afghanistan" as Afghanistan.
	Instead of attacking Afghanistan when the United States is not attacked, say "You are not able to do that, yet."
	After attacking Afghanistan:
		try entering Afghanistan;
		continue the action.

The Mountains of Afghanistan is a room. "[if unvisited]You have invaded the nation of Afghanistan, bombing the Taliban nearly out of existence.[otherwise if Iraq is not invaded]You and your army are in Afghanistan.[otherwise]You and a few badly-outnumbered bits of your army are in Afghanistan."

This is the Afghanistan movement rule:
	yes.

The long-suffering people of Afghanistan is a audience. They are in the Mountains of Afghanistan. They can be callously abandoned in favor of more profitable endeavors.

Osama Bin Laden is a male person with printed name "Osama Bin Laden, mastermind of the 9/11 attacks,". He is in the Mountains of Afghanistan.

Iraq is a country. It is everywhere. The associated room is Baghdad.
	Before attacking Iraq:
		if Afghanistan has been invaded and the long-suffering people of Afghanistan are not callously abandoned in favor of more profitable endeavors begin;
			say "(Leaving Afghanistan first.)[command clarification break]";
			now the long-suffering people of Afghanistan are callously abandoned in favor of more profitable endeavors;
		end if;
	Instead of attacking Iraq when the public consent for war is not manufactured or Afghanistan is not invaded:
		say "You are not able to do that, yet."
	After attacking Iraq:
		try entering Iraq;
		now the player is carrying the flightsuit;
		continue the action.


Baghdad is a room. "[if unvisited]You enter the Iraqi capital of Bagdad, having toppled the government and captured the nation's key cities in only 21 days. You can't seem to find the promised throngs of citizens greeting you as liberators, but the footage of the Saddam statue being pulled down looks great on Fox![otherwise]You are trapped in an interminable conflict in Iraq."

This is the Iraq movement rule:
	yes.

The carefully-controlled photo-op is a backdrop that is scenery. It is enterable. It is everywhere. Understand "photoop" as the photo-op.
	Instead of entering photo-op:
		move player to Photo Op.

This is the Photo Op movement rule:
	yes.

Home is a backdrop that is scenery. It is enterable. It is everywhere.
	Before entering home:
		if the United States is attacked, say "You fly around aimlessly for a while, then return to the White House."
	Instead of entering home:
		move player to Oval Office;
		change last real place of the player to Oval Office.

Understand "White House" as Home.

Photo Op is a room. "You are at a the Emma T. Booker Elementary School, along with a gaggle of obsequious members of the mainstream media."

Instead of swearing obscenely in the Photo Op:
	say "Karl's lessons with the shock collar have taught you not to say things like that in public."

A book is here. The description is "[if not examined]You read 'My Pet Goat.'[otherwise]You continue to read 'My Pet Goat.'"
	After examining book:
		if the United States is not attacked begin;
			say "In the distance, terrorists attack the United States.";
			change the United States to attacked;
			end if.
	After examining the book for the fifth time, say "It's such a gripping tale -- it's impossible to put it down!"
	After examining the book for the tenth time, say "Keep reading... pretty soon you'll be past the first page!"
	After examining the book for the 15th time, say "Boy, you sure love this book."
	After examining the book for the 25th time, say "You wonder what happens at the end. Someday, you promise yourself, someday..."
	After examining the book for the 35th time:
		say "Dick Cheney comes by and takes the book away, growling something about work to do as he departs.";
		remove the book from play;
		say "[line break]Darn."

Some children are here. The description is "The children is learning. You're the education prezdint!" The indefinite article is "some". They are plural-named.

Rule for writing a paragraph about the children:
	say "There are some children here." instead.
[*** not the right way to do this! ***]

The vacation is a backdrop that is scenery. It is everywhere.
	Instead of taking the vacation:
		say "Taken."

The mission is a backdrop that is scenery. It is everywhere.

Instead of examining the mission when the United States is not attacked,
		say "Right now, your instructions are to stay out of trouble. Dick said he'll call if he needs you."
Instead of examining the mission when the United States is attacked,
		say "The mission is not accomplished."
Instead of examining the mission when the insurgents are large or overwhelming, say "You'd rather not talk about the mission right now."

Halliburton is a well-connected gang of war profiteers in the Oval Office.

Bechtel is a well-connected gang of war profiteers in the Oval Office.

The Carlyle group is a well-connected gang of war profiteers in the Oval Office.


Chapter 2 - The Ideological World

A direction can be political or spatial.

Right is a direction with opposite left, Inform property "r_to"
and Inform object "r_obj". Include (- with name 'r//' 'right',
door_dir r_to, -) when defining right. Right is political.

Left is a direction with opposite right, Inform property "l_to" and
Inform object "l_obj". Include (- with name 'l//' 'left', door_dir
l_to, -) when defining left. Left is political.

Include (- with r_to 0, l_to 0, -) when defining a room.

The Political Spectrum is a region.

Instead of going a political direction when not in the Political Spectrum:
	move the player to the last political stance of the player, without printing a room description;
	consider standard set going variables rule;
	continue the action.	

After going in the Political Spectrum:
	change last political stance of the player to the location;
	continue the action.

Instead of going a spatial direction when in the Political Spectrum:
	move the player to the last real place of the player, without printing a room description;
	consider standard set going variables rule;
	abide by the real world movement restrictions rule;
	continue the action.	

After going from somewhere not in the Political Spectrum:
	change last real place of the player to the location;
	continue the action.

A political stance is a kind of room. An ideology is a kind of political stance.

Compassionate Conservatism is a political stance in the Political Spectrum. "You are right-of-center on the political spectrum."
	Instead of going left in Compassionate Conservatism, say "That would be going the way of the DINOs."

John McCain is a man. He is in Compassionate Conservatism.

Joseph Lieberman is a man. He is in Compassionate Conservatism.

Far-Right is a political stance in the Political Spectrum. "You are on the far right of the political spectrum." Far-Right is right from Compassionate Conservatism.

Jesse Helms is a man. He is in Far-Right.

John Ashcroft is a man. He is in Far-Right.

Pat Buchanan is a man.

Sean Hannity is a chickenhawk.

Tom Delay is a man.

Michelle Malkin is a woman.

Radical Right is a political stance in the Political Spectrum. "You are on the extreme right of the political spectrum." Radical Right is right from Far-Right.
	Instead of going right in Radical Right, say "This is as far to the Right as you can get without growing a funny mustache."

Dick Cheney is a man. He is in Radical Right.
	Every turn:
		if something that is a contract is held by Cheney begin;
			say "Cheney quickly gives back the war contracts. He recommends that you pass them on to a company that he has 'no financial connections' to, like Halliburton.";
			now every contract held by Cheney is held by the player;
		end if;

Pat Robertson is a man. He is in Radical Right.

Rick Santorum is a man.

Ann Coulter is a female person.


The public mindset is a thing.

Your favorability rating is a number which varies.

The threat of Al Qaeda is a thing in the public mindset. It can be grossly inflated.

The fear of other religions is a thing in the public mindset. It can be skillfully mongered.

The accurate perception of reality is a thing in the public mindset. It can be poisoned by Fox News.

The testimony of administration critics is a thing in the public mindset. It can be criminally undermined.

The Democrat's general attitude is a thing. It can be either completely panic-struck or crippled by fear of reprisal.

Public consent for war is part of the public mindset. It can be manufactured.

The Iraq invasion plan is a well-documented pre-existing goal. It can be either backed by an anguished confused public or just waiting for a catalyzing event like a new Pearl Harbor.

An every turn rule:
	if the threat of Al Qaeda is grossly inflated and the fear of other religions is skillfully mongered and the accurate perception of reality is poisoned by Fox News and the testimony of administration critics is criminally undermined and the Democrat's general attitude is completely panic-struck and the Iraq invasion plan is just waiting for a catalyzing event like a new Pearl Harbor begin;
		change Iraq invasion plan to backed by an anguished confused public;
		change public consent for war to manufactured;
		say "Your plan to invade Iraq now has the backing of the American people and Congress.";
	end if;


Chapter 3 - Startup and Miscellaneous

Section 0 - The Setup

Your favorability rating is 58.

The player has a room that varies called last political stance. The last political stance is Compassionate Conservatism.

The player has a room that varies called last real place. The last real place is Oval Office.

The player has a thing called election survival status. It can be somehow reelected to another term or not yet determined.

Section 1 - The Intro

Section 2 - Things That Start Nowhere But Can Enter the Game

Clinton's shoes are clothing. They can be either found or lost. Instead of wearing Clinton's shoes: say "You are unable to fill Clinton's shoes."

The flightsuit is clothing.
	Instead of examining player when the player is wearing the flightsuit, say "You always did love the way you look in uniform. Why, you wore your old Air Force costume two or three times!"


Some terrorists are a criminal organization.

Insurgency size is a kind of value. The insurgency sizes are nonexistant, very small, small, moderate, large, huge, or overwhelming.

The insurgents are a thing. The insurgents have an insurgency size.  Understand "insurgency" as insurgents. The insurgents are nonexistant. The description of the insurgents is "[if insurgents are very small]There are a few dead-enders here.[otherwise if the insurgents are overwhelming]There is an overwhelming number of insurgents here.[otherwise]There is a [insurgency size] number of insurgents here." The insurgents are plural-named. The indefinite article of the insurgents is "some".
	Instead of examining the insurgents, say "On closer inspection, a few of these guys look familiar..."
	Instead of taking the insurgents:
		say "You try to remove some insurgents by putting them in Abu Ghraib. More show up to replace them shortly."

To describe the state of the insurgency:
	say the description of the insurgents;
	say "[line break]".

Rule for writing a paragraph about the insurgents:
	describe the state of the insurgency.

An every turn rule:
	if the insurgents are in Baghdad and the insurgents are nonexistant, the change the insurgents to very small.

After coursestaying the course when Iraq is invaded and the insurgents are not in Iraq for the third time:
		move the insurgents to Baghdad;
		indicate the arrival of more insurgents.

After coursestaying the course when the insurgents are very small the second time:
	indicate the arrival of more insurgents;
	change insurgents to small;
	describe the state of the insurgency.

After coursestaying the course when the insurgents are small the second time:
	indicate the arrival of more insurgents;
	change insurgents to moderate;
	describe the state of the insurgency.

After coursestaying the course when the insurgents are moderate the first time:
	bring on the election.

To bring on the election:
	remove Jesse Helms from play;
	remove John Ashcroft from play;
	move Sean Hannity to Far-Right;
	move Pat Buchanan to Far-Right;
	change election year to happening now;
	say "An election year arrives."

To wrap up the election:
	remove Pat Buchanan from play;
	remove Sean Hannity from play;
	move Michelle Malkin to Far-Right;
	move Tom DeLay to Far-Right;
	remove Dick Cheney from play;
	remove Pat Robertson from play;
	move Ann Coulter to Radical Right;
	move Rick Santorum to Radical Right;
	change the election year to not happening now;
	change the player to somehow reelected to another term;
	say "(Hopefully, nobody will look too closely at Ohio.)".

After coursestaying the course when the insurgents are moderate the second time:
	indicate the arrival of more insurgents;
	change insurgents to large;
	describe the state of the insurgency.

After coursestaying the course when the insurgents are large the second time:
	indicate the arrival of more insurgents;
	change insurgents to huge;
	describe the state of the insurgency.

After coursestaying the course when the insurgents are huge the second time:
	indicate the arrival of more insurgents;
	change insurgents to overwhelming;
	describe the state of the insurgency.


A contract is a kind of thing.

Some standard war contracts are a contract. The description is "These contracts are not the juiciest, but they'll still be useful for paying back contributors."
	An every turn rule:
		if Afghanistan is invaded and Iraq is invaded and the standard war contracts are not handled, move the standard war contracts to the player.

Some no-bid war contracts are a contract. The description is "These contracts are worth an incredible amount of taxpayer money."
	An every turn rule:
		if Afghanistan is invaded and Iraq is invaded and the no-bid war contracts are not handled begin;
			move the no-bid war contracts to the player;
			follow the contractors follow the money rule;
		end if.

Check giving contracts to something:
	ignore the can't give to a non-person rule.

Check giving contracts to a well-connected gang of war profiteers:
	ignore the block giving rule.

An every turn rule (this is the contractors follow the money rule):
	if the no-bid war contracts are held by the player begin;
		now all the well-connected gang of war profiteers are in the location;
	otherwise;
		now all the well-connected gang of war profiteers are in the Oval Office;
	end if;

Does the player mean speechgiving an audience: It is likely.

[Does the player mean giving contracts to a well-connected gang of war profiteers: It is very likely.]

After reading a command (this is the watch for two-word give contracts command rule):
	if the player's command matches "give contracts", replace the player's command with "give contractor contracts".

To decide whether (N - an object) fits the parse list: 
    (- (FindInParseList({N})) -) 


Include (- 
[ FindInParseList obj i k marker; 
    marker = 0; 
    for (i=1 : i<=number_of_classes : i++) { 
    while (((match_classes-->marker) ~= i) && ((match_classes-->marker) ~= -i)) marker++; 
    k = match_list-->marker; 
    if (k==obj) rtrue; 
    } 
    rfalse; 
]; 
-) 

Definition: a thing is matched if it fits the parse list. 

[This is the rule intended to be kicked off by "give contracts" command.]
Rule for asking which do you mean when everything matched is a well-connected gang of war profiteers:
	say "Who do you want to give the contracts to?"

The giving action has an object called intended recipient. The giving action has some text called named-recipient.

Before asking which do you mean when everything matched is some contracts:
	if the player's command includes "Halliburton", change named-recipient of the giving action to "Halliburton";
	if the player's command includes "Bechtel", change named-recipient of the giving action to "Bechtel";
	if the player's command includes "Carlyle" or the player's command includes "Group", change named-recipient of the giving action to "the Carlyle Group";


Rule for asking which do you mean when everything matched is some contracts:
	say "What kind of contracts do you wish to give [named-recipient of the giving action]?"

After giving the no-bid contracts to a well-connected gang of war profiteers, say "You give the no-bid contracts to [the second noun]."

The course is a backdrop. It is everywhere.
	Instead of coursestaying the course when the United States is not attacked, say "You haven't set a course yet!"

To indicate the arrival of more insurgents:
		say "Some insurgents arrive[run paragraph on]";
		if the player is in Baghdad begin;
			say ".";
		otherwise;
			say " in Iraq.";
		end if;

An election year is a backdrop. It is everywhere. It can be happening now.
	Instead of doing something to an election year:
		If an election year is not happening now begin;
			say "This is not an election year.";
		otherwise;
			 say "Best leave all that politics stuff to Karl.";
		end if;


Section 3 - Overridden Outworld Actions

Check requesting the score:
	if the United States is attacked and the American People are not spoken to and Afghanistan is not invaded, say "We can't take a poll now! What you need is a bullhorn, some rubble, and some good lighting." instead.

Carry out requesting the score:
	say "Your favorability rating is [your favorability rating]% out of a possible 100%.";
	stop the action.

Carry out quitting the game:
	say "Oh, how we wish you would.";
	stop the action.

Section 4 - Tracking Favorability

An every turn rule (this is the initial favorability spike rule):
	if the United States is attacked and the American people are spoken to and Afghanistan is not invaded,
		now your favorability rating is 84.

An every turn rule (this is the Afghanistan invasion spike rule):
	if the United States is attacked and Afghanistan is invaded,
		now your favorability rating is 90.

An every turn rule (this is the Iraq invasion spike rule):
	if the United States is attacked and Afghanistan is invaded and Iraq is invaded and the insurgents are not in Baghdad,
		now your favorability rating is 80.

An every turn rule (this is the dust settles but insurgents remain rule):
	if the insurgents are small or the insurgents are moderate,
		now your favorability rating is 71.

An every turn rule (this is the things look worse all the time rule):
	if the insurgents are large or the insurgents are huge,
		now your favorability rating is 59.

An every turn rule (this is the total quagmire rule):
	if the insurgents are overwhelming,
		now your favorability rating is 47.

Section 5 - Core Game Test

Test before-9-11 with "invade iraq / look mirror / pet seal / examine chairs / fill shoes / examine desk / eat pretzel / invade iraq / invade iraq / go right / go right / invade iraq / take vacation / invade iraq / score / go photoop / read book"

Test prep-invasion with "read book / read book / read book / go home / give speech / american people / diagnosis / invade iraq / invade afghanistan / invade iraq / invade iraq / fuck / hype threat / monger fear / muddy water / punish critics / railroad congress"

Test prep-election with "invade iraq / give contracts / halliburton / no-bid / stay course / stay course / wear flightsuit / say 'mission accomplished' / examine mission / stay course / stay course / stay course / stay course / stay course / stay course / go left / go left"

Test endgame with "get reelected / go right / go right / stay course / stay course / stay course / stay course / stay course / score / admit mistakes / accept responsibility / declare victory / quit"

Test me with "test before-9-11 / test prep-invasion / test fail-badly / test endgame"

Section 6 - Copyright Announcement, Bibliographic Data, and Materials

The story title is "Iraqi Invasion".
The story headline is "Interactive Propaganda".
The story genre is "Comedy".
The release number is 88.
The story creation year is 2008.

After printing the banner text:
	say "Copyright 2008 by Anonymous. Released under GPLv3.";
	say "Based on original idea and sample transcript by Matthew Baldwin, used by permission.";
	say "See original at: http://www.defectiveyeti.com/archives/001561.html";	say "[paragraph break]";

Release along with the introductory booklet and a file of "terms and conditions for distribution (GNU General Public License v3, text file)" called "COPYING".