options

    pack.



$include 'syntax.a'

$include 'msgs.a'

$include 'hero.a'

$include 'inv.a'

$include 'toasense.a'

$include 'spscore.a'

$include 'toaquit.a'



location kitchen

description

    "This is the kitchen. The toaster is here."

exit nw, n, ne, e, se, s, sw, w, u, d to kitchen

    check "You're not going anywhere."

end exit.

end location.



object bread at kitchen

is loose.

description ""

verb get, take

    check bread at limbo

        else "There is no bread."

does only "Bug."

end verb.

verb examine, look_in does only

    "There is no bread."

end verb.

verb eat does only

    "There is no bread."

end verb.

end object.



object toaster at kitchen

is loose.

is not toasting.

has time 1.

container

description ""

verb get, take

    check toaster at limbo

        else "You can't take the toaster with you."

does only "Bug."

end verb.

verb examine, look_in does only

    "It's a toaster all right. It has a small lever and a dial that can

    be set to a number between 1 and 5. The dial is currently set to"

    say time of toaster.

    "$$."

    if toaster is toasting then

        "$pThe toaster is toasting."

    end if.

end verb.

verb fuck_it does only

    "You shouldn't put any meat in the toaster."

end verb.

verb feel

    check toaster is toasting

        else "It's not hot."

does only

    "It's hot."

end verb.

end object.



object dial at kitchen

description ""

verb examine, look_in does only

    "You can turn it to a number between 1 and 5. Currently it is set

    to"

    say time of toaster.

    "$$."

end verb.

verb turn does only

    "You must set the dial to a number between 1 and 5."

end verb.

verb turn_to does only

    if num < 1 or num >5 then

        "You must set the dial to a number between 1 and 5."

    elsif num = time of toaster then

        "It is already set to that."

    else

        set time of toaster to num.

        "You set the dial to"

        say num.

        "$$."

    end if.

end verb.

end object.



object lever at kitchen

description ""

verb examine, look_in does only

    "You can pull it."

end verb.

verb pull, push

    check toaster is not toasting

        else "Wait until the toaster stops toasting."

does only

    "You pull the lever down. The toaster starts heating up."

    make toaster toasting.

    schedule pop after time of toaster.

end verb.

end object.



event pop

"$pThe lever of the toaster springs back up and the toaster cools down."

make toaster not toasting.

end event.



--

start at kitchen.

"$t$t$t$t$t$tTHERE IS NO BREAD"

"$p$t$tWritten by Mikko Vuorinen (mvuorine@cc.helsinki.fi)"