! La Pietra della Luna
! Avventura Testuale realizzata da Paolo Lucchesi
! da un'idea di Paolo Lucchesi, Andrea Gnesi e Stefano Masi
! Questo prodotto @`e libero, rilasciato sotto licenza GPL (Gnu Public License), 
! riportata nel file allegato gpl.txt. 
! Questo prodotto @`e distribuito senza alcuna garanzia. L'autore non pu@`o essere 
! ritenuto responsabile per qualsiasi danno dovuto direttamente o indirettamente 
! all'uso del prodotto.
! ------------------------------------------
!           Il Villaggio di Har Plenais
! ------------------------------------------

ORoom SentieroPalazzo "Sentiero per il palazzo"
  with description
    "Un piccolo sentiero in terra battuta si snoda tra la vegetazione brulla di questa zona. Ad est esso conduce verso il palazzo del barone, e andando verso sud si incontrano le prime case del piccolo villaggio.",
    name 'sentiero' 'vialetto',
    ne_to DavantiPalazzo, e_to DavantiPalazzo, se_to DavantiPalazzo, ! nel file lunapal.inf
    w_to PianuraOvest, sw_to PianuraOvest,
    nw_to PianuraNord, n_to PianuraNord,
    s_to DavantiEmporio, 
    cant_go "Puoi andare in qualsiasi direzione, ma comunque il villaggio @`e verso sud e il palazzo verso est.";

Prop -> "vegetazione"
  with name 'vegetazione' 'piante' 'erba',
    description "La vegetazione ai lati del sentiero non sembra troppo rigogliosa.",
    cant_go "@`E solo semplice vegetazione.",
  has female;
  
Direction -> "villaggio"
  with name 'villaggio' 'borgo' 'har' 'plenais' 'case' 'abitazioni' 'costruzioni' 'edifici', dir_to s_obj;
  
Direction -> "palazzo"
  with name 'palazzo' 'castello' 'edificio' 'costruzione' 'villa', dir_to e_obj;
    
ORoom PianuraOvest "Pianura"
  with description
    "La brulla pianura che si stende ad ovest del villaggio ha un aspetto quasi desolante, paragonata alla rigogliosa foresta che occupa quasi tutta la valle.",
    name 'pianura',
    e_to SentieroPalazzo, se_to SentieroPalazzo,
    ne_to PianuraNord,
    n_to [; print "Attraversi la pianura seguendo la traccia di un vecchio sentiero che da nord curva verso est.^"; return PianuraNord; ],
    before [; Go: if (noun == w_obj or sw_obj or nw_obj or s_obj)
                    "Non ti sembra ci sia niente di interessante in quella direzione."; ],
    cant_go "La pianura si stende tutto intorno a te; il palazzo e il villaggio si trovano verso est.",
  has female;

ORoom PianuraNord "Pianura"
  with description
    "La brulla pianura che si stende a nord del villaggio e del palazzo ha un aspetto quasi desolante, paragonata alla rigogliosa foresta che, verso est, occupa quasi tutta la valle.",
    name 'pianura',
    s_to SentieroPalazzo, 
    sw_to PianuraOvest,
    nw_to "Non ti sembra ci sia niente di interessante in quella direzione.",
    se_to ForestaL1, e_to ForestaL1, ne_to ForestaL2, ! nel file lunafor.inf
    n_to [; print "Un piccolo sentiero tortuoso curva da nord ad est addentrandosi nella parte pi@`u settentrionale della foresta.^"; return ForestaL2; ],
    w_to [; print "Segui la traccia quasi invisibile di un sentiero che curva da ovest a sud.^"; return PianuraOvest; ],
    cant_go "La pianura si stende tutto intorno a te; il palazzo e il villaggio si trovano verso sud, e verso est vedi i primi alberi della foresta.",
  has female;

ORoom DavantiEmporio "Il villaggio (davanti a un emporio)"
  with description
    "L'acciottolato si snoda fra le piccole costruzioni in legno e pietra, alte mai pi@`u di due piani. Camminando verso nord si esce dal villaggio, andando verso il palazzo, mentre a sud si vede una piazza. Una piccola bottega, probabilmente un emporio, risalta fra le altre case a est della strada.",
    name 'villaggio' 'borgo' 'har' 'plenais' 'strada',
    n_to SentieroPalazzo, s_to PiazzaVillaggio, e_to GoEmporio, in_to GoEmporio,
    cant_go "Puoi andare solo a nord e a sud, o entrare nell'emporio andando ad est.",
    initial [; LeftPicture(Village_img, -1, -1); ];
    
Prop -> "case"
  with name 'case' 'costruzioni' 'abitazioni' 'casa' 'costruzione' 'abitazione' 'edifici',
    description "Le case qui intorno sono simili a quelle del resto del villaggio, e a quelle di molti altri piccoli villaggi.",
    cant_go "Sono solo le case degli abitanti del villaggio."
  has pluralname female static;

Direction -> "emporio"
  with name 'emporio' 'negozio' 'bottega' 'porta' 'edificio', dir_to e_obj,
    description [;
      if (night || sunset) "Quando @`e chiuso l'emporio @`e quasi indistinguibile dalle altre case.";
      "Il piccolo emporio @`e riconoscibile dalla merce, per lo pi@`u di infimo valore, esposta fuori.";
    ],
    before [; 
        Open, Unlock, Knock: if ((~~night) && (~~sunset)) "L'emporio @`e aperto.";
                             if (action==##Knock) "Nessuna risposta.";
                             "La porta @`e chiusa a chiave.";
    ];
    
Direction -> "piazza"
  with name 'piazza' 'osteria' 'locanda' 'taverna' 'tempio', dir_to s_obj, has female;
  
Direction -> "palazzo"
  with name 'palazzo' 'castello' 'villa', dir_to n_obj;
    
Prop -> "merce" 
  with name 'merce' 'merci',
   description "La merce esposta fuori sembra di pessima qualit@`a e completamente inutile.",
   cant_go "Lascia perdere. @`E per la maggior parte robaccia inutile.",
  has female;

[GoEmporio; if (night || sunset) "La porta dell'emporio @`e chiusa."; return(Emporio); ];
  
Object martello "chiodi e martello"
  with name 'martello' 'chiodi',
    description "Un piccolo martello e una manciata di chiodi.",
    before [;
      Buy: if (player in Emporio) "Non hai bisogno di un altro martello o di altri chiodi.";
    ],
  has pluralname;
  
IRoom Emporio "L'emporio"
  with description 
    "E' difficile farsi strada all'interno dell'emporio, tanto @`e pieno di merce di ogni tipo. Pare infatti che qui venga venduto di tutto: derrate alimentari, utensili, attrezzi da boscaiolo, cordami e altro ancora.",
    name 'emporio' 'bottega' 'negozio',
    w_to DavantiEmporio, out_to DavantiEmporio,
    cant_go "L'uscita @`e a ovest.",
  has light;
  
Prop -> "merce" 
  with name 'merce' 'merci' 'derrate' 'alimentari' 'casse' 'cassa',
   description "Le varie merci e oggetti in vendita in questo negozio occupano praticamente tutte le pareti, e anche diverse casse sparse disordinatamente sul pavimento.",
   cant_go "Lascia perdere. @`E per la maggior parte robaccia inutile.",
  has female;
  
Object -> utensili "utensili"
  with name 'utensili' 'attrezzi' 'utensile' 'attrezzo' 'martello' 'chiodi' 'chiodo',
    description [;
        if (self has general) "Non vedi niente di particolarmente utile.";
        "Le uniche cose che ti sembrano di una certa utilit@`a sono un piccolo martello e dei chiodi.";
    ],
    before [; Buy, Take: 
        if (self has general) "Hai gi@`a comprato quello che ti serviva.";
        if (soldi notin player) "Al momento non hai soldi.";
        move martello to player;
        give self general;
        "Acquisti un martello e dei chiodi.";
    ],
  has scenery pluralname;
  
Object -> cordami "cordami"
  with name 'corde' 'corda' 'funi' 'fune' 'cordame' 'cordami',
    description "Con occhio attendo noti che le corde vendute qui sono tutte di pessima qualit@`a, mal intrecciate e spesso anche marce.",
    before [;
      Buy, Take: "Una corda in quello stato non ti potrebbe servire a nulla.";
    ],
  has scenery pluralname;
        
NPC -> erlik
  with short_name [; if (self has proper) print "Erlik"; else print "negoziante"; rtrue; ],
       name 'erlik' 'negoziante' 'venditore', article "il",
       description [;
         if (self has proper) print "Erlik "; else print "Il negoziante ";
         "si muove in modo concitato, come se non riuscisse a star fermo un minuto. Non @`e ancora giunto alla mezz'et@`a ed @`e di bassa statura. I suoi abiti, tutt'altro che scadenti, sono abbastanza chiassosi.";
       ],
       greet false,
  conversor erliktalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "L'uomo pare accorgersi ora della tua presenza.^";
    }
    Answer: "Ti sembra che non abbia capito niente.";
    Give, Show: if (noun == mandato)
                    "Vuoi far sapere a tutto il villaggio cosa sei veramente venuto a fare in questa valle?";
                if (noun == soldi)
                    "@<<Prego. Qualunque cosa voglia acquistare, il mio negozio @`e a sua diposizione.@>>";
                print_ret (The)self, " osserva ", (the)noun, " e dice: @<<No, grazie, non credo riuscirei mai a vendere una cosa del genere.@>>";
    Kiss: "Non @`e una buona idea...";
    ThrowAt, Attack: "Non lo farai...";
    !default: "L'uomo ti guarda stupito.";
  ],
  lifedefault "L'uomo ti guarda, perplesso.",
  Orders [;
    Give: if (noun == utensili) <<Buy utensili>>;
  ],
  rs 0,
  each_turn [;
    give m_erlik ~locked;
    if ((~~self.greet) && player hasnt invisible) {
        self.greet=true;
        self.talkto(false);
        if (iarin in real_location) "^Il negoziante si volge verso di te e dicendo: @<<Salve, e benvenuto nel mio umile negozio. Un attimo e sono da lei.@>>";
        "^Appena varchi la porta, il negoziante si precipita da te dicendo: @<<Salve, e benvenuto nel mio umile negozio.@>>";
    }
    if (silenceturns > 2 && random(2) == 1 && self in Emporio) {
      switch(++self.rs) {
        2: print_ret "^", (The) self, " cerca, senza risultato, di mettere ordine in una pila di merce.";
        5: print_ret "^", (The) self, " si mette distrattamente a contare le casse sul pavimento.";
        7: print_ret "^", (The) self, " controlla i cordami e gli utensili con aria da intenditore, annuendo.";
        9: print_ret "^", (The) self, " si affaccia un attimo dalla porta, come per controllare se stiano arrivando clienti.";
        10: self.rs = 0;
      }
    }    
  ],
  has;

Object erliktalk
    with before  [flag;
        if (flag && easy) {
          if (erlik.cnumber >= 1 && t_erlik_culti.cnumber == 0) { t_erlik_culti.act(); rtrue; }
          if (erlik.cnumber >= 1 && t_erlik_triven.cnumber == 0 && m_triven hasnt locked) { t_erlik_triven.act(); rtrue; }
          if (erlik.cnumber >= 2 && t_erlik_donna.cnumber == 0 && m_donna hasnt locked) { t_erlik_donna.act(); rtrue; }
          if (erlik.cnumber >= 2 && t_erlik_barone.cnumber == 0) { t_erlik_barone.act(); rtrue; }
          if (erlik.cnumber >= 2 && t_erlik_naradas.cnumber == 0) { t_erlik_naradas.act(); rtrue; }
          if (erlik.cnumber >= 2 && t_erlik_culti.cnumber <= 1) { t_erlik_culti.act(); rtrue; }
        }
      ],
      description
          [; give self proper;
             "@<<Salve, buon uomo...@>>^
              @<<Salute a te, straniero@>> risponde lui, @<<Io sono Erlik, e qui dentro mando avanti la baracca. Dammi pure del tu e di qualunque cosa tu abbia bisogno, non esitare a chiedere: ce l'ho, e se non ce l'ho me la procuro.@>>";
          ]
          "@<<Che si dice qui al villaggio?@>>^
           @<<Niente di nuovo. Per@`o se hai bisogno di informazioni su qualsiasi argomento, puoi chiedere a me. Ogni voce, pettegolezzo e diceria passa dal mio negozio.@>>"
          "Non hai altro da chiedere, e inoltre temi la logorrea di Erlik.",        
    cant_go [; "Sentita la tua domanda ", (the)erlik, " risponde: @<<Mi spiace, non ne so niente... ma posso vedere di informarmi.@>>"; ];

Topic ->
    with name 'lui' 'egli' 'se' 'stesso',
         metatopic m_erlik,
         before [;
            if (erlik hasnt proper) {
                give erlik proper;
                "@<<Come ha detto di chiamarsi?@>>^
                 @<<Non l'ho ancora detto, ma puoi chiamarmi Erlik.@>>";
            }
         ],
         description
            "@<<Che mi dici di te?@>>^
             @<<Che senza di me il villaggio sarebbe perduto. Sono l'unico a vendere oggetti di prima necessit@`a nel raggio di molte miglia. Ma nonostante ci@`o non trover@`a esosi i miei prezzi.@>>"
            "@<<Ma mi sai dire qualcosa di te personalmente?@>>^
             @<<Non c'@`e molto da dire@>> ti risponde Erlik, @<<Mi sono trasferito qui da diversi anni, prima avevo una bottega simile a questa, ereditata da mio padre, in un villaggio sul mare. Ma gli affari non andavano benissimo, e non sopportavo pi@`u l'odore di salmastro. Quindi ho venduto tutto e mi sono spostato in montagna, ed eccomi qui.@>>"
            "Non osi chiedere altre informazioni. Potresti ottenerle.";

Topic -> t_erlik_barone
    with metatopic m_barone,
         description
            "@<<Che pensi del barone Inderus?@>>^
             @<<Grand'uomo, il barone... Uno che ha capito come vivere...@>>, Erlik ammicca prima di continuare, @<<Gli @`e bastato assumere un amministratore capace e ora pu@`o dedicarsi tranquillamente alla caccia e alla bella vita... Ammetto che lo invidio, ma d'altronde non si pu@`o avere tutto dalla vita... Sto mettendo da parte un po' di risparmi, e fra un po' conto di ritirarmi...@>>"
            "@<<Hai altro da dire sul barone?@>>^
             @<<Mi stai interrogando? Comunque ho una grande stima in lui. Forse non un ottimo governante, ma in un modo o nell'altro qui la vita scorre tranquilla e tutti hanno da mangiare, e non @`e poco visto che le miniere sono esaurite. Poi forse dobbiamo ringraziare pi@`u Naradas che lui, ma ascolti me, il barone ha capito come prendere la parte migliore della vita.@>>"
            "Non pensi di scoprire altro. Anche il negoziante ti conferma che @`e Naradas a governare il feudo.";

Topic -> t_erlik_culti
    with metatopic m_culti,
         description 
           [; give m_triven ~locked;
              "@<<Hai mai sentito parlare di culti particolari, o di sette segrete?@>>^
               @<<Voci ne girano, certo. E' sicuro che qualcosa di strano accade. Mio cugino, che @`e taglialegna, mi ha detto che certe volte di notte gli @`e parso di sentire delle voci che cantavano. E mio nonno mi raccontava che diversi anni fa, a quando pare, un mago, o studioso, non ricordo, venne da queste parti per studiare qualcosa di strano che aveva trovato in questa valle.@>>";
         ]
              "@<<Sai altro su strani culti o rituali misteriosi?@>>^
               @<<Lo ripeto, qualcosa di strano di notte nella foresta accade. Per lo meno, cos@`i mi hanno detto, visto che per conto mio cerco di rimanere sempre al villaggio, specialmente con il buio. Non che sia un codardo, ma preferisco evitare inutili rischi.@>>"
              "Strani canti che si odono di notte nella foresta, e uno studioso di qualche tipo venuto nella valle qualche anno fa. Informazioni interessanti. Non pensi che l'uomo sappia altro.";

Topic -> t_erlik_donna
    with metatopic m_donna,
        description
            "@<<Sai niente per caso di una donna, una straniera, passata di qui qualche tempo fa?@>>^
             @<<Certo, come posso dimenticarmela. Non era giovanissima, ma era comunque una donna bellissima, di una bellezza inusuale e non banale, come qui non se ne vedono - insomma, come credo se ne vedano poche ovunque. @`E un peccato che fosse solo di passaggio, altrimenti sono sicuro che sarei riuscito ad affascinarla. Che donna, e che occhi che aveva...@>>"
             [; give vade proper;
                "@<<Ti ricordi cosa ha acquistato quella bella straniera?@>>^
                 @<<Niente di particolare. Delle corde, una lanterna e dell'olio minerale, se mi ricordo. Ah, aveva con se un pacchetto fatto da Vade, l'alchimista; non so cosa ci fosse dentro.@>>"; ]
             "@<<Ti ricordi altro sulla straniera?@>>^
              @<<A parte i suoi occhi? No, ma credo non sia rimasta al villaggio pi@`u di mezza giornata, anche se non ricordo di averla vista ripartire.@>>"
             "La donna era molto bella e aveva occhi stupendi, e ha comprato corde e una lanterna; oltre a questo non credi che sappia dirti altro d'interessante.";

Topic -> t_erlik_triven
    with metatopic m_triven,
         description
            "@<<Ti ricordi qualcosa a proposito di questo mago?@>>^
             @<<Non molto. Mio nonno mi raccont@`o dell'arrivo di questo strano stregone, che abitava fuori dal villaggio e veniva qui solo per fare strane domande a tutti, un po' come te. Non stette qui molto, perch@'e ad un tratto scomparve nel nulla. Si disse che era stato ucciso.@>>"
            "@<<Sai altro su questo stregone, o studioso, o quel che era?@>>^
             L'uomo sembra riflettere un attimo prima di rispondere: @<<Non ricordo molto di pi@`u, ma questa storia viene raccontata abbastanza spesso nelle notti fredde in osteria, assieme a molte altre storie che potrebbero interessarti@>>."
            "Non credi che possa dirti di pi@`u; comunque ti ha detto che questo mago era una una specie di studioso o investigatore, e che non abitava al villaggio.";

Topic -> t_erlik_naradas
    with metatopic m_naradas,
         description
            "@<<Di Naradas che pensi?@>>^
             @<<Un uomo abile, con in se l'istinto innato del commerciante. Nonostante la miniera di diamanti sia ormai quasi esaurita, sotto la sua amministrazione la valle sta prosperando grazie al legname. Il barone ha pienamente ragione a fidarsi di lui.@>>"
            "@<<Sai dirmi altro su Naradas?@>>^
             @<<Che lo vorrei come socio. Mi stupisce soltanto che continui a vivere modestamente, visto che gestendo il governo la valle si sar@`a sicuramente arricchito, come ogni buon amministratore farebbe. A meno che non sia onesto, ma di persone oneste ne conosco veramente poche, per non dire nessuna.@>>"
            "Non hai altro da chiedere, e ti ha gi@`a detto che Naradas, pur amministrando saggiamente la valle, non approfitta della sua posizione per arricchirsi, o che per lo meno non lo da a vedere.";

Topic ->
   with metatopic m_tempio,
      description
          "@<<Dove posso trovare il tempio?@>>^
           @<<Nella piazza principale, poco pi@`u a sud.@>>";

Topic ->
    with metatopic m_dippin,
         description
            "@<<Che mi dici del sacerdote?@>>^
             @<<Ammetto onestamente che non frequento molto il tempio. D'altronde il negozio prende quasi tutto il mio tempo. Comunque credo che sia una persona a posto, anche se non disprezza assolutamente i piaceri mondani. In particolare un'ottima cena.@>>"
            "@<<Sai altro sul sacerdote?@>>^
             @<<No. Non sono una persona religiosa; rispetto gli dei e i loro sacerdoti, sia ben chiaro, ma spero che loro pensino ai loro affari mentre io penso ai miei.@>>"
            "Non hai altro da chiedere.";
            
Topic ->
  with metatopic m_dei,
    description
      "@<<Lei, da buon mercante, @`e fedele a Oster, vero?@>>^
       @<<S@`i, certo. Inoltre sono nato in un posto di mare, in un villaggio dove l'unico tempio era quello di Oster, come qui ad Har Plenais l'unico tempio @`e quello di Maral. Certo, ho sempre preferito pregare in privato, quando ho tempo, che partecipare alle cerimonie dei templi.@>>"
      "Non credi che ti possa rivelare niente di interessante sull'argomento.";

Topic ->
    with metatopic m_vade,
         description 
           [; give vade proper;
              "@<<C'e' il negozio di un alchimista, nel villaggio...@>>^
               @<<Si, il buon Vade. Una brava persona, come ce ne sono poche al villaggio. Molto abile, anche... Diverse persone gli devono la vita. Ma c'@`e qualcosa in lui che non riesco a comprendere bene. In un certo senso riesce a mettermi a disagio.@>>"; ]
           "@<<Sai dirmi altro su Vade, l'alchimista?@>>^
            @<<Qui al villaggio @`e non solo alchimista, ma anche medico e consulente, ed @`e sempre disponibile con tutti. Certo, ci sono alcuni che non lo stimano, forse perch@'e pensano che la sua professione sia in qualche modo disdicevole o contraria alla religione, ma per me sono solo sciocchezze.@>>"
           "Non pensi di dover credere altro. @`E comunque interessante il fatto che ci siano opinioni discordanti su Vade.";
           
Topic ->
    with metatopic m_aloe,
      description
        "@<<Sa per caso dirmi a cosa servono le foglie di aloe che ha ordinato l'alchimista?@>>^
         @<<Onestamente no. Mi limito ad ordinarle quando me le richiede. Non mi intendo di queste cose, mi spiace.@>>"
        "Non credi possa dirti altro.";
           
Topic -> 
  with metatopic m_osteria,
    description
      [; give m_bano ~locked; give bano proper; give m_dippin ~locked;
         "@<<C'@`e un posto dove bagnarsi la gola?@>>^
          @<<Certo, l'osteria di Bano. Per arrivardi devi continuare verso sud fino alla piazza, poi @`e quasi impossibile sbagliare. Basta solo non entrare nella porta con gli scalini di marmo: quello @`e il tempio e l@`i non servono niente di buono da bere.@>>"; ]
      [; t_erlik_bano.act(); ];

Topic -> t_erlik_bano
    with metatopic m_bano,
      description
        "@<<Conosce l'oste che gestisce la locanda?@>>^
         @<<Certo. Sono pochi gli uomini a non conoscerlo. Bene o male tutti frequentiamo la sua locanda, l'unica del villaggio, quando abbiamo bisogno di birra per rinfrescarci la gola o liquore per affrontare le fredde notti invernali.@>>"
        "@<<Sa dirmi qualcosa a proposito dell'oste?@>>^
         @<<Credo non mi veda di buon occhio, ignoro per quale motivo; nonostante questo non mi ha rifiutato mai da bere. Probabilmente ha molta pi@`u simpatia per i miei soldi che per me.@>>"
        "Non hai altre domande da fare sull'oste.";

Topic ->
    with name 'commercio' 'emporio' 'merci' 'merce',
         description
            "@<<E' buona la merce che vendi nel tuo negozio?@>>^
             @<<Mi preoccupo personalmente di scegliere ogni oggetto che metto in vendita, e faccio in modo che sia della miglior qualit@`a possibile, pur cercando di non far spendere una fortuna ai miei clienti. L a mia merce @`e la migliore che puoi trovare nella valle...@>>"
            "Inutile. Sarebbe come chiedere ad un oste come @`e il suo vino. O, nel caso, il suo aceto.";

Topic ->
    with name 'attrezzi' 'utensili' 'chiodi' 'martello',
         description
            "@<<Questi attrezzi sembrano in buono stato.@>>^
             @<<Certo che lo sono. Se ti serve qualcosa non esitare a chiedere. Posso farti un buon prezzo.@>>"
            "Certo ti direbbe qualsiasi cosa pur di venderteli.";

Topic ->
    with metatopic m_miniere,
         description
            "@<<Delle miniere che mi dici?@>>^
             @<<Quando le miniere del monte Kalnam erano ancora aperte, qui giravano molti pi@`u soldi e ci si poteva arricchira facilmente...@>> risponde lui con un sospiro di nostalgia, prima di continuare: @<<Ma adesso che la valle sopravvive solo con il commercio di legname. Certo, ci si pu@`o vivere, ma la ricchezza che davano i diamanti era un'altra cosa@>>."
            "@<<Ma le miniere sono versamente esaurite?@>>^
             @<<Come le tasche di un ubriaco alla fine di una serata in osteria. Se qualcuno trovasse un nuovo filone si saprebbe subito. Ma negli ultimi anni non @`e successo, e dubito che succeder@`a in futuro.@>>"
            "@<<Adesso le miniere sono ancora esplorate, o visitate da qualcuno?@>>^
             @<<Fino a qualche anno fa qualcuno ci provava di tanto in tanto, ma senza risultati, e sempre pi@`u raramente. Adesso sono solo un dedalo di gallerie buie, abbandonate e pericolose; il rischio di perdersi @`e troppo alto, e le speranze di trovare qualcosa di buono sempre pi@`u misere.@>>"
            "Le miniere sono esaurite e abbandonate. Non credi che ti sappia dire qualcosa di pi@`u.";

!ORoom Vicolo "Il villaggio (un vicolo)"
!  with description
!    "Le modeste case del villaggio, qui talmente strette da essere separate solo da uno stretto vicolo, andando verso nord si diradano lasciando aria ai campi che circondano il palazzo del barone. Il vicolo procede verso sud, allargandosi di poco, fino ad incrociare una strada pi@`u larga.",
!    name 'villaggio' 'vicolo',
!    scenic
!      'case' 'costruzioni' 'abitazioni' 'casa' 'costruzione' 'abitazione' 0 "A giudicare dall'aspetto delle case, questa deve essere la parte pi@`u misera del villaggio.",
!    n_to SentieroPalazzo, s_to Quadrivio,
!    cant_to "Il vicolo conduce da nord a sud.";

ORoom PiazzaVillaggio "Piazza del villaggio"
  with description       
    "Tutte le piccole strade che si dipanano fra le case paiono incontrarsi qui, in questa piccola piazza che sembra essere il centro del villaggio. Verso nord-ovest si erge un piccolo tempio dedicato a Maral, mentre a sud-ovest la porta di una piccola osteria rimane aperta, come un benvenuto per i clienti. Le strade conducono verso nord, verso sud e verso est.",
    name 'piazza' 'villaggio' 'borgo' 'har' 'plenais',
    n_to DavantiEmporio, e_to DavantiAlchimista, s_to DavantiForgia,
    nw_to GoTempio, sw_to GoOsteria,
    cant_go "Le strade conducono a nord, a est e a sud, mentre a nord-ovest vedi il tempio di Maral e a sud-ovest l'osteria.",
    each_turn [;
        give m_dippin ~locked;
        give m_bano ~locked;
    ],
    initial [; AbovePicture(Square_img, -1, -1); ],
  has female;

Prop -> "case"
  with name 'case' 'costruzioni' 'abitazioni' 'casa' 'costruzione' 'abitazione' 'edifici',
    description "Le case qui intorno sono simili a quelle del resto del villaggio, e a quelle di molti altri piccoli villaggi.",
    cant_go "Sono solo le case degli abitanti del villaggio."
  has pluralname female;

Direction -> "emporio"
  with name 'emporio' 'negozio', dir_to n_obj;
  
Direction -> "bottega dell'alchimista"
  with pname 'bottega' '.or' 'laboratorio' '.x' 'dell^' '.or' 'del' '.or' 'di' 'alchimista' '.or' 'erborista' '.or' 'medico' '.or' 'cerusico', dir_to e_obj, has female;
  
Direction -> "forgia"
  with name 'forgia' 'fabbro', dir_to s_obj, has female;

Direction -> "tempio"
  with pname 'tempio' '.or' 'chiesa' '.p' 'portone' '.or' 'porta' '.x' 'principale' '.x' 'del' '.or' 'di' 'tempio', 
    dir_to nw_obj,
    description "Il tempio @`e piccolo, ma dalla pietra, dai marmi e dal legno usati per la facciata e il portone d'ingresso capisci che non sono state fatte economie nella sua costruzione.",
    before [; 
        Open, Unlock, Knock: if (~~night) "Il tempio @`e aperto.";
                             if (action==##Knock) "Nessuno risponde al tuo bussare.";
                             "Il portone @`e solido, robusto e chiuso dall'interno con un paletto.";
    ];


Direction -> "osteria"
  with pname 'osteria' '.or' 'locanda' '.or' 'taverna' '.or' 'cartello' '.p' 'porta' '.x' 'dell^' '.or' 'della' '.or' 'di' 'osteria' '.or' 'locanda' '.or' 'taverna',
    dir_to sw_obj,
    description "Sopra la porta un cartello con l'immagine di un boccale e le parole ~Al vulcano spento~ ti confermano che questa non pu@`o che essere un'osteria.",
    before [; 
        Open, Unlock, Knock: if ((~~night) || phase>=6) "L'osteria sembra aperta.";
                             if (action==##Knock) "Nessuno risponde.";
                             "La porta dell'osteria @`e robusta e ben chiusa.";
    ],
  has female;

[GoTempio; if (night) "Il portone principale del tempio @`e chiuso."; return(Tempio); ];

[GoOsteria; if (night && phase<6) 
                "L'osteria @`e chiusa a quest'ora."; return(Osteria); ];

IRoom Tempio "Il Tempio di Maral"
  with description
    "All'interno il tempio ha un aspetto ancora pi@`u sfarzoso di quanto appaia all'esterno. Colonne istoriate e statue pregiate creano quasi un corridoio che conduce fino all'altare in marmo immacolato, che a sua volta @`e sovrastato da un arazzo. Dietro l'altare una tenda copre un passaggio verso nord.",
    name 'tempio' 'chiesa',
    se_to PiazzaVillaggio, out_to PiazzaVillaggio, n_to AppartamentoTempio,
    cant_go "L'uscita @`e a sud-est e gli appartamenti del sacerdote sono a nord.",
  has light;

Class Statue
  with before [;
      Push, Pull, Turn, Take: "La statue sono troppo pesanti.";
      Search, LookUnder: <<Examine self>>;
      Touch: "La pietra @`e fredda al tatto.";
    ],
  has scenery female;
  
Prop -> "colonne" 
  with name 'colonne' 'colonna',
    description "Le colonne, alte e istoriate, sono in marmo pregiato.",
  has pluralname static female;
  
Statue -> "statue"
  with name 'statue' 'dei',
    description "Quattro statue rappresentano gli dei nella loro forma umana. Aran, Irdil, Oster e Maral paiono osservare ogni tuo movimento.",
  has pluralname;
  
Statue -> "statua di Aran"
  with pname 'statua' '.x' 'di' 'aran',
    description "Aran, dio del sole, @`e rappresentato nell'atto di attaccare un nemico con la sua spada.";
    
Statue -> "statua di Irdil"
  with pname 'statua' '.x' 'di' 'irdil',
    description "Irdil, dea dell'aria, della magia e dell'artigianato, @`e vista come una donna che regge in mano un piccolo martello d'argento.";
    
Statue -> "statua di Oster"
  with pname 'statua' '.x' 'di' 'oster',
    description "Oster, dio del mare e del commercio, @`e rappresentato come un uomo barbuto con un tridente in una mano e una bilancia sull'altra.";
      
Statue -> "statua di Maral"
  with pname 'statua' '.x' 'di' 'maral',
    description "La statua di Maral, dea delle messi, @`e ovviamente la pi@`u vicina all'altare. In marmo ella @`e una donna che reca sulle spalle una falce.";
    
Prop -> "altare"
   with pname 'altare' '.or' 'blocco' '.x' 'di' '.x' 'marmo',
     description "L'altare @`e un blocco unico di un marmo che sai essere molto pregiato. Su di esso @`e inciso solo il simbolo di una falce.",
    before [;
      Search, LookUnder: "L'altare non nasconde niente.";
      Take, Push, Pull, Turn: "L'altare @`e pesante e ben fissato al pavimento.";
      Receive: "L'altare non @`e un tavolino su cui appoggiare oggetti, ma un oggetto di culto.";
    ],     
    !cant_go "L'altare pu@`o essere utile solo per pregare."
  has supporter;
     
Prop -> "arazzo"
  with name 'arazzo' 'dipinto' 'scena' 'creazione' 'quadro' 'affresco',
    description "L'arazzo rappresenta una scena della creazione del mondo, Maral nell'atto di plasmare la terra.",
    before [;
      Search, Push, Pull: "L'arazzo non sembra nascondere niente.";
      Take: "L'arazzo @`e ben fissato alla parete.";
    ],    
    cant_go "@`E solo un arazzo.";
    
Direction -> "passaggio" with name 'tenda' 'passaggio' 'appartamenti' 'appartamento', dir_to n_obj,
  description "La tenda di velluto color ocra copre il passaggio che porta all'appartamento del sacerdote.";

NPC -> cerdil
  with short_name [; if (self has proper) print "Cerdil"; else print "giovane accolito"; rtrue; ],
       name 'cerdil' 'giovane' 'accolito' 'chierichetto',
       description [;
         if (self has proper) print "Cerdil "; else print "L'accolito ";
         "@`e un ragazzo di non pi@`u di vent'anni, alto, quasi allampanato. Nei suoi occhi vedi brillare uno sguardo che hai gi@`a visto in passato in giovani simili a lui, una commistione di idealismo, fede e ingenuit@`a.";
       ],
       count 0, vanished FALSE, greet FALSE,
  conversor cerdiltalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "Il giovane @`e sorpreso dalla tua improvvisa apparizione.^";
    }
    Answer: "Il giovane ti squadra sospettoso.";

    Kiss: "Direi di no...";
    Show, Give: if (noun == mandato)
                    "Mostri il mandato al giovane e lo legge interessato. I suoi occhi si illuminano mentre dice: @<<Se in qualsiasi cosa posso essere d'aiuto, sappia che io sono presente. Intanto, se mi permette, forse dovrebbe parlare con il sacerdote@>>.";
                if (noun == soldi && action==##Give)
                    "Lasci una piccola offerta nelle mani dell'accolito.";
                if (noun == dlibro or diariotriven) "Non pensi che l'accolito sia la persona giusta a cui far conoscere certe informazioni.";
                print_ret (The)self, " non sembra interessato.";
    ThrowAt, Attack: "Non ti ha fatto niente di male... e non credi che ne sar@`a mai capace...";
    !default: "Il giovane ti osserva, perplesso.";
  ],
  lifedefault "Il giovane ti osserva, perplesso.",
  rs 0,
  each_turn [;
       give m_cerdil ~locked;
       if (phase==7) {
         self.count++;
         if (self.count>=3) {
           addhint(h_sparizioni);
           Achieved(28);
           self.vanished=TRUE;
           if (iarin.follower) iarin.talk = 10;
           remove self;
           print "^D'improvviso ";
           if (self has proper) print "Cerdil"; else print "il giovane accolito";
           print " sparisce nel nulla. Per un'attimo la sua figura diventa scura, come avvolta da una cortina di tenebra, e poi con orrore ti rendi conto di non vederlo pi@`u.^^";
           rtrue;
         }
       }
       if ((~~self.greet) && player hasnt invisible) {
           self.greet=true;
           self.talkto(false);
           "^Un giovane, probabilmente un accolito, si rivolge verso di te appena entri, dicendo: @<<Benvenuto in questo luogo di pace e preghiera, Messere. La luce di Maral illumini la vostra vita.@>>";
       }
       if (silenceturns > 2 && random(2) == 1 && self in Tempio) {
         switch(++self.rs) {
           2: print_ret (The) self, " pulisce con uno straccio la superficie gi@`a linda dell'altare.";
           5: print_ret (The) self, " si sofferma per un attimo in silenzio davanti alla statua di Maral, evidentemente in preghiera.";
           8: print_ret (The) self, " controlla che il pavimento del tempio sia sufficientemente pulito.";
           10: self.rs = 0;
      }
    }         
  ],
  react_before [;
    go: if (noun == n_obj && real_location == Tempio && player hasnt invisible) {
          if (~~(dippin in AppartamentoTempio)) "Vieni fermato energicamente dal giovane accolito che dice: @<<Mi spiace, ma non posso assolutamente ammettere che qualcuno entri negli appartamenti del sacerdote in sua assenza.@>>";
        }
    ],
  has;

Object cerdiltalk
    with before [flag;
        if (cerdil hasnt proper) {
          give dippin proper;
          give cerdil proper;
          print "@<<Salve...@>>^
                 @<<Salute a te, che cerchi il conforto della dea in questo luogo. Il mio nome @`e Cerdil e servo la dea e il sacerdote Dippin. Posso aiutarvi?@>>^";
          pretalked = 1;
          return flag;
        }
        if (flag && easy) {
            if (t_cerdil_culti.cnumber == 0) { t_cerdil_culti.act(); rtrue; }
            if (t_cerdil_donna.cnumber <= 1 && m_donna hasnt locked) { t_cerdil_donna.act(); rtrue; }
            if (t_cerdil_dippin.cnumber == 0) { t_cerdil_dippin.act(); rtrue; }
            if (t_cerdil_culti.cnumber <= 0) { t_cerdil_culti.act(); rtrue; }
        }
    ],
    description
        "@<<Salve, Cerdil...@>>^
         @<<La pace della dea Maral sia con voi.@>>",
    cant_go [;
       if (pretalked) print "^";
       print_ret (The)cerdil, " ti ascolta e risponde con tono quasi affranto: @<<Mi spiace, ma non ne so niente...@>>";
    ];

Topic ->
    with name 'lui' 'egli' 'se' 'stesso',
         metatopic m_cerdil,
         before [;
            if (cerdil hasnt proper) {
                give cerdil proper;
                "@<<Salve a lei. Quale @`e il suo nome?@>>^
                 @<<Il mio nome @`e Cerdil, accolito della dea Maral.@>>"; }
         ],
         description
            [; give dippin proper;
               "@<<Mi dica di lei, Cerdil.@>>^
                @<<Io vivo per servire la mia dea, la signora delle messi, e sto imparando le sue vie da padre Dippin.@>>"; ]
            "@<<Presta servizio da molto tempo qui?@>>^
             @<<Da pi@`u di tre anni; sono quasi al termine del mio periodo di servizio e presto me ne dovr@`a andare per compiere gli studi che mi permetteranno di diventare sacerdote.@>>"
            "Non hai altro da chiedere.";

Topic ->
    with metatopic m_barone,
         description
            "@<<Che mi dice del barone Inderus?@>>^
             @<<Forse non dovrei dirlo, ma penso che il barone sia un uomo troppo poco dedito alle cose sacre. Ma @`e giovane, spero gli anni gli portino consiglio.@>>"
            "@<<Sa dirmi altro sul barone Inderus?@>>^
             @<<Non sono in grado di stimarlo come governante, ma preferirei un feudatario pi@`u vicino ai dettami del culto.@>>"
            "Non pensi di aver altro da chiedere.";
            
Topic ->
    with name 'biblioteca' 'libro' 'libreria' 'libri',
         description [;
            give m_biblioteca ~locked;
            "@<<C'@`e una biblioteca, nel villaggio?@>>^
             @<<Solo al palazzo del barone, di che io sappia.@>>";
         ];

Topic -> t_cerdil_culti
    with metatopic m_culti,
         before [;
            if (knowcult && self.cnumber > 0)  !era: if (action==##Tell && knowcult)
               "Ti fidi poco del sacerdote, e questo giovane correrebbe subito a riferirgli tutto. Meglio lasciarlo all'oscuro.";
        ],
        description 
          [;
            give dippin proper; give m_donna ~locked;
            "@<<Ha mai sentito parlare di riti proibiti che si svolgerebbero all'interno della valle?@>>^
             @<<Maral non voglia mai. Girano delle voci, ma voglio ben sperare che siano solo tali. L'opera degna del sacerdote Dippin dovrebbe scacciare il male da qui. Ma se @`e vero, @`e sicuramente colpa di quella straniera che ha profanato il tempio qualche tempo fa.@>>";     ]
          "@<<Quali voci girano a proposito di riti e culti proibiti?@>>^
           @<<Cerco di non prestarvi nemmeno ascolto, convinto che siano solo indegne leggende; comunque si parla di cose che succedevano di notte nella foresta.@>>"
          "I rituali si svolgerebbero di notte nella foresta... Quanta originalit@`a... Tanto vale non chiedere altro sull'argomento. @`E per@`o interessante il riferimento a quella profanatrice di templi.";
          
Topic -> t_cerdil_donna
    with metatopic m_donna,
      description 
        "@<<Parlami di quella donna; in che modo avrebbe profanato il tempio?@>>^
         @<<Con la sua sola presenza, direi... Non era di qui, @`e passata dal villaggio circa un mese fa, non so per far cosa. Si @`e fermata per qualche minuto al tempio, davanti alla statua di Maral; sembrava pregasse, ma io ero l@`i accanto e ho sentito che stava pronunzianto bestemmie e frasi demoniache. Credo anche si sia accorta che la stavo ascoltando, perch@`e mi ha rivolto uno sguardo cattivo.@>>"
        "@<<Quella donna, cosa stava dicendo mentre fingeva di pregare?@>>^
         @<<Non ripeterei mai le sue parole, anche se molte non le capivo, erano in una lingua strana; ma in qualche modo capivo che stava offendendo i quattro dei... Ripeteva spesso la parola ia, come una cantilena: ia ia ia...@>>"
        "@<<Ti ricordi altro sulla donna... la profanatrice?@>>^
         @<<Non si @`e fermata che pochi minuti. Poi si @`e voltata verso di me e mi ha fissato in faccia; era scura di capelli, ma del suo viso ricordo solo gli occhi scurissimi che sembravano volermi maledire. Alla fine mi ha voltato le spalle ed @`e uscita.@>>"
        "Probabilmente l'accolito lavora molto di fantasia, ma questa straniera che entra in un tempio solo per recitare preghiere oscure potrebbe aver qualcosa a che fare con il resto.";

Topic ->
    with name 'tempio' 'edificio' 'costruzione',
         description
            "@<<Questo tempio @`e molto bello, specialmente per un villaggio cos@`i piccolo.@>>^
             @<<Infatti. Ma secondo me un tempio pi@`u umile sarebbe un luogo di preghiera migliore.@>>"
            "L'accolito evidentemente non apprezza la ricchezza di questo tempo.";

Topic ->
    with name 'dea' 'maral',
         description
            "@<<Lei @`e molto devoto a Maral?@>>^
             @<<Che domanda...@>>, il tono del giovane si fa pi@`u intenso mentre continua: @<<Ella @`e la mia Signora, e ho donato a lei la mia vita@>>."
            "@<<Maral @`e la dea dei raccolti. Non @`e strano che sia venerata in questa valle dove si coltiva ben poco?@>>
             @<<Mi stupisco che lei mi faccia questa domanda. Maral @`e la dea dei raccolti e dell'agricoltura, ma anche della natura nella sua interezza e della vita in ogni sua forma.@>>"
            "L'accolito @`e sicuramente fedele fino all'eccesso, anche se la sua preparazione teologica, per quanto tu ne sappia, lascia un po' a desiderare, ma avr@`a sicuramente tempo di rimediare.";

Topic ->
    with name 'dei' 'dio' 'oster' 'aran' 'irdil' 'statue' 'statua',
         description
            "@<<In questo luogo vengono venerati anche gli altri dei?@>>^
             @<<Certamente. Il tempio @`e consacrato a Maral, ma chiunque pu@`o entrare e rivolgere la sua preghiera ad Aran, ad Oster o, come credo accada nel suo caso, a Irdil. Come testimoniano le statue.@>>"
            "@<<Al villaggio abitano molte persone fedeli ad altri dei?@>>^
             @<<No, non molti. La maggior parte degli abitanti della valle sono fedeli a Maral.@>>"
            "Non hai altro da chiedere.";             

Topic ->
    with metatopic m_naradas,
         description
            "@<<Che pensa di Naradas?@>>^
             @<<Lo conosco poco, ma lo ritengo un uomo rigoroso e capace... Se solo fosse pi@`u pio...@>>"
            "@<<Sa dirmi altro su Naradas?@>>^
             @<<Non frequenta molto il tempio, probabilmente per impegni legati al suo incarico; me ne spiaccio perch@'e secondo me, se la luce di Maral lo avesse illuminato, sarebbe potuto diventare un ottimo sacerdote.@>>"
            "Non credi che il ragazzo possa dirti altro.";

Topic -> t_cerdil_dippin
    with metatopic m_dippin, name 'padre',
         description 
           [; give dippin proper;
              "@<<Cosa pensa del sacerdote?@>>^
               @<<Non si lasci ingannare dai beni materiali di cui si circonda. Padre Dippin @`e un uomo retto e giusto, un degnissimo sacerdote di Maral. Sono orgoglioso di svolgere il mio noviziato sotto di lui, anche se confinato in questo feudo sperduto.@>>"; ]
           [; print "@<<E' possibile parlare con il sacerdote Dippin?@>>^";
              if (dippin in AppartamentoTempio) "@<<Certamente... Lo trova nei suoi appartamenti.@>>";
              if (dippin in Tempio) "@<<Certo, non vede che @`e qui?@>>";
              "@<<Mi spiace, ma purtroppo @`e assente in questo momento. Provi pi@`u tardi.@>>";
           ];

Topic ->
    with metatopic m_vade,
         description
            "@<<Conosce il proprietario del laboratorio alchemico?@>>^
             @<<Onestamente non lo conosco molto. Parrebbe una persona a posto, ma il sacerdote dice di non fidarsene.@>>"
            [; give dippin proper;
               "@<<Sa dirmi altro sull'alchimista?@>>^
                @<<Sembra una brava persona, ma non frequenta molto il tempio e, le ripeto, padre Dippin sostiene che sia persona di cui diffidare.@>>"; ]
            "@<<Come mai il sacerdote Dippin non si fida dell'alchimista?@>>^
             @<<Dice che @`e a causa della sua professione, che spesso @`e in contrasto con i dettami dei culti dei quattro dei.@>>"
            "Meglio non chiedere altro. Comunque hai scoperto che Dippin non si fida dell'alchimista a causa - dice - della sua professione. Cosa che fra l'altro @`e una grossa sciocchezza, visto che i migliori alchimisti lavorano per i templi di Irdil.";
            
Topic ->
  with metatopic m_bris,
    description
      [; give bris proper;
         "@<<Conosce la cameriera della locanda?@>>^
          @<<Bris? Si, la conosco da quando eravamo ragazzi. Peccato che lavorare in quel postaccio la stia rovinando.@>>"; ]
      "@<<Cosa sa dirmi a proposito di Bris?@>>^
       @<<Niente di che. Era una brava ragazza, ma crescendo @`e diventata sempre pi@`u... sfacciata. Non so se capisce. Non posso che dispiacermente.@>>"
      "Evidentemente si rammarica del fatto che Bris lavori in una taverna e non sia invece la promessa sposa di un giovane accolito, ma a parte questo non pensi possa dirti qualcosa di veramente interessante su di lei.";
      
Topic -> t_cerdil_bano
  with metatopic m_bano,
    description
      "@<<Conosce il proprietario della locanda?@>>^
       @<<Poco. Cerco di tenermi lontano da quel posto. Le bevande inebrianti allontanano dalla retta via, e mi dispiaccio che l'osteria sia cos@`i vicina al sacro tempio di Maral, mi pare quasi una profanazione.@>>"
      "Meglio non insistere. L'ultima cosa di cui hai bisogno @`e un accolito che fa un sermone contro il vizio del bere.";
      
Topic ->
  with metatopic m_osteria, 
    description [; give m_bano ~locked; t_vade_bano.act(); ];

IRoom AppartamentoTempio "Appartamenti del sacerdote"
  with description
    "Lo sfarzo del tempio continua nei lussuosi appartamenti del sacerdote. Tutto qui contrasta con la figura del pio e semplice uomo di chiesa tipica del culto di Maral, dal letto a baldacchino allo scrittoio in mogano intagliato, al folto tappeto.",
    name 'appartamento' 'appartamenti',
    s_to Tempio, out_to Tempio,
    cant_to "Puoi solo andare a sud.",
    each_turn [; if (dippin notin self && cerdil notin self) solved(h_dippin); ],
  has light;

Object -> "letto"
  with name 'letto' 'cuscino' 'cuscini' 'lenzuolo' 'lenzuola' 'coperta' 'coperte' 'baldacchino',
       description "Un letto a baldacchino che pare pi@`u comodo di qualsiasi letto tu abbia provato.",
       react_before [;
         LieDown: <<enter self>>;
       ],
       before [;
         Go, Enter, Climb: "Non @`e il tuo letto.";
         LookUnder: "Non trovi niente sotto il letto.";
         Push, Pull, Turn: "Il letto @`e troppo pesante.";
         Open, Search: if (dippin in parent(self)) { addhint(h_dippin); "Non @`e consigliabile, con il sacerdote presente."; }
                       "Cerchi nel letto del sacerdote, ma non trovi niente.";
       ],
  has scenery supporter enterable;  
  
Prop -> "tappeto"
    with name 'tappeto',
      description "Un bellissimo tappeto.",
      before [;
        Take, LookUnder, Push, Pull, Turn: "Non credi che nasconda una botola, n@'e altro.";
      ];
      !cant_go "Un bel tappeto, ma inutile.";  
  
Object -> scrivaniadippin "scrittoio"
  with name 'scrivania' 'scrittoio' 'calamaio' 'penna',
    description [;
      print "Un prezioso scrittoio in mogano intagliato. Su di esso vedi una penna";
      if (letteradippin in parent(self)) ", un calamaio e un foglio di pergamena, probabilmente una lettera.";
      " e un calamaio.";
    ],
    before [;
      Open, Search: "Lo scrittoio non ha cassetti.";
    ],
  has scenery;

Object -> letteradippin "lettera"
  with pname 'lettera' '.or' 'missiva' '.or' 'foglio' '.or' 'pagina' '.x' 'di' '.x' 'pergamena',
       description [;
         if (dippin in location || cerdil in location) {
           addhint(h_dippin);
           if (player has invisible) "Il foglio di pergamena @`e arrotolato. Anche se sei invisibile, aprirlo rivelerebbe la tua presenza.";
           "Non oseresti mai sbirciare quella lettera sotto occhi vigili.";
         }
         give dippin proper;
         give m_parnias ~locked;
         solved(h_dippin);
         Achieved(7);
         give m_figli ~locked; 
         "Pare una lettera indirizzata al conte Parnias, signore del feudo confinante.^
          @<<Caro parente,^
           @<<Le voci che ho contribuito a mettere in giro a quanto pare hanno sortito l'effetto desiderato. Ieri sera @`e giunto uno straniero, e potrei giurare che @`e una spia inviata dalla capitale per indagare sui culti. A questo punto basta fare in modo che scopra la quercia alta e magari assista ai riti dei Figli della Valle. Questo segner@`a la caduta del povero barone Inderus.^
           @<<Ritengo di non averti potuto dare informazioni migliori.^
           @<<Fedele a te, il tuo parente Dippin, sacerdote di Maral.@>>^";
       ],
       before [;
         Take: "Meglio lasciarla dov'@`e..."; 
       ],
  has scenery female concealed;

NPC -> dippin
  with short_name [; if (self has proper) print "Dippin"; else print "sacerdote"; rtrue; ],
       name 'dippin' 'sacerdote' 'prete', article "il",
       description [;
         if (self has proper) print "Dippin "; else print "Il sacerdote ";
         "@`e un uomo ancora non anziano, di corporatura robusta e aspetto florido che tradiscono una particolare predilezione per la buona tavola. Indossa una veste talare finemente ricamata e, al collo, una piccola falce d'oro.";
       ],
       called 0,
  conversor dippintalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "Il sacerdote sobbalza alla tua apparizione.^";
    }
    Answer: "Dall'espressione del sacerdate comprendi che non ti ha compreso.";
    Show, Give: if (noun == mandato)
                    "Il sacerdote legge la tua lettera d'incarico e poi soggiunge: @<<Benvenuto, allora. Stavamo aspettando proprio voi. Spero proprio facciate un buon lavoro@>>.";
                if (noun == soldi && cerdil.vanished)
                    "La ringrazio, ma non credo che un'offerta possa risolvere il problema.";
                if (noun == soldi)
                    "Se vuol lasciare un'offerta la lasci pure al mio accolito.";
                if (noun == diariotriven)
                    "Il sacerdote scorre il vecchio diario e poi commenta, rendendotelo: @<<Fanfaluche. Vecchie storie e leggende prive di senso. Si occupi invece di quello che accade ai nostri giorni@>>.";
                if (noun == dlibro)
                    "Non pensi sia una buona idea. Farebbe strane domande sul come te lo sei procurato.";
                "Non credi che mostrare ", (the)noun, " ", (arta)self, " possa portarti vantaggi.";
    Greet: self.talkto(true);
           if (dippintalk.before(true)) rtrue;
           if (self has proper) print "@<<Salve, padre Dippin.@>>^"; else print "@<<Salve, padre.@>>^";
           "@<<Salve a lei, messere, Maral la accompagni.@>>";                    
    Kiss: "Meglio di no...";
    ThrowAt, Attack: "Non ti ha fatto niente di male.";
    !default: "Il sacerdote sorride con sguardo condiscendente.";
  ],
  lifedefault "Il sacerdote sorride con sguardo condiscendente.",
  daemon [;
    !print "Dippin [ ", self.called, " ]^";
    if (self.called==2 && real_location == Tempio) { self.called=3; rtrue; }
    if (self.called==3) {
        if (real_location == AppartamentoTempio) { self.called==2; rtrue; }
        if (self in AppartamentoTempio && random(3) == 1) {
            npcmove(self, s_obj, Tempio, " esce dal suo appartamento.", " esce di passo svelto dai suoi appartamenti.", 2); rtrue; }
        if (self in Tempio) {
            npcmove(self, se_obj, PiazzaVillaggio, " attraversa il tempio rivolgendo un cenno di saluto a te e al giovane accolito per poi uscire nella piazza del villaggio.", " esce dal tempio.", 2); rtrue; }
        if (self in PiazzaVillaggio) {
            npcmove(self, n_obj, DavantiEmporio, " prende la strada che conduce verso nord.", " arriva dalla piazza del villaggio.", 2); rtrue; }
        if (self in DavantiEmporio) {
            npcmove(self, n_obj, SentieroPalazzo, " passa oltre l'emporio, dirigendosi verso nord.", " arriva da sud, dal sentiero che proviene dal villaggio.", 2); rtrue; }
        if (self in SentieroPalazzo) {
            npcmove(self, e_obj, DavantiPalazzo, " prende la strada che conduce verso est, verso il palazzo.", " arriva da sud.", 2); rtrue; }
        if (self in DavantiPalazzo) {
            npcmove(self, e_obj, Ingresso, " entra all'interno del palazzo del barone rivolgendo un veloce cenno di saluto alle guardie.", 0, 2); rtrue; }
        if (self in Ingresso) {
            npcmove(self, e_obj, Scalinata, " attraversa l'ingresso e l'arco verso est.", " arriva dall'ingresso.", 2); rtrue; }
        if (self in Scalinata) {
            npcmove(self, u_obj, Pianerottolo, " prende con un po' d'affanno le scale che conducono al piano di sopra.", " arriva dal piano inferiore.", 2); rtrue; }
        if (self in Pianerottolo) {
            npcmove(self, s_obj, AnticameraBarone, " pare avere un attimo di esitazione prima di dirigersi verso l'anticamera degli appartamenti del barone.", " arriva da nord.", 2); self.called=4; rtrue; }
    }    
    if (self.called == 4) {
        self.called = 5; if (self in real_location) "^Naradas si volge verso Dippin dicendo: @<<Buongiorno e benvenuto, sacerdote Dippin, l'ho convocata perch@'e mi continuano a giungere voci a proposito del modo con cui si scaglia contro il barone nei suoi sermoni. Queste voci corrispondono al vero?@>>"; rtrue; }
    if (self.called == 5) {
        self.called = 6; if (self in real_location) "^Dippin risponde: @<<E anche se cos@`i fosse? Le ricordo che io rispondo solo all'autorit@`a religiosa, e non a quella secolare. E quindi sono libero di predicare come meglio ritengo, e come meglio mi suggeriscono la mia coscienza e la mia dea@>>."; rtrue; }
    if (self.called == 6) {
        self.called = 7; if (self in real_location) "^@<<La sua autonomia@>> continua Naradas, @<<non comprende il diritto a istigare alla sedizione. La prego di limitarsi a predicare su argomenti religiosi, tralasciando argomenti secolari. Altrimenti il barone sar@`a costretto a prendere provvedimenti.@>>"; rtrue; }
    if (self.called == 7) {
        self.called = 8; if (self in real_location) "^@<<Prendo atto delle sue minacce, e vedr@`a di comportarmi di conseguenza. @`E tutto quello che voleva dirmi?@>> Il tono della voce di Dippin @`e molto meno sicuro delle sue parole."; rtrue; }
    if (self.called == 8) {
        self.called = 9; if (self in real_location) "^@<<@`E tutto@>> conclude Naradas, @<<pu@`o ritenersi congedato.@>>"; rtrue; }
    if (self.called == 9) {
        if (self in AnticameraBarone) {
            npcmove(self, n_obj, Pianerottolo, " esce infuriato dalla stanza, dirigendosi verso le scale.", " esce infuriato dall'anticamera degli appartamenti del barone.", 2); rtrue; }
        if (self in Pianerottolo) {
            npcmove(self, d_obj, Scalinata, " scende le scale verso il piano inferiore.", " arriva dal piano superiore, irato in volto.", 2); rtrue; }
        if (self in Scalinata) {
            npcmove(self, w_obj, Ingresso, " si dirige verso l'ingresso del palazzo.", " arriva da est.", 2); rtrue; }
        if (self in Ingresso) {
            npcmove(self, w_obj, DavantiPalazzo, " esce dal palazzo mugugnando qualcosa tra i denti.", " esce dal portone del palazzo a testa bassa.", 2); rtrue; }
        if (self in DavantiPalazzo) {
            npcmove(self, w_obj, SentieroPalazzo, " si allontanta dal palazzo verso ovest.", " arriva dal palazzo, cercando malamente di nascondere un'espressione di rabbia sul volto.", 2); rtrue; }
        if (self in SentieroPalazzo) {
            npcmove(self, s_obj, DavantiEmporio, " si dirige a sud, verso il villaggio.", " arriva da nord.", 2); rtrue; }
        if (self in DavantiEmporio) {
            npcmove(self, s_obj, PiazzaVillaggio, " continua a camminare verso la piazza del villaggio.", " arriva dalla strada che proviene da nord.", 2); rtrue; }
        if (self in PiazzaVillaggio) {
            npcmove(self, nw_obj, Tempio, " sale gli scalini di marmo con un'espressione esasperata sul volto, per poi entrare all'interno del Tempio", " entra nel tempio con un'espressione esasperata sul volto.", 2); rtrue; }
        if (self in Tempio) {
            npcmove(self, n_obj, AppartamentoTempio, " si dirige sbuffando verso i suoi appartamenti.", " entra di colpo nei suoi appartamenti brontolando qualche offesa molto poco religiosa nei confronti del barone e di Naradas.", 2); self.called=10; StopDaemon(self); rtrue; }
    }
            
        
!        self.called=3;
!        move self to AnticameraBarone;
!        "Il sacerdote esce di passo svelto dai suoi appartamenti e attraversa il tempio rivolgendo un veloce cenno di saluto a te e al suo giovane accolito, per poi uscire nella piazza del villaggio e dirigersi, ti pare, verso nord.";
!    }                  
!    if (self.called==3 && real_location==AnticameraBarone && Dippin in AnticameraBarone) {
!        move self to Tempio;
!        "Entrando incroci il sacerdote del tempio che sta lasciando la stanza dicendo @<<Se questo @`e tutto, porgo i miei saluti a lei e al barone.@>>";
!    }
  ],     
  has;

Object dippintalk
    with before [flag;
      if (dippin.called >= 4 && dippin.called <=8) "Meglio non interrompere la discussione.";
      if (self hasnt general) {
        give self general;
        if (dippin hasnt proper)  print "@<<Salute a lei...@>>^";
         else                     print "@<<Salute a lei, sacerdote Dippin.@>>^";
        if (real_location==AppartamentoTempio)
            print "@<<Salve, straniero@>> risponde voltandosi verso di te, @<<Cosa c'@`e di tanto urgente da venirmi a disturbare nella mia camera?@>>^";
          else
            print "@<<Benvenuto, e Maral la protegga... Posso aiutarla.@>>^";
        pretalked = 1;
        return flag;
      }
      if (flag && easy) {
          if (t_dippin_culti.cnumber <= 1) { t_dippin_culti.act(); rtrue; }
          if (t_dippin_barone.cnumber == 0) { t_dippin_barone.act(); rtrue; }
          if (t_dippin_naradas.cnumber == 0 && dippin.called == 1) { t_dippin_naradas.act(); rtrue; }
          if (t_dippin_donna.cnumber == 0 && m_donna hasnt locked) { t_dippin_donna.act(); rtrue; }
          if (t_dippin_vade.cnumber <= 0 && m_vade hasnt locked) { t_dippin_vade.act(); rtrue; }
      }
   ],
   description
     "@<<Come sta procedendo il suo incarico in questo tempio?@>>^
      @<<Non male@>> @`e la risposta, @<<anche se non sarebbe male se ci fosse pi@`u gente alle funzioni.@>>"
     "Non ti sovviene altro da chiedere.",
   cant_go [;
       if (pretalked) print "^";
       "Il sacerdote ascolta le tue parole, si sofferma un attimo a pensare e poi risponde: @<<Mi spiace, ma non ne so molto...@>>";
   ];

Topic ->
  with name 'lui' 'se' 'stesso' 'egli' 'padre',
       metatopic m_dippin,
       before [;
            if (dippin hasnt proper) {
                give dippin proper;
                "@<<Mi scusi, come posso chiamarla?@>>^
                 @<<Eccellenza potrebbe andar bene, ma cerchiamo di essere meno formali. Mi chiami padre Dippin.@>>";
            }
       ],
       description
           "@<<Come mai un sacerdote cos@`i capace @`e finito in un posto tanto isolato?@>>^
            @<<@`E stata una mia scelta. Ho sentito il bisogno di vita tranquilla.@>> Dal tono della sua voce non sembra convinto; probabilmente questo incarico @`e solo il migliore a cui poteva aspirare."
           "@<<Serve qui da molto tempo?@>>^
            @<<Sono pi@`u di dieci anni.@>>"
           "Pensi di non dover chiedere altro sull'argomento.";

Topic -> t_dippin_barone
  with metatopic m_barone,
       description
            "@<<Mi parli del barone Inderus?@>>^
             @<<Aim@`e@>> sospira, @<<la spina del fianco di questa valle. Un uomo troppo debole per portare su di se il fardello del governo. Ho cercato e sto cercando di indurlo alla saggezza, ma per ora senza alcun risultato.@>>"
            "@<<Come mai ha cos@`i poca stima del barone?@>>^
             @<<Come ripeto spesso nei miei sermoni, una persona capace potrebbe far prosperare questa valle, secondo il volere degli dei. Ma invece lui non @`e in grado di governare nemmeno un piccolo feudo come questo.@>>"
            "Pare chiaro che il sacerdote non stimi il barone, al punto di osteggiarlo apertamente anche di fronte a te e ai fedeli.";

Topic ->
  with name 'biblioteca' 'libri' 'libro' 'libreria',
       description 
         [;
            give m_biblioteca ~locked;
            "@<<C'@`e una biblioteca, nel villaggio?@>>^
             @<<Il barone ha una biblioteca molto fornita, e lascia tanta sapienza a prendere polvere.@>>";
         ]
         "@<<A proposito della biblioteca...@>>^
          @<<L'unica in tutta la valle @`e nel palazzo del barone. Credo che se ne occupi Naradas.@>>";

Topic -> t_dippin_culti
  with metatopic m_culti,
       before [;
            if (knowcult)  !era: if (action==##Tell && knowcult)
                "Questo sacerdote ti ispira pochissima fiducia. Meglio lasciarlo all'oscuro.";
       ],
       description
            "@<<Si odono voci su strani culti che vengono praticati nella valle. Lei, come sacerdote di Maral, ne sa niente?@>>^
             @<<Sono pi@`u che voci, purtroppo. Succedono cose molto strane nella foresta durante la notte, e il male si sta lentamente diffondendo. Pi@`u volte ne ho parlato con il barone, perch@'e sterminasse questi riti blasfemi, ma egli non vuole prestarmi orecchio, e preferisce far finta di non vedere. A meno che anche egli...@>>"
            "@<<Cosa succede esattamente di notte nella foresta?@>>^
             @<<Non lo so esattamente, ma si parla di osceni rituali e di persone che venerano entit@`a diverse dai quattro dei, portando cos@`i il male in mezzo a noi.@>>"
            "@<<Lei non ha mai fatto niente per fermare questi rituali?@>>^
             @<<Ho denunciato i fatti al barone. Sono solo un debole sacerdote in un feudo sperduto, cosa potrei fare di pi@`u?@>>"
            "@<<Dove posso trovare prove di questi rituali?@>>^
             @<<Suppongo nella foresta. Ma non credo che ci sia bisogno di prove; bisogna soltanto trovare i colpevoli e punirli, e redarguire il barone per l'inettitudine con cui ha permesso tutto questo.@>>"
            "Il sacerdote sembra ben sicuro nel denunciare culti eretici che operano nella foresta, anche se diventa restio quando si parla di prove e insiste un po' troppo nel sottolineare la responsabilit@`a del barone. Sospetto, ma non di meno @`e tua responsabilit@`a indagare fino in fondo su quello che sostiene.";
            
Topic -> t_dippin_figli
  with metatopic m_figli,
    description 
        "@<<Che mi sa dire dei ~Figli della Valle~?@>>^
         Per un attimo cogli un lampo di esultanza negli occhi del sacerdote, prima che questi ti risponda: @<<Non molto. Mi @`e stato riferito questo strano nome da alcuni fedeli, riguardo attivit@`a perverse che si svolgono nella foresta.@>>"
        "@<<E non sa altro a proposito di questi ~Figli della Valle~?@>>^
         @<<Anche le persone pi@`u fedeli a Maral diventano molto sfuggevoli su quest'argomento, come se volessero proteggere i loro compaesani. Ma da quello che ho capito temo sia un culto dedito al male, e non mi stupirei se compissero orribili sacrilegi nascosti nelle ombre della foresta. Ovviamente sono sicuro che il barone ne sia a conoscenza, e che non voglia far niente.@>>"
        "@<<Quindi, a quanto mi dice, i ~Figli della Valle~ sarebbero dei fedeli di un culto proibito, giusto?@>>^
         @<<Temo proprio di s@`i@>> risponde il sacerdote, con un tono di voce che in qualche modo ti disturba, @<<un culto proibito e malvagio che fiorisce in questa piccola valle un tempo felice. Purtroppo per@`o non so dirle altro a proposito.@>>^"
        "Il sacerdote ti ha riferito di vaghe testimonianze secondo cui i ~Figli della Valle~ sarebbero fedeli di un culto proibito, i cui riti si svolgono nella foresta. Secondo il suo parere, che ha espresso con gioia e abbondanza di aggettivi, il culto @`e corrotto, malvagio e prospera sotto l'occhio accondiscendente del barone.";
         
Topic -> t_dippin_donna
  with metatopic m_donna,
    description 
      [; give cerdil proper;
         "@<<Lei sa niente di una donna che avrebbe profanato il tempio?@>>^
          @<<Cerdil lo ha detto anche a lei? Il ragazzo probabilmente si @`e fatto suggestionare. Probabilmente la donna era una straniera e pregava in un'altra lingua.@>>"; ]
         "@<<Quindi lei non pensa che l'episodio della profanatrice sia preoccupante?@>>^
          @<<Non ero presente, ma non credo ci sia stata alcuna profanatrice. Dia retta a me, i veri profanatori non entrano nel tempio. Io li cercherei nel folto della foresta.@>>"
         "Il sacerdote non crede alla storia di Cerdil. Inutile chiedere altro.";

Topic -> t_dippin_naradas
  with metatopic m_naradas,
       before [;
            if (dippin.called==1) {        !era: if (self.called==1 && action==##Tell) {
                dippin.called=2;
                StartDaemon(dippin);
                "@<<Naradas, il segretario del barone, mi ha detto che la stava aspettando...@>>^
                 @<<Giusto. Ha fatto benissimo a ricordarmelo. Mi recher@`o al pi@`u presto a palazzo.@>>";
            }
            if (dippin.called==2 or 3 && self hasnt general) {        !era: if (self.called==2 && action==##Tell) {
                give self general;
                "@<<Le ho gi@`a detto che Naradas la stava aspettando?@>>^
                 @<<S@`i, grazie...@>>";
            }
        ],
        description
            "@<<Conosce Naradas?@>>^
             @<<Non abbastanza. So solo che @`e lui spesso a rimediare alle inadempienze del suo padrone e a prendere decisioni al suo posto.@>>"
            "@<<Sa dirmi qualcosa in pi@`u su Naradas?@>>?^
             @<<Lo conosco poco. Purtroppo non frequenta molto il tempio.@>>"
            "Ti ha detto che Naradas @`e l'uomo che si occupa del governo della valle e ne ha approfittato per parlar male del barone. Non pensi sappia dirti di pi@`u.";

Topic ->
  with name 'tempio' 'edificio' 'costruzione',
       description
            "@<<I miei complimenti. Questo tempio @`e stupendo.@>>^
             @<<Grazie. Tutto merito della ricchezza che aveva la valle nei tempi passati. Questo tempio @`e stato costruito poco pi@`u di mezzo secolo fa, in sostituzione di una modesta costruzione in legno.@>>"
            "@<<Non pensa che questo tempio sia troppo ricco per un villaggio tutto sommato modesto?@>>^
             @<<Non credo. Glorificare Maral dovrebbe essere lo scopo principale di tutti gli abitanti della valle. E se avessimo un buon governante, il villaggio non sarebbe cos@`i modesto.@>>"
            "Non credi di dover chiedere altro. Evidentemente il sacerdote @`e estremamente soddisfatto dello sfarzo che lo circonda.";

Topic ->
  with name 'dea' 'maral',
       description
            "@<<Lei @`e  il rappresentante del culto di Maral in questo luogo...@>>^
             @<<Esatto. E come fedele figlio di Maral e fedele servo del patriarca, pu@`o contare su di me per avere tutto l'aiuto possibile.@>>"
            "@<<I feudi di montagna tendono ad avere templi di Aran o, dove ci sono  miniere, Irdil. Come mai qui invece viene prevalentemente venerata Maral?@>>
             @<<@`E sempre stato cos@`i@>> il sacerdote sembra pensare alla sua risposta per un attimo: @<<Probabilmente l'enorme foresta che riempie quasi tutta la valle testimonia la grandezza della dea della vita@>>."
            "@<<Maral @`e molto venerata dagli abitanti del villaggio?@>>^
             Non hai da chiedere altro.";

Topic ->
  with name 'dei' 'dio' 'oster' 'aran' 'irdil' 'statue' 'statua',
       description
            "@<<Ho visto anche le statue di Oster, Aran e Irdil.@>>^
             @<<Ovviamente. Questo tempio deve essere un punto di riferimento per tutti coloro che adorano i quattro dei.@>>"
            "@<<Ci sono molte persone fedeli ad altri dei?@>>^
             @<<Non moltissime, ma ci sono. E ci sono diverse persone che professano di venerare i quattro dei allo stesso modo, anche se io trovo questo atteggiamento al limite della blasfemia.@>>"
            "Non hai altro da chiedere sull'argomento.";
             

Topic ->
  with metatopic m_cerdil,
       before [;
            give cerdil proper;
            if (cerdil.vanished) {
              if (self hasnt general) {
                give self general;
                "@<<Padre, devo dirle che il suo accolito @`e scomparso.@>>^
                 @<<Scomparso? Cerdil @`e scomparso nel nulla? Questo @`e terribile... Dobbiamo fare qualcosa. Deve fare qualcosa... E' qui per questo, o sbaglio?@>>";
              }
              "@<<Padre, a proposito di Cerdil...@>>^
               @<<Non dica niente, si affretti a ritrovarlo. Lei deve fare qualcosa?@>>";
            }
        ],
        description        
            "@<<Il suo accolito sembra un giovane capace...^@>>
             @<<S@`i, Cerdil @`e proprio un bravo giovane. La sua fede @`e forte e salda, e possiede quell'idealismo che solo i giovani possono avere. E' forse solo un po' troppo rigido nei suoi giudizi.@>>"
            "@<<Sa dirmi altro su Cerdil?@>>^
             @<<Serve al tempio da quasi quattro anni; mi spiacer@`a lasciarlo andare ai suoi studi, ma imparer@`a molte cose, forse anche ad essere meno rigido, e diventer@`a un ottimo sacerdote.@>>"
            "Non credi possa dirti altro su Cerdil.";

Topic -> t_dippin_vade
  with metatopic m_vade,
       description
            "@<<C'@`e il laboratorio di un alchimista. Lo conosce?@>>^
             @<<Lo conosco. Parrebbe una brava persona, ma intuisco in lui qualcosa di oscuro.@>>"
            "@<<Cosa la spinge a dubitare dell'alchimista?@>>^
             @<<Intuito, e poi una persona devota non dovrebbe esercitare una professione simile.@>>"
            "@<<Perch@'e ritiene indegna la professione di alchimista?@>>^
             @<<Sono arti oscure, generalmente collegate alla stregoneria e all'eresia. Lei dovrebbe saperlo.@>>"
            "Il sacerdote dubita dell'alchimista e ritiene l'alchimia una scienza che confina con l'eresia. A te sembra confuso quanto un accolito, e rimarrebbe molto stupito vedendo i laboratori alchemici del grande tempio di Irdil. Probabilmente vive da troppo tempo lontano dalla civilt@`a.";
            
Topic ->
  with metatopic m_bano,
    description 
      [; give bano proper;
        "@<<Conosce il padrone della locanda?@>>^
         @<<Si, certo. Non che io la frequenti spesso, ma ho occasione di parlare abbastanza spesso con Bano, una persona molto schietta e allo stesso tempo gradevole.@>>"; ]
      "Non ti viene altro da chiedergli.";
      
Topic ->
  with metatopic m_bris,
    description
      [; give bano proper; give bris proper; 
         "@<<Conosce la cameriera dell'osteria?@>>^
          @<<S@`i, certo. @`E Bris, la figlia di Bano, l'oste. @`E una brava ragazza, anche se gradirei frequentasse di pi@`u le funzioni. Ma probabilmente il suo lavoro non le lascia molto tempo.@>>"; ]
      "Non credi di aver altro da chiedere.";

IRoom Osteria "L'osteria"
  with description
    "Quattro gradini scendono fino al pavimento dell'osteria. L'ambiente @`e abbastanza buio e l'odore di mosto e luppolo fermentati corre alle narici. Un lungo bancone di legno si para di fronte all'entrata, mentre rozzi tavoli pi@`u o meno lunghi, sedie e panche riempiono il resto dell'ampio locale.",
    name 'osteria' 'locanda' 'taverna',
    ne_to PiazzaVillaggio, out_to PiazzaVillaggio,
    cant_go "L'uscita @`e a nord-est.",
    before [;
      Go: if ((noun == ne_obj or out_obj) && 
              (birra in player || vino in player || liquore in player)
              && (bano in osteria)) 
                  "L'oste ti ferma dicendo: @<<Per favore, non si allontani con i miei bicchieri@>>.";
      Smell: "A giudicare dall'odore il vino e la birra serviti in questo luogo non sono affatto male.";
    ],
  has light female;
  
Object -> "bancone"
  with name 'bancone' 'banco',
    description "Un bancone in faggio rozzamente intagliato.",
    before [;
      Push, Pull, Turn: "@`E troppo pesante.";
      Search, LookUnder: "Il bancone non nasconde niente.";
    ],
  has supporter scenery;
  
Prop -> "tavoli"
  with name 'tavoli' 'tavolo' 'sedia' 'sedie' 'panca' 'panche',
    description "I tavoli, le sedie e le panche che costituiscono l'arredamento del locale non saranno il massimo del lusso, ma adempiono pienamente alla propria funzione.",
    before [;
      Push, Pull, Turn: "Inutile. Non troveresti niente.";
      Search, LookUnder: "Non trovi niente.";
    ],
  has pluralname;
!Object -> bevande "bevande"
!    with name "birra" "vino" "da bere" "bevanda" "alcool" "alcol" "bevande" "liquore",
!         description "Dietro il bancone fanno mostra di se due barilotti di birra, diversi otri di vino e una bottiglia di liquore.",
!    before [;
!      Buy: "Dovresti essere pi@`u specifico. Vino, birra o liquore?";
!    ],
!    has scenery;

[ testbevanda ostefirst;
    if (soldi notin player) "Non credi che l'oste faccia credito agli stranieri...";
    if (birra hasnt scenery || vino hasnt scenery || liquore hasnt scenery)
          "Forse sarebbe meglio bere quello che gi@`a hai, prima di ordinare di nuovo.";
    if (bris notin real_location && bano notin real_location)
          "Strano. Non c'@`e nessuno a cui ordinare da bere.";
    if (bris notin real_location || ostefirst) 
                                  print "Ti avvicini al bancone e l'oste ti serve ";
     else                         print "La cameriera ti serve subito ";
    rfalse;
];

Object -> bevande "bevande"
    with name 'bevanda' 'bevande' 'da' 'bere' 'barile' 'barilotto' 'barili' 'barilotti' 'otre' 'otri' 'bottiglia',
         description [;
           if (self in player) "Un boccale di legno traboccante di birra scura.";
           "Dietro il bancone fanno mostra di se due barilotti di birra, diversi otri di vino e una bottiglia di liquore.";
          ],
    before [; Buy, Take: "L'osteria offre birra, vino, oppure un liquore che pare ottimo."; ],
    has scenery female pluralname concealed;
        
! Le bevande cambiano aspetto a seconda che abbiano o meno l'attributo scenery

Object -> birra "boccale di birra"
    with name 'boccale' 'di' 'della' 'birra',
         description [;
           if (self in player) "Un boccale di legno traboccante di birra scura.";
           "Dietro il bancone fanno mostra di se due barilotti di birra, diversi otri di vino e una bottiglia di liquore.";
          ],
    before [;
      Buy, Take:
           if (action==##Take && self hasnt scenery) rfalse;
           if (testbevanda(0)) rtrue;
           move self to player;
           give self ~scenery;
           print (a) self,".^";
           if (action_to_be == ##Take or ##Buy) rtrue;
      Drink:
           if (self has scenery) "Forse sarebbe meglio prima ordinare...";
           if (drunk_level >= 3) "Hai bevuto abbastanza. Meglio restare lucidi.";
           drunk_level++;
           move self to osteria;
           give self scenery;
           "Forte e dissetante...";
      Empty, EmptyT: "Non servirebbe a nulla. Sarebbe solo uno spreco.";
    ],
    has scenery;

Object -> vino "bicchiere di vino"
    with name 'bicchiere' 'di' 'vino',
         description [;
           if (self in player) "Un bicchiere pieno di uno scuro vino dal colore leggermente ambrato.";
           "Dietro il bancone fanno mostra di se due barilotti di birra, diversi otri di vino e una bottiglia di liquore.";
          ],
    before [;
      Buy, Take: 
           if (action==##Take && self hasnt scenery) rfalse;
           if (testbevanda(0)) rtrue;
           move self to player;
           give self ~scenery;
           print (a) self,".^";
           if (action_to_be == ##Take or ##Buy) rtrue;
      Drink:
           if (self has scenery) "Forse sarebbe meglio prima ordinare...";
           if (drunk_level >= 3) "Hai bevuto abbastanza. Meglio restare lucidi.";
           drunk_level++;
           move self to osteria;
           give self scenery;
           "Veramente ottimo...";
      Empty, EmptyT: "Non servirebbe a nulla. Sarebbe solo uno spreco.";
    ],
    has scenery;

Object -> liquore "bicchiere di liquore"
    with name 'bicchiere' 'di' 'liquore',
         description [;
           if (self in player) "Un piccolo bicchiere pieno di un liquore quasi trasparente.";
           "Dietro il bancone fanno mostra di se due barilotti di birra, diversi otri di vino e una bottiglia di liquore.";
          ],
    before [;
      Buy, Take: 
           if (action==##Take && self hasnt scenery) rfalse;
           if (testbevanda(0)) rtrue;
           move self to player;
           give self ~scenery;
           print (a) self,".^";
           if (action_to_be == ##Take or ##Buy) rtrue;
      Drink:
           if (self has scenery) "Forse sarebbe meglio prima ordinare...";
           if (drunk_level >= 3) "Hai bevuto abbastanza. Meglio restare lucidi.";
           drunk_level++;
           move self to osteria;
           give self scenery;
           "Forte e secco... L'ideale per queste giornate fredde...";
      Empty, EmptyT: "Non servirebbe a nulla. Sarebbe solo uno spreco.";
    ],
    has scenery;

NPC bano "l'oste" osteria
    with name 'bano' 'oste' 'locandiere', !article "l'",
      description "L'oste @`e esattamente come si potrebbe immaginare il proprietario di un'osteria in un feudo sperduto. Alto, robusto, muscoloso e con stampata sul volto un'espressione che @`e a met@`a strada fra l'ira e la giovialit@`a.",
  conversor banotalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "L'oste ti squadra sospettoso quando si accorge all'@`improvviso della tua presenza.^";
    }
    Answer: "L'oste ti guarda attonito. Non credi proprio abbbia capito.";
    Kiss: "Meglio di no...";
    Show, Give: if (noun == mandato) "Se l'oste sapesse che sei una spia, probabilmente ti farebbe a pezzi.";
                if (noun == soldi) "L'oste osserva i tuoi soldi e dice: @<<Prego, messere, ordini pure quello che vuole@>>.";
                "Non credi che all'oste possa interessare ", (arta)self, ".";
    ThrowAt, Attack: "Non ci pensi nemmeno. Ti farebbe a pezzi.";
    !default: "L'oste ti sorride con fare burbero.";
  ],
  lifedefault "L'oste ti sorride con fare burbero.",
  Orders [;
    Give: if (noun == bevande)
              "@<<Abbiamo vino, birra, oppure un liquore che distillo personalmente. Cosa vuole?@>>";
          if (noun == birra or vino or liquore) {
               if (testbevanda(1)) rtrue;
               move noun to player;
               give noun ~scenery;
               print_ret (a) noun,".";
          }
  ],
  rs 0,
  each_turn [; 
    if (silenceturns > 2 && random(2) == 1) {
      switch(++self.rs) {
        2: print_ret "^L'oste sgombera il bancone e prova a pulirlo con uno straccio, senza grandi risultati.";
        5: print_ret "^L'oste controlla le botti e le bottiglie alle sue spalle.";
        8: print_ret "^L'oste si sposta da una parte all'altra del bancone.";
        10: self.rs = 0;
      }
    }
  ],  
  has proper;

Object banotalk
    with
        before [flag;
            if (flag && easy && bano.cnumber >= 1) {
                if (t_bano_culti.cnumber <= 1) { t_bano_culti.act(); rtrue; }
                if (t_bano_uomo.cnumber == 1) { t_bano_uomo.act(); rtrue; }
            }
        ],
        description
           "@<<Salve...@>>^
            @<<Salve, straniero. Si accomodi e prenda qualcosa da bere.@>>"
           "@<<Cosa si racconta da queste parti?@>>^
            @<<Niente di nuovo. Qua sulle montagne non succede mai molto.@>>"
           "Non ti sovviene altro altro da chiedere all'oste.",
         cant_go "@<<Mi spiace, ma non conosco...@>> @`e la secca risposta dell'oste alle tue parole.";

Topic ->
    with name 'egli' 'lui' 'se' 'stesso',
         metatopic m_bano,
         description
            "@<<La domanda potr@`a parle strana, ma mi pu@`o dire qualcosa di lei?@>>^
             @<<Non ho molto da dire, e niente di interessante. Si goda piuttosto il mio vino e la mia birra, ne vale la pena.@>>"
            [; give bano proper;
               "@<<Posso almeno chiedere il suo nome?@>>^
                @<<Ma certo, mi scusi. Nel villaggio mi conoscono tutti, ma lei @`e straniero. Mi chiamo Bano.@>>"; ]
            "L'oste non sembra molto propenso a parlare di se stesso.";

Topic ->
    with metatopic m_osteria,
         description
            "@<<Mi piace questa locanda. Ha un'aria accogliente.@>>^
             @<<Faccio quello che posso@>> risponde lui con un sorriso di malcelato orgoglio, @<<per offrire un po' di sollievo a questa dura gente di montagna.@>>"
            "@<<Questa osteria @`e frequentata da molta gente?@>>^
             @<<Praticamente da tutti gli uomini della valle. @`E il vantaggio di non avere concorrenza.@>>"
            "Non hai altro da chiedere.";

Topic ->
    with metatopic m_barone,
         description
            "@<<Che mi dice del barone?@>>^
             @<<Bah... i suoi ordini di vino e birra sono sempre molto abbondanti, ed @`e un gran pagatore. Cosa posso volere di pi@`u.@>>"
            "@<<Pu@`o dirmi altro sul barone?@>>^
             @<<Sa godersi la vita, quindi @`e il tipo di persona che pi@`u apprezzo, nonostante sia un nobile.@>>"
            "Non credi possa dirti altro sul barone Inderus";

Topic -> t_bano_culti
    with metatopic m_culti,
         description
            "@<<Sto ricercando notizie su culti e strane religioni di queste zone. Lei ne sa niente?@>>^
             @<<Mah... Ogni tanto, la sera, qualcuno dice di aver notato cose strane, e per tutta la sera non si parla d'altro. Ma la sera dopo tutto pare dimenticato. Evidentemente la mia birra @`e troppo forte per qualcuno dei miei clienti.@>>"
            "@<<Si ricora qualcuna di queste storie su culti, riti o strane cose che accadono?@>>^
             @<<Non ci faccio mai molto caso, e in genere le storie sono molto diverse tra loro. C'@`e chi parla di luci spettrali nella foresta, chi sostiene di aver visto strani animali, chi dice di aver trovato al mattino segni di riunioni clandestine. Per me non c'@`e niente di vero, ma con quelle storie si vende molta pi@`u birra.@>>"
            "@<<Non sa dirmi altro su culti e eventi misteriosi?@>>^
             @<<Le dico solo una cosa: in genere quelli che raccontano queste storie sono quelli che bevono di pi@`u. Sar@`a un caso...@>>"
            "L'oste ha riferito di storie di luci spettrali, strani animali e segni di riunioni clandestine, ma nemmeno lui ci crede molto.";

Topic ->
    with metatopic m_dippin, name 'tempio' 'templi',
         description
            "@<<Che pensa del vostro sacerdote?@>>^
             @<<E' bene che anche i santi uomini non trascurino le buone bevande. E il nostro sacerdote pare apprezzarle alquanto. Ci vorrebbero pi@`u sacerdoti come lui.@>>"
            "@<<Quindi lei stima il sacerdote del culto di Maral?@>>^
             @<<@`E un buon cliente; non frequenta l'osteria ma apprezza particolarmente il mio vino e se na fa recapitare spesso una botticella o due. Non saprei come giudicare il suo operato come sacerdote, ma un buon bevitore @`e una buona persona.@>>"
            "Al sacerdote piace il buon vino, a quanto pare. Non credi che l'oste sappia altro.";
            
Topic ->
    with metatopic m_cerdil,
         description
            "@<<E del giovane accolito al tempio che mi dice?@>>^
             @<<Mmmm... Mai visto qui dentro. Troppo rigido per diventare un buon sacerdote, nonostante la sua fede e il suo entusiasmo. Forse sarebbe pi@`u tagliato per la vita militare.@>>"
            "@<<Sa dirmi altro dell'accolito che serve presso il tempio?@>>^
             @<<Lo conosco poco, ma penso che diventer@`a uno di quei sacerdoti che vorrebbero che tutti i loro fedeli fossero dei santi. O magari un predicatore errante, sempre pronto a castigare le mancanze della fede in ogni citt@`a e villaggio che incontra. O, peggio ancora, un inquisitore.@>>"
            "Non credi che l'oste sappia molto, e tutto sommato non sei molto interessato al suo parere.";

Topic ->
    with metatopic m_vade,
         description
            "@<<Conosce l'alchimista che ha la bottega qui vicino?@>>^
             @<<Si, lo conosco. Siamo amici da anni. E' una persona di cui ci si pu@`o fidare.@>>"
            "@<<Sa dirmi qualcosa in pi@`u sull'alchimista?@>>^
             @<<@`E una delle persone pi@`u sagge e disponibili dell'intero villaggio. In molti si rivolgono a lui se hanno bisogno di un consiglio.@>>"
            "Non hai altro da chiedere.";

Topic ->
    with metatopic m_iarin,
         description 
           [;
            if (iarin in real_location)
              "@<<Conosce una ragazza chiamata Iarin?@>>^
               @<<La nipote dell'alchimista? Certo, @`e quella ragazza alle sue spalle. Strano, pensavo che foste arrivati insieme...@>>";
            "@<<Conosce una ragazza chiamata Iarin?@>>^
             @<<E' la nipote dell'alchimista. Una brava ragazza, degna nipote di suo zio.@>>"; ]
           "Non hai altro da chiedere.";

Topic ->
    with metatopic m_erlik, name 'emporio',
         description
            [; give erlik proper;
              "@<<Conosce il padrone dell'emporio?@>>^
               @<<Si, conosco Erlik. Sicurmente guadagna alle nostre spalle pi@`u di quanto non sembri.@>>"; ]
            "@<<Sa dirmi altro su Erlik?@>>^
             @<<In molti pensano che sia un piccolo truffatore, ma il suo @`e il solo emporio in tutta la valle, e quindi continuano a servirsi da lui.@>>"
            "Non pensi di dover chiedere altro, e non credi che il sospetto che Erlik sia un truffatore sia di qualche rilevanza per il tuo incarico.";

Topic -> t_bano_olfer
    with metatopic m_olfer, name 'forgia',
         description 
           [;
            give olfer proper;
            print "@<<Conosce il fabbro di questo villaggio?@>>^";
            if (olfer in osteria)
                "@<<Olfer? E' il nostro miglior cliente, lo pu@`o vedere seduto a quel tavolo. In genere resta qui fino a che non ha bevuto abbastanza e poi torna al lavoro, ma in questi giorni @`e un po' a corto di soldi.@>>";
            "@<<Olfer? E' il nostro miglior cliente. Credo che ora sia tornato alla forgia.@>>";
           ]
           "@<<Sa dirmi altro su Olfer?@>>^
            @<<@`E un brav'uomo e un bravo fabbro, anche se beve un po' troppo. @`E anche abbastanza scorbutico, quando @`e sobrio.@>>"
           "Non hai altro da chiedere.";

Topic ->
    with name 'birra' 'vino' 'liquore' 'liquori' 'bevande',
         description
             "@<<Vedo che servite birra, vino e liquore. Niente altro?@>>^
              @<<Mi spiace, straniero, ma non siamo in capitale. Comunque assaggi qualcosa. Non se ne pentir@`a.@>>"
             "Chiedere all'oste come @`e il suo vino generalmente @`e una perdita di tempo.";

Topic -> t_bano_uomo
    with name 'uomo' 'avventore',
         description 
           [;
            if (olfer in osteria) {
                give olfer proper;
                give m_olfer ~locked;
                "@<<Chi @`e l'uomo seduto a quel tavolo?@>>^
                 @<<Olfer, fabbro e nostro miglior cliente.@>>";
            }
           ]
           [; t_bano_olfer.act(); ];

Topic ->
    with metatopic m_bris, name 'ragazza',
         description
            "@<<Carina la cameriera...@>>^
             @<<Molto... E siccome @`e mia figlia, non aggiungere altro e stalle lontano...@>>"
            "Considerando il tono e la stazza dell'oste @`e meglio non insistere sull'argomento.";
            
Topic ->
    with metatopic m_rabam,
      description
        [; give rabam proper;
           "@<<Conosce il giardiniere che lavora a palazzo?@>>^
            @<<Ma certo, conosco benissimo Rabam. Viene qui abbastanza spesso, sebbene difficilmente beva pi@`u di un boccale. Viene principalmente per stare lontano dalla chiacchere della moglie.@>>"; ]
        "@<<Che cosa sa dirmi su Rabam?@>>^
         @<<@`E sempre stato un brav'uomo e un gran lavoratore. Per il resto non c'@`e molto da dire su di lui, se non che i giardini a palazzo hanno tutto un altro aspetto da quando ci lavora lui.@>>"
        "Non hai altro da chiedere.";

Topic ->
  with metatopic m_dei,
    description 
      "@<<So che @`e una domanda personale, ma posso chiederle quale dei quattro culti segue?@>>^
       @<<Non ho problemi a risponderle. Sono seguace di Maral, anche se occasionalmente mi rivolgo a Oster perch@'e protegga i miei affari.@>>"
      "Non sei cos@`i tanto interessato alla fede dell'oste.";

NPC bris "" osteria
    with short_name [; if (self has proper) print "Bris"; else print "cameriera"; rtrue; ],
    with name 'bris' 'cameriera' 'ragazza',
      description "Per un attimo ti perdi ad osservare la bellezza non comune di questa giovane ragazza dagli occhi quasi viola e lunghi capelli neri che scendono su di un corpo perfetto, ben evidenziato dall'abito che indossa. Ti chiedi se la tua missione potrebbe permetterti qualche distrazione.",
  count 0, vanished FALSE, greet FALSE,
  conversor bristalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "La ragazza trattiene un'urlo, vedendoti all'improvviso.^";
    }
    Answer: "Non ti pare che la ragazza ti abbia compreso.";
    Kiss: if (bano in real_location) "Con l'oste presente? Ci tieni troppo, alla tua vita.";
          "Ti avvicini alla ragazza e le dai un bacio. Lei ti sorride maliziosa.";
    Show, Give: if (noun == mandato) "Non credi che sia una buona idea mostrarle la tua lettera d'incarico.";
                if (noun == soldi) "@<<Prego@>> risponde lei osservando la tua borsa, @<<si accomodi e ordini pure quello che vuole.@>>";
                "Non pensi che ", (arta)self, " possa interessare ", (the)noun, ".";
    ThrowAt, Attack: "Non potresti mai far del male ad una ragazza tanto bella.";
    Greet: if (self hasnt proper) if (bristalk.before(true)) rtrue;
           self.talkto(true);
           "@<<Salve, Bris, sempre felice di vederla.@>>^
            @<<Salve a lei, e grazie.@>>";
    !default: "La ragazza ti sorride.";
  ],
  lifedefault "La ragazza ti sorride.",
  Orders [;
    Give: if (noun == bevande) "@<<Cosa posso portarle? del vino, della birra, o preferisce un buon liquore per scaldarsi?";
          if (noun == birra or vino or liquore) {
               if (testbevanda(0)) rtrue;
               move noun to player;
               give noun ~scenery;
               print_ret (a) noun,".";
          }
  ],
  rs 0,
  each_turn [;
    give m_bris ~locked;
    if ((~~self.greet) && player hasnt invisible) {
        self.greet=true;
        "^La giovane cameriera ti rivolge un sorriso e un cenno di saluto.";
    }
    if (silenceturns > 1 && random(2) == 1) {
      switch(++self.rs) {
        3: print_ret (The) self, " riordina le sedie attorno ad un tavolo.";
        6: print_ret (The) self, " si sofferma per un attimo a sistemarsi i capelli.";
        9: print_ret (The) self, " raccoglie i bicchieri lasciati su di un tavolo e li porta fino al bancone.";
        11: self.rs = 0;
      }
    }
  ],
  has female;

Object bristalk
  with before [flag;
        if (bris hasnt proper) {
          give bris proper;
          print "@<<Mai vidi tanta bellezza. Quale @`e il tuo nome?@>>^
                 @<<Non merito tanto, signore. Mi chiamo Bris, posso aiutarla in qualche modo?@>>^";
          pretalked = 1;
          return flag;
        }
        if (flag && easy && bris.cnumber >= 1) {
            if (t_bris_culti.cnumber == 0) { t_bris_culti.act(); rtrue; }
            if (t_bris_triven.cnumber == 0 && m_triven hasnt locked) { t_bris_triven.act(); rtrue; }
            if (t_bris_uomo.cnumber == 0) { t_bris_uomo.act(); rtrue; }
            if (t_bris_olfer.cnumber <= 1) { t_bris_olfer.act(); rtrue; }
        }
    ],
    description 
        "@<<Bris, permettimi di dire che sono incantato dai suoi occhi.@>>^
         @<<Oh, grazie... Vuole qualcosa da bere?@>>"
        "@<<@`E una gradita sorpresa incontrare tanta grazia e dolcezza in questa valle.@>>^
         @<<Grazie, mi sta mettendo in imbarazzo@>> risponde lei, anche se la sua espressione dice tutt'altro."
        "@<<Credimi, anche nella capitale @`e impossibile trovare ragazze pi@`u belle di te.@>>^
         @<<Non ci credo, ma mi piace sentirle dire questo.@>>"
        "Preferisci tenere altre galanterie in serbo per dopo.",
    cant_go [;
        if (pretalked) print "^";
        "La ragazza ascolta la tua domanda, per poi scuotere graziosamente la testa e rispondere: @<<Non ne so niente... mi spiace...@>>";
    ];

Topic ->
    with metatopic m_bris, name 'lei' 'se' 'stessa' 'ella',
         before [;
             if (bris hasnt proper) {
               give bris proper;
               "@<<Posso ardire tanto da chiedere qual @`e il nome di una ragazza tanto bella?@>>^
                @<<Non merito tanto, signore. Mi chiamo Bris, posso aiutarla in qualche modo?@>>"; }
         ],
         description
             "@<<Non pensavo che tra queste montagne nascessero fiori tanto belli...@>>^
              @<<Lei mi vuol far arrossire.@>>"
             "@<<Dimmi qualcosa di te...@>>^
              @<<Non ho molto da raccontare. Sono solo la cameriera di una locanda in un piccolo villaggio.@>>"
             "Non hai altro da chiedere o da dire, per ora.";

Topic ->
    with metatopic m_barone,
         description
            "@<<Che sai del barone?@>>^
             @<<Non molto. Viene qui di rado, e quando viene non mi stacca mai gli occhi di dosso.@>>"
            "@<<Invece, tu cosa pensi del barone Inderus?@>>^
             @<<Tutto sommato sarebbe una brava persona, ma gli piacciono troppo le donne e il vino.@>>"
            "Non pensi sappia molto a proposito del barone.";

Topic -> t_bris_culti,
    with metatopic m_culti,
         description
            "@<<Sai qualcosa di culti proibiti o sette segrete?@>>^
             @<<Solo le voci che sento in giro. Spero proprio siano false. Queste cose mi spaventano.@>>"
            "@<<Puoi raccontarmi qualcosa su queste voci che si sentono su culti, sette e rituali?@>>^
             @<<Ogni tanto qui alla locanda qualcuno parla di fatti strani, ma di solito ho troppo da fare per starli ad ascoltare.@>>"
            "Non credi sappia molto, anche se la locanda sembra il punto giusto dove raccogliere informazioni.";
            
Topic ->
    with metatopic m_donna,
        description
            [; give cerdil proper;
               "@<<Qualche tempo fa @`e passata da qui una straniera. Ne sai niente?@>>^
                @<<La strega? Non l'ho vista ma me ne ha parlato Cerdil. Ha detto che ha profanato il tempio con preghiere blasfeme e che lo ha maledetto con lo sguardo.@>>"; ]
            "Non credi che sappia niente di pi@`u oltre a quello che le ha detto l'accolito.";

Topic ->
    with metatopic m_dippin,
         description
            [;  give dippin proper;
                "@<<Che pensi del sacerdote di Maral?@>>^
                 @<<Siamo fortunati ad avere un sacerdote come padre Dippin, che capisce che ci sono molti modi in cui qualcuno pu@`o essere fedele agli dei, e non solo con digiuni e penitenze.@>>"; ]
            "@<<Quindi padre Dippin non @`e un sacerdote rigido e inflessibile?@>>^
             @<<Assolutamente no. Non vado molto spesso alle sue cerimonie, ma ho occasione di parlargli di tanto in tanto, @`e sempre molto disponibile.@>>"
            "Secondo la cameriera Dippin @`e un sacerdote comprensivo. Ti chiedi se questo dipenda dall'avvenenza della ragazza o dal vino fornito dall'oste.";

Topic ->
    with metatopic m_cerdil,
         description
            "@<<Conosci il giovane accolito che presta servizio al tempio?@>>^
             @<<E' tanto carino@>> risponde lei, @<<peccato che sia cos@`i rigido.@>>"
            [; give cerdil proper;
              "@<<Sai dirmi altro a proposito del giovane accolito?@>>^
               @<<Conosco Cerdil da quando eravamo bambini, e in effetti ha sempre avuto la fissazione della religione. Da quando ha preso servizio al tempio poi @`e diventato bigotto in modo insopportabile.@>>"; ]
            "Non hai altro da chiedere.";

Topic ->
    with metatopic m_vade,
         description
            "@<<Qui vicino c'@`e un alchimista, lo conosci?@>>^
             @<<Mio padre lo conosce bene. Io non molto.@>>"
            "@<<Sai dirmi altro sull'alchimista?@>>^
             @<<Mi spiace, ma non lo conosco molto bene. Chieda a mio padre, l'oste.@>>";

Topic ->
    with metatopic m_iarin,
         before [;
            if (iarin in real_location)
              "@<<Conosci una ragazza chiamata Iarin?@>>^
               @<<Stai scherzando? Vi ho visto entrare insieme...@>>";
         ],
         description 
            "@<<Conosci una ragazza chiamata Iarin?@>>^
             @<<Poco. Non andiamo assolutamente d'accordo e preferiamo ignorarci.@>>"
            "Non credi sappia dirti altro.";

Topic -> t_bris_triven
    with metatopic m_triven,
         description 
           [; give m_olfer ~locked;
              "@<<Sa niente di un mago, uno studioso, che abit@`o qui tempo addietro?@>>^
               @<<Non ne so niente, ma mi pare di aver sentito Olfer parlarne, una o due volte.@>>";  ]
         "Non pare ne sappia niente, ma ti ha suggerito di parlare con Olfer.";

Topic -> t_bris_olfer
    with metatopic m_olfer, name 'forgia',
         description 
           [; give olfer proper;
              if (wtopicword == 'olfer' or 'uomo' or 'avventore')
                  print "@<<Esattamente, chi sarebbe Olfer?@>>^
                         @<<E' il fabbro del villaggio";
               else
                  print "@<<Sai chi @`e il fabbro di questo villaggio?@>>^
                         @<<E' Olfer";
              if (olfer in osteria)
                  ", l'uomo seduto a quel tavolo. Mio padre lo conosce molto bene.@>>";
              ". Era qui fino a poco fa.@>>";
         ]
         "@<<Sai dirmi altro su Olfer?@>>^
          @<<@`E molto scorbutico, specialmente con chi non ha in simpatia. Ma ama molto birra, vino e storie da osteria.@>>"
         "A sentir lei, Olfer @`e la persona giusta a cui chiedere informazioni.";

Topic -> t_bris_uomo,
    with name 'uomo' 'avventore',
         description [;
            if (olfer in osteria) {
                give m_olfer ~locked;
                give olfer proper;
                "@<<Chi @`e l'uomo seduto a quel tavolo?@>>^
                 @<<E' Olfer, il fabbro.@>>";
            }
         ]
         [; t_bris_olfer.act(); ];


Topic ->
    with metatopic m_bano, name 'padre' 'babbo' 'papa' 'pap@`a' 'papa^',
         description
            "@<<Conosci l'oste da molto tempo?@>>^
             @<<Da quando sono nata, visto che @`e mio padre.@>>"
            "@<<Che mi sai dire su tuo padre?@>>^
             @<<Sarebbe il miglior padre che potrei desiderare, se non fosse tanto geloso.@>>"
            "L'oste, il padre della cameriera, @`e molto geloso. Meglio essere prudenti nel fare complimenti alla ragazza.";
            
Topic ->
  with metatopic m_dei,
    description
      "@<<Posso chiederti quale culto segui principalmente?@>>^
       @<<Sono fedele a Maral, come molti altri qui al villaggio.@>>"
      "Non credi di avere altro da chiedere riguardo alla fede della ragazza.";

NPC olfer "" osteria
  with short_name [; if (self has proper) print "Olfer";
                        else if (real_location == Osteria) print "avventore";
                              else print "fabbro";
                       rtrue; ],
  name 'olfer' 'fabbro' 'avventore' 'uomo',
      description [;
        if (real_location == Osteria)
            "Un uomo robusto, calvo e non troppo alto, siede da solo ad un tavolo in disparte.";
        if (real_location == Forgia)
            "Il fabbro @`e un uomo robusto, calvo e non troppo alto. In questo momento sta battendo
             sull'incudine dei ferri da cavallo. Sembra comunque leggermente alticcio.";
        "Il fabbro @`e un uomo robusto, calvo e non troppo alto.";
      ],
  drunk 0, walk 0,
  conversor olfertalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "L'uomo trasale quando si accorge della tua presenza.^";
    }
    Answer: "L'uomo ti guarda in tralice...";
    Give: if ((noun == birra or vino or liquore) && noun hasnt scenery) {
              self.drunk++;
              move noun to osteria;
              give noun scenery;
              switch (self.drunk) {
                1: Achieved(6);
                   solved(h_olfer);
                   self.talkto(true);
                   print_ret "L'uomo sembra gradire la tua offerta. Infatti esclama: @<<Questo @`e un buon modo di presentarsi, straniero!@>> prima di scolarsi ", (the) noun, ".";
                2: print_ret "@<<Ma certo... un bicchiere in pi@`u non pu@`o che farmi bene.@>> dice prima di bere ", (the) noun, " tutto d'un fiato.";
                3: give m_olfer ~locked;
                   StartDaemon(self);
                   self.walk = 1;
                   print_ret "L'uomo acccetta con piacere la tua offerta dicendo: @<<Un ultimo bicchiere, prima di riprendere il lavoro@>> prima di bere ", (the) noun, ".";
                default: "@<<Grazie, ma credo di aver gi@`a bevuto troppo.@>>";
              }
          }
          if (noun == mandato) "Meglio di no. Non sai chi sia veramente quest'uomo.";
          if (noun == mazzuolo) "Potrebbe servirti. Glielo renderai poi...";
          "Non credi che sia interessato ", (arta) noun, ".";
    Show: if ((noun == birra or vino or liquore) && noun hasnt scenery)
              "L'uomo pare interessato alla tua offerta...";
          if (noun == mandato) "Meglio di no. Non sai chi sia veramente quest'uomo.";
          if (noun == mazzuolo) "Mostrargli qualcosa che gli hai rubato? Meglio non farlo.";
          "Non credi che sia interessato ", (arta) noun, ".";
    Kiss: "Lascia perdere...";
    ThrowAt, Attack: "Ti ha fatto qualcosa?";
    !default: "L'uomo sbuffa e ti guarda storto...";
  ],
  lifedefault "L'uomo sbuffa e ti guarda storto...",
  daemon [;
      if (self.walk == 1) { self.walk = 2; rtrue; }
      if (self.walk == 2) {
        if (self in Osteria) {
          npcmove(self, ne_obj, PiazzaVillaggio, " si alza in piedi, fa un cenno di saluto nella tua direzione e in quella dell'oste, e poi esce dalla locanda barcollando.", " esce dalla locanda barcollando.", 2); rtrue; }
        if (self in PiazzaVillaggio) {
          npcmove(self, s_obj, DavantiForgia, " si dirige con andatura malferma per la strada che conduce verso sud.", " arriva dalla piazza del villaggio, evidentemente alticcio.", 2); rtrue; }
        if (self in DavantiForgia) {
          solved(h_forgia);
          npcmove(self, w_obj, Forgia, " estrae una chiave da una tasca e, dopo un paio di tentativi, apre la porta della forgia ed entra.", " entra dalla porta.", 2); self.walk == 3; StopDaemon(self); rtrue; }
      }
  ],
  has;

Object olfertalk
    with before [flag;
            if (~~olfer.drunk) {
               addhint(h_olfer);
               "Provi a rivolgere la parola all'uomo, ma lui ti risponde solo con uno sguardo che ti fa comprendere quanto poco egli desideri la tua compagnia.";
            }
            if (olfer hasnt proper && flag) {
              give olfer proper;
              give m_olfer ~locked;
              print "@<<Salve. La disturbo?@>>^";
              if (self in Osteria) print "@<<Chi offre da bere non disturba mai. Mi chiamo Olfer, e sono il fabbro del villaggio.@>>^";
              print "@<<Assolutamente no. Mi chiamo Olfer e sono il fabbro del villaggio.@>>^";
              pretalked = 1;
              return flag;
            }
            if (flag && easy && olfer.cnumber >= 1) {
                if (t_olfer_culti.cnumber == 0) { t_olfer_culti.act(); rtrue; }
                if (t_olfer_triven.cnumber == 0 && m_triven hasnt locked) { t_olfer_triven.act(); rtrue; }
                if (t_olfer_donna.cnumber == 0 && m_donna hasnt locked) { t_olfer_donna.act(); rtrue; }
                if (t_olfer_pietra.cnumber == 0 && m_pietra hasnt locked) { t_olfer_pietra.act(); rtrue; }
            }
         ],
         description
              [; if (self in Osteria)
                     "@<<Salve, Olfer.@>>^
                      @<<Salve a lei... Mi fa compagnia per un bicchiere o due?@>>";
                     "@<<Salve, e buon lavoro...@>>^
                      @<<Salve a lei, e grazie...@>>";
              ],
      cant_go [;
          if (pretalked) print "^";
          "Alla tua domanda l'uomo risponde soltanto: @<<No... Non ne so niente, mi spiace.@>>";
      ];

Topic ->
  with metatopic m_olfer, name 'avventore' 'lui' 'se' 'stesso' 'egli',
       before [;
            if (olfer hasnt proper) {
                give olfer proper;
                "@<<Salve. Quale @`e il suo nome?@>>^
                 @<<Olfer. Mi chiamo Olfer, straniero. Ah, sono il fabbro del villaggio, se le interessa.@>>";
            }
       ],
       description
           "@<<Come va, Olfer?@>>^
            @<<Non male, straniero.@>>"
           "@<<Ha sempre abitato qui al villaggio?@>>^
            @<<Ci sono nato e cresciuto@>> risponde lui, @<<ma ho passato molti anni nell'esercito imperiale, dove ho imparato il mio mestiere. Quando mi sono congedato sono tornato qui e ho rilevato l'attivit@`a del vecchio fabbro che si stava ritirando.@>>"
           "Non ti viene altro da dire.";

Topic ->
  with metatopic m_barone,
       description
            "@<<Che mi dice del barone Inderus?@>>^
             @<<Bah... tutti i nobili e i governanti sono una piaga. Lui non @`e peggio di altri.@>>"
            "@<<Ma cosa pensa lei del barone?@>>^
             @<<@`E un buon bicchiere, e questo @`e un punto a sua favore, e per fortuna si disinteressa del governo della valle, invece di mandarci in rovina.@>>"
            "Non pensi possa dirti molto, oltre al fatto che ritiene il barone un inetto e un gaudente che non si occupa affatto del suo feudo.";

Topic -> t_olfer_culti
  with metatopic m_culti, name 'radura' 'quercia' 'foresta' 'alberi' 'bosco' 'albero',
       description
            "@<<Sa qualcosa di culti proibiti, riti segreti, o altre cose strane?@>>^
             @<<Dia retta a me. In questa valle succedono cose strane, e qualcuno c'@`e dentro fino al collo. Un mese fa ero a caccia nella parte pi@`u ad est della valle quando sono giunto in una radura dominata da un'alta quercia. Tutta la radura era coperta di impronte di piedi calzati, come se decine di persone si fossero ritrovate in quel luogo la notte prima.@>>"
            "@<<Sa dirmi altro su questa radura?@>>^
             @<<Non molto di pi@`u di quello che ho gi@`a detto. Evidentemente ci sono persone che si ritrovano nella foresta, in segreto. Se quello non @`e un culto proibito, non so cosa altro lo sia.@>>"
            "Non credi possa dirti altro, ma ti ha gia' detto abbastanza: persone che si radunano in segreto in una radura dominata dalla quercia, nella parte est della foresta. Tutto questo merita attenzione.";
            
Topic -> t_olfer_donna
  with metatopic m_donna, name 'pugnale' 'coltello',
       description
           "@<<Qualche tempo fa una donna @`e arrivata qui al villaggio. Lei l'ha vista?@>>^
            @<<S@`i, due mesi fa o poco pi@`u. @`E venuta alla forgia per farsi affilare un coltello, un'arma molto strana e molto bella - non @`e stato facile affilarlo. Anche la donna, ripensandoci, era molto strana e molto bella.@>>"
           "@<<Si ricorda altro sulla straniera del pugnale?@>>^
            @<<Mi ha lasciato il pugnale dicendo che doveva passare al tempio e a fare altri acquisti, ed @`e venuta a riprenderlo dopo un po'. No, non ricordo altro.@>>"
           "La donna gli ha portato uno strano pugnale ad affilare. Per il resto non credi sappia altro.";

Topic -> t_olfer_pietra
  with metatopic m_pietra,
       description
           "@<<Ha mai visto una grossa pietra nera, nella foresta?@>>^
            @<<Una pietra a forma di cerchio? Mi @`e capitato di arrivarci per caso, qualche volta. Ma quando sono andato per ricercarla, non sono riuscito a ritrovarla. Credo che sia maledetta.@>>"
           "Non credi che sia maledetta come sostiene lui, ma probabilmente @`e nascosta nella foresta pi@`u fitta, ed @`e quasi impossibile trovarla.@>>";
           
Topic -> t_olfer_triven
  with metatopic m_triven, name 'capanna' 'casupola' 'baracca',
       description
            "@<<Sa niente di un mago che venne in questa valle tempo addietro?@>>^
             @<<Qualcosa mi hanno raccontato, ma @`e storia vecchia. Si dice che abitava in una specie di baracca oltre il fiume, e che fu assassinato misteriosamente nel sonno, non si sa da chi.@>>"
            "@<<Sa dirmi altro a proposito di quel mago?@>>^
             @<<@`E una storia che viene raccontata di tanto in tanto, ogni tanto con nuovi dettagli: ad esempio ogni tanto qualcuno sostiene di aver trovato la sua baracca, sul lato sud del fiume.@>>"
            "Ti ha detto abbastanza: questo studioso viveva in una baracca sul lato sud del fiume e fu assassinato nel sonno.";

Topic ->
  with metatopic m_dippin,
       description
            "@<<Che pensa del sacerdote del tempio?@>>^
             @<<Ci sono sacerdoti peggiori...@>>"
            "@<<Pu@`o dirmi altro del sacerdote?@>>^
             @<<Credo e rispetto i quattro dei, e quindi preferisco non parlare dei loro rappresentanti.@>>"
            "Non hai altro da chiedere.";

Topic ->
  with metatopic m_bris, name 'ragazza',
       description
            "@<<La cameriera @`e molto bella, non trova?@>>^
             @<<Molto... Ma stia molto attento a suo padre, l'oste... E' molto geloso...@>>"
            "Non pensi di dover chiedere di pi@`u.";

Topic ->
  with metatopic m_bano,
       description
            "@<<Conosce bene l'oste?@>>^
             @<<Considerando che passo pi@`u tempo qui che a casa@>> risponde lui ridendo, @<<direi che lo conosco meglio di mia moglie.@>>"
            "@<<E dell'oste, cosa mi sa dire?@>>^
             @<<@`E un uomo gioviale, anche se un po' rude. Ed @`e l'unico in questa valle che offra un po' di ristoro ad una gola riarsa.@>>"
            "Non hai altro da chiedere sull'oste.";

Topic ->
  with name 'moglie' 'sposa',
       description
            "@<<Lei @`e sposato, mi par di capire...@>>^
             @<<Esatto... E mia moglie @`e l'ultima persona di cui voglio parlare...@>>"
            "Non sei cos@`i interessato a sua moglie.";
            
Topic ->
  with metatopic m_dei,
    description
      "@<<Posso chiederle, se vuole rispondermi ovviamente, quale dei quattro culti segue?@>>^
       @<<Non @`e semplice. Da buon ex soldato sono fedele ad Aran, ma rispetto anche Irdil, che mi guida nel mio mestiere, e Olfer, che protegge i miei affari. E, visto che c'e' un solo tempio qui al villaggio, di tanto in tanto frequento le cerimonie del culto di Maral.@>>"
      "La fede @`e una questione personale. Ogni domanda ulteriore potrebbe essere offensiva.";

ORoom DavantiAlchimista "Il villaggio (a est della piazza)"
  with description
    "La strada che corre tra le case @`e molto larga, e le case stesse sembrano di fattura migliore rispetto al resto del villaggio. Guardando verso ovest si vede ancora la piazza principale, mentre verso est le costruzioni si fanno pi@`u rade, come se la strada portasse fuori dal villaggio. Verso nord si apre la porta di un negozio.",
    name 'strada' 'villaggio' 'borgo' 'har' 'plenais',
    w_to PiazzaVillaggio, e_to VersoForesta,
    n_to GoLaboratorio, in_to GoLaboratorio,
    cant_go "La strada si stende da est a ovest, e il negozio @`e a nord.",
    initial [; LeftPicture(Village_img, -1, -1); ];

Prop -> "case"
  with name 'case' 'costruzioni' 'abitazioni' 'casa' 'costruzione' 'abitazione' 'edifici',
    description "Le case non sono molto dissimili dalle altre, ma qui la maggior parte delle costruzioni sono in pietra, e realizzate con una cura particolare.",
    cant_go "Sono solo le case degli abitanti del villaggio."
  has pluralname female;

Direction -> "piazza"
  with name 'piazza' 'locanda' 'osteria' 'taverna' 'tempio', dir_to w_obj, has female;
  
Direction -> "foresta"
  with name 'foresta' 'alberi' 'bosco' 'boschi', dir_to e_obj, has female;

Direction -> "laboratoio"
  with name 'laboratoio' 'negozio' 'bottega' 'porta' 'edificio', dir_to n_obj,
    description [;
        give m_vade ~locked;
        "Una piccola targa d'ottone accanto alla porta reca incisa una boccetta di vetro. Questo negozio deve essere sicuramente il laboratorio di un alchimista."; ],
    before [;
        Open, Unlock, Knock: if (GoLaboratorio(true)>1) "La porta @`e aperta.";
                             if (action==##Knock) "Nessuno viene ad aprire.";
                             "La porta @`e chiusa a chiave.";
    ],
  has scenery concealed;

[GoLaboratorio sil; 
    if ((night || sunset || vade notin Laboratorio) && phase <6)
        if (~~sil) "La bottega @`e chiusa.";
         else  rtrue;
    return(Laboratorio);
];

IRoom Laboratorio "La bottega dell'Alchimista"
  with description
    "Questo negozio @`e ben pulito e ordinato, quasi all'eccesso, anche se un odore acre pervade l'aria. Su di una scaffalatura trovano posto fiale e bottigliette, e dall'altra parte della stanza un bancone ospita una buona collezione di erbe e altro, tenute in barattoli ben chiusi. Una piccola porta si apre nella parete nord.",
    name 'negozio' 'bottega' 'laboratorio' 'stanza',
    s_to DavantiAlchimista, out_to Laboratorio,
    n_to PortaLaboratorio,
    cant_go "L'uscita @`e verso sud, e c'@`e una porta a nord.",
    before [;
      smell: "Odor d'ammoniaca e solfuro, mescolati ad altri che non riconosci.";
    ],
    each_turn [;
        give m_vade ~locked;
        if (vade in self) give vade general; ],
  has light;
    
Prop -> "fiale"
  with name 'fiale' 'fiala' 'bottiglia' 'bottiglie' 'scaffali' 'scaffale' 'scaffalatura',
    description "Le fiale e le bottigliette contengono liquidi di un tenue color ambra, o di un verde carico, o perfettamente cristallini.",
    before [;
        Take: "Non sei ferrato in alchimia, e non sapresti come usarli.";
        Push, Pull, Turn, Search, LookUnder: "Dopo una rapida occhiata ti rendi conto che scaffali e bottigliette non nascondono niente.";
    ],
    !cant_go "@`E solo materiale da erboristi."
  has female pluralname;
    
Prop -> "barattoli"      
  with name 'erbe' 'barattolo' 'barattoli' 'bancone' 'banco',
    description "Erbe medicinali, probabilmente...",
    before [;
      Take: "Non hai la minima idea riguardo al loro uso. Inutile prenderli.";
      Push, Pull, Turn, Search, LookUnder: "N@'e il bancone n@'e i barattoli nascondono alcunch@'e.";
    ],
    !cant_go "@`E solo materiale da erboristi."
  has pluralname;

MyDoor -> PortaLaboratorio "porta"
  with pname 'porta' '.x' 'verso' '.or' 'a//' '.x' 'nord' '.or' 'n//',
    description "Una piccola ma robusta porta in legno.",
    door_to DavantiAlchimista, ! can't happen
    door_dir n_to,
  has locked;

NPC -> vade
  with short_name [;
           if (self in Laboratorio) give self general;
           if (self has proper) print "Vade";
            else if (self has general) print "alchimista";
             else print "uomo";
           rtrue; ],
       name 'vade' 'alchimista' 'medico' 'cerusico' 'erborista' 'uomo', !article "l'",
       description [;
         if (self has proper) print "Vade @`e";
          else if (self has general) print "L'alchimista @`e";
           else print "E'";
         print " un uomo di mezza et@`a, ma ancora ben prestante. Asciutto di corporatura, di lui ti colpiscono le mani, dalla pelle rovinata dal continuo contatto con le sostanzde con cui lavora, e lo sguardo, che ispira una immediata fiducia.";
         if (self in Radura) print " E' vestito con una semplice tunica da cerimonia verde scura e regge in mano un pesante bastone di quercia.";
         "";
       ],
       greet FALSE,
  conversor vadetalk,
  life [;
    if (player has invisible) {
      give player ~invisible;
      print "L'uomo @`e sorpreso di vederti all'improvviso.^";
    }
    if (self in Radura) rtrue;
    Answer: "Non credi che ti abbia capito.";
    Kiss: "Lasciamo perdere...";
    Show, Give:
      if (noun == mandato) "Meglio restare nell'anonimato. Ti conviene.";
      if (noun == diariotriven) "L'uomo scorre velocemente il vecchio diario, soffermandosi incredulo a leggere alcuni passaggi. Poi soggiunge, rendendoti il volume, @<<Quello che leggo in queste pagine mi preoccupa non poco. Mi chiedo se queste creature infestano ancora la foresta.@>>";
      if (noun == dlibro) "Non pensi che sia una buona idea. Probabilmente rivendicherebbe sul libro qualche diritto, pretendendolo per se.";
      print_ret (The)self, " osserva ", (the)noun, " ma non pare molto interessato.";
    ThrowAt, Attack: "Che ti ha fatto di male?";
    !default: "L'uomo ti guarda e abbozza un mezzo sorriso.";
  ],
  lifedefault "L'uomo ti guarda e abbozza un mezzo sorriso.",
  rs 0,
  each_turn [;
     if ((~~self.greet) && player hasnt invisible && self in Laboratorio) {
         self.greet=TRUE;
         self.talkto(false);
        "^Come entri, l'uomo si rivolge a te dicendo: @<<Buona giornata a voi, messere, sebbene il clima sia ancora freddo.@>>";
     }
     if (self in Laboratorio && silenceturns > 2 && random(2) == 1) {
       switch(++self.rs) {
         3: print_ret (The) self, " si ferma per qualche attimo davanti allo scaffale, controllando che le fiale siano messe in ordine.";
         6: print_ret "Ti sembra che per un attimo, solo per un attimo,", (the) self, " si soffermi a guardarti in volto, come se volesse capire dal tuo sguardo che tipo di persona tu sia in realt@`a.";
         9: print_ret (The) self, " riordina distrattamente i barattoli sul bancone. Hai l'impressione che per@`o ti stia osservando, sorridendo tra s@'e e s@'e.";
         11: self.rs = 0;
       }
     }      
  ],
  has;

Object vadetalk
    with before [flag;
            if (vade hasnt proper) {
                 give vade proper;
                 print "@<<Salve, buon uomo...@>>^
                        @<<Salve, messere. Io sono Vade, medico e alchimista. Le serve qualcosa?@>>^";
                 pretalked = 1;
                 return flag;
            } 
        if (flag && easy && vade.cnumber >= 1) {
            if (t_vade_culti.cnumber <= 1) { t_vade_culti.act(); rtrue; }
            if (t_vade_triven.cnumber == 0 && m_triven hasnt locked) { t_vade_culti.act(); rtrue; }
            if (t_vade_pietra.cnumber == 0 && m_pietra hasnt locked) { t_vade_pietra.act(); rtrue; }
            if (t_vade_donna.cnumber == 0 && m_donna hasnt locked) { t_vade_donna.act(); rtrue; }
        }
    ],
    description
        "@<<Salute a lei, Vade; come sta?@>>^
         @<<Non male, direi. Mi auguro che anche lei stia bene.@>>"
        "@<<Un'attivit@`a come la sua rende anche in un villaggio tanto piccolo?@>>^         
         @<<S@`i, considerando che lavoro anche come medico e erborista, quando occorre, come artigiano del legno o come esperto delle malattie delle piante.@>>"
        "Non hai altro da chiedere.",
      cant_go [;
          if (pretalked) print "^";
          "L'uomo ti ascolta con attenzione ma pu@`o solo rispondere: @<<Mi spiace, non so aiutarla... Non so niente a proposito...@>>";
      ];

Topic ->
    with metatopic m_vade, name 'lui' 'se' 'stesso' 'egli',
    before [;
        if (vade hasnt proper) {
            give vade proper;
            "@<<Salve. Lei @`e...?@>>^
             @<<Io sono Vade, medico e alchimista. Le serve qualcosa?@>>"; }
    ],
    description 
      "@<<Lavora da molto tempo come alchimista?@>>^
       @<<Da quasi tutta la vita@>> risponde lui, @<<Ho concluso l'apprendistato presso il tempio di Irdil a Marad Vor quando avevo meno di vent'anni, e da allora non ho fatto altro.@>>"
      "Non pensi di aver altro da chiedere.";

Topic ->
    with metatopic m_barone,
         description
            "@<<Che sa del barone Inderus?@>>^
             @<<Il nostro ben poco saggio governante. Non @`e una cattiva persona, ma @`e, come dire, poco capace... Non lo dico per offenderlo, sia ben chiaro...@>>"
            "@<<Quindi lei non stima molto il barone, giusto?@>>^
             @<<Non ho detto questo, assolutamente. Per@`o @`e ancora giovane e inesperto, questo @`e innegabile. Probabilmente con il passare degli anni diverr@`a un buon governante, e intanto ha avuto la saggezza di assumere un amministratore capace ed evitare che i suoi capricci da giovane nobile influenzassero troppo il governo della valle.@>>"
            "Ovviamente non stima il barone, ma almeno @`e molto pi@`u diplomatico di altri.";

Topic -> t_vade_culti
    with metatopic m_culti,
         before [;
             if (seguaci.count > 1 && self.cnumber >= 3) { t_vade_figli.act(); rtrue; } 
         ],
         description
            "@<<Lei sa qualcosa di culti o di strani rituali?@>>^
             @<<Effettivamente ci sono dicerie abbastanza diffuse, come quella che sostiene che strani esseri si aggirano di notte nella foresta. Personalmente, io non li ho mai visti, e non conosco nemmeno nessuno che ammetta di averli visti.@>>"
            "@<<Sa dirmi altro di questi esseri@>> chiedi ripensando a quello che hai visto ieri sera.^
             @<<Si parla - ma sono soltanto voci, badi bene - di creature mostruose in parte umane e in parte animali, che si aggirano nelle parti pi@`u scure della foresta, lontano dal villaggio.@>>"
            "@<<Oltre a questo sa dirmi altro su culti proibiti, riti, riunioni segrete?@>>^
             @<<Storie da locanda, probabilmente. Credo che in ogni feudo girino voci simili, ma ben difficilmente sono vere.@>>"
            "Credi di aver chiesto abbastanza: la storia di queste creature per met@`a uomini e per met@`a animali sembrerebbe una leggenda, se tu non fossi sicuro di aver visto qualcosa di simile."; 
            
Topic -> t_vade_figli
    with metatopic m_figli,
        before [;
            if (seguaci.count == 0) {
                if (self hasnt general) {
                    give self general;
                    "@<<Sa dirmi qualcosa di un gruppo chiamato ~Figli della Valle~?@>>^
                     @<<No@>> risponde lui dopo un attimo di esitazione, @<<mai sentiti nominare@>>";
                }
                "A quanto pare non ne sa niente.";
            }
        ],
        description
            "@<<Scusi se lo chiedo, ma ha mai sentito parlare dei ~Figli della Valle~@>>^
             @<<La prego, messere@>> ti risponde, @<<Non prendiamoci in giro. So bene che ha assistito al nostro rituale. E so bene anche chi lei sia.@>>"
            "@<<Allora, cosa pu@`o dirmi del vostro... culto.@>>^
             @<<Lei pu@`o credermi o no, ma lasci che le dica che la nostra religione @`e pi@`u antica delle vostre. La nostra signora @`e la madre terra, donatrice di vita, ed @`e lei che amiamo in ogni sua forma, rispettando ogni forma di vita, rifiutando ogni forma di violenza.@>>"
            "@<<Sa che il vostro culto @`e proibito, che dovr@`o riferire ai miei superiori...?@>>
             @<<Ovviamente. Ma stanno succedendo cose peggiori, e per questo non posso impedirglielo. Posso per@`o garantirle che io sono l'unico responsabile: io ho ricreato questo culto, io ho raccolto attorno a me i Figli della Valle, e se c'@`e qualcuno da punire, quello sono io, e nessun altro.@>>"
            "Difende il suo culto con vigore, cercando allo stesso tempo di proteggere gli altri e assumersi tutte le colpe. Non credi di riuscire ad ottenere altre informazioni da lui.";
             

Topic -> t_vade_donna
    with metatopic m_donna,
        description
            "@<<Tempo addietro una donna dovrebbe essere passata da qui. Ne sa niente?@>>^
             @<<S@`i, ricordo, due mesi fa, pi@`u o meno. Le ho preparato un infuso d'erbe secondo una ricetta che mi ha detto lei.@>>"
            "@<<Sa dirmi altro su quella donna e sull'infuso che le ha preparato?@>>^
             @<<Guardi, era fatto da una mistura di erbe che crescono tutte qui nella valle. Avevo tutto in laboratorio. Non so a cosa servisse, a quanto ne so poteva avere solo un leggero effetto stordente.@>>"
            "@<<Si ricorda altro su quella donna?@>>^
             @<<Era bella, ma di una bellezza inquietante, in grado di mettere a disagio chiunque si trovasse con lei. Non so da dove venisse, so soltanto che si @`e fermata solo per poche ore, probabilmente solo per fare qualche acquisto.@>>"
            "La donna ha comperato un infuso fatto con le erbe che crescono nella valle, secondo una ricetta portata da lei. Non credi che l'alchimista sappia dirti altro.";

Topic ->
    with metatopic m_naradas,
         description
            "@<<Di Naradas che pensa?@>>^
             @<<Non @`e un cattivo amministratore, ma il barone lascia troppo potere nelle sue mani.@>>"
            "@<<Sa dirmi altro su Naradas?@>>^
             @<<@`E freddo e calcolatore, che sono due virt@`u in un amministratore. Non sembra interessato alla ricchezza o al potere, e sembra veramente operare per governare la valle al meglio, e - devo ammettere - con un certo successo. Mi chiedo se nasconda qualcosa.@>>"
            "Stando a quando dice, Naradas @`e un buon amministratore, capace e non particolarmente avido. Lui infatti si chiede se ci sia qualcosa sotto, e in effetti @`e un dubbio legittimo.";

Topic ->
   with metatopic m_tempio,
       description [; give m_dippin ~locked; t_vade_dippin.act(); ];

Topic -> t_vade_dippin
    with metatopic m_dippin,
         description
            "@<<Che ne pensa del sacerdote del tempio?@>>^
             @<<Per molti @`e un uomo giusto e rigoroso, ma alcuni - non certo io - sostengono che, nel concedere indulgenze, sia molto pi@`u disposto con chi pu@`o ricambiarlo con doni o inviti a cena.@>>"
            "@<<Ma lei personalmente cosa pensa del sacerdote?@>>^
             @<<Non @`e mia abitudine giudicare gli altri, specialmente se si tratta di uomini di fede.@>>"
            "Non credi che possa o voglia dirti molto altro. Evidentemente non lo stima e sospetta che sia ipocrita e corrotto, ma - per indole o per prudenza - non lo dir@`a mai apertamente.";

Topic ->
  with metatopic m_osteria, 
    description [; give m_bano ~locked; t_vade_bano.act(); ];

Topic -> t_vade_bano
  with metatopic m_bano,
    description
      [; give bano proper;
         "@<<Conosce bene l'oste?@>>^
          @<<S@`i, sebbene non frequenti molto l'osteria. @`E un brav'uomo, rude e spontaneo.@>>"; ]
      "Non ti viene altro da chiedere sull'oste.";
      
Topic ->
  with metatopic m_bris,
    description
      [; give bris proper; give bano proper;
         "@<<Che mi sa dire della cameriera della locanda?@>>^
          @<<Si chiama Bris, ed @`e la figlia di Bano, l'oste. Non so molto di pi@`u, mi spiace.@>>"; ]
      "Non credi sappia dirti altro, n@'e sei particolarmente interessato, in fondo.";
      
Topic ->
    with metatopic m_erlik, name 'emporio',
         description 
           [; give erlik proper;
              "@<<Che pensa del proprietario dell'emporio?^@>>
               @<<Stia molto attento a quello che acquista. Erlik @`e - a quanto si sente in giro - un piccolo imbroglione, e molti tra gli abitanti del villaggio sostengono di essere stati truffati.@>>";   ]
           "@<<Mi sa dire altro su Erlik?@>>^
            @<<Sebbene si dubiti della sua onest@`a, e sebbene sia troppo ciarliero, @`e tutto sommato un brav'uomo, affabile e disponibile.@>>"
           "Erlik @`e un truffatore simpatico e chiaccherone. Non credi di serva sapere altro.";

Topic -> t_vade_triven
    with metatopic m_triven,
         description
            "@<<Ho sentito parlare di un mago che si stabil@`i nella valle qualche tempo fa.@>>^
             @<<Si, ne ho sentito parlare, anche se sono fatti di quasi un secolo fa. Ho sentito dire che era stato inviato dall'accademia per studiare non so cosa. Mi pare si chiamasse Triven, o qualcosa del genere.@>>"
            "@<<Come mai conosce il nome di questo Triven?@>>^
             @<<In diversi se ne ricordano, e la gente ha memoria lunga, anche se non sembra.@>>"
            "@<<Sa dirmi altro su questo Triven?@>>^
             @<<Non pi@`u di quello che le ho gi@`a detto. Venne, si stabil@`i fuori dal villaggio - forse nella foresta - e poi scomparve misteriosamente.@>>"
            "@`E strano che l'alchimista conosca il nome di questo studioso - Triven. Per il resto ti ha detto che forse era stato inviato dall'accademia, che forse abitava nella foresta e che scomparve misteriosamente.";

Topic ->
    with metatopic m_iarin, name 'ragazza' 'giovane' 'nipote',
         description
            "@<<Sua nipote pare una ragazza intelligente...@>>^
             @<<Lo @`e senza dubbio, e non @`e il suo solo pregio...@>>"
            "@<<Le @`e molto affezionata?@>>^
             @<<Credo proprio di s@`i. La conosco da quando era piccola, e ora le sto insegnando il mio mestiere.@>>"
            "Non ti viene altro da domandare a proposito.";
            
Topic ->
    with metatopic m_aloe,
        description
          "@<<A cosa servono le foglie di aloe?@>>^
           @<<Sono un ottimo rimedio medicinale. Ad esempio sono ottime per fare impacchi per far rimarginare le ferite, ma servono anche ad abbassare la febbre. Peccato che non si riesca a far crescere l'aloe con il clima freddo della valle.@>>"
          "Non ti viene altro da domandare a proposito.";

Topic ->
  with metatopic m_nilis,
    description
      [; give nilis proper; give hila proper; give rabam proper;
         "@<<Conosce la ragazza che lavora come cameriera a palazzo?@>>^
          @<<Si, certo. Si chiama Nilis, ed @`e figlia di Hila e Rabam - lavorano anche loro per il barone - ed @`e una cara amica di mia nipote.@>>"; ]
      "Non pensi che sappia o voglia dirti altro su Nilis.";
Topic ->
  with metatopic m_hila,
    description
      [; give hila proper;
         "@<<Conosce la cuoca che lavora per il barone?@>>^
          @<<Certo che conosco la cara Hila. Non potrei sopravvivere pi@`u di una settimana senza sentire un po' delle sue chiacchere.@>>"; ]
      [; give dippin proper;
         "@<<Sa dirmi altro su Hila?@>>^
          @<<@`E una brava cuoca, una brava madre e una brava moglie, a dispetto di quello che dice suo marito. Inoltre @`e una persona molto pia, molto devota a Maral; ha addirittura una grossa stima in padre Dippin.@>>"; ]
      "Non credi che ti dir@`a di pi@`u; a quanto pare Hila @`e una sua cara amica, una brava madre di famiglia e una persona molto religiosa.";
      
Topic ->
  with metatopic m_rabam,
    description
      [; give rabam proper;
         "@<<Conosce l'uomo che sistema i giardini del barone?@>>^
          @<<Rabam? Certo, lo conosco da anni.@>>"; ]
      "@<<Che mi sa dire su Rabam?@>>^
       @<<Niente di particolare. Ha lavorato per anni come boscaiolo, e questo spiega il suo carattere burbero. Poi non c'@`e molto da dire su di lui.@>>"
      "Non credi che sappia dirti altro d'interessante.";  
      
Topic ->
  with metatopic m_valle,
    description
      "@<<E su questa valle, su questo feudo, sa dirmi qualcosa?@>>^
       @<<Non sono uno studioso di storia, mi spiace.@>>"
      "Non hai altro da chiedere.";
      
Topic ->
  with metatopic m_villaggio,
    description
      "@<<Di questo villaggio sa dirmi qualcosa?@>>^
       @<<Har Plenais dovrebbe risalire a quattro o cinque secoli fa, anche se probabilmente col passare del tempo ogni casa @`e stata ricostruita pi@`u e pi@`u volte.@>>"
      "@<<E come mai questo villaggio si chiama Har Plenais?@>>^
       @<<Me lo sono sempre chiesto, ma non sono un esperto in lingue antiche. Molti altri villaggi sulle montagne hanno un nome che inizia con Har, o Kaar, o Aer, una parola che significa borgo, villaggio o centro abitato. Per la parola Plenais per@`o brancolo nel buio.@>>"
      "Non hai altro da chiedere.";
      
Topic ->
  with metatopic m_miniere,
    description
      "@<<Ha mai visitato le miniere?@>>^
       @<<Un paio di volte, qualche anno fa, ma sempre fermandomi vicino all'ingresso. Non mi trovo a mio agio sotto terra.@>>"
      "@<<Le miniere sono veramente esaurite?@>>^
       @<<Ogni miniera prima o poi si esaurisce. Certo, c'@`e sempre la possibilit@`a che venga scoperto qualche nuovo giacimento, ma dubito che succeda.@>>"
      "Non hai altro da chiedere a proposito delle miniere.";
      
Topic ->
  with metatopic m_fiume,
    description
      "@<<Il fiume che attraversa la valle arriva fino al mare?@>>^
       @<<S@`i, @`e lo stesso Vlis che sfocia nel mare, anche se diventa un grande fiume solo pi@`u a valle, dopo aver ricevuto un paio di affluenti. Ora @`e in piena, ma d'estate spesso non @`e pi@`u che un ruscello.@>>"
      "Non hai altro da chiedere, ma tieni a mente il suggerimento di muoversi verso sud-est per uscire dalla foresta.";
      
Topic ->
  with metatopic m_foresta,
    description
      "@<<Le capita mai di andare nella foresta?@>>^
       @<<Abbastanza spesso, soprattutto per cercare erbe, ma cerco di non allontanarmi mai dal sentiero che porta alle miniere o dal corso del fiume.@>>"
      "@<<La foresta @`e pericolosa?@>>^
       @<<Non ci sono animali feroci, se @`e questo che chiede. Comunque @`e molto fitta e molto vasta, @`e abbastanza facile perdersi. Se le dovesse succedere, le consiglio di andare sempre verso sud-est, per ritrovare qualche punto di riferimento.@>>"
      "Non credi di avere altro da chiedere sulla foresta.";
      
Topic -> t_vade_pietra
  with metatopic m_pietra,
    description
      "@<<Ha mai visto, o ha mai sentito parlare di una enorme pietra circolare?@>>^
       @<<S@`i. Una grossa pietra circolare, di roccia nera, probabilmente basalto. Si trova nel folto della foresta, ma @`e difficilissimo trovarla, anche se si conosce, o - dovrei dire - se si crede di conoscere la strada. Trovarla @`e un gioco comune dei bambini del villaggio.@>>"
      "@<<Sa dirmi qualcosa di pi@`u su quella pietra? Non @`e naturale, vero?@>>^
       @<<No, @`e stata decisamente fatta dall'uomo, ma molto tempo fa. Non so chi l'abbia fatto, n@'e che scopo avesse.@>>"
      "Pensi ti abbia detto tutto quello che sa: la pietra @`e stata fatta da qualcuno, tanto tempo fa, ed @`e nascosta nel folto della foresta.";

Topic ->
  with metatopic m_dei,
    description
        "@<<Posso chiederle a quale dei quattro @`e maggiormente fedele?@>>^
         @<<In giovent@`u mi sentivo vicino a quello che - se non sbaglio - @`e il suo culto, Irdil, ma ora mi sento pi@`u affine alla tranquillit@`a del culto di Maral.@>>"
        "La religione @`e una cosa molto personale. Preferisci non chiedere altro.";            

Object corpovade 
  with short_name [;
      print "corpo immobile ";
      if (vade has proper) print "di Vade"; 
       else print "dell'alchimista"; 
      rtrue; ],
    pname 'corpo' '.x' 'di' '.or' 'del' '.or' 'dell^' 'vade' 'alchimista' 'medico' 'cerusico' 'erborista' 'uomo', article "il",
    description [;
        if (vade has proper) print "Vade ";
         else print "L'alchimista ";
         "giace riverso sul pavimento della sua bottega, privo di sensi. Fortunatamente ti rendo conto che respira ancora, debolmente ma in modo regolare. Non ha traccia di ferite o di altro che possa spiegare il suo stato.";
    ],
    aura "Il corpo dell'alchimista emana un'aura particolare, come se fosse soggetto ad un incantesimo che lo tiene in questo stato.",
    before [;
        Take: "Non riusciresti a sollevarlo.";
    ],
    life [;
        WakeOther: "Provi a rialzare l'uomo e a fargli riprendere conoscenza, ma senza risultato.";
        Attack, Kiss: "Non ti sembra proprio il caso.";
        default: "L'uomo non reagisce in alcun modo.";
    ],
  has static animate;
  
ORoom DavantiForgia "Il villaggio (a sud della piazza)"
  with description
    "Le case del villaggio sembrano pi@`u fitte in questa zona. Da qui la strada porta verso nord, in direzione della piazza, e verso sud, fuori dal villaggio. Ad ovest una piccola costruzione in pietra ospita la forgia del fabbro del villaggio.",
    name 'villaggio' 'borgo' 'har' 'plenais' 'strada',
    each_turn [; give m_olfer ~locked; ],
    n_to PiazzaVillaggio, s_to PonteNord,
    w_to GoForgia, in_to GoForgia,
    cant_go "La strada porta a nord e a sud, e la forgia @`e a ovest.",
    initial [; LeftPicture(Village_img, -1, -1); ];

Prop -> "case"
  with name 'case' 'costruzioni' 'abitazioni' 'casa' 'abitazione' 'edifici',
    description "Le case qui intorno sono simili a quelle del resto del villaggio, e a quelle di molti altri piccoli villaggi.",
    cant_go "Sono solo le case degli abitanti del villaggio."
  has pluralname female;

Direction -> "piazza"
  with name 'piazza' 'osteria' 'locanda' 'taverna' 'tempio', dir_to n_obj, has female;
  
Direction -> "ponte"
  with name 'ponte' 'fiume' 'torrente' 'vlis', dir_to s_obj;

Direction -> "forgia"
  with name 'costruzione' 'forgia' 'porta' 'edificio', dir_to w_obj,
    description "L'insegna sopra la porta rappresenta un'incudine.",
    before [; 
        Open, Unlock, Knock: if ((~~night) && olfer in Forgia) "La porta @`e aperta."; 
                             addhint(h_forgia);
                             if (action==##Knock) "Nessuna risposta...";
                             if (action==##Unlock && second == leva or spada or stiletto or mazzuolo) "Provi a forzare la porta, senza successo.";
                             "La porta, chiusa a chiave, @`e per di pi@`u rinforzata in ferro.";
        Attack: "La porta @`e estremamente robusta.";
    ],
  has female;

[GoForgia; if (night || olfer notin Forgia) { addhint(h_forgia); "La porta @`e chiusa."; } 
           return(Forgia); ];

IRoom Forgia "La forgia"
  with description
    "Il calore @`e intenso in questo piccolo ambiente dove il fabbro del villaggio lavora. Il fuoco, caldo abbastanza da fondere il ferro, @`e acceso. Una larga incudine, una vasca d'acqua e decine di attrezzi sono le uniche cose che si possono trovare qui.",
    name 'forgia',
    e_to DavantiForgia, out_to DavantiForgia,
    cant_go "L'uscita @`e a est.",
  has light female waterhere;

Object -> "camino"
  with name 'camino' 'fuoco' 'forno',
    description "Caldo... Molto caldo...",
    before [;
      SwitchOff: "Non sapresti nemmeno come fare.";
      SwitchOn: "@`E gi@`a acceso.";
      Search: "Non credi che possa contenere nulla.";
      Touch: "@`E caldo, ovviamente.";
      Receive: <<Burn noun>>;
    ],
    !cant_go "@`E solo un camino."
  has container scenery;

Prop -> "incudine"
  with name 'incudine',
    description "L'incudine pare estremamente pesante.",
    before [;
        Take, Push, Pull, Turn, LookUnder: "L'incudine @`e troppo pesante per essere spostata.";
    ],
    !cant_go "@`E solo un'incudine."
  has female;
  
Object -> "vasca"
  with name 'vasca' 'acqua',
    description "Una vasca d'acqua fredda, per la tempra.",
    before [;
      Search: "Non vedi niente nella vasca.";
      Receive: print_ret (The) noun, " non @`e un oggetto da temprare.";
      Touch: "L'acqua @`e abbastanza fredda.";
    ],
  has container scenery female;
  
Prop -> "attrezzi"
  with name 'attrezzo' 'arnese' 'attrezzi' 'arnesi',
    description "Tutto quello che serve ad un buon fabbro.",
    before [;
      Take: "Non ne hai bisogno.";
    ],
    cant_go "Puoi anche lasciar stare gli arnesi del fabbro.",
  has pluralname;

Object -> Mazzuolo "mazzuolo"
  with name 'mazzuolo' 'mazza' 'martello' 'maglio',
    description "Un robusto e pesante mazzuolo in legno e ferro.",
    initial "Un mazzuolo giace in un angolo.",
    after [; Take: if (self hasnt general) {
               give self general;
               Achieved(4);
               "Aspetti che il fabbro si volti e ti impadronisci del mazzuolo.";
             }    
    ];

!ORoom Quadrivio "Il villaggio (quadrivio)"
!  with description
!    "Le piccole strade acciottolate che separano le piccole case del villaggio si incrociano in questo punto, formando un quadrivio. La strada a est conduce fuori dal villaggio, verso la foresta.",
!    name 'villaggio' 'quadrivio',
!    scenic
!      'case' 'costruzioni' 'abitazioni' 'casa' 'costruzione' 'abitazione' 0 "Le case qui intorno sono simili a quelle del resto del villaggio, e a quelle di molti altri piccoli villaggi.",
!    n_to Vicolo, s_to DavantiForgia, e_to VersoForesta, w_to DavantiAlchimista,
!    cant_go "Le strade portano a nord, a sud, a est e a ovest.";

ORoom PonteNord "Il ponte"
  with description
    "Un imponente e robusto ponte di pietra, verso sud, supera quasi con un balzo il largo fiume Vlis, e oltre esso la strada conduce verso il passo. Verso nord si stende il piccolo villaggio e a est una piccola scala scende verso gli argini.",
    name 'strada',
    before [;
      Listen: "Senti il fiume Vlis scorrere impetuosamente sotto di te.";
    ],
    n_to DavantiForgia, s_to PonteSud, 
    e_to Sponda1, d_to Sponda1,! nel file lunafor.inf
    cant_go "Puoi solo seguire la strada, andando a nord o a sud, o scendere una piccola scala che porta ad est.";
    
Direction -> "ponte"
  with name 'ponte', dir_to s_obj,
    description "Il ponte @`e robusto e massiccio, e sembra essere qui da tempo immemorabile, unico mezzo per superare la furia del Vlis nei periodi di piena. Le sue alte balaustre circondano la larga strada che conduce verso il villaggio e verso il palazzo.";
    
Direction -> "villaggio"
  with name 'villaggio' 'borgo' 'har' 'plenais' 'case' 'abitazione' 'edifici' 'costruzioni' 'casa' 'abitazione' 'edificio' 'costruzione', dir_to n_obj;    
    
Prop -> "fiume"
  with name 'fiume' 'torrente' 'vlis',
    description "Il Vlis @`e in piena, in questo periodo.",
    cant_go "Sei troppo lontano. Dovresti arrivare agli argini.";

ORoom PonteSud "Oltre il ponte"
  with description
    "Il largo e robusto ponte di pietra scavalca il fiume Vlis dando accesso, verso nord, alla valle di Nigat e al suo unico villaggio. Andando verso sud la strada si inerpica ripida fra le colline, verso il passo che conduce fuori dalla valle.",
    name 'strada',
    before [;
      Listen: "Senti il fiume Vlis scorrere impetuosamente sotto di te.";
    ],
    n_to PonteNord,
    s_to "Non trovi motivi per lasciare la valle, e ancora meno per lasciarla a piedi.",
    cant_go "Puoi solo seguire la strada, andando a nord o a sud.";

Direction -> "ponte"
  with name 'ponte', dir_to n_obj,
    description "Il ponte @`e robusto e massiccio, e sembra essere qui da tempo immemorabile, unico mezzo per superare la furia del Vlis nei periodi di piena. Le sue alte balaustre circondano la larga strada che conduce verso il villaggio e verso il palazzo.";
    
Direction -> "villaggio"
  with name 'villaggio' 'borgo' 'har' 'plenais' 'case' 'abitazione' 'edifici' 'costruzioni' 'casa' 'abitazione' 'edificio' 'costruzione', dir_to n_obj;    
    
Prop -> "fiume"
  with name 'fiume' 'torrente' 'vlis',
    description "Il Vlis @`e in piena, in questo periodo.",
    cant_go "Sei troppo lontano. Dovresti arrivare agli argini.";

ORoom VersoForesta "Verso la foresta"
  with description
    "Le ultime case del villaggio, ad ovest, hanno lasciato solo un piccolo sentiero battuto che si inotra tra gli alberi verso est, e l'immensa foresta che occupa quasi interamente la valle si stende verso est per chilometri.",
    name 'sentiero' 'viottolo',
    w_to DavantiAlchimista, 
    e_to SentieroForesta1, ne_to ForestaL1, se_to Sponda1, ! nel file lunafor.inf
    cant_go "Il villaggio si trova verso ovest, mentre il sentiero conduce verso est. Puoi anche inoltrarti nella foresta andando verso nordest o sudest.";

Direction -> "villaggio"
  with name 'villaggio' 'borgo' 'har' 'plenais' 'case' 'abitazione' 'edifici' 'costruzioni' 'casa' 'abitazione' 'edificio' 'costruzione', dir_to w_obj,  
    description "Guardando verso ovest puoi vedere, a pochi metri, le prime case in legno e pietra del piccolo villaggio.";
    
Direction -> "foresta"
  with name 'foresta' 'alberi' 'bosco' 'boschi', dir_to e_obj,
    description "La foresta che si stende ad est @`e immensa, tanto da mettere soggezione.",
  has female;