! La Pietra della Luna
! Avventura Testuale realizzata da Paolo Lucchesi
! da un'idea di Paolo Lucchesi, Andrea Gnesi e Stefano Masi
! Questo prodotto e' libero, rilasciato sotto licenza GPL (Gnu Public License), 
! riportata nel file allegato gpl.txt. 
! Questo prodotto e' distribuito senza alcuna garanzia. L'autore non pu@`o essere 
! ritenuto responsabile per qualsiasi danno dovuto direttamente o indirettamente 
! all'uso del prodotto.
! ------------------------------------------
!           Libri
! ------------------------------------------

Book diariotriven "" scrivaniatriven
  with pname '.x' 'piccolo' 'libro' '.or' 'diario' '.x' 'trovato' '.x' 'nella' '.x' 'in' '.x' 'capanna' '.p' 'libro' '.or' 'diario' '.x' 'dello' '.x' 'del' '.x' 'di' 'stregone' '.or' 'mago' '.or' 'studioso' '.or' 'triven',
    short_name [;
        if (self hasnt moved) print "piccolo libro";
        else print "libro trovato nella capanna";
        rtrue;
    ],
    article [;
        if (self hasnt moved) print "un";
        else print "il";
        rtrue;
    ],
    initial "Sulla scrivania c'@`e un piccolo libro.",
    description "Un piccolo libro rilegato in cuoio. Parrebbe un diario, o qualcosa di simile.",
  before [; read, consult:
    addhint(h_diario);
    self.short_name="diario dello stregone";
    self.article="il";
    Achieved(9);
    give m_triven ~locked;
    print "^@<<Sento la necessit@`a di appuntare le mie riflessioni su quella strana razza che abita le foreste di questa valle e che presenta caratteristiche uniche. Ho iniziato ad osservarli da qualche giorno, avvicinandomi sempre di pi@`u a loro, che continuavano ad ignorare la mia presenza. Questa @`e un'occasione di studio unica per me, giovane studioso delle arti arcane e della natura umana.^
    @<<Essi hanno l'aspetto di uomini, diversi solo per la maggior lunghezza delle braccia, tale da farli sembrare simili a delle buffe scimmie glabre, e per l'inquietante espressione dei loro volti, sempre vacua e assente.^
    @<<A quanto ho visto vivono cacciando nella foresta, e non fanno alcun uso di attrezzi, fatta eccezione per dei rozzi coltelli di pietra e dei bastoni. Non credo costruiscano abitazioni di alcun genere e sembrano incapaci di parlare.@>>^^";
    if (self hasnt general) waitkey();
    print "@<<Ieri, seguendo uno di loro, ho trovato quello che potrebbe essere chiamato il loro villaggio. Infatti essi vivono in una serie di caverne sul limitare delle montagne. Attorno al loro villaggio ho trovato anche un gran numero di sculture in pietra ed in legno, opere di una inquietante bellezza, tanto che pare incredibile siano state realizzate da esseri tanto primitivi. Molti di loro si dedicano a questa attivit@`a, forse come una forma di venerazione verso i loro dei, i loro idoli, o qualunque cosa essi adorino. Effettivamente, ripensandoci, sarebbe l'unica forma di religione che ho visto praticare loro.^
    @<<Ho osservato attentamente diverse tra queste sculture, rimanendone meravigliato. Esse rappresentano assurde scene di caccia in bassorilievo, o distorte figure umane, oppure esseri deformi che paiono provenire da un incubo. Ma nella loro assurdit@`a, poich@'e non trovo altro termine per definerle, riescono ad infondere in chi le guarda la sensazione di osservare qualcosa che gli occhi non possono vedere.@>>^^";
    if (self hasnt general) waitkey();
    print "@<<L'altra notte ho scoperto qualcosa di pi@`u sulla `religiosit@`a', se cos@`i pu@`o essere detta, di queste creature. Trovandomi al tramonto vicino al loro villaggio ho notato che tutti, senza eccezione, si stavano incamminando. Furtivamente li ho seguiti attraverso la foresta, giungendo poi ad una radura dove sorgeva una enorme pietra circolare, poteva sembrare l'altare di qualche dio dimenticato. In quel luogo li ho osservati mentre rimanevano prostrati, in una sorta di blasfema adorazione, mentre dalle loro gole che credevo incapaci di emettere suoni che abbiano un senso si levava una litania costituita da un'unica sillaba : `Ia Ia Ia Ia Ia...'^
    @<<Non so se fu solo suggestione, o forse qualche potere insito in quella litania. So solo che la sensazione di un immane orrore senza volto si impadron@`i della mia anima. Solo quando vidi diversi esseri volgere lo sguardo nella mia direzione ritrovai le mie forze e, colto dal terrore, mi diedi ad una fuga precipitosa.@>>^^";
    print "(A questo punto il diario contiene uno schizzo di una mappa della valle, su cui @`e marcato con un cerchio un punto che ti pare si trovi circa al centro della foresta.)^^";
    if (self hasnt general) waitkey();
    print "@<<Ho avuto un'occasione irripetibile. Mentre vagavo per la foresta, cercando di ritrovare la strada per l'altare circolare, ho trovato il cadavere di uno di loro. Un veloce esame mi rivel@`o che era morto a causa del morso di un serpente. Dopo averlo nascosto alla vista, sono corso al villaggio, dove ho preso in prestito un piccolo carro con cui trasportare il cadavere alla mia casa. Sono sicuro che comprender@`o molto esaminandolo.@>>^^";
    if (self hasnt general) waitkey();
    print "@<<E' incredibile. Ho terminato la dissezione del cadavere, ed ho scoperto qualcosa di veramente stupefacente. Questi esseri sono umani in tutto e per tutto, tutti i loro organi interni corrispondono a quelli degli uomini. Solo una cosa differisce : il loro cervello @`e privo della parte sinistra. Dovrebbe essere impossibile vivere in quelle condizioni, ma loro lo fanno. Forse @`e proprio quella la causa di tutti i loro bizzarri comportamenti. Presto partir@`o per la capitale, sono veramente ansioso di mostrare quello che ho scoperto ai colleghi dell'accademia. Inoltre questo posto mi sta iniziando a fare paura. Poc'anzi, mentre riposavo, ho sognato un paio di occhi di una malvagit@`a infinita che mi osservavano, e non @`e stato un sogno piacevole.@>>^^";
    if (self hasnt general) waitkey();
    print "@<<Non so come abbiano fatto, ma devono aver scoperto che ho trafugato il cadavere di uno di loro, e forse considerano ci@`o un sacrilegio. Fatto sta che sono giunti in massa alla mia abitazione, e mi stanno tenendo in assedio. Penso che tenteranno un attacco entro poco, questa piccola capanna non pu@`o resistere alla loro furia. Se dovessi morire, che Irdil conduca la mia anima presso di s@'e.@>>^^";
    if (self hasnt general) waitkey();
    give self general;
    remark(2);
    rtrue;
  ],
  each_turn [;
      if (self has moved && self notin dmensole) give self ~concealed;
  ],
  list_together BOOKS_GROUP,
  has legible concealed;

Book dlibro "libro trovato nel tempio sotterraneo" dleggio
  with pname 'libro' '.or' 'diario' '.x' 'trovato' '.x' 'nel' '.x' 'in' '.x' 'tempio' '.x' 'sotterraneo' '.x' 'druidico' '.p' 'libro' '.or' 'diario' '.x' 'del' '.x' 'di' '.x' 'druido' '.x' 'carnissar' '.x' 'bastondiquercia',
  article "il",
    description "Un libro largo ma non troppo spesso, rilegato, parrebbe, con corteccia d'albero.",
    aura "Il libro emana una lieve aura di protezione dal male.",
    describe [; if (self in dleggio) { print "Un libro rimane appoggiato su di un leggio."; rtrue; } ],
  before [; read, consult:
    Achieved(18);
    print "^@<<Io, Carnissar Bastondiquercia, druido della foresta di Heegat, dietro ordine del mio superiore Saregin dalla mente acuta, lascio scritto in queste poche pagine il resoconto degli ultimi giorni, in cui abbiamo sconfitto, grazie alla forza provenente dalla terra nostra madre, l'abominio che minacciava il nostro mondo. E' scritto nel destino della madre terra che queste pagine saranno ritrovate se occorrer@`a.^
      @<<Da diversi mesi i segni erano nefasti. Le piante morivano, i raccolti erano scarsi, la moria aveva colpito i pesci del fiume che fende la foresta e molti animali, e perfino qualche essere umano, moriva di un male sconosciuto. E molti degli abitanti della valle si stavano allontanando tanto dai nostri insegnamenti  quanto da quelli del sacerdote di Maer Ral che abitava con loro. Qualcosa di sinistro iniziava a strisciare nelle tenebre della notte, di questo ci rendevamo conto. Qualcosa stava accadendo, qualcosa di orribile. Poi, alfine, capimmo.@>>^^";
      if (self hasnt general) waitkey();
      print "@<<Alcuni abitanti della valle, gli stessi che avevano abbandonato i nostri insegnamenti, avevano iniziato ad adorare una sinistra dea dalla malvagit@`a tanto enorme che scelgo di non riportare il suo nome, sperando venga dimenticato per sempre. Essi adoravano la loro nuova dea in caverne poste nel pi@`u alto monte tra quelli che sovrastano la valle, oppure presso un'enorme pietra di basalto nero.^
      @<<Ben presto scoprimmo che gli adoratori della dea crescevano in numero man mano che i giorni passavano. Era come se ella lentamente li attirasse a se. Ella parlava ai suoi fedeli tramite i sogni, e riceveva forza dalle loro deliranti invocazioni, e rubava loro l'intelletto, rendendoli simili a folli, ed altres@`i riceveva potenza dai sacrifici che i suoi fedeli le offrivano. Essi volevano che ella venisse in questo mondo, e stavano preparando un rito per spianarle la strada.@>>^^";
      if (self hasnt general) waitkey();
      print "@<<Per puro colpo di fortuna uno dei seguaci della dea si ravvedette, e corse da noi a riferirci molte cose, prima di morire miseramente. Venimmo a sapere che il rito sarebbe stato in una notte di luna piena, in una vasta caverna all'interno del monte. E scoprimmo anche che il rito era descritto sulla pietra nella foresta che essi adoravano, e che tali incisioni apparivano - solo per pochi attimi - quando la pietra veniva colpita dai primi raggi di luna nella notte del plenilunio; ed assieme al rito era descritto il modo per impedire che il rito avesse successo.@>>^^";
      if (self hasnt general) waitkey();
      print "@<<Era ormai quasi troppo tardi, i suoi cuccioli stavano gia passando in queste terre, e troppo presto lei stessa sarebbe arrivata. Ma grazie a quelle informazioni, pur perdendo molti dei nostri, arrivammo appena in tempo per impedire che Ella arrivasse tra noi, portando la distruzione in questo mondo. Ma Ella era vicina, troppo vicina perch@'e la sua ira non colpisse. La montagna esplose pochi minuti dopo, ed i fedeli della dea si dispersero come dementi, ed ancora non siamo riusciti a curare le loro menti, forse distrutte per sempre.@>>^^";
      if (self hasnt general) waitkey();
      print "@<<Queste poche parole sono state lasciate perch@'e vengano ritrovate da colui o coloro che ancora si troveranno di fronte allo stesso immane pericolo. Similmente @`e stato lasciato anche un dono prezioso, realizzato in lunghi anni. Se lo avessimo posseduto la giovane Alamdia sarebbe ancora tra noi.^
      @<<Questo @`e in breve quello che accadde. Questo @`e quello che io, Carnissar Bastondiquercia, ho scritto. Che la madre terra continui in eterno a donare vita.@>>^^"; 
      if (self hasnt general) waitkey();
    remark(4);
    give self general;
    rtrue;
  ],
  after [;
      Take: if (easy && self hasnt moved) "Con attenzione prendi il libro dal leggio. A questo punto non credi ci sia molto altro da trovare, in questo luogo.";
            if (self hasnt moved) "Con attenzione prendi il libro dal leggio.";
  ],
  list_together BOOKS_GROUP,
  has legible;

Book storia "@<<Storia della valle di Nigat@>>"
  with pname 'libro' '.x' 'di' '.x' 'storia' '.p' 'storia' '.x' 'della' '.x' 'valle' '.x' 'di' '.x' 'nigat',
    description "Un volume di medie dimensioni, dalla copertina in cuoio bordato in argento e le pagine finemente manostritte e talvolta miniate. Probabilmente un'edizione unica, in ogni caso un libro di discreto valore.",
  before [wd i;
    read: MakeMenu(); storiamenu.select(); UnMakeMenu(); rtrue;
    !"Dai una scorsa al libro; scritto da un certo Criban Vasteil non @`e un libro molto antico, avr@`a non pi@`u di mezzo secolo. Vi puoi trovare notizie sulle miniere, sul vulcano, sull'eruzione, sul villaggio, sulla casata Inderus, e anche su antiche religioni.";
    consult:
      wn=consult_from;
      for (i=0: i<consult_words: i++) {
        wd=NextWord();
        switch(wd) {
          'miniere', 'diamanti': storia_miniere.description(); rtrue;
          'vulcano', 'eruzione': storia_vulcano.description(); rtrue;
          'villaggio', 'har', 'plenais': storia_villaggio.description(); rtrue;
          'inderus','casata','barone': storia_inderus.description(); rtrue;
          'culti', 'religioni', 'religione', 'riti': storia_culti.description(); rtrue;
        }
      }
      "Non trovi niente sull'argomento.";
    ],
    list_together BOOKS_GROUP,
  has legible proper female;
  
Menu storiamenu "Storia della valle di Nigat";

Option -> storia_intro "Introduzione"
  with description "Questo libro, scritto da un certo Criban Vasteil, non @`e molto antico, avr@`a non pi@`u di mezzo secolo. Vi puoi trovare notizie sulle miniere, sul vulcano, sull'eruzione, sul villaggio, sulla casata Inderus, e anche su antiche religioni.";
  
Option -> storia_miniere "Le miniere di diamanti"
    with description "@<<Fin dai tempi pi@`u antichi la ricchezza della valle di Nigat erano principalmente dovute al fiume, facile via di transito tra queste montagne, al legname non pregiato ma molto abbondante, e soprattutto alle miniere nella catena settentrionale. In esse si raccoglieva ferro, argento e - soprattutto - diamanti di una purezza tale da lasciare senza fiato. Questi ultimi vengono sovente descritti nelle mie fonti come il bene pi@`u prezioso e pi@`u nascosto dell'alto monte Kalnam.@>>^
    In un brano riportato pi@`u avanti leggi per@`o che @<<i diamanti sembrano una ricchezza quasi inesauribile e facile da raccogliere, il vulcano Kalnam ne @`e ben generoso.@>>";
    
Option -> storia_vulcano "Il vulcano Kalnam, e la sua eruzione"
    with description "@<<Avvenne in quei giorni di un freddo dicembre che il monte Kalnam esplodesse in tutta la sua furia, scagliando fuoco verso il cielo e colando la sua lava fino al limitare della foresta, tanto che tutti gli abitanti della valle temettero per la loro vita. Il cielo rimase scuro per tre giorni. Da allora il vulcano non erutt@`o pi@`u, e oggi @`e ritenuto spento.@>>";
    
Option -> storia_villaggio "Il villaggio di Har Plenais"
    with description "@<<Sebbene da sempre la valle di Nigat sia stata abitata, le prime pietre del villaggio che sorge nella parte orientale dovrebbero essere state posate circa un secolo prima dell'eruzione. In origine pare che il villaggio non avesse un nome preciso. Solo pi@`u tardi gli fu dato da un sacerdote il nome di Har Plenais, che dovrebbe significare `borgo della luna'.@>>";
   
Option -> storia_culti "Culti e Religioni"
    with description "@<<Nei testi da me faticosamente raccolti molto si parla di religione. Pare che in passato molto fosse venerata in questa valle una dea chiamata Mae Ras, che non esito ad identificare con la santa Maral, signora delle messi. E si parla anche di una casta sacerdotale che era ben influente in questa zona nei tempi in cui il glorioso impero stava iniziando l'ascesa verso la sua attuale potenza. Tale casta non si riferiva a Maral con il suo nome, ma usava formule come 'madre terra' e 'donatrice di vita', e avevano rituali elaborati, complessi e, si dice, di immane bellezza che si svolgevano principalmente tra gli alberi della foresta.@>>^
    Trovi anche un'altro brano: @<<Nei tempi che precedettero la catastrofe, si narra che oscure presenze vennero adorate in questa valle. Una delle mie fonti, non troppo attendibile in realt@`a, narra di giovani ragazze uccise, di apparizioni di emissari di antichi dei, di riti innominabili, e di uomini retti che si opposero a tutto ci@`o, ma pare che riportando ci@`o l'autore abbia dato sfogo alla sua peggior vena romanzesca.@>>";  
    
Option -> storia_inderus "La casata Inderus"
    with description "@<<La guerra fu lunga e crudele, e solo dopo molti anni il regno di Barkar dichiar@`o la sua resa accettando le condizioni imposte dall'impero Taraisiano. E la valle di Nigat, cos@`i come altre zone che si trovavano sul confine, fu strappata dalle crudeli mani Barkariane e annessa al glorioso impero. Venne assegnata come feudo ad una nobile casata, che ben si era distinta durante la guerra...@>>";    

Book leggende "@<<Miti e Leggende@>>"
  with pname 'libro' '.x' 'di' '.x' 'miti' '.x' 'e//' '.x' 'leggende' '.x' 'favole',
    description "Un volume in ottavo, rilegato con una copertina in pelle conciata. Il titolo completo @`e ~Miti e Leggende delle montagne karniane e delle terre del nord~. Sembra vecchio, ma non antico, non particolarmente raro n@'e particolarmente in buono stato.",
  before [wd i;
    read: print "Sembrava pi@`u interessante. Invece per la maggior parte questo libro raccoglie leggende sentite e risentite. Solo tre ti sono sconosciute: la prima narra di un faro, un'altra racconta la storia di un cacciatore, e l'ultima, che pare particolarmente interessante, parla di un vulcano.^";
    waitkey();
    MakeMenu(); leggendemenu.select(); UnMakeMenu(); rtrue;
    consult:
      wn=consult_from;
      for (i=0: i<consult_words: i++) {
        wd=NextWord();
        switch(wd) {
          'faro': leggende_faro.description(); rtrue;
          'cacciatore': leggende_cacciatore.description(); rtrue;
          'vulcano': leggende_vulcano.description(); rtrue;
        }
      }
      "Non @`e in questo libro.";
    ],
    list_together BOOKS_GROUP,
  has legible proper;
  
Menu leggendemenu "Miti e Leggende";

Option -> leggende_faro "Il faro nelle nebbie"
    with description "Secondo la leggenda, sulla costa, vicino alla foce del Vlis, sorge un piccolo villaggio di pescatori, costruito attorno ad un alto faro privo d'entrate ma che illumina sempre la rotta ai naviganti. Il libro narra di un nobile paladino che sconfisse e releg@`o negli abissi un mostro che usciva dal mare ammantato di tenebra, perdendo per@`o la vita. Il faro, la cui luce poteva scongiurare le tenebre gettate dalla creatura, fu posto in quel luogo come guardiano, per impedire che il mostro tornasse a portare morte e distruzione.";
    
Option -> leggende_cacciatore "Il cacciatore"
    with description "Sembrava pi@`u interessante, invece ti accorgi che questa storia @`e molto simile a quella del cacciatore Gianak, colui che impugnava la spada donatagli da Aran e l'arco donatogli da Maral. L'unico episodio - fra l'altro confuso - che non conoscevi @`e quello in cui il cacciatore affronta una creatura conosciuta come la 'madre nera', e la sua progenie, ma viene sconfitto e costretto alla fuga. La descrizione della 'madre' @`e molto vaga, ma comunque sinistra e inquietante.";
    
Option -> leggende_vulcano "La figlia del vulcano"
    with description "Speravi che questa leggenda parlasse del monte Kalnam, ma invece non @`e cos@`i. La storia @`e molto triste e narra di una giovane donna rapita per essere scagliata in un vulcano e placare cos@`i il demone che vi giaceva. Il suo promesso sposo insegue i rapitori e riesce a salvare la sua compagna, ma alla fine il demone si manifesta e la giovane sceglie di gettarsi di sua volont@`a nella lava per evitare che altri muoiano. Quasi sei commosso da questo terribile finale.";

Book eibon "libro dalla copertina nera"
  with pname 'libro' '.x' 'nero' '.p' 'libro' '.x' 'dalla' '.x' 'copertina' 'nera' '.p' 'libro' 'di' 'eibon',
    description [;
      print "Un piccolo libro, un volume in sedicesimo, rilegato con una copertina in cuoio nero e privo di titolo.";
      if (player has msight) " Il libro brilla tenuamente di un color violaceo.";
      "";
    ],
    aura [; print "Il libro dalla copertina nera emana un'aura di malvagit@`a.^"; return 2; ],
    before [;
      Consult, Read: 
        give self general;
        if (player has msight) {
          solved(h_libronero);
          Achieved(3);
          "Le parole e i segni che ad un primo sguardo potevano parere privi di senso prendono una nuova forma, e nuovo significato. Quello che sembrava un libro privo di senso ma innocuo si rivela essere un grimorio di magia nera. Le oscure formule in esso contenute sono volte a comunicare, a compiecere e a evocare dei o demoni di primeva malvagit@`a. Non osi andare avanti con la lettura, la tua mente e il tuo spirito potrebbero venirne spezzati.";
        }
        addhint(h_libronero);
        "Il libro sembra contenere soltanto una collezione di rime prive di alcun senso e disegni stilizzati che paiono non rappresentare nulla. Non sembra avere alcun significato, e pare piuttosto l'opera di un folle.";
    ],
    list_together BOOKS_GROUP,
  has legible;

Book devermismisteriis "libro dalla copertina rossa" comodinonaradas
  with pname 'libro' '.x' 'rosso' '.p' 'libro' '.x' 'dalla' '.x' 'copertina' 'rossa' '.p' 'de' 'vermis' 'misteriis',
    description [;
      print "Un volume in sedicesimo, rilegato con una copertina in cuoio tinta di un color rosso.";
      if (player has msight) " Il libro brilla tenuamente di un color violaceo.";
      "";
    ],
    aura [; print "Il libro dalla copertina rossa emana un'aura di malvagit@`a."; return 2; ],
    ! initial "Sul comodino @`e stato posato un libro dalla copertina rossa.",
    before [;
      Consult, Read: 
        if (player has msight) {
          Achieved(30);
          print "Sulle pagine del libro brillano in violetto parole di un significato oscuro e terribile. Formule di magia nera, descrizioni di orribili, blasfemi rituali, invocazioni ad esseri abominevoli. In particolare il libro si @`e aperto alla pagine che contiene una preghiera ad una dea che viene definita 'oscura madre' e 'nero capro dai mille cuccioli'. Leggere queste parole fiacca il tuo spirito, preferisci interrompere la lettura.^";
          remark(7);
        }
        else print "Il libro contiene stranamente soltanto pagine bianche.^";
        if (self hasnt general) {
            Achieved(29);
            move mappaminiere to parent(self);
            give self general;
            solved(h_naradas);
            "Tra le pagine del libro trovi un foglio ripiegato in quattro, che pare essere una mappa di qualche tipo.";
        }
        rtrue;
    ],
    list_together BOOKS_GROUP,
  has legible;
  
Object mappaminiere "mappa"
  with pname 'mappa' '.or' 'cartina' '.x' 'delle' 'miniere',
    path 0,
    description [;
      print "@`E molto confusa, ma pare essere una mappa delle miniere, su cui @`e stato segnato un percorso.^";
      if (real_location==FondoBaratro) self.path=0;
      if (real_location==FondoBaratro or Miniere) {
          ! Per seguire la mappa, passo dopo passo
          switch(self.path) {
              0: Miniere.dir=nw_obj;
              "Riconosci le gallerie tracciate sulla mappa. Il percorso da qui conduce verso nordovest.";
              1: Miniere.dir=w_obj;
              "Secondo la mappa, se non sbagli ad interpretarla, per seguire il percorso segnato devi andare verso ovest.";
              2: Miniere.dir=n_obj;
              "Ti pare di riconoscere le gallerie che ti circondano, confrontandole con la mappa. Se @`e cos@`i, il percorso segnato porta verso nord.";
              3: Miniere.dir=sw_obj;
              "La mappa non @`e molto chiara, ma se non erri adesso puoi seguire il percorso verso sudovest.";
              default: Miniere.dir=0;
              if (Miniere.posy==0 && Miniere.posx>0) {
                  "Non sei sul percorso segnato, ma seguendo la mappa, se non t'inganni, devi andare verso ovest, verso il centro del sistema di gallerie.";
              }
              "Per quanto tu guardi la mappa, non riesci a capire dove sei. Sai solo che evidentemente ti sei allontanato dal percorso segnato.";
          }
      }
       
    ],
  has female;