! La Pietra della Luna
! Avventura Testuale realizzata da Paolo Lucchesi
! da un'idea di Paolo Lucchesi, Andrea Gnesi e Stefano Masi
! Questo prodotto e' libero, rilasciato sotto licenza GPL (Gnu Public License), 
! riportata nel file allegato gpl.txt. 
! Questo prodotto e' distribuito senza alcuna garanzia. L'autore non pu@`o essere 
! ritenuto responsabile per qualsiasi danno dovuto direttamente o indirettamente 
! all'uso del prodotto.
! ------------------------------------------
!           La foresta
! ------------------------------------------

[forestcantgo exc;
    ! Per gestire le uscite bloccate nella foresta
    if ((action~=##Exits)) {
        if (noun==n_obj or s_obj or e_obj or w_obj or ne_obj or nw_obj or se_obj or sw_obj) 
            print "Gli alberi troppo fitti non permettono di andare in quella direzione.^";
        else
            print "Non puoi andare da quella parte.^";
    }
    exitlist(exc); rtrue;
];

Prop sottobosco "vegetazione"
  with name 'vegetazione' 'piante' 'erba' 'cespugli' 'cespuglio' 'pianta' 'sottobosco' 'fogliame',
    description [; if (location provides vegdesc) if (location.vegdesc(1)) rtrue;
                   "Vegetazione rigogliosa."; ],
    before [;
      Search, LookUnder, Touch: "Il sottobosco non nasconde niente.";
    ],
    cant_go "@`E solo la vegetazione del bosco.",
    found_in SentieroForesta1 SentieroForesta2 SentieroForesta3 ForestaL1 ForestaL2 ForestaR1 ForestaR2 ForestaR3 ForestaR4 ForestaR5 ForestaR6 ForestaR7 RaduraPietra Radura DavantiCapanna,
  has female;
  
Prop "alberi"
  with name 'albero' 'alberi' 'ramo' 'rami' 'foglie' 'foglia',
    description [; if (location provides vegdesc) if (location.vegdesc(0)) rtrue;
                   "Gli alberi, principalmente abeti e larici, svettano alti e fitti."; ],
    before [;
      Search, Touch: "Gli alberi non sembrano nascondere niente.";
    ],    
    found_in SentieroForesta1 SentieroForesta2 SentieroForesta3 ForestaL1 ForestaL2 ForestaR1 ForestaR2 ForestaR3 ForestaR4 ForestaR5 ForestaR6 ForestaR7 DavantiCapanna,
  has pluralname;

ORoom SentieroForesta1 "Sentiero attraverso la foresta"
  with description
    "Uno stretto sentiero si apre tra gli alberi sempreverdi della foresta, che si infittiscono sempre di pi@`u verso est. Il sentiero conduce verso nord-est, oppure verso ovest, ritornando al villaggio, ma @`e possibile anche addentrarsi tra gli alberi in altre direzioni.",
    name 'foresta' 'sentiero',
    before [; Listen: "Verso sud ti pare di sentire scorrere il fiume."; ],
    w_to VersoForesta, ! nel file lunavil.inf
    ne_to SentieroForesta2, n_to ForestaL1, nw_to ForestaL1,
    s_to Sponda1, se_to Sponda2, e_to ForestaR1, 
    cant_go forestcantgo,
    initial [; LeftPicture(Path_img, -1, -1); ],
  has woods;
  
ERoom SentieroForesta2 "Sentiero attraverso la foresta"
  with description
    "La foresta, gi@`a folta, lascia solo uno spazio angusto per il sentiero che porta da sud-ovest a nord. Dall'alto la luce penetra con fatica fra i rami. Inoltrarsi nella vegetazione potrebbe essere pericoloso.",
    name 'foresta' 'sentiero',
    vegdesc [flag;
      if (flag) "La vegetazione ai lati del sentiero @`e folta e rigogliosa.";
      rfalse;
    ],
    sw_to SentieroForesta1, n_to SentieroForesta3, w_to ForestaL1, nw_to ForestaL2,
    se_to ForestaR1, e_to ForestaR2, ne_to ForestaR3,
    cant_go forestcantgo,
    initial [; LeftPicture(Path_img, -1, -1); ],
  has woods;

ORoom SentieroForesta3 "Sentiero attraverso la foresta"
  with description
    "Tra gli abeti e i larici che si stanno facendo a poco a poco meno fitti, il sentiero tortuosamente conduce da sud a nord, dalla foresta pi@`u folta verso la catena montuosa ed il monte Kalnam, il vulcano spento che a tratti pu@`o essere scorto tra le cime degli alberi.",
    name 'foresta' 'sentiero',
    vegdesc [flag;
      if (flag) "Anche i cespugli si fanno pi@`u radi andando verso nord.";
      "Gli alberi, sempre alti, si fanno pi@`u radi in questa zona.";
    ],
    s_to SentieroForesta2, n_to SentieroMiniere, w_to ForestaL2, ! nw_to ForestaL2,
    e_to ForestaR3, se_to ForestaR3, 
    nw_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    ne_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    cant_go forestcantgo,
    initial [; LeftPicture(Path_img, -1, -1); ],
  has woods;

ORoom SentieroMiniere "Sentiero per le miniere"
  with description
    "Il sentiero si inerpica, andando verso nord, sulle pendici del monte Kalnam, conducendo all'ingresso delle vecchie miniere di diamanti. A sud si stende vastissima la foresta.",
    name 'sentiero',
    s_to SentieroForesta3, sw_to ForestaL2, se_to ForestaR3,
    n_to DavantiMiniere, ! nel file lunamin.inf
    before [ ; 
        Go: if (noun == e_obj or w_obj or ne_obj or nw_obj)
          "La montagna @`e irta, scoscesa, il terreno @`e friabile, meglio rimanere sul sentiero.";
          if (noun == d_obj) <<Go s_obj>>;
          if (noun == u_obj) <<Go n_obj>>;
    ];

Direction -> "foresta"
  with name 'foresta' 'alberi' 'albero', dir_to s_obj,
    description "Il sentiero, andando verso sud, si addentra nella foresta.",
    cant_go "I primi alberi della foresta sono qualche decina di passi lontani da te, verso sud."
  has female;

ORoom ForestaL1 "Foresta"
  with description
    "Anche se non c'@`e traccia di sentiero, in questa zona la foresta non @`e particolarmente folta. Probabilmente il villaggio non @`e molto lontano da qui, verso sud-ovest.",
    name 'foresta' 'alberi',
    vegdesc [flag;
      if (flag) rfalse;
      "Gli alberi si fanno meno fitti andando verso ovest.";
    ],
    e_to SentieroForesta2, n_to ForestaL2, 
    w_to PianuraNord, nw_to PianuraNord, sw_to VersoForesta, ! nel file lunavil.inf
    se_to SentieroForesta1, s_to SentieroForesta1,
    cant_go forestcantgo,
    initial [; AbovePicture(Fir_img, -1, -1); ],
  has woods;

ORoom ForestaL2 "Foresta"
  with description
    "La foresta declina rapidamente avvicinandosi alle pendici delle montagne che limitano la valle verso nord. Il villaggio dovrebbe essere verso sud-ovest, mentre verso nord-est vedi in lontananza troneggiare il monte Kalnam.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "Anche il sottobosco si fa pi@`u rado qui.";
      "Gli abeti e i larici sono qui meno fitti.";
    ],
    s_to ForestaL1, se_to SentieroForesta2,
    sw_to PianuraNord, ! nel file lunavil.inf
    e_to SentieroForesta3, ne_to SentieroMiniere,
    n_to "Da quella parte le pendici della montagna sono troppo ripide da scalare.",
    nw_to "Da quella parte le pendici della montagna sono troppo ripide da scalare.",
    w_to [; print "Percorri uno stretto sentiero che, seguendo le pendici delle montagne, descrive un'ampia curva da ovest a sud.^"; return PianuraNord; ],
    cant_go forestcantgo,
    initial [; AbovePicture(Fir_img, -1, -1); ],
  has woods;

Object -> statua "roccia scolpita"
  with name 'statua' 'pietra' 'scolpita',
    description "Sembra una statua di pietra, rozzamente scolpita, che rappresenta una creatura sconosciuta, in parte animale, in parte pianta. Osservandola, provi una sottile angoscia.",
    before [;
      Search: <<Examine self>>;
      LookUnder, Push, Pull, Turn: "@`E troppo pesante, non pu@`o essere spostata.";
      Touch: "@`E stranamente fredda al tatto.";
    ],
  has static female;

[noswim; 
    "Il Vlis @`e in piena, e, stando a quanto ricordi, c'@`e una cascata a valle. Non te la senti di attraversarlo a nuoto."; 
];

Object "fiume Vlis"
  with name 'fiume' 'torrente' 'vlis',
    description "Il Vlis @`e in piena, in questo periodo.",
    before [;
      Search, LookUnder: "Non pare che le acque del fiume nascondano niente.";
      Drink, Touch: "L'acqua @`e fredda ma limpida.";
      Enter, Swim: noswim(); rtrue;
    ],
    found_in Sponda1 Sponda2 Sponda3 OltreFiume,
  has scenery enterable;
  
Distance "foresta"
  with name 'foresta' 'albero' 'alberi',
    description "Gli alberi della foresta arrivano quasi fino al fiume.",
    cant_go "Pochi passi ti separano dalla foresta.",
    found_in Sponda1 Sponda2 Sponda3 OltreFiume,
  has female;

ORoom Sponda1 "Sponda del fiume"
  with description
    "Il fiume Vlis scorre ruggendo da est a ovest, gettandosi sotto il robusto ponte di pietra che @`e l'unica via di accesso alla valle. A nord si stende la foresta, che arriva quasi fino all'argine, mentre il villaggio si trova a nord-ovest.",
    name 'sponda' 'argine',
    n_to SentieroForesta1, e_to Sponda2, ne_to ForestaR1,
    nw_to VersoForesta, w_to PonteNord, ! nel file lunavil.inf
    se_to noswim, s_to noswim, sw_to noswim,
    cant_go [; forestcantgo(noswim); rtrue; ],
    initial [; AbovePicture(River_img, -1, -1); ],
  has female waterhere;

ORoom Sponda2 "Sponda del fiume"
  with description
    "Il fiume Vlis, che impetuoso attraversa la foresta e la valle da nord-est ad ovest, forma qui una piccola ansa dove le sue acque paiono calmarsi, come per riposarsi prima della corsa fino alle cascate. I resti di un piccolo ponte di legno, divelto dalla corrente, forse un tempo portavano ad una casupola in rovina che pu@`o essere intravista, facendo attenzione, tra gli alberi dall'altra parte del fiume.",
    name 'sponda' 'argine' 'ansa',
     w_to Sponda1, ne_to Sponda3, n_to ForestaR1, nw_to SentieroForesta1,
     sw_to noswim, se_to noswim, e_to noswim,
     s_to [; <<Enter pontedivelto>>; ],
     cant_go [; forestcantgo(noswim); rtrue; ],
     initial [; AbovePicture(River_img, -1, -1); ],
   has female waterhere;

Distance -> "capanna"
  with name 'casa' 'capanna' 'casupola',
    description "Una piccola casa, poco pi@`u che una capanna, si trova a diversi metri dal fiume, immersa tra gli alberi.",
    cant_go "La capanna @`e dall'altra parte del fiume.",
  has female;

Object pontedivelto "ponte"
  with pname 'resti' '.or' 'rudere' '.or' 'ruderi' '.x' 'del' '.or' 'di' '.x' 'piccolo' 'ponte' '.x' 'di' '.x' 'legno',
    description "Questo ponte @`e ormai inutilizzabile.",
    before [;
      Enter, Go, Climb: "Il ponte, o - meglio - quel che ne rimane, non arriva dall'altra parte del fiume, e comunque non ti reggerebbe.";
      Attack, Push, Pull, Turn: "Ti sembra conciato gi@`a abbastanza male.";
      Touch: "Il poco legno che rimane @`e per di pi@`u fradicio e marcio.";
      Search, LookUnder: "Quel che rimane del ponte non nasconde niente.";
      Fix, Nail, NailTo: "Non credi che si possa fare pi@`u molto, per questo povero ponte.";
    ],
    found_in Sponda2 OltreFiume,
  has scenery;
  
ORoom Sponda3 "Sponda del fiume"
  with description
    "La sponda e l'argine del fiume Vlis, che scorre da est verso sud-ovest tagliando la foresta e la valle, paiono quasi sparire su di una piccola spiaggia argillosa, rendendo impossibile il procedere ulteriormente verso monte.",
    name 'sponda' 'argine',
    sw_to Sponda2, w_to ForestaR1, n_to ForestaR4, nw_to ForestaR1, ne_to ForestaR7,
    e_to "La riva del fiume non @`e pi@`u percorribile, in quella direzione.",
    se_to noswim, s_to noswim,
    cant_go [; forestcantgo(noswim); rtrue; ],
    initial [; AbovePicture(River_img, -1, -1); ],
  has female waterhere;
    
Object -> spiaggia "argilla" 
  with name 'spiaggia' 'argillosa' 'argilla' 'impronte' 'impronta',
    description "I tuoi piedi hanno lasciato profonde impronte su di una piccola spiaggia d'argilla, bagnata dal fiume.",
    initial "I tuoi piedi affondano nell'argilla della spiaggia, lasciando profonde impronte.",
    before [;
      Take, Insert:
        if (action==##Insert && second~=pentola && second~=pentolaargilla)
            "Non sembra un contenitore adatto.";
        if (pentola in player) {
            move pentolaargilla to parent(pentola);
            remove pentola;
            pentolaargilla.lifespan=96+random(8);
            Achieved(31);
            "La pentola ora @`e piena d'argilla.";
        }
        if (pentolaacqua in player) {
            move pentolaargilla to parent(pentolaacqua);
            remove pentolaacqua;
            pentolaargilla.lifespan=96+random(8);
            Achieved(31);
            "Versi l'acqua e riempi la pentola d'argilla.";
        }           
        if (pentolaargilla in player) {
            pentolaargilla.lifespan=16+random(8);
            "Svouti con pazienza la pentola dall'argilla in essa contenuta e la riempi nuovamente di argilla fresca.";
        }
        "Non puoi prenderla a mani nude. Avresti bisogno di un contenitore.";
    ],
  has static female;

Object -> barca "piccola barca"
  with name 'piccola' 'barca' 'nave' 'chiatta' 'zattera' 'barchetta' 'imbaracazione' 'remo',
!    short_name [;
!        if (self has general) print "piccola barca";
!        else print "piccola barca ormeggiata dall'altra parte del fiume.";
!        rtrue;
!    ],
    ! count -> damaged
    count FALSE,
    description [;
        print "Una piccola barca, poco pi@`u che una chiatta, con un solo lungo remo.";
        if (self.count) {;
          addhint(h_riparazione);
          " Purtroppo la barca ha colpito duramente la riva, e una falla si @`e aperta sul fondo.";
        }
        if (self has moved) "";
        " @`E legata con un pezzo di corda ad un ceppo, dall'altra parte del fiume."; 
    ],
    initial "Una barca @`e legata dall'altra parte del fiume.",
  before [;
    Go, Enter, Climb, Take:
        if (self in Sponda2 or OltreFiume) {
          if (self.count) {
            addhint(h_riparazione);
            "C'@`e una falla sul fondo. Non te la senti di affrontare il fiume in piena in queste condizioni.";
          }
          if (self hasnt solid) {
            addhint(h_riparazione);
            "Provi a salire sulla barca, ma ti rendi subito conto che la riparazione non @`e abbastanza ben fatta, e cederebbe quasi immediatamente.";
          }
          solved(h_riparazione);
          Achieved(8);
          print "Sali";
          if (iarin.follower) print "te";
          print " sulla piccola barca spingendola via dalla riva. In poco tempo, manovrando con l'unico remo a tua disposizione, riesci faticosamente a guadagnare la riva opposta.^";
          if (self in Sponda2)  { move self to OltreFiume; PlayerTo(OltreFiume,2); }
           else                 { move self to Sponda2; PlayerTo(Sponda2,2); }
          rtrue;
        }
        "La barca @`e dall'altra parte del fiume.";
    Fix, Nail:
        if (self hasnt moved) "La barca @`e troppo lontana.";
        if (~~self.count) "La barca non sembra troppo malconcia.";
        if (second ~= martello or asse or NULL or 0) "Non credi di poter riparare la barca con ", (the)second, ".";
        if (martello notin player || asse notin player)
            "Con quello che possiedi non riesci a riparare la barca.";
        self.count=FALSE;
        remove asse;
        "La riparazione @`e forse posticcia, ma @`e sempre meglio di niente. Ti chiedi se sia sufficiente.";
    Girdle:
        if (self has solid || self.count) rfalse;
        give self solid;
        solved(h_riparazione);
        "Concentri l'energia dell'incantesimo sul fondo della barca, cercando di rinforzare l'asse di legno che chiude la falla.";
  ],
  each_turn [; addhint(h_barca); ],
  has static female;

Object -> corda "corda"
  with name 'corda' 'pezzo' 'fune',
    description "Un pezzo di corda che tiene legata la barca ad un ceppo.",
    before [;
      Missile: if (self has solid) rfalse;
               solved(h_barca);
               remove self;
               move barca to Sponda2;
               give barca moved;
               barca.count=TRUE;
               "Il dardo colpisce con precisione la corda, recidendola. La barca si stacca dal suo ormeggio e segue la corrente verso valle.";
  ],
  has scenery concealed female;

ORoom OltreFiume "Dall'altra parte del fiume"
  with description
    "Il fiume Vlis scorre vicinissimo alle pendici delle montagne settentrionali, tanto che la sua riva sinistra @`e ripida e scoscesa, e lascia ben pochi punti di approdo. In questo luogo una piccola spiaggia @`e circondata da alberi e vegetazione tanto fitta da lasciare ben poche possibilit@`a di passaggio. Solo un piccolo sentiero appena accennato si inoltra verso sud.",
    name 'sponda' 'argine' 'spiaggia',
    s_to DavantiCapanna, se_to DavantiCapanna,
    nw_to noswim, ne_to noswim,
    n_to [; <<Enter pontedivelto>>; ],
    cant_go "Il fiume  e la foresta molto fitta attorno a te sembrano non lasciare passaggi se non verso sud.",
  has waterhere;

Distance -> "capanna"
  with name 'casa' 'capanna' 'casupola',
    description "La capanna @`e a malapena visibile tra gli alberi della foresta.",
    cant_go "Sei ancora distante dalla capanna.",
  has female;  

ORoom DavantiCapanna "Piccola radura"
  with description
    "A poca distanza dalla sponda meridionale del fiume Vlis, la fittissima foresta che si stende sulle pendici delle montagne si apre in una piccola radura, probabilmente opera dei tagliaboschi, in cui, verso sud, sorge una piccola casupola di tronchi.",
    name 'radura' 'foresta',
    before [; Listen: "Verso nord senti scorrere il fiume."; ],
    s_to CapannaTriven, in_to CapannaTriven, n_to OltreFiume, nw_to OltreFiume,
    cant_go "La foresta @`e molto fitta qui, e l'unico passaggio sembra un accenno di sentiero verso nord. La capanna @`e a sud.",
    initial [; AbovePicture(Hut_img, -1, -1); ],
  has woods;

Direction -> OutCapanna "capanna"
  with name 'capanna' 'casa' 'casupola' 'costruzione' 'porta', dir_to s_obj,
    description "Una piccola capanna fatta di tronchi d'albero, evidentemente ormai abbandonata da tempo. La porta d'ingresso sembra sia stata sfondata.",
    before [; Search: "L'interno della capanna sembra in uno stato ancora peggiore dell'esterno."; ],
  has female;

IRoom CapannaTriven "Capanna nella foresta"
  with description
    "A quanto pare una lotta furibonda si @`e svolta all'interno di questa piccola casupola, poco pi@`u che una capanna. Mobili e suppellettili sono stati fatti a pezzi con violenza. Un cadavere, ormai niente pi@`u che uno scheletro, giace riverso in un angolo, ai piedi dei resti di quello che doveva essere un banco da lavoro. Le uniche cose che rimangono intere sono un lungo e robusto tavolo di legno e una scrivania.",
    name 'capanna' 'casa' 'casupola',
    n_to DavantiCapanna, out_to DavantiCapanna,
    cant_go "L'unica uscita @`e verso nord.";
    
Prop -> "mobili"
  with name 'resti' 'pezzi' 'mobili' 'suppellettili' 'letto' 'mobile' 'mobilio' 'armadio' 'comodino',
    description "Vedi solo i resti di un semplice letto, un piccolo armadio e un comodino.",
    before [;
      Search, Push, Pull, Turn, Take, LookUnder: "I mobili, ridotti a pezzi, non sembrano nascondere niente.";
      Attack: "Dubiti di poter danneggiarli ulteriormente.";
    ],
  has pluralname;
  
Prop -> "banco"
  with name 'banco' 'laboratorio' 'alchemico' 'fiale' 'provette' 'fiala' 'provetta' 'alambicco' 'alambicchi' 'pezzi' 'vetro',
    description "Doveva essere un piccolo laboratorio alchemico, ma ora rimangono solo i pezzi di vetro di fiale, provette, alambicchi.",
    cant_go "Non credi di poter cavare qualcosa di utile da questo disastro.";
    
Object -> "tavolo"
  with name 'tavolo',
    description "Non ti vorresti ingannare, ma potrebbe essere un rudimentale tavolo da dissezione.",
  has supporter scenery;

Object -> triven "cadavere"
  with name 'cadavere' 'scheletro' 'morto' 'mago' 'stregone' 'studioso' 'triven',
    description [;
      if (m_triven has locked) "Il cadavere, oltre ad avere diverse ossa rotte, ha il cranio sfondato. Per lo meno non dovrebbe aver sofferto a lungo.";
      "Il cadavere, oltre ad avere diverse ossa rotte, ha il cranio sfondato. Il povero mago - ammesso che si tratti di lui - non dovrebbe aver sofferto a lungo, per lo meno.";
    ],
  before [;
    Take: "Ti accingi a raccogliere il cadavere, ma poi cambi idea. Questa casa sar@`a la sua tomba.";
    Search: <<Examine self>>;
  ],
  has scenery;

Object -> scrivaniatriven "scrivania"
  with name 'scrivania' 'scrittoio',
    description [;
      if (diariotriven in self) {
          give diariotriven ~concealed;
          "Sulla scrivania trovi penna e calamaio, entrambi inutilizzabili, e un piccolo libro.";
      }
      "Sulla scrivania trovi solo penna e calamaio, entrambi inutilizzabili.";
    ],
  before [;
    search: <<Examine self>>;
  ],
  has scenery female supporter;

Prop -> -> pennacalamaio "penna e calamaio"
  with name 'penna' 'calamaio' 'inchiostro',
    description "L'inchiostro @`e secco, la penna spuntata.",
    cant_go "Non pensi che penna e calamaio possano essere minimamente utili.",
  has pluralname;
    
ORoom ForestaR1 "Foresta"
  with description
    "Gli alberi si fanno sempre pi@`u fitti e folti avvicinandosi al cuore della foresta, tanto che il cielo @`e quasi completamente nascosto dalle fronde di abeti e larici. In compenso l'alacre lavoro dei tagliaboschi, che in questa zona devono aver trovato una vera ricchezza, ha lasciato ampi passaggi tra gli alberi.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "I tuoi piedi si muovono quasi a fatica nel folto sottobosco.";
      rfalse;
    ],
    before [; Listen: "Verso sud ti par di sentire scorrere il fiume."; ],
    w_to SentieroForesta1, nw_to SentieroForesta2, e_to Sponda3,
    s_to Sponda2, sw_to Sponda1, se_to Sponda3,
    ne_to ForestaR2, n_to ForestaR3,
    cant_go forestcantgo,
    initial [; AbovePicture(Fir_img, -1, -1); ],
  has woods;
    
Object -> catasta "catasta di legna"
  with name 'catasta' 'di' 'legna' 'legno' 'legname' 'assi' 'asse',
    description "Una piccola catasta di legno in parte gi@`a rozzamente sagomato in assi, lasciata qui da qualche taglialegna.",
    before [; Take: 
        if (self has general) 
            "Non te la senti di depredare ulteriormente un povero taglialegna.";
        give self general;
        move asse to player;
        "Raccogli dalla catasta una piccola asse di legno.";
    ],
  has female static;
  
Object asse "asse di legno"
  with name 'asse' 'di' 'legno' 'tavola',
    description "Una piccola asse di legno rozzamente sagomata.",
    before [; Nail:
                if (second ~= martello or 0 or NULL) "Non credi che sia il sistema migliore.";
                if (martello notin player) "Non credi di riuscire ad inchiodare niente, senza gli strumenti adatti.";
                if (ishere(barca)) <<Fix barca>>;
                if (ishere(pontedivelto)) <<Fix pontedivelto>>;
                "Non credo ti possa servire a molto inchiodare l'asse qui.";
              NailTo:
                if (martello notin player) "Non credi di riuscire ad inchiodare niente, senza gli strumenti adatti.";
                if (second == barca) <<Fix barca>>;
                if (second == pontedivelto) <<Fix pontedivelto>>;
                "Non credi serva a qualcosa inchiodare l'asse ", (ArtA)second, ".";
    ],
  has female;

ORoom ForestaR2 "Foresta"
  with description
    "La foresta, sempre pi@`u fitta tutto intorno, diventa pi@`u rada in questo punto, come se un tempo qui ci fosse una radura ora invasa dagli alberi. In alto il cielo si mostra bene alla vista tra le cime degli alberi.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "Erba e radi cespugli formano il basso sottobosco.";
      "Gli alberi meno fitti rivelano come qui, un tempo, ci fosse una radura.";
    ],
    each_turn [;
      if (self hasnt general && diariotriven has general) {
          give self general; give ForestaR4 general;
          "^La foresta @`e folta, ma se il tuo senso dell'orientamento non ti inganna, dovresti essere abbastanza vicino al punto indicato nel diario che hai trovato nella capanna; esso dovrebbe trovarsi verso est da qui.";
       }
    ],
    w_to SentieroForesta2, sw_to ForestaR1, nw_to ForestaR3, se_to Sponda3,
    e_to [; if (self has general) {
                if (creature in RaduraPietra && creature has general)
                  "Ricordando il terrore che hai provato, non osi avvicinarti nuovamente a quelle creature mostruose.";
                return RaduraPietra;
            }
            return ForestaR4; ],
    cant_go forestcantgo,
    initial [; RightPicture(Forest_img, -1, -1); ],
  has woods;

ORoom RaduraPietra "Vicino alla pietra"
  with description
    "La foresta qui si apre in una piccola radura, al cui centro sorge maestosa, come se fosse qui da sempre, una larga pietra di basalto nero quanto le tenebre pi@`u scure.",
    name 'radura',
    vegdesc [flag;
      if (flag) "Strano... attorno alla pietra non c'@`e traccia d'erba.";
      rfalse;
    ],
    each_turn [; Achieved(10); ],
    w_to ForestaR2, e_to ForestaR4, ne_to ForestaR5, 
    sw_to ForestaR1, nw_to ForestaR3,
    cant_go forestcantgo,
    initial [; AbovePicture(MStone_img, -1, -1); ],
  has woods;

Distance -> "foresta"
  with name 'foresta' 'alberi' 'albero',
    description "Attorno a questa radura la foresta sorge folta e rigogliosa, ma la radura @`e completamente brulla.",
    cant_go "Gli alberi della foresta sono lontani una decina di passi, in ogni direzione."
  has female;

Object -> pietradellaluna "pietra della luna"
  with name 'pietra' 'della' 'luna' 'altare' 'basalto', article "la",
    count 0, clay 0,
    ! .clay : 0 niente, 1 umida nelle iscrizioni, 2 sporca, 3 ok
    description [;
      print "La pietra @`e perfettamente circolare e perfettamente liscia; di basalto nero, alta fino ai tuoi fianchi e pi@`u larga di quanto tu sia alto. Osservandola provi una sensazione strana, come se ti sentissi diviso tra disperazione e speranza. Ma @`e solo un attimo...^";
      if (player has msight) print "La pietra brilla di una luminescenza violacea.^";
      ! C'e' l'argilla solidificata sulla pietra
      if (self.clay==2) <<Examine argillapietra>>;
      if (iscrizioni in self) <<Examine iscrizioni>>;
      rtrue;
    ],
    aura "La pietra emana una potente aura di malvagit@`a, ma a questa si aggiunge una seconda aura, che potresti definire di ~comunicazione~.",
    before [;
      Climb: <<enter self>>;
      Girdle: if (self.clay==1) {
                self.clay=3;
                pietradellaluna.count=98;
                solved(h_iscrizioni);
                solved(h_notte);
                addhint(h_notte2);
                Achieved(32);     
                print "Concentri l'energia dell'incantesimo sull'argilla che riempie le iscrizioni, e questa sembra aquisire una maggiore solidit@`a. Poi aspett";
                if (iarin in real_location) print "ate"; else print "i";
                " per troppi attimi trepidanti fino a che le incisioni nella pietra spariscono. Osservi il risultato e noti che @`e sufficiente; quasi tutte le incisioni sono sempre leggibili in questo improvvisato calco d'argilla.";              }
              "Percepisci la cinta di protezione che si dissolve attorno alla roccia.";
      Attack, Missile: "La pietra sembra non subire minimamente i tuoi attacchi, quasi fosse indistruttibile.";
      Touch: "La roccia @`e stranamente fredda al tatto.";
      Rub: if (argillapietra notin self) "La pietra sembra gi@`a abbastanza pulita.";
           if (self.clay >= 3) "Non ti sembra una buona idea, dopo tutta la fatica che hai fatto.";
           remove argillapietra; self.clay = 0;
           if (iarin in real_location) print "Ripulite"; else print "Ripulisci";
           " velocemente la pietra dall'argilla.";
    ],
    react_before [i wd c e f;
      ! Se di fronte alla pietra dici "ia ia ia ia"...
      ! e = errore, f = "recita formula", c = numero di ia pronunciati
      Say, Autosay: c=0; e=FALSE; f=FALSE;
           wn=consult_from;
           if (action==##Autosay) {
               if (firsttopic=='ia') c++; else e=TRUE;
           }
           for (i=0: i<consult_words: i++) {
             wd=NextWord();
             if (i==0 && wd=='formula' or 'litania' or 'preghiera') f=TRUE;
              else if (wd=='ia') c++;
               else e=TRUE;
           }
           if (e || c==0) {
               if (f) "Quale formula vuoi recitare?";
               "Non accade nulla di particolare.";
           }
           if (c<3) "Ti senti molto a disagio recitando questa litania insensata.";
           "Reciti questa folle litania e la tua vista si oscura per un attimo, mentre nella tua mente si formano pensieri di disperazione, di terrore, di infinito orrore... Per fortuna la visione dura solo pochi istanti.";
    ],
    each_turn [;
      solved(h_diario);
      give m_pietra ~locked;
      if (phase==8) {
          give m_iscrizioni ~locked;
          ! Appaiono e spariscono le iscrizioni
          switch (++self.count) {
              2: "^La luna piena splende alta nel cielo, la sua luce che filtra tra gli alberi si sta avvicinando alla pietra.";
              4: move iscrizioni to self;
                 "^La luce della luna arriva a toccare la pietra e di colpo dal nulla appaiono sul nero basalto della sua superficie delle iscrizioni, come un complesso bassorilievo.";
              7: remove iscrizioni;
                 addhint(h_iscrizioni);
                 print "^Cos@`i come erano apparse, le iscrizioni spariscono nel nulla. Ti chiedi se riappariranno nel corso della notte.^";
                 self.checkclay(); rtrue;
             13: move iscrizioni to self; 
                 if (iscrizioni.exam>1) iscrizioni.exam=1;
                 "^La luce della luna illumina pienamente la pietra. All'improvviso le iscrizioni appaiono nuovamente sul basalto della sua superficie. Ti pare che per@`o, incredibilmente, siano disposte diversamente rispetto alla volta precedente.";
             16: remove iscrizioni;
                 print "^Ancora una volta, inesorabilmente, le iscrizioni spariscono, senza lasciare traccia alcuna.^";
                 self.checkclay(); rtrue;
             23: move iscrizioni to self;
                 if (iscrizioni.exam>2) iscrizioni.exam=2;
                 "^Ancora una volta, nella luce innaturale della luna piena, le iscrizioni si formano sulla pietra nera, disposte ancora in modo diverso.";
             26: remove iscrizioni;
                 print "^Come la luna avanza, nascondendosi tra gli alberi, le iscrizioni spariscono, lasciando solo la pietra liscia. Ancora una volta ti domandi se riappariranno.^";
                 self.checkclay(); rtrue;
             34: if (easy) self.count = 3;
             38: move iscrizioni to self; 
                 if (iscrizioni.exam>2) iscrizioni.exam=2;
                 "^Quando stavi per perdere la speranza, le iscrizioni tornano a formarsi ancora sulla superficie di basalto, disposte ancora una volta in modo differente. Hai anche l'impressione che siano meno pronunciate.";
             41: remove iscrizioni;
                 print "^Le iscrizioni spariscono di nuovo dalla superficie della pietra. Temi proprio che per stanotte non riappariranno pi@`u e che ogni altro tentativo per leggerle sar@`a vano e inutile.^";
                 self.checkclay(); rtrue;
          }
      }
    ],
    checkclay [;
        if (self.clay==1) { 
            self.clay=2;
            "Come le iscrizioni spariscono, l'argilla perde forma; ora @`e impossibile leggerci qualsiasi cosa.";
        }
    ],
  has female scenery enterable supporter;
  
Object iscrizioni "iscrizioni"
  with name 'iscrizione' 'iscrizioni' 'preghiera' 'preghiere' 'bassorilievo' 'incisioni' 'parole',
    exam 0,
    description [;
      if (pietradellaluna.clay>=3) {
        AbovePicture(StoneRunes_img, -1, -1);
        give m_sodnigguerth ~locked;
        print "Ti soffermi a leggere le parole rimaste nel calco di argilla. Sono scritte in lingua arcaica, alcuni tratti mancano, e spesso il significato delle parole @`e oscuro, ma cerchi di fare del tuo meglio.^
        L'iscrizione inizia con una preghiera, se cos@`i pu@`o essere chiamata, rivolta ad un essere che da tempo antico vive tra gli uomini regalando la sua malvagia saggezza, seguita da un'invocazione a colui che @`e ~la chiave e il portale~, al nero capro dai mille cuccioli, al signore del vuoto e del nulla e chi dorme sommerso. Ignori a chi siano rivolte realmente queste parole.^
        Viene poi descritto un blasfemo rituale per aprire le porte dell'abisso eterno e portare in questo mondo quella che viene definita l'oscura madre, e che assoggetter@`a a s@'e tutti i viventi, portando morte e disperazione. Si parla di due pietre, due altari, sepolti sotto la roccia. Uno di essi @`e il luogo dove tutto questo deve accadere.^
        Da quello che comprendi l'evocazione si conclude con la frase @<<Ia Ia, Sod Nigguerth, oscura bestia, abitatrice dei boschi, madre di mille cuccioli, raggiungici nel mondo dei mortali e domina su noi e su ogni altro essere vivente, portando tra noi le tue tenebre e la tua volont@`a@>>. Il rito deve culminare orribilmente con l'uccisione di una giovane donna. A quel punto il portale sar@`a aperto.^
        Le ultime parole che riesci a leggere sembrano quasi tracciate da un'altra mano: @<<Nel momento in cui il cancello sar@`a aperto, solo un disperato estremo gesto potr@`a impedire che eterne tenebre calino. Cos@`i come un gesto pu@`o aprire il cancello, un identico gesto mortale lo pu@`o per sempre chiudere. La salvezza sar@`a nelle mani di una figlia degli uomini, che essa dovr@`a volerlo o tutto sar@`a vano.@>>^
        Angosciato da queste parole oscure, che hai letto a bassa voce, allontani i tuoi occhi dalla pietra";
        if (iarin in real_location) {
            if (~~iarin.seenstone) iarin.trust++;
            iarin.seenstone=TRUE;
            iarin.talk=6;
            print " accorgendoti che anche Iarin ha letto quelle parole";
        }
        print ".^";
        if (self hasnt general) { give self general; waitkey(); }
        remark(8);
        rtrue;
      }
      if (pietradellaluna.clay==2) "L'argilla sparsa sulla superficie della pietra ti impedisce di leggere le iscrizioni.";
      if (pietradellaluna.clay==1) print "L'argilla sulla superficie della pietra evidenzia le iscrizioni scolpite nella pietra e apparsa dal nulla nella luce della luna.^";
       else print "Sulla superficie, che dovrebbe essere perfettamente liscia, appaiono delle iscrizioni, scolpite nella pietra.^";
      switch(++self.exam) {
          1: "Sono in linguaggio arcaico. Hai bisogno di tempo per decifrarle, e la scarsa luce non ti aiuta. Solo comprendere da dove iniziare a leggere @`e difficoltoso.";
          2: "Ti sembra di capire che l'incisione inizia con una preghiera, se cos@`i si pu@`o chiamare, un'invocazione a colui che solo tra gli antichi volle mescolarsi agli uomini.";
          3: "Di seguito leggi un'invocazione a colui che @`e la chiave e il portale, al nero capro dai mille cuccioli, al signore del vuoto e del nulla, a colui che dorme sommerso.";
          4: "Quello che segue, ti pare, @`e la descrizione di un rituale per aprire le porte del mondo all'oscura madre.";
          default: "Il seguito @`e molto confuso, avresti bisogno di pi@`u tempo per capirci qualcosa.";
      }
      rtrue;
    ],
    before [;
        Search, Consult: <<Examine self>>;
        Touch: <<Touch pietradellaluna>>;
        Rub: <<Rub pietradellaluna>>;
        Missile: <<Missile pietradellaluna>>;
        Girdle: <<Girdle pietradellaluna>>;
    ],
    aura "Le iscrizioni emanano una strana aura che non riesci ad identificare.",
  has scenery concealed female pluralname;
  
Object argillapietra "argilla sulla pietra"
  with name 'argilla',
    description [;
      switch (pietradellaluna.clay) {
        1, 3: if (iscrizioni in pietradellaluna) <<Examine iscrizioni>>;
        2: "La pietra @`e coperta da uno strato informe d'argilla.";
      }
      "L'argilla ricopre la pietra.";
    ],
    before [;
      Search, Consult: <<Examine self>>;
      Take, Push, Pull, Rub: <<Rub pietradellaluna>>;
      Girdle: <<Girdle pietradellaluna>>;
      Missile: <<Missile pietradellaluna>>;
    ],
  has scenery concealed female;

Object creature "branco di creature"
  with name 'creature' 'creatura' 'esseri' 'essere' 'branco' 'gruppo',
    description "Attorno alla pietra puoi vedere diversi esseri dall'aspetto grottesco e mostruoso. Sembrano uomini ma non portano abiti, la loro postura @`e pi@`u simile a quella di un animale, e le loro braccia sono smisuratamente lunghe, tanto da arrivare quasi al suolo. I loro sguardi persi nel vuoto e l'espressione animalesca del loro volto sono inquietanti.",
    aura "Le creature emanano una percepibile aura di demenza.",
    status 0, cnt 0,
    each_turn [;
      switch (++self.status) {
          1: give self ~scenery;
          solved(h_iarinmeet);
          "^Arrivando vicino alla pietra vi accorgete che un gruppo di circa una ventina di creature sono nella radura. Temendo il peggio, vi tenete al limitare della radura. Le creature non paiono prestarvi la minima attenzione.";
          2: "^Le grottesche creature paiono percorrere una strana, contorta processione attorno alla pietra nera.";
          3: give self general;
          print "^Ad un tratto le creature si arrestano, levando la testa verso il cielo. Poi si prostano a terra e si alza un grido corale: @<<Ia, Ia, Ia, Ia, Ia, Ia, Ia...@>>^
          Udendo questa assurda e blasfema litania, si forma nella tua mente l'immagine terrificante di una citt@`a sommersa dove un mostruoso dio dimenticato dorme. Preso da un'innaturale terrore perdi il controllo di te stesso e non puoi far altro che fuggire da questo luogo...^";
          Achieved(20);
          addhint(h_fuga);
          PlayerTo(ForestaR1,2); if (iarin.follower) move iarin to ForestaR1;
          waitkey();
      }
    ],
    react_before [;
      Listen: if (self.status==3) "L'orrenda litania risuona nella tua mente.";
    ],
    life [;
      ! Qualunque cosa tu faccia, e' una pessima idea...
      NoPicture();
      deadflag=1;
      "Come ti muovi verso di loro, le creature sembrano accorgersi della tua presenza. D'un tratto interrompono il loro rito e ti sono addosso. L'ultima cosa che senti @`e il rumore delle tue ossa che si spezzano...";
    ],
  has animate;

ORoom ForestaR3 "Foresta"
  with description
    "Gli alti alberi sempreverdi si fanno meno fitti nella parte della foresta pi@`u vicina alla catena montuosa settentrionale. Fra le cime degli alberi vedi a tratti spuntare il monte Kalnam.",
    name 'foresta',
    w_to SentieroForesta3, sw_to SentieroForesta2, nw_to SentieroMiniere,
    se_to ForestaR2, s_to ForestaR1, ne_to ForestaR5,  e_to ForestaR5,
    n_to "Gli alberi troppo fitti e il terreno scosceso non ti permettono di procedere verso nord.",
    cant_go forestcantgo,
    initial [; RightPicture(Forest_img, -1, -1); ],
  has woods;

ERoom ForestaR4 "Foresta"
  with description
    "Gli alberi maestosi lasciano poco spazio tra loro, rendendo sempre pi@`u difficile procedere in questa fittissima foresta. Solo grazie al lavoro dei taglialegna @`e possibile trovare passaggi tra la vegetazione.",
    name 'foresta',
    before [; Listen: "Verso sud ti par di sentire scorrere il fiume."; ],
    each_turn [;  
      if (self hasnt general && diariotriven has general) {
          give self general; give ForestaR2 general;
          "^La foresta @`e folta, ma se il tuo senso dell'orientamento non ti inganna, dovresti essere abbastanza vicino al punto indicato nel diario che hai trovato nella capanna; esso dovrebbe trovarsi verso ovest da qui.";
       }
    ],
    w_to [; if (self has general) {
                if (creature in RaduraPietra && creature has general)
                  "Ricordando il terrore che hai provato, non osi avvicinarti nuovamente a quelle creature mostruose.";
                return RaduraPietra;
            }
            return ForestaR2; ],
    sw_to ForestaR1, s_to Sponda3, n_to ForestaR5, 
    e_to GoRadura, se_to ForestaR7, ne_to ForestaR6,
    cant_go forestcantgo,
    initial [; RightPicture(Forest_img, -1, -1); ],
  has woods;

ERoom ForestaR5 "Foresta"
  with description
    "La foresta qui rimane fitta nonostante le pendici delle montagne siano vicine e il terreno evidentemente in salita. Questa sembra una zona relativamente inesplorata della valle.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "Anche il sottobosco @`e fittissimo.";
      rfalse;
    ],
    w_to ForestaR3, sw_to ForestaR3, s_to ForestaR4, se_to GoRadura, e_to ForestaR6,
    n_to [;
      if (UscitaMiniera has visited) return(UscitaMiniera);
      print "Gli alberi troppo fitti e il terreno scosceso non ti permettono di procedere verso nord.^";
      exitlist(n_obj); rtrue;
    ],
    cant_go [; 
               if (UscitaMiniera has visited) { forestcantgo(); rtrue; }
               forestcantgo(n_obj); rtrue;
            ],
  has woods;

[GoRadura;
    ! Per evitare al giocatore una fine immeritata
    if (seguaci in Radura && player hasnt invisible) {
        solved(h_radura);
        addhint(h_rituale);
        "Avvicinandoti alla radura senti il vociare di molte persone che sembrano essersi riunite in quel luogo. Temendo per la tua incolumit@`a ritorni sui tuoi passi.";
    }
    if (seguaci in Radura) print "Avvicinandoti alla radura senti il vociare di molte persone, ma, grazie all'incantesimo del manto d'ombra e muovendoti con estrema cautela, osi avvicinarti per vedere cosa succede.^";
    return(Radura);
];

ORoom Radura "Radura nella Foresta"
  with description [;
      print "Gli alberi della foresta si diradano in questo punto, lasciando spazio ad una piccola radura quasi circolare, ";
      if (quercia in self) print "su cui troneggia, quasi in contrasto con i sempreverdi che dominano il resto della foresta, una quercia gigantesca. ";
      if (alberofiamme in self) print "dominata dai resti di un albero maestoso in preda alle fiamme. "; 
      if (alberomorto in self) print "dominata dai resti di un albero sicuramente maestoso, ma ormai morto, arso dalle fiamme. ";      
      "In mezzo all'alta erba che riempie la radura si vede anche una grossa pietra.";
    ],
    name 'radura',
    vegdesc [flag;
      if (flag) "Sembra quasi che l'erba sia stata calpestata di recente da molte persone.";
      rfalse;
    ],
    nw_to ForestaR5, s_to ForestaR7, w_to ForestaR4, n_to ForestaR6,
    e_to ForestaR8, se_to ForestaR7, 
    cant_go forestcantgo,
    initial [; AbovePicture(Oak_img, -1, -1); ],
  has woods;

Distance -> "foresta"
  with name 'foresta' 'alberi',
    description "Gli alberi della foresta circondano la radura, cos@`i quasi simile ad una piazza o un'arena, lasciando passaggi in varie direzioni.",
    cant_go "Gli alberi della foresta sono lontani una decina di passi, in ogni direzione."
  has female;
      
Prop -> "altare"
  with name 'grossa' 'pietra' 'macigno' 'altare',
    description "Al centro della radura sta una grossa pietra, simile quasi ad un rozzo altare.",
    before [;
      Search: "La roccia non nasconde niente.";
      Take, Push, Pull, Turn, LookUnder: "La roccia @`e troppo pesante.";
      Receive: "Ti mette a disagio l'idea di appoggiare oggetti su questa pietra.";
      Touch: "La pietra @`e ruvida, ma allo stesso tempo piacevole al tatto.";
    ],     
    cant_go "Preferisci non farlo. Provi un'irrazionale forma di rispetto per questo oggetto.",
  has supporter;

Object -> quercia "quercia"
    with name 'quercia' 'albero',
    description [;
        print "Un'alta quercia robusta con la chioma, nonostante la stagione, folta e carica di foglie.";
        if (player has msight) {
          self.add_to_scope = simboli;
          " e che pare emanare un tenue chiarore. In particolare brillano luminosi quattro piccoli simboli, disposti dall'alto in basso: un occhio, una clessidra, un bastone e un sole.";
        }
        ".";
    ],
    aura "La quercia emana una strana aura, ti pare benigna, che per@`o @`e stata in qualche modo protetta, in modo da non permetterne l'interpretazione.",
    status 0,
    add_to_scope 0,
    before [;
      Attack: "Non riesci a capire come mai, ma ti senti incapace di recar danno a quest'albero maestoso.";
      Girdle: "Come lanci l'incantesimo senti quanto la quercia sia gi@`a protetta, e quello che hai fatto @`e niente al confronto.";
      Missile: "Il dardo incredibilmente manca il bersaglio.";
      Touch:  
        if (seguaci in real_location) "Non riusciresti a passare tra la gente per raggiungere la quercia.";
        if (phase == 3) "La stanchezza inizia a pesare sulle tue spalle e non te la senti di attraversare ancora una volta le caverne sotterranee. Eventualmente puoi sempre tornare domani, dopo una buona notte di sonno.";
        if (self.status>0) { 
          self.status=2;
          "Appoggi la mano sulla quercia e senti una strana energia fluire dentro di te.";
        }
    ],
    react_before [i wd c f a;
      ! Recitare la formula
      ! f = "recita formula", c = numero parole giuste, a = modificatore
      Say, Autosay: c=0; f=0; a=0;
           wn=consult_from;
           if (action==##Autosay) {
               a++;
               if (firsttopic=='saregin') c++;
           }
           for (i=0: i<consult_words: i++) {
             wd=NextWord();
             if (i==0 && wd=='formula' or 'litania' or 'preghiera') { f++; a--; }
             if ((i+a)==0 && wd=='saregin') c++;
             if ((i+a)==1 && wd=='alamdia') c++;
             if ((i+a)==2 && wd=='carnissar') c++;
             if ((i+a)==3 && wd=='rinoeld') c++;
           }
           if (c<4 || self.status==0) {
               if (f) "Quale formula vuoi recitare?";
               "Non accade niente di particolare.";
           }
           if (phase==3 && self.status > 0) { self.status=1; <<Touch self>>; }
           if (self.status==1) "Non accade niente. Eppure sei sicuro di aver detto la formula correttamente.";
           if (self.status==2) {
               self.status=1;
               Achieved(12);
               solved(h_quercia);
               subphase=1;
               print "Ad un tratto ti senti quasi risucchiare all'interno della quercia, e attraverso di essa, nel terreno sottostante, fino a ritrovarti in una vasta caverna.^^";
               if (self hasnt general) { give self general; waitkey(); }
               PlayerTo(DIngresso,2);
               if (iarin.follower) {
                   move iarin to real_location;
                   print "^Dopo qualche attimo vedi apparire ", (the)iarin, " accanto alla quercia.^";
               }
               rtrue;
           }
    ],
    has scenery female static;
    
Prop simboli "simboli"
  with name 'simbolo' 'simboli' 'occhio' 'clessidra' 'bastone' 'sole',
    description [;
      if (ishere(fusto2)) "Un bastone, un occhio, un sole e una clessidra, disposti dall'alto in basso. Quattro simboli che brillano luminosi sulla corteccia della quercia.";
      "Un occhio, una clessidra, un bastone e un sole, disposti dall'alto in basso. Quattro simboli che brillano luminosi sulla corteccia della quercia.";
    ],
    before [;
      if (player hasnt msight) "Adesso non riesci pi@`u a vedere i simboli.";
      Touch: if (ishere(quercia)) <<Touch quercia>>;
             if (ishere(fusto2)) <<Touch fusto2>>;
    ],
    cant_go "Sono solo dei simboli incisi."
  has pluralname;      

Object alberofiamme "albero in fiamme"
  with pname 'quercia' 'albero' 'in' 'fiamme',
    description "La quercia maestosa che permetteva di accedere alle misteriose caverne sotterranee ora @`e avvolta dalle fiamme, che la stanno distruggendo poco a poco.",
    before [;
      Touch, Take, Push, Pull, Turn: "Il calore ti tiene lontano."; 
      Girdle: "Le fiamme distruggono l'energia che avrebbe voluto rinforzare l'albero.";
    ],
  has scenery static;
    
Object alberomorto "albero morto"
  with name 'quercia' 'albero' 'morto',
    description "La quercia maestosa che permetteva di accedere alle misteriose caverne sotterranee ora @`e ridotta ad una carcassa contorta, arsa completamente dalle fiamme provenienti dal vulcano, priva di vita e di potere.",
    before [;
      Touch: "Non avverti assolutamente niente... Purtroppo il potere dell'albero @`e sparito."; 
    ],
  has scenery static;

Object seguaci "gruppo di persone"
    with name 'gruppo' 'folla' 'persone' 'gente' 'cultisti' 'seguaci' 'hila' 'cuoca' 'nilis' 'cameriera' 'rabam' 'giardiniere' 'figli' 'della' 'valle',
    description [;
      move iarin to parent(self);
      move vade to parent(self);
      print "Un gruppo di circa trenta persone occupa quasi tutta la radura. Indossano abiti grigi e verdi, e sono intenti a cantare una soffusa e dolce melodia, che alcuni di loro accompagnano con flauti e cembali. Due di loro attizzano un fal@`o da cui esce un fumo dall'odore piacevolmente dolce. Il tutto sembra proprio essere parte di una qualche cerimonia religiosa che non riesci a individuare; proprio uno di quei culti proibiti su cui stai investigando per conto degli inquisitori.^";
      if (self hasnt general) {
          give self general;
          print "Tra le persone presenti riconosci qualcuno che hai gi@`a visto: la cuoca, il giardiniere e la cameriera del palazzo del barone, ad esempio.";
          if (vade hasnt general) " Ti colpiscono, fra gli altri, l'uomo che sembra presiedere la cerimonia e una ragazza il cui abito bianco spicca tra gli altri.";
          print " Oppure l'alchimista, che sembra presiedere la cerimonia";
          if (~~iarin.known) ", e ti colpisce particolarmente una ragazza il cui abito bianco spicca tra gli altri.";
          ", o sua nipote, il cui abito bianco spicca particolarmente tra gli altri."; 
      }
    ],
    atfirst false,
    describe [;
      if (~~self.atfirst) {
          self.atfirst=true;
          self.description();
          rtrue;
      }
      "Diverse persone stanno partecipando ad un rituale di qualche tipo.";
    ],
    count 0,
    movein [;
        self.count=0;
        give self ~general;
        move seguaci to Radura;
        move rituale to Radura;
        remove nilis;
        remove hila;
        remove rabam;
        remove vade;
        remove iarin;
        move falo to Radura;
    ],
    moveout [;
        remove seguaci;
        remove rituale;
        remove nilis;
        move vade to Laboratorio;
        remove iarin;
        move hila to Cucine;
        move rabam to Giardini;
        remove falo;
        Follow.create(self, "Non ti pare il caso di seguirli; riusciresti solo a farti scoprire e credi di avere altro da fare qui nella radura.");
        Follow.create(iarin, "Non ti pare il caso di seguirla adesso, anche se vorresti parlarci in seguito.");
        Follow.create(vade, "Non ti pare il caso di seguirlo, sicuramente gli altri seguaci lo scorteranno fino al villaggio.");
    ],
    react_before [;
      Listen:
        "I canti e la musica sono dolci e sereni, e riescono a riempire il tuo animo di una tranquillit@`a che difficilmente ti riesce di provare.";
    ],
    each_turn [;
      solved(h_radura);
      solved(h_firstday);
      solved(h_rituale);
      addhint(h_cattura);
      if (player hasnt invisible) {
          NoPicture();
          deadflag=1;
          "^Le persone presenti si rendono conto immediatamente della tua presenza e ti circondano. Sopraffatto da disarmato e tramortito.^^
          Ti viene fatta bere a forza una bevanda che ti fa piombare in uno stato di beata incoscienza, mentre - ti pare - i tuoi carcerieri discutono su come renderti inoffensivo. Le ore, o forse i giorni, passano, fino a che le tenebre e la distruzione piombano su di te, su coloro che ti tenevano prigioniero, sulla valle e forse sul mondo intero...";
      }
      knowcult=TRUE;
      if (self has general) {
          ! Descrizione del rituale
          switch(++self.count) {
              2: "^La voce baritonale dell'officiante si leva sopra i canti, elevando una preghiera alla madre terra e alla luna, signora del cielo, mentre appoggia il suo bastone sulla pietra che sorge al centro della radura.";
              3: give m_figli ~locked;
                 "^L'officiante si rivolge alla folla dicendo: @<<Benvenuti, Figli della Valle, benvenuti in questo luogo dove possiamo liberamente seguire gli insegnamenti di coloro che prima di noi qui veneravano la madre terra. Essi ci insegnano ad amare ogni creatura e a vivere liberi, e anche se i tempi stanno cambiando, solo seguendo i loro insegnamenti riusciremo a mantenere la nostra purezza. Quindi @`e per noi necessario controllare e fermare lo straniero mandato dalla capitale, ma @`e ancora pi@`u importante farlo senza recargli alcun danno@>>. Ti senti sollevato da quest'ultima affermazione.";
              4: quercia.status=1; remove iarin;
              "^La ragazza vestita di bianco si ferma davanti all'altare, mentre l'officiante le impartisce una sileziosa benedizione, poi, danzando al suono dei flauti e dei cembali, ella si avvicina alla quercia, la tocca e pronuncia una strana formula: @<<Saregin Alamdia Carnissar Rinoeld@>>. Quasi non credi ai tuoi occhi quando la vedi sparire, quasi fosse entrata all'interno della quercia.";
              5: "^I canti continuano. Sono melodie molto dolci, che riescono ad infondere serenit@`a nel tuo spirito. Ti chiedi che fine abbia fatto la ragazza.";
              6: move iarin to parent(self);
                 "^Ad un tratto la ragazza riappare di fronte alla quercia, poi si avvicina alla pietra e dice, rivolta alla folla: @<<State attenti, amici miei. Un pericolo enorme ci attende. Proprio in questa valle un male antico incombe su tutti noi. Lo straniero, a questo punto, non @`e il pericolo pi@`u grave, ma anzi potrebbe essere la nostra sola speranza@>>. Per un attimo ti pare che la ragazza guardi verso di te.";
              7: Achieved(11);
              solved(h_cattura);
              addhint(h_quercia);
              self.moveout();
              sunset=TRUE;
              print "^Con un ultima breve preghiera l'officiante congeda gli astanti. Il fuoco viene spento e la piccola folla si disperde per sentieri diversi. Rimani solo in mezzo alla radura nella luce del crepuscolo.^";
              remark(3);
              rtrue;
          }
      }
    ],
    life [;
        if (player has invisible) {
            give player ~invisible;
            "La folla si rende conto della tua presenza.";
        }
        "Non credi sia una buona idea.";
    ],
    has animate static;

Object falo "fal@`o"
  with name 'falo' 'fal@`o' 'fuoco' 'fumo',
    description "Un piccolo fal@`o, circondato da pietre, in cui bruciano legna e probabilmente erbe. Il fumo che ne esce @`e particolarmente denso.",
    react_before [; Smell: "L'odore del fumo @`e piacevolmente dolce, rende la testa leggera e riesce a donare una certa quieta serenit@`a."; ],
  has scenery;
  
Prop rituale "rituale"
  with name 'rito' 'rituale',
    description "Il rituale che si sta svolgendo @`e, nella sua semplicit@`a, colmo di una serena bellezza.",
    cant_go "Meglio non avvicinarsi troppo.";

ERoom ForestaR6 "Foresta"
  with description
    "Gli alberi sempreverdi sono alti e fitti in questa zona, vicino ai confini orientali della valle. Trovare passaggi tra gli alberi @`e sempre pi@`u difficoltoso.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "Un folto sottobosco.";
      rfalse;
    ],
    sw_to ForestaR4, s_to GoRadura, w_to ForestaR5, se_to ForestaR8,
    n_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    ne_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    cant_go forestcantgo
  has woods;

ERoom ForestaR7 "Foresta"
  with description
    "Questa zona della foresta sembra quasi completamente inesplorata, avvolta in un silezio suggestivo. Non c'@`e traccia del lavoro dei tagliaboschi, ne del passaggio di altri esseri umani tra questi alberi fitti che paiono voler bloccare la strada in ogni direzione.",
    name 'foresta',
    vegdesc [flag;
      if (flag) "I tuoi piedi affondano tra l'alta erba di uno stupendo sottobosco.";
      rfalse;
    ],
    w_to ForestaR4, nw_to ForestaR4, n_to GoRadura, 
    ne_to ForestaR8, sw_to Sponda3,
    e_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    cant_go forestcantgo,
    initial [; RightPicture(Forest_img, -1, -1); ],
  has woods;

ERoom ForestaR8 "Foresta"
  with description
    "Nella parte pi@`u orientale della foresta gli alberi si fanno ancora pi@`u fitti mentre si inerpicano sulle pendici delle montagne, tanto che @`e impossibile vedere il cielo, in alto. Probabilmente ben poche persone hanno messo piede in questa zona intricata e priva di sentieri.",
      name 'foresta',
    vegdesc [flag;
      if (flag) "Il lussureggiante sottobosco contribuisce a creare qui un'atmosfera da foresta incantata.";
      "Larici e abeti, qui particolarmente alti e fitti, lasciano poco spazio ai tuoi passi.";
    ],
    w_to GoRadura, sw_to ForestaR7, nw_to ForestaR6,
    e_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    ne_to "Da quella parte la foresta si inerpica per le pendici delle montagne, e il passaggio si rivela ben presto troppo difficoltoso.",
    cant_go forestcantgo
  has woods;