! La Pietra della Luna
! Avventura Testuale realizzata da Paolo Lucchesi
! da un'idea di Paolo Lucchesi, Andrea Gnesi e Stefano Masi
! Questo prodotto e' libero, rilasciato sotto licenza GPL (Gnu Public License), 
! riportata nel file allegato gpl.txt. 
! Questo prodotto e' distribuito senza alcuna garanzia. L'autore non pu@`o essere 
! ritenuto responsabile per qualsiasi danno dovuto direttamente o indirettamente 
! all'uso del prodotto.
! ------------------------------------------
!           Conclusione e Altro
! ------------------------------------------

IRoom UltimaStanza "Una pedana di roccia"
  with description [;
      print "Il tunnel termina risalendo fino ad una pedana di roccia che domina dall'alto un'ampia caverna circolare rischiarata dalla luce di torce e candele. Qui, su questa pedana, sorge una larga pietra circolare in basalto nero, simile a quella della foresta, mentre una seconda pietra si trova pi@`u in basso, dalla parte opposta della caverna.^";
      print "La caverna @`e occupata da molti degli esseri subumani che vivono nella valle, mentre da una parte, involontari spettatori, diverse persone sono tenute prigioniere, guardate a vista.^";
      if (win) print "Tra gli altri vedi anche Naradas e l'altra donna che con lui officiava il rito dell'apertura del passaggio.";
      else print "Dietro la seconda pietra vedi Naradas, assieme ad altre due persone, un uomo e una donna, intenti chiaramente ad officiare il rito dell'apertura del passaggio.";
      print " Distesa sulla pietra vedi Nilis, la giovane cameriera del palazzo del Barone.^";
      rtrue;
    ],
    name 'pedana' 'caverna' 'tunnel' 'galleria',
    each_turn [;
        addhint(h_evocazione);
        if (self hasnt general && iarin.seenstone) {
            give self general;
            remark(9);
        }
    ],
    n_to [;
        if (win) "Da quella parte c'@`e solo un vicolo cieco.";
        "Vorresti allontanarti da qui e fuggire, ma qualcosa te lo impedisce.";
    ],
    d_to [;
      ! Dopo che l'antico e' sconfitto, puoi fuggire
      if (win) {
          endscene(FALSE);
          rtrue;
      }
      NoPicture();
      deadflag=1;
      "Ti getti in mezzo alla caverna, ma gli astanti ti circondano da ogni lato. Per tua fortuna vieni ucciso prima che l'evocazione abbia termine.";
    ],
    cant_go "Il tunnel conduce verso nord.",
    antimagic 3,
    initial [; LeftPicture(CaveEnd_img, -1, -1); ],
  has female light;
  
Prop -> evocazione "evocazione"
  with name 'rituale' 'rito' 'evocazione' 'sacrificio',
    description "Il rituale di evocazione @`e officiato Naradas assieme ad una donna e un uomo a te sconosciuti. Le creature subumane, assieme a qualcuno tra gli abitanti del villaggio, sono raccolti attorno alla pietra pi@`u lontana da voi, pietra su cui Nilis attende inerme di essere sacrificata all'oscura dea.",
    cant_go "Dovresti avvicinarti, pessima idea.",
  has female;

Object -> pietre "pietra di basalto"
  with name 'pietra' 'pietre' 'altare' 'altari' 'rocce',
    description [;
        print "Identiche alla loro compagna nella foresta, entrambe le pietre sono circolari, perfettamente lisce, in basalto nero, e sembrano vibrare d'energia. ";
        if (vittima in parent(self)) "La povera Nilis @`e distesa e legata, vittima inerme, sulla pietra pi@`u lontana da te. ";
        if (iarin in self) "Similmente Iarin si @`e stesa volontariamente sulla pietra a te vicina, il suo seno scoperto, attendendo con un coraggio che non credevi possibile.";
        if (player has msight) "^Entrambe le pietre sono circondate da un'aura violacea, per@`o la pietra a te pi@`u vicina mostra dei riflessi argentei che l'altra non ha.";
        "";
    ],
    aura "L'aura delle due pietre @`e in qualche modo una sola, ed @`e un'aura di immane malvagit@`a, ma la pietra a te pi@`u vicina ha anche una seconda aura, quasi benigna, di negazione.",
    before [;
      Climb: <<enter self>>;
      Enter: if (iarin in self) "Iarin @`e gi@`a sdraiata sulla pietra.";
             if (iarin.seenstone) "Una parte di te lo vorrebbe, sarebbe pi@`u semplice. Ma non sei tu quello che deve sdraiarsi su questa pietra.";
      Receive: if (iarin in self || iarin.seenstone) print "Sai bene che non @`e un oggetto che deve andare sulla pietra.";
      Girdle: "Percepisci la gilda di protezione che si dissolve attorno alla roccia.";
      Missile, Attack: "I tuoi sforzi sono vani. Sembra quasi che nessuna forza di questo mondo possa minimamente danneggiare queste pietre.";
    ],
    react_before [i wd c e f;
      LieDown: <<enter self>>;
      Say, Autosay: c=0; e=FALSE; f=FALSE;
           wn=consult_from;
           if (action==##Autosay) {
               if (firsttopic=='ia') c++; else e=TRUE;
           }
           for (i=0: i<consult_words: i++) {
             wd=NextWord();
             if (i==0 && wd=='formula' or 'litania' or 'preghiera') f=TRUE;
              else if (wd=='ia') c++;
               else e=TRUE;
           }
           if (e || c==0) {
               if (f) "Quale formula vuoi recitare?";
               "Non accade nulla di particolare";
           }
           if (c<3) "Ti senti molto a disagio recitando questa litania, in questo luogo.";
           NoPicture(); ! Forse anche qui l'immagine di Shubi
           deadflag=1;
           "Reciti questa orribile litania e la tua vista si oscura, il tuo spirito viene spezzato, la tua volont@`a infranta, e dentro di te offri la tua fedelt@`a l'orribile Sod Nigguerth. Tutto @`e lei, tutto appartiene a lei... Ia, Ia, Ia, Ia, Ia, Ia, Ia...";
    ],    
  has female scenery supporter enterable;
  
Object -> cultisti "cultisti"
  with name 'creature' 'esseri' 'subumani' 'cultisti' 'adoranti' 'adoratori' 'astanti',
    description [;
      if (win) "Adesso gli adoratori di Sod Nigguerth sembrano presi dal panico, e tentano di fuggire in ogni direzione.";
      "Saranno circa trenta, e tutti sembrano partecipare a loro modo all'orribile rito che si sta compiendo. Vedi che alcuni abitanti del villaggio sono mescolati tra le creature.";
    ],
    before [;
      Look, Examine, AutoCast: ;
      default: "Dovresti avvicinarti, ma non credi sia una buona idea.";
    ],
    life [;
      "Non credi sia una buona idea.";
    ],
  has scenery pluralname animate;
  
Object -> prigionieri "prigionieri"
  with name 'prigionieri' 'catturati' 'persone' 'catturate' 'prigioniere' 'accolito' 'cerdil' 'oste' 'locandiere'  'bano' 'bris' 'figlia' 'figli' 'barone' 'inderus',
    description [;
      if (win) "Nella confusione i prigionieri, pieni di nuova speranza, si stanno liberando, cercando scampo nella fuga.";
      "Sembrano tutti abitanti del villaggio. Fra di loro riconosci il giovane accolito, l'oste e sua figlia, qualcuno dei 'figli della valle' e addirittura il barone Inderus.";
    ],
    before [;
      Look, Examine, AutoCast: ;
      default: "Dovresti avvicinarti a loro, ma ti sembrano ben sorvegliati.";
    ],  
    life [;
        "Dovresti avvicinarti a loro, ma ti sembrano ben sorvegliati.";
    ],
  has scenery pluralname animate;

Object -> officianti "officianti"
  with name 'officianti' 'officiante' 'sacerdoti' 'sacerdote' 'naradas' 'segretario' 'maggiordomo' 'uomo' 'donna' 'sacerdotessa',
    description [;
      if (win) "L'uomo ammantato di nero @`e scomparso, mentre Naradas e l'altra donna sembrano anch'essi disordinatamente cercare la fuga assieme agli altri adoratori.";
      "Dei tre officianti, solo Naradas ti @`e noto. Quest'ultimo e la donna sono vestiti con complessi abiti da cerimonia verdi e neri, mentre l'altro uomo @`e completamente ammantato di nero, e forse anche per questo pare che egli emani un'aura di malvagit@`a quasi tangibile. La donna @`e al centro degli altri due e tiene impugnato un lungo pugnale ricurvo.";
    ],
    count 0,
    before [;
      Look, Examine, AutoCast: ;
      default: "Dovresti avvicinarti, ma non credi sia una buona idea.";
    ],
    ! In pratica gli eventi nell'ultima locazione
    each_turn [;
        switch(++self.count) {
            2: "^Naradas e le due persone con lui intonano una dissonante litania di cui non riesci ad afferrare le parole.";
            3: "^Come il canto si interrompe, dalla grottesca assemblea si alza il ripetersi di un unica sillaba: @<<Ia, Ia, Ia, Ia...@>>^Inizia a spirare un vento fetido.";
            4: "^Naradas inizia a salmodiare sullo stesso tema dissonante di prima: @<<Chiave e cancello per il luogo dove dimorano gli dei oscuri, sul loro monte che sorge oltre il deserto, Igg Sotheud, la tua verit@`a ci pervada@>>. Contemporaneamente la donna con il pugnale traccia una leggera incisione sulle spalle della povera ragazza, che geme impotente.";
            5: move sodnigguerth to parent(self);
            "^Naradas continua a salmodiare: @<<Tetro e antico signore che dormi sepolto nella perduta Rjal, sogna e i tuoi sogni siano i nostri sogni, vita ti offriamo per il tuo risveglio@>>. La donna traccia incisioni con il pugnale sul ventre della vittima.^Ti pare di intravedere un'ombra scura che si forma sospesa al centro della caverna.";
            6: "^Il salmodiare di Naradas continua incessante: @<<Signore del vuoto cosmico, sultano del nulla e dell'immensit@`a, Asdoeth che vivi tra i mondi, venga a noi la tua saggezza proibita@>>. La donna incide con la lama il seno di Nilis.^L'ombra scura diventa pi@`u presente, chiaramente visibile. Oscure bestemmie sembrano provenire da essa e la disperazione ti assale.";
            7: "^@<<Ia Ia, Sod Nigguerth@>>, continua Naradas, @<<Oscura bestia, abitatrice dei boschi, madre di mille cuccioli, raggiungici nel mondo dei mortali e domina su noi e su ogni altro essere vivente, portando tra noi le tue tenebre e la tua volont@`a.@>> La donna solleva il pugnale sopra il petto della ragazza.^Quella che era solo un'ombra @`e ora qualcosa di reale e terribile, e occupa tutta la parte alta della caverna.";
            8: "^La donna di colpo affonda il pugnale nel petto di Nilis, squarciando il cuore della povera ragazza. Il portale @`e aperto, adesso la vedi chiaramente. Sod Nigguerth sta varcando le porte di questo mondo e l'orrore @`e troppo grande per essere sopportato.";
            9: NoPicture(); !!! Ma magari qui ci vorrebbe l'immagine di Shubi
            deadflag=1;
            "^L'oscura madre dalla infinita progenie @`e qui adesso, e la sua voce @`e troppo forte per non essere ascoltata. Essa penetra nella tua mente spezzando il tuo pensiero ed il tuo spirito. Tutto @`e lei, tutto appartiene a lei... Ia, Ia, Ia, Ia, Ia, Ia, Ia...";
        }
    ],
    life [;
        "Non @`e una buona idea.";
    ],
  has scenery pluralname animate;
  
Object -> vittima "nilis"
  with name 'ragazza' 'vittima' 'sacrificale' 'nilis' 'cameriera',
    description [;
      print "La povera ragazza @`e distesa sulla pietra, nuda ed incatenata. @`E ";
      if (officianti.count>=7) "ormai priva di vita, uccisa dalla lama del pugnale.";
      if (officianti.count>=4) print "ferita ma @`e ";
      "ancora cosciente, e vedi la paura nei suoi occhi.";
    ],
    before [;
      Look, Examine, AutoCast: ;
      default: "Dovresti avvicinarti, ma non credi sia una buona idea.";
    ],    
    life [;
        "Sarebbe un gesto inutile e pericoloso.";
    ],
  has scenery female proper animate;
  
Object sodnigguerth "Sod Nigguerth"
  with name 'ombra' 'sagoma' 'dea' 'madre' 'oscuro' 'oscura' 'capro' 'sod' 'nigguerth',
    description "Terribile @`e la sua visione. La speranza non esiste pi@`u. Tutto @`e solo disperazione infinita.",
    aura "Percepisci un'aura di totale malvagit@`a, di disperazione, di terrore, di abisso...",
    before [;
      Look, Examine, AutoCast: ;
      default: "Dovresti avvicinarti, ma non credi sia una buona idea.";
    ],    
    life [;
        NoPicture(); ! Anche qui l'immagine di Shubi
        deadflag=1;
        "Ti rivolgi verso l'orribile visione che sai essere l'oscura Sod Nigguerth, e la tua mente ne rimane prigioniera. Il tuo spirito @`e spezzato dalle orribili verit@`a che vieni a conoscere... Niente ha pi@`u senso o speranza... Ia, Ia, Ia, Ia, Ia, Ia...";
    ],
  has scenery female proper animate;  
  
[endscene is;
    ! I due finali
    if (is) print "^Nel crollo imminente aiuti Iarin, ancora troppo debole per farlo da sola, ad alzarsi e, lasciandovi alle spalle il corpo senza vita di Nilis, vi lanciate";
     else print "Abbandonando il corpo ormai senza vita di Iarin, ti lanci";
    print " gi@`u dalla pedana, in una fuga precipitosa per le caverne che stanno crollando attorno a te. Guidando il gruppo di persone che erano prigioniere, ";
    if (is) print "percorrete"; else print "percorri";
    print " cunicoli, larghe caverne, ponti di roccia, fino a che finalmente non trovate un passaggio che conduce all'esterno, sul fianco del vulcano. La vostra fuga precipitosa continua fino alla vasta foresta.^";
    if (is) print "Solo quando finalmente potete fermarvi a riposare, realizzi che, grazie all'immenso coraggio di Iarin, l'orribile dea chiamata Sod Nigguerth @`e sconfitta. Il tuo animo @`e affranto pensando a Nilis, alla povera ragazza che ha perso la vita su quell'orrido altare, ma le prime luci dell'alba portano serenit@`a su questa valle. Al tuo fianco Iarin sorride dolcemente anche se un lieve velo di tristezza riempie i suoi occhi.^";
     else print "Solo quando finalmente puoi fermarti a riposare, realizzi che, grazie all'estremo sacrificio di Iarin, l'orribile dea chiamata Sod Nigguerth @`e sconfitta. Il tuo animo @`e per@`o pieno di tristezza, pensando a quelle due povere ragazze, Iarin e Nilis, che hanno perso la loro vita su quegli orridi altari. E nelle prime luci dell'alba ancora provi orrore sapendo che Iarin @`e morta per tua mano.^";
     waitkey();
     if (is) print "^I giorni successivi passano tranquilli e con tuo stupore devi ammettere che preferisci la compagnia di Vade, degli altri Figli della Valle e soprattutto di Iarin a quella di altre persone, come l'inetto barone Inderus o il corrotto sacerdote Dippin. Certo, il dolore per la morte di Nilis @`e forte, ma pi@`u forte @`e la gioia per lo scampato pericolo. E giunge con tristezza il giorno della tua partenza dalla valle di Nigat.^";
     else print "^Nemmeno la tranquillit@`a dei giorni successivi placa il tuo tormento, nemmeno le parole di Vade che tristemente parla con te a lungo di come questo era necessario per sconfiggere l'orrore; dentro di te continui a credere che forse potevi evitare tutto questo. @`E con sollievo che giunge finalmente il giorno della tua partenza dalla valle di Nigat.^";
     print "Ancora non sai cosa racconterai ai tuoi superiori quando risali in sella a Guilnern. Decidi per@`o di non prendere la strada che conduce fuori dalla valle. Prima vuoi tornare a vedere quella quercia - ora priva di vita - che era il centro del culto dei Figli della Valle, quel culto che ti ha permesso di sconfiggere l'antica dea. ";
    if (is) print "Iarin viene con te, decisa ad accompagnarti fino al momento della tua partenza. ";
     else print "Quasi un silenzioso omaggio per la dolce Iarin.^";
    if (is) print "Sicuro di ritornare ben presto in questi luoghi, ";
     else print "Sicuro che non rimetterai pi@`u piede in questa valle, ";
    print "volgi il muso di Guilnern verso il passo che ti condurr@`a fuori dalla valle e ";
    if (is) print "riprendete il vostro"; else print "riprendi il tuo"; 
    print " cammino. Ma ad un tratto, per un attimo, ";
    if (is) print "scorgete"; else print "scorgi";
    print " delle figure correre per i boschi. Sei sicuro di quello che hai visto, erano Naradas e la donna che con lui guidava il rito dell'apertura del portale. Ma soprattutto ti ha colpito l'espressione completamente vacua dei loro volti, simile a quella di un folle, di un idiota, oppure a quella di quelle strane creature che abitano queste foreste e discendono da coloro che un tempo adoravano l'oscura Sod Nigguerth.^^";
    
    deadflag=2;
    rtrue; 
];

!Array task_scores -> 2 3 1 2 1 2 1 3 2 2 3 3 4 2 3 1 3 2 3 3 1 2 3 2 3 3 3 1 2 2 2 2 5 3 2 2 4 5 5 1 1;

[ PrintTaskName ach;
    ! Obbiettivi
    switch(ach) {
        0: "Hai fatto fuggire la creatura";                     ! 2
        1: "Hai raggiunto il palazzo del barone";               ! 3
        2: "Hai ottenuto la chiave della biblioteca";           ! 1   0
        3: "Hai letto il libro nero";                           ! 2   1
        4: "Sei riuscito a parlare con il fabbro";              ! 1   2
        5: "Hai incontrato Iarin per la prima volta";           ! 2   3
        6: "Hai preso il mazzuolo";                             ! 1   4
        7: "Hai letto la lettera scritta da Dippin";            ! 3   5
        8: "Hai attraversato il fiume";                         ! 2   6
        9: "Hai letto il diario dello stregone";                ! 2
       10: "Hai trovato la pietra";                             ! 3   7
       11: "Hai assistito al rito dei Figli della Valle";       ! 3   8
       12: "Hai raggiunto il tempio sotterraneo";               ! 4   9
       13: "Hai toccato la sfera";                              ! 2  10
       14: "Sei passato attraverso la seconda quercia";         ! 3  11
       15: "Hai riempito la vasca";                             ! 1  12 
       16: "Ti sei purificato nella vasca";                     ! 3
       17: "Hai raggiunto il tempio druidico";                  ! 2
       18: "Hai letto il libro nel tempio druidico";            ! 3  13
       19: "Hai incontrato Iarin nella radura";                 ! 3
       20: "Hai assistito al rito delle creature subumane";     ! 1  14
       21: "Sei rientrato a palazzo per la notte";              ! 2
       22: "Ti sei risvegliato la mattina dopo";                ! 3
       23: "Hai portato Iarin nel tempio sotterraneo";          ! 2
       24: "Iarin si @`e purificata nella vasca";               ! 3
       25: "Iarin ha aperto la nicchia della fiala";            ! 3
       26: "Sei sceso nelle miniere";                           ! 3  15
       27: "Sei uscito per la via secondaria dalle miniere";    ! 1
       28: "Hai visto sparire gli abitanti del villaggio";      ! 2
       29: "Hai trovato la mappa delle miniere";                ! 2  16
       30: "Hai letto il libro rosso";                          ! 2
       31: "Hai raccolto l'argilla";                            ! 2  17
       32: "Hai letto le iscrizioni sulla pietra";              ! 5  18
       33: "Hai attraversato le miniere";                       ! 3  19
       34: "Hai fatto rotolare il macigno";                     ! 2  20
       35: "Hai attaccato l'insetto mostruoso";                 ! 2
       36: "Sei saltato dal ponte di roccia";                   ! 4  21
       37: "Hai ricacciato indietro l'antica Sod Nigguerth";    ! 5  22
       38: "Hai salvato Iarin";                                 ! 5  23
       39: "Sei riuscito a baciare Iarin";                      ! 1  24
       40: "Sei riuscito a baciare Iarin nella vasca";          ! 1
    }
];

[ remark i;
    ! Commenti
    if (i<=lastremark) rfalse;
    lastremark=i;
    style underline;
    print "^";
    switch(i) {
      1: print "Ancora non riesci a credere a quello che @`e accaduto la scorsa notte. Probabilmente ti sei lasciato suggestionare, anche se ci@`o non @`e da te, e hai creduto di vedere cose che in realt@`a non esistevano. Ma adesso l'aria @`e frizzante e il cielo @`e terso. E tu hai del lavoro da svolgere, quindi @`e meglio cominciare a darsi da fare.";
      2: print "Veramente interessante. Certo, sembra proprio che tutto ci@`o sia completamente irrilevante per quanto riguarda il tuo incarico. Per@`o sei curioso, come al tuo solito, e vorresti avere il tempo di scoprire cosa @`e successo a questo povero stregone.";
      3: print "Certo, questi ~Figli della Valle~ sembrano pacifici e innocui, incapaci di far del male a qualcuno, ma nonostante ci@`o @`e tuo dovere riferire all'inquisizione quello che hai scoperto. Ne va della tua seriet@`a professionale. Ma prima di tutto devi cercare di saperne di pi@`u, e soprattutto scoprire cosa nasconde quella strana quercia e come ha fatto la ragazza a sparire nel nulla.";
      4: print "A quanto pare i tuoi sono i primi occhi che si posano su queste pagine da secoli. Ti chiedi se c'@`e un motivo, in questo. Certo, tu non credi a profezie e destini segnati, ma nondimeno la coincidenza @`e curiosa. Sarebbe veramente terribile se quello che @`e accaduto allora si ripetesse. Sarebbe immensamente pi@`u grave dei pacifici riti dei ~Figli della Valle~. Ti chiedi anche quale sia l'oggetto di cui il diario parla verso la fine. Inoltre, adesso che ci pensi, domani ci sar@`a la luna piena...";
      5: print "Un incubo orribile... cos@`i reale... Vorresti non esserti mai addormentato ieri sera. Ti chiedi se abbia un significato. Deve averlo, non hai mai avuto sogni cos@`i vividi. Qualcosa di marcio sta accadendo attorno a te.";
      6: print "Stanno accadendo troppe cose terribili. I tuoi sogni, l'eruzione del monte Kalnam, queste inspiegabili sparizioni... Lo senti, stanotte accadr@`a qualcosa. E se il tuo istinto non ti inganna, ci deve essere una persona responsabile di tutto. Ma chi?";
      7: print "Naradas... Il sempre disponibile ed efficiente Naradas... Ecco chi sta tirando i fili di tutta questa orribile faccenda. Ma cosa puoi fare per trovarlo e impedirgli di portare a termine il suo disegno?";
      8: print "A quanto pare devi ringraziare i costruttori di questa pietra. Come hai letto nel libro di Carnissar, la pietra riporta anche le istruzioni per impedire l'evocazione. Certo, se hai ben interpretato le parole, il prezzo @`e alto, forse troppo alto. Ma se l'evocazione viene portata a compimento, niente avr@`a pi@`u importanza...";
      9: print "Dunque questo @`e il luogo che cercavate, e a quanto pare siete arrivati giusto in tempo. Ora tutto @`e nelle tue mani, e in quelle di Iarin.";
    }
    style roman;
    "^";
];