!----------------------------------------------------------------------------
!********************************* MISCELLANOUS OR UNCATEGORIZED MESSAGES #2
!----------------------------------------------------------------------------

routine PrintText15(val1,val2)
{
    select val1

    case 1 {
        !Responses when trying to get the girl's attention.
        select val2

        case 1 {
            !Usage: (15,1,1)
            !Player is "talking" to the girl, who hasn't noticed him.
            !This also goes for trying to "show" things to the girl.
            "With her back turned, she takes no notice. Tap... tap...
            tap goes her hand against the tree trunk."
        }
    }

    case 2 {
        !Messages dealing with the parser/game itself. System messages.
        select val2
        case 1 {
            !Usage: (15,2,1)
            "That isn't supported by GLK versions of the Hugo
            interpreter. Sorry."
        }
        case 2 {
            !Usage: (15,2,2)
            print "You are already using the \""; word[2];
            print "\" "; verbword; "."
        }
        case 3 {
            !Usage: (15,2,3)
            print "Switching to the \""; word[2];
            print "\" "; VerbWord; "."
        }
        case 4 {
            !Usage: (15,2,4)
            "You are already using brief descriptions."
        }
        case 5 {
            !Usage: (15,2,5)
            "You are already using verbose descriptions."
        }
        case 6 {
            !Usage: (15,2,6)
            !Confirmation, before switching to verbose descriptions.
            "You are about to switch to \"verbose\" descriptions. If you
            are apt to skim or skip, this may make it more difficult to
            notice events or differences that would otherwise be obvious
            as you return to prior locations. Switch to verbose mode? >";
        }
        case 7 {
            !Usage: (15,2,7)
            "You can type BRIEF to use brief descriptions again."
        }
        case 8 {
            !Usage: (15,2,8) - tell the player which theme we are using.
            !Begin with space, because when it's printed, it's a
            !continue from 15,2,9 version (listing the themes).
            " You are currently using the ";
            if (GAME_PRINTSTYLE = 1) {
                "\"default\" ";
            } else {
                "\"custom\" ";
            }
            print verbword; "."
        }
        case 9 {
            !Usage: (15,2,9) - tell the player which themes are avail.
            print "You can use either the \"custom\" "; verbword;
            print " (recommended), or the \"default\" "; verbword;
            " (uses your Hugo settings).";
        }
        case 10 {
            !Usage: (15,2,10) - no such theme exists.
            print "That's not a valid "; verbword; ". ";
            PrintMessage(15,val1,9) !Print the valid ones.
            print newline !And then a linefeed. We're done.
        }
        case 11 {
            !Usage: (15,2,11) - cheat commands are not enabled.
            print "Sorry. Cheat commands have not been enabled."
        }
        case 12 {
            !Usage: (15,2,12) - cheat commands already enabled.
            print "Cheat commands are already enabled."
        }
        case 13,14 {
            !Usage: (15,2,13/14) - cheat commands are turned on/off.
            print "Done. Cheat commands are now ";
            if (val2=13): "enabled."
            else: "disabled."
        }
        case 15 {
            !Usage: (15,2,15) - Trying to skip backwards - earlier chapter.
            print "You are already ahead of that chapter."
        }
        case 16 {
            !Usage: (15,2,16) - Trying to skip backwards - the same chapter.
            print "You are already in that chapter."
        }
        case 17 {
            !Usage: (15,2,17) - Wrong type of item to "cheat get".
            print "You can't cheat-get "; The(object); ". That's of
            an object type that can't be carried."
        }
        case 18 {
            !Usage: (15,2,18) - We did a cheat-get on an object.
            print "You now have "; The(object); "."
        }
        case 19 {
            !Usage: (15,2,19) - Trying to see walkthrough after IFComp.
            "An in-game walkthrough is not available in this version of
            Tales of the Traveling Swordsman. To request it, please email ";
            print "si"; "dne"; "yme"; "rk"; "@h"; "otm"; "ail."; "com, and
            be sure to say that you need the Swordsman walkthrough.\n"
            "The walkthrough is also available at the TTS homepage:\n"
            print "\_\_\_http://www.s"; "idn"; "eyme"; "rk.";
            "com/swordsman.shtml\n"
            "There, you will also find the latest version of the game."
        }
        case 20 {
            !Usage: (15,2,20) - The endgame options.
			"(R)ESTART, R(E)STORE, (U)NDO, or (Q)UIT? ";
        }
    }

    case 3 {
        !Usage: (15,3,dir)
        !Following the NPC to a different room (val2 = direction).
        print "(following "; object.pronouns #2;
        select val2
        case u_obj: " upward)"
        case d_obj: " downward)"
        case else: print " to the "; val2.name; ")"
    }

    case 4 {
        !Reasons why we might not be able to draw the sword.
        select val2

        case 1 {
            !Usage: (15,4,1) - We're on mill steps, and blades moving.
            if (steps.misc #1) {
                !We already saw the warning, so give a shorter one now.
                "With the sail arms turning, it would be too dangerous to
                draw your sword now."
            } else {
                !Not yet seen this message
                "You are perched high up the side of the windmill, between
                the wall and the spinning sail arms. Granted, they don't
                spin fast, but they're large and dangerous nonetheless. It
                would be too risky to draw your sword now. One slip, and
                you might break an arm, or worse, be thrown off by a blade."
            }
        }
    }

    case 5 {
        !Player is attempting (or succeeding) to "eat" something.
        select val2
        case apple {
            !Usage: (15,5,obj)
            if (val2.misc #1) {
                "Good heavens, no. The first bite was bad enough."
            } else {
                "You clean dirt from the apple, then take a bite.
                It's bad. As perfectly appealing as it looks, the
                taste is another matter entirely."
            }
        }
    }
    
    case 6 {
        !Custom LOCKING and CLOSING messages.
        select val2
        case mill_door {
            !Usage: (15,6,obj)
            "You place the rusty lock back on the mill door's latch."
        }
    }

    case 7 {
        !Responses when trying to REST or SLEEP.
        select val2
        case 1 {
            !Usage: (15,7,1)
            ! I don't want to say "You don't feel particularly tired"
            ! because I think that's probably a default in other games.
            ! But this means pretty much the same thing.
            if (player = swordsman) {
                print "If it's ";
                if (VerbWord = "nap"): "a nap";                
                else: print VerbWord;
                " you want, you might have
                stayed back in Homesdale a while longer."
            } else {
                "You aren't tired." !For the motherly maiden.
            }
        }
        case 2 {
            !Usage: (15,7,2)
            print CThe(object);
            print MatchPlural(object,"doesn't", "don't");
            " seem like a particularly comfortably place to ";
            print VerbWord; "."
        }
        case clearing {
            !Usage: (15,7,obj)
            print "The clearing is an ideal place to "; VerbWord; ", ";
            "but not while so much of the day remains ahead of you."
        }
        case simple_bed {
            !Usage: (15,7,obj)
            "From appearances, not even the captain uses this bed."
        }
    }    
    
    case 8 {
        !Usage: (15,8)

        ! Pick a random hut in the village, and enter it.
        ! This is also a way (one way?) for the player to obtain the burlap
        ! sack, if they left it behind in a prior chapter. In order to find
        ! it, though, the player must have entered Part 3 without the sack
        ! OR the pipe, because both can be used to solve the pressure-plate
        ! puzzle. The pipe is too obvious, so if the player needs to get a
        ! thing to solve the puzzle, we'll go for the sack instead. Also, I
        ! ordinarily would try to avoid object logic in the PrintMessage,
        ! but here it'll be easier to just do it. Plus, IFComp deadline is
        ! now just ten days away. I'll have to go for speed, not elegance.

        "You enter one of the huts.\n" !Get the message started.

        if (not player.misc #1) and (not player.misc #2) {
            !The player entered this chapter with *neither* of the items.
            "A few trinkets have been left behind; nothing of interest,
            really. As you turn to leave, though, you do notice something.
            A strangely familiar burlap sack has been left behind by the
            hut's missing resident.\n"
            "You pick it up.\n"
            !Basically, so player can't drop it, come back, get it again.
            player.misc #1 = true !Flag that have obtained it in this part.
            ! On the off chance that the player put something inside and
            ! left it behind in a prior chapter, remove all its contents.
            while Child(sack) {
                remove Child(sack) !Get rid of the contents.
            }
            ! And then give the sack to the player
            Acquire(player, sack) !We have it back!
        } else {
            rnd = random(8) !Pick a random hut to enter.
            select rnd
            case 1 {
                "Simple furnishings have been left behind by the hut's
                residents. Hand-crafted artwork adorns the walls. You see
                nothing else of interest.\n"
            }
            case 2 {
                "Patches of sky are visible through gaping holes in a roof
                that is in obvious ill repair. The hut doesn't seem
                livable now.\n"
            }
            case 3 {
                "A counter and shelves make this larger hut seem perfectly
                suited to the sale of simple merchandise. A few trinkets
                remain, but the store is otherwise empty.\n"
            }
            case 4 {
                "An assortment of useless junk is stacked along one wall.
                None of it seems important.\n"
            }
            case 5 {
                "The residents of this hut probably had children. Markings
                of coal and chalk adorn the walls. None of it seems
                important.\n"
            }
            case 6 {
                "It looks as though nobody lived here, even before the
                village was abandoned. This hut is entirely empty.\n"
            }
            case 7 {
                "Benches and tables host an assortment of fishing tackle
                and other items in this small hut. You can make no use
                of any of it.\n"
            }
            case 8 {
                "A bed of straw and a broken table are about all of note
                in this hut. Neither seem important.\n"
            }
        }
        
        "You leave the hut."
        !The player might get confused if they don't read closely, thinking
        ! that they really are still inside the hut. So, let's re-show the
        ! short version of the room description.
        DescribePlace(location, false)
    }
    
    case 9 {
        !Usage: (15,9,obj) - The (door) has no locking mechanism.
        print CThe(val2); " has no conspicuous locking mechanism."
    }
    
    case 10 {
        ! Messages when trying to "talk" to the tyrant. May also be used
        ! when trying to interact with him in other ways. Give/show, maybe?
        select val2
        case 1 {
            !Usage: (15,10,1)
            rnd = random(4)
            select rnd
            case 1 {
                "The tyrant doesn't know what you're trying to do, but
                he seems to dislike it."
            }
            case 2 {
                "He tilts his head in confusion."
            }
            case 3 {
                "The tyrant sneers, without really understanding you."
            }
            case 4 {
                "He seems unwillingly to do anything but fight."
            }
        }
    }
    
    case 11 {
        !Trying to frighten someone.
        !Usage: (15,11,obj)
        print "How exactly do you hope to "; VerbWord; " "; The(val2); "?"
    }
}