!\---------------------------------------------------------------------------

	GB.G
	Grammar for Guilty Bastards by Kent Tessman (c) 1998

---------------------------------------------------------------------------\!

!----------------------------------------------------------------------------
! New xverbs:

xverb "version", "ver"
	*						Version

#ifset INCLUDE_HELP
xverb "hint", "hints"
	*						DoHint
#endif

#ifset INCLUDE_FOOTNOTES
xverb "footnote", "note"
	*                                               DoFootnote
	* number                                        DoFootnote

xverb "help"
	* "footnotes"					DoFootnoteMode

xverb "footnotes", "notes"
	*						DoFootnoteMode
	* "always"					DoFootnoteMode
	* "on"/"normal"					DoFootnoteMode
	* "off"/"never"					DoFootnoteMode
#endif

! Okay, so the swearing syntax is kinda flexible--hopefully people won't
! be checking too hard to make sure it's "grammatically correct"
xverb "fuck", "shit", "damn", "dammit", "hell", "sod", "piss"
	*						DoSwear
	* "you"/"it"/"off"				DoSwear
	* object					DoSwear
	
xverb "xyzzy"
	*						DoXyzzy


!----------------------------------------------------------------------------
! New verbs:

verb "allo", "salut"	! for Johnny LaFleure
	*						DoHello
	! because a comma becomes "~and":
	* "~and" object					DoHello
	* object					DoHello

verb "get"
	* "in"                                          DoGetIn

verb "drive"
	*                                               DoVague
	* object                                        DoDriveTo
	* "to" anything                                 DoDriveTo
	* "back" "to" anything                          DoDriveTo
	
verb "hide"
	*						DoHide
	* "behind"/"in"/"inside"/"on"/"under"/ \
		"beneath"/"beside" object		DoHide
	* object "in"/"inside" container		DoPutIn
	* object "on" platform				DoPutIn
	
verb "knock", "rap"
	*						DoVague
	* "on" object					DoKnock
	* object					DoKnock

verb "shoot"
	*						DoVague
	* object					DoShoot
	
verb "frisk"
	*						DoVague
	* object					DoSearch
	
verb "arrest"
	*						DoVague
	* object					DoArrest
	
verb "come"	! i.e., "come with me" = "follow me"
	* "with" object					DoFollow
	
! For "Billy, stop", "tell Billy to stop following me", etc.
verb "stop"
	*						DoStop
verb "stop", "quit", "cease"
	* "following"					DoStop
	* "following" "me"				DoStop
	* "following" object				DoStop
	
#ifset INCLUDE_DUFFY
verb "analyze", "analyse", "dust", "fingerprint"
	*						DoVague
	* object					DoAnalyze
	* object "for" "fingerprints"			DoAnalyze

verb "send"
	*						DoVague
	* object "to" "lab"/"laboratory"		DoAnalyze
	
verb "take"
	* object "to" "lab"/"laboratory"		DoAnalyze

verb "call", "summon", "conjure"
	*						DoVague
	* anything					DoSummon
#endif


!----------------------------------------------------------------------------
! New verbs for certain sections:

#ifset PART1
! For the receptionist at Rocket Pictures:
verb "ask"
	* "for" anything				DoAskQuestion
	* living "for" anything				DoAsk

! For Cindy Painter's TV:
verb "change", "switch"
	* (tvchannel)					WhatsOnTV

! For pencil and pad in dumpster:
verb "rub"
	*						DoVague
	* object "on"/"against" xobject			DoRubOn
	* object "with" xobject				DoRubWith
	* object					DoRubOn

verb "shade", "scratch"
	*						DoVague
	* object "with" xobject				DoRubWith
	* object					DoRubOn
	
verb "draw", "sketch", "doodle"
	*						DoVague
	* "on" object					DoRubOn
	* "on" object "with"/"using" xobject		DoRubWith

! For watch in dumpster:
verb "set"
	*						DoVague
	* (watch)					DoSetWatch
	* (watch) "to" number				DoSetWatch
#endif	! ifset PART1

#ifset PART2
verb "swim"
	* "in" (ocean)					DoSwim
	* "to" anything					DoSwim

verb "ring"
	*						DoVague
	* (doorbell)					DoPush

! For the string and fire alarm:
verb "thread", "slip", "put", "feed", "push"
	*						DoVague
	* object "through"/"into"/"in" (grill)		DoThread

verb "tie", "attach", "loop", "hook"
	*						DoVague
	* object					DoAttachObject
	* object "to"/"around"/"on"/"onto" xobject	DoAttachObject
	* object "over" xobject				DoAttachObject

! For Chuck Bixby's desk blotter:
verb "lift", "raise"
	*						DoVague
	* object					DoMove

! For safecracking:
verb "turn", "spin", "rotate", "set"
	* object					DoTurnDial
	* object "to" number				DoTurnDial
#endif	! ifset PART2