!\---------------------------------------------------------------------------
	CHUCK.HUG
	Chuck Bixby's character
	for Guilty Bastards by Kent Tessman (c) 1998

	(Included by "gb2.hug")
---------------------------------------------------------------------------\!

character chuck "Chuck"
{
	inherits NPC
	in chucksoffice
	nouns "chuck", "bixby"
	adjective "chuck"
	parse_rank 1		! prefer to other objects
	long_desc
		"Chuck is in his late thirties, graying hair clipped short,
		hanging onto cool for as long as he can.  He regards you for
		the most part with a bemused raised eyebrow--but then you
		get the impression he regards pretty much everyone this way."
	short_desc
	{
		if location = chucksoffice
			"Chuck Bixby is sitting at his desk."
		else
			"Chuck Bixby is standing around, like everyone else,
			waiting for the fire alarm to stop ringing."
	}
	graphic IMAGES1, "chuck"
	lying_about_holly true
	knows_about_photos false
	knows_about_screeningreport false
	after
	{

!------------------
! DoAsk responses:
!------------------

		object DoAsk
		{
			select xobject
			case cindy
			{
				if billy in location
					"Chuck looks at Billy, then back at
you.  \"He's probably told you something like I had something for her, like
I had a crush on her.  Well, it wasn't like that.  I \Idid\i care about her 
a lot, more than this jerk apparently did,\" Chuck says, nodding at Billy.  \
\"And maybe she didn't feel the same way.  But I would never do anything to 
hurt her.  Unlike some people in this room.\""
				else
					"\"Cindy?  I thought the world of
her,\" Chuck says.  \"I still do.  I was as proud of her as of anybody I've
ever represented.  She was going to go far--and she was such a good person,
too.\""
			}
			
			case murder
				"\"You know, it's so terrible, so goddamned
awful, I can barely believe it happened,\" Chuck says.  \"They'd better
find whoever did it...\""
			
			case billy
			{
				if billy in location
					"Chuck speaks to you in a low
					voice:  ";
				"\"Look,\" he says, \"I never really thought
that much of him, not that it matters at all.\""
			}
			
			case milt
				"\"Milt Walker is a tough guy, a good guy,
an honest guy, a bastard of a tough negotiator,\" Chuck tells you.  \"You 
ask around this town, you'll get all sorts of opinions on what people
think of Milt Walker.\""
			
			case holly
			{
				if self.lying_about_holly
					"Chuck shrugs.  \"She's a movie 
star.  I don't know her.  I probably don't know much more than you.\""
				else
				{
					"\"She's a movie star!  And I've got
pictures of her naked!\" he exclaims.  \"It's a big responsibility having
those pictures, you know.  And not nearly as good a deal as you think--I 
can't even put them on the Internet.  Man, those could make her look bad.\"";
					if billy in location
						"  Chuck looks at Billy.  \
						\"No offense,\" he says."
					print newline
				}
			}
			
			case stuart
				"\"He was the studio guy in charge of
Cindy's movie, but I've really only talked to him a couple of times,\" Chuck
tells you."
			
#ifset INCLUDE_OTHER_ACTORS
			case johnny
				"\"I was almost his agent once,\" Chuck tells
you.  \"A few years ago, he'd done about nine lousy movies in a row and no
one in town would even talk to him.  So we went out to dinner and he tried to
sleep with my wife and I ended up punching him in the eye and, hey, today I'm
not his agent.\""
#endif
			
			case photos
			{
				if not self.knows_about_photos
					"\"What?  What photos?\" Chuck
					asks.  Seems kinda edgy, though."
				else
				{
					if billy in location
						"Chuck looks uneasily at
						Billy before answering.  ";
					"\"She asked me to keep them,\" Chuck 
tells you.  \"Cindy--she asked me.  I don't know where she got them, but she 
asked me to keep them and not tell anybody.  I don't know if she was 
embarrassed or what, but she didn't want anybody to know.  You didn't know
Cindy, but believe me, you wouldn't have expected her to react like that.   \
She seemed sad as much as every thing.  I guess...I guess she really loved
that jerk.\"";
					if billy in location
						"  Again glancing at Billy."
					print newline
					
					if foldednote in nothing
					{
						"\nChuck produces a folded
note and hands it to you.  \"She said this came with the photos.\""
						if not Acquire(player, 
							foldednote)
						{
						  "\n(You're carrying too
						  much to take the note.)"
						}
					}
					print newline
				}
			}
			
			case negatives
				"\"You found those in Stuart Fina's trunk?  \
				Damn, I never did like that guy...\""

			case cindysmovie
				"\"Well, I've never seen it--not even a
test screening,\" Chuck says.  \"The studio's really, really close-lipped
about it.  What, do I think she would've moved on, got a new agent?  Maybe.\"  \
Chuck shrugs.  \"These things happen.  You lose clients, you get new clients.  \
You can't let it really affect you one way or the other.\"  A beat.  \
\"Waitasec--you weren't really asking about me, were you?\""

			case screeningreport
			{
				if self.knows_about_screeningreport
					"\"I don't get it,\" Chuck says.  \"I
					had no idea it was screening that
					badly.\""
				else
					"\"I've never seen anything like
					that.\""
			}

			case sinatras
			{
				if not self.knows_about_photos
					"\"I have no idea what you're talking
					about.  What a crazy idea,\" he 
					says.  But he sounds kinda edgy."
				else
					"\"What?  What do you want to know?  \
They're fakes, all right?  Fake signed Sinatras.  Look, I know it's illegal--\
can you plead temporary insanity to fraud?  Temporary insanity to bootlegging 
signed Sinatra albums?\" he asks.  He finishes by muttering to himself:  \
\"Stupid...stupid...\""
			}

			case computer
			{
				! If the player has crashed it
				if computer is special
					"\"I don't know.  Looks like it
crashed.  Don't ask me--these things scare the hell out me.\""
				else
					"\"As long as it minds its business
and I mind mine, we seem to get along all right.\""
			}
			
			case torncard
				"\"Yeah, that's mine.\""
				
			case safe
			{
				if not self.knows_about_photos
					"\"That's a good safe,\" Chuck tells
					you.  \"Paid top dollar for it.\""
				else
					"\"Well, guess I got ripped off,
seeing as it was so easy for you to bust in,\" Chuck complains.  \"But
maybe I shouldn't have kept that combination under the desk blotter...\""
			}
			
			case foldednote
				"\"Cindy gave it to me along with the
				photos.  I don't know anything else about
				it.\""

			case else
				return false
		}

!-------------------
! DoTell responses:
!-------------------

		object DoTell
		{
			select xobject
			case photos, sinatras
			{
				if not self.knows_about_photos
					"\"Look, I have no idea what you're
					talking about,\" he says."
				else
				{
					CThe(self)
					" already knows all about ";
					print The(xobject); "."
				}
			}
			
			case screeningreport
			{
				if self.knows_about_screeningreport
					"\"I know--you showed me,\" he says."
				else
					"\"\IWhat?\i  I don't believe you,\"
					Chuck says."
			}
				
			case else
				return false
		}

!-------------------
! DoShow responses:
!-------------------

		xobject DoShow
		{
			select object
			case photos, sinatras
			{
				if not self.knows_about_photos
				{
					"Chuck is flabbergasted.  \"What...?  \
How...?   How did you...?  Did you--?\"  He stops himself from sputtering any
further.  Then:  "
					PrintFootnote(23)
				}
				"\n\"I guess you've found, well...\"  He raises 
his eyebrows.  \"I guess you've found just about everything.\""
				self.lying_about_holly = false
				self.knows_about_photos = true
			}
			
			case screeningreport
			{
				if self.knows_about_screeningreport
					"\"I know--you already showed me.\""
				else
				{
					self.knows_about_screeningreport = true
					"\"Chuck's eyes go wide.  ";
					Perform(&DoAsk, chuck, object)
				}
			}
			
			! Same as asking:
			case torncard, negatives
				Perform(&DoAsk, self, object)
				
			case else
				return false
		}
	}
}