synonyms
	n = north.
	s = south.
	e = east.
	w = west.
	--ne = northeast.
	--nw = northwest.
	--se = southeast.
	--sw = southwest.
	--u = up.
	--d = down.

--location Directions
--exit north, south, east, west, northeast, northwest, southeast, southwest,
--	up, down to Directions.
--end location.

location Nowhere
description
	"You shouldn't be here. Please submit a bug report to your
	local deity in charge of space-time anomalies."
end location.

syntax
	'use' = 'use' (dobj).
	use_on = 'use' (dobj) 'on' (iobj).
	'look' = 'use' 'eyes'.
	examine = 'use' 'eyes' 'on' (dobj)
		where dobj isa object or actor
			else "You can't examine that sort of thing."
	--help = 'use' 'help'.
	take_or_drop = 'use' 'hand' 'on' (dobj)*.

object attributes
	not needing_dobj.
	not needing_iobj.
	not moved.
	not ignition_source.

verb 'use' does
	if dobj is needing_iobj then
		"You'll have to say what you want to use that on."
	elsif dobj is needing_dobj then
		"There's no obvious way to use that on anything, but
		you might be able to use something else on it."
	else
		"You don't need to use that for anything."
	end if.
end verb.

verb 'use_on' does
	"There's no obvious way to use the $1 on the $2."
end verb.

verb 'look' does
	look.
end verb.

verb examine does
	"You learn nothing useful."
end verb.

--verb help does
--	"This game has only one verb, and that's USE. You'll have to
--	think of a way of phrasing whatever you want to do using that.
--	Some obvious examples:$n
--	$tUSE BUTTON to push it.$n
--	$tUSE KNIFE ON BREAD to cut it.$n
--	Some less obvious examples:$n
--	$tUSE EYES to look around you.$n
--	$tUSE EYES ON PAINTING to examine it.$n
--	$tUSE HAND ON EMERALD to take or drop it."
--end verb.

object attributes
	not takeable.
	
verb take_or_drop
	check dobj is takeable
		else "That's not something you can pick up or put down."
	does
		make dobj moved.
		if dobj not in inventory then
			locate dobj in inventory.
			"Taken."
		else
			locate dobj at hero.
			"Dropped."
		end if.
end verb.

location FrontDoorstep
	name Front Doorstep
	description
		if front_door is not open then
			"$tThe architecture is no less disturbing from here at the
			top of the front doorsteps. 
			The angles of the frame around the large, solid door wrench the eyes, and the
			twisted carvings on its panels threaten your sanity.
			$iA large brass doorknob in the likeness of a cheetah's pancreas
			defies you to touch it.
			$p"
		else
			"$iThe front door stands open to the north. A forbidding dimness
			lies beyond.
			$p"
		end if.
	--exit north to Hallway
	--	check front_door is open
	--		else "A small problem: the door is closed."
	--end exit.
	--exit east, west, south, southeast, southwest to Nowhere
	--	check "Running aways is undoubtedly the wisest, and safest, course
	--		of action. But since when did an adventurer achieve anything
	--		by being prudent?"
	--end exit.
end location.

object front_door
	name large solid front north door
	name north
	at FrontDoorstep
	is not open.
	description
	verb examine does only
		"Don't look at it. You'll hurt your neurons."
	end verb.
	verb 'use'
		check front_door is open else
			"It's closed. Try using the doorknob first."
		does only
			locate hero at Hallway.
	end verb.
end object.

object front_doorsteps
	name front steps
	name front doorsteps
	at FrontDoorstep
	description
	verb 'use' does only
		"Running aways is undoubtedly the wisest, and safest, course
		of action. But since when did an adventurer achieve anything
		by being prudent?"
	end verb.
end object.

object front_doorknob
	name doorknob
	name knob
	at FrontDoorstep
	description
	verb examine does only
		"Whoever made it had a veterinarian's knowledge of
		animal anatomy combined with the artistic talent of a master sculptor. 
		You can almost imagine it squishing were you to take hold of it."
	end verb.
	verb 'use' does only
		if front_door is not open then
			"It turns, and the door creaks open. A forbidding dimness lies
			beyond. Go north if you dare."
			make front_door open.
		else
			"The door is already open."
		end if.
	end verb.
end object.

object interior_door
	description
		"All the interior doors in the house are the same,
		good solid oak, darkly varnished, with elaborate
		mouldings around the wood panels. So elaborate, in
		fact, that there's only about a square inch of panel
		left in the middle."
end object.

$include 'Hero.alan'
$include 'Hallway.alan'
$include 'DrawingRoom.alan'
$include 'DiningRoom.alan'
$include 'Kitchen.alan'
$include 'Upstairs.alan'
$include 'Library.alan'
$include 'Bedroom.alan'
$include 'Study.alan'
$include 'Chapel.alan'
$include 'Crypt.alan'

start at FrontDoorstep.
--start at Bedroom.
--start at Hallway.
--start at DrawingRoom.
--start at Kitchen.
--start at Landing.
--start at Crypt.
	--locate match in inventory. --
	--locate candle in inventory. --
	--locate emerald in inventory. --
	--locate note in inventory. --
	"Even from afar, the mansion looks forbidding. The work of Klaus
	Artur Schlobbe, otherwise known as the Mad Architect, it has the look
	of a luntatic asylum designed by the inmates. No one knows what lies
	inside -- no one has had the courage to set foot inside the door since
	Schlobbe's death. Some rumors say it hides a fortune in gold and gems;
	others hint at dark deeds and satanic rituals performed within, and say
	that demonic powers still haunt its halls. Perhaps you will be the one
	to discover the truth... if you dare...$n
	$n
	---------------------------------------------------$n
	No Earthly Use$n
	An Interactive Monoverbal Experiment$n
	perpetrated by Greg Ewing for the UseComp$n
	---------------------------------------------------$n
	$n
	(Warning: This game has an unusual command structure. If you're having
	trouble, type USE INSTRUCTIONS.)"
	visits 255.
	use script 1 for shade.