location Study
	description
		"$tThis small room is furnished with a writing desk and
		a chair. The desk has a drawer in it"
		if desk is open then
			"$$, which is open"
		end if.
		"$$.
		$iThe only exit is to the west."
		if desk is open then
			"$p"
			list desk.
		end if.
		"$p"
	does
		if piano not here and piano is possessed then
			schedule piano_to_study after 0.
		end if.
	--exit west to HallwayNorth.
end location.

object Study_west_door
	name west door
	name west
	at Study
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at HallwayNorth.
	end verb.
end object.

object desk
	name writing desk
	name drawer
	at Study
	container
		header "The drawer contains"
		else "The drawer is empty."
	is not open.
	description
	verb examine does only
		"An ink-stained leather writing pad covers the surface,
		and a wooden stand holds a few ancient pens and some
		dried-out ink pots. The single drawer is"
		if desk is open then 
			"open.$p"
			list desk.
		else 
			"closed." 
		end if.
	end verb.
	verb 'use' does only
		if piano here and piano is possessed then
			"The piano growls menacingly at you, and won't let
			you near the desk."
		else
			if desk is not open then
				"You open the drawer."
				make desk open.
				empty closed_desk in desk.
				list desk.
			else
				"You close the drawer."
				make desk not open.
				empty desk in closed_desk.
			end if.
		end if.
	end verb.
end object.

object closed_desk
	container
end object.

object key
	name small brass key
	in closed_desk
	is takeable.
	is needing_iobj.
	verb examine does only
		"It's a small key, of the sort that might open a
		drawer or padlock."
	end verb.
	verb use_on does only
		if iobj = chest then
			"Success! The padlock clicks open, allowing you to
			lift the lid."
			make chest open.
			empty closed_chest in chest.
			list chest.
		else
			"The key doesn't seem to be able to open that."
		end if.
	end verb.
end object.

event piano_to_study
	"$p$tYou hear the squeaking of tiny wheels, coming closer.
	Suddenly the piano rolls into the room, apparently under it's
	own power, and positions itself between you and the desk.
	$iThe piano makes a rumbling sound with its low strings
	that sounds ominously like the growling of a wild animal."
	locate piano at study.
	make study not seen_without_piano.
end event.