location Library
	description
		"$tThree huge bookcases fill the walls of this room.
		The first one is filled with books on architecture,
		and the second is crammed with musical scores. The
		third one seems to contain works on various occult
		subjects.
		$iThe exit from the library is to the west.
		$p"
	--exit west to Hallway.
end location.

object Library_west_door
	name west door
	name west
	at Library
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at Hallway.
	end verb.
end object.

object bookcase1
	name first bookcase
	name bookcases
	at Library
	description
	verb examine does only
		"Old Schlobbe certainly took his architecture very
		seriously. There are treatises here on the architectural
		styles of every time an culture you could imagine, as
		well as biographies of many famous architects."
	end verb.
end object.

object bookcase2
	name second bookcase
	name bookcases
	at Library
	description
	verb examine does only
		"Next to architecture, Schlobbe's second greatest passion
		was classical music. All the great composers are represented
		here -- Bach, Mozart, Beethoven, Chopin, Tchaikovsky,
		Rachmanninoff, and many, many more."
	end verb.
end object.

object bookcase3
	name third bookcase
	name bookcases
	at Library
	description
	verb examine does only
		"Schlobbe's interest in architecture and music was well
		known, but nobody seems to have suspected that he was into
		black magic as well. Most of the books here are written
		in some obscure ancient language whose alphabet you don't
		even recognise. The ones in English have titles that
		you'd rather not think about."
	end verb.
end object.

object coffee_table
	name low coffee table
	name book
	name books
	at Library
	description
		"$pThree books are open on a low table in one corner of the
		room."
	verb examine does only
		"One of the books on the table is a biography of the well-known
		architect Sir Christopher Wren. Another is titled 'Exhumation -
		A Hobbyists's Guide'. The remaining one is written in a strange,
		unfamiliar script.
		$iSlipped into the third book is a piece of paper with some
		handwriting on it."
	end verb.
end object.

object note
	name note
	name piece 'of' paper
	name incantation
	name words
	name meaningless jumble 'of' syllables
	at Library
	is takeable.
	is not read.
	description
	verb examine does only
		"It's a page torn out of a notebook. You can make out the
		words: '...and to banish the shade, illume it with the light
		of a candle burned low, filtered through a green gemstone, while
		reciting the following incantation...' The next few words seem
		to be a meaningless jumble of syllables."
		make note read.
	end verb.
	verb 'use' does only
		"You make your best effort at getting your mouth around the
		incantation."
		if shade here and shade is illuminated then
			schedule banish_shade after 0.
		else
			"Nothing seems to happen, though."
		end if.
	end verb.
end object.