location Kitchen
	description
		"$tA huge coal range dominates this room. There is also a long
		bench, and many shelves, cupboards and hooks for storing pots
		and pans. Only a few dented and tarnished cooking implements
		remain, however.
		$iNo kitchen in a Schlobbe-designed house would be complete
		without at least one architectural oddity, and here it's the
		fireman's pole that descends through the floor into the
		dining room. Evidently he was very particular about having
		his food served hot.
		$iIf you don't fancy a slide down, you can leave the room through
		the door to the east.
		$p"
	--exit east to UpstairsHallway.
	--exit down to DiningRoom
	--	does
	--		"You experience a moment of vertigo as you slide
	--		down the pole into the..."
	--end exit.
end location.

object Kitchen_east_door
	name east door
	name east
	at Kitchen
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at UpstairsHallway.
	end verb.
end object.

object Kitchen_pole
	name 'fireman''s' pole
	at Kitchen
	description
	verb examine does only
		"It's made of metal and very smooth."
	end verb.
	verb 'use' does only
		"You experience a moment of vertigo as you slide
		down the pole into the..."
		locate hero at DiningRoom.
	end verb.
end object.

object box_of_matches
	name box 'of' matches
	name matchbox
	at Kitchen
	container
	is takeable.
	description
		"$pThere is a box of kitchen matches on one corner of the
		bench."
	verb examine does only
		"There's a good number of matches left in it."
	end verb.
	verb take_or_drop
		check "It seems to have become stuck to the bench with the
			passage of time. You could take one of the matches, though."
	end verb.
end object.

object match
	name kitchen match
	in box_of_matches
	is takeable.
	is not burned_out.
	verb examine 
		check match not in box_of_matches else
			"You'll have to take a match out of the box to get
			a closer look."
		does only
			if match is ignition_source then
				"The match is alight."
			elsif match is burned_out then
				"The match is burned out."
			else
				"It's a long match, designed for lighting coal ranges. Be
				careful, it doesn't look like it's a safety match."
			end if.
	end verb.
	verb 'use' 
		check match in inventory else
			"You'll have to pick the match up first."
		does only
			if match is burned_out then
				"You're not going to get any more use out of this match."
			else
				"A quick flick against a nearby surface, and the match bursts
				into flame."
				make match ignition_source.
				schedule match_going_out at match after 5.
			end if.
	end verb.
	verb use_on
		when dobj
			check match is ignition_source else
				"If you're trying to light something, you need a match
				that's burning."
		does only
			"Setting fire to the $2 wouldn't be a good idea."
	end verb.
	verb take_or_drop
		does only
			if match in inventory then
				if match is ignition_source then
					"Hey, careful! Dropping burning matches around the place would
					not be a good idea, especially with all this dust about."
				else
					"The match falls to the ground and is lost in the dust."
					locate match in box_of_matches.
					make match not burned_out.
				end if.
			else
				if match in box_of_matches then
					"You pluck a match out of the box."
				else
					"Taken."
				end if.
				locate match in inventory.
			end if.
	end verb.
end object.

event match_going_out
	"$pThe match goes out."
	make match not ignition_source.
	make match burned_out.
end event.