actor hero
	name me
	container
	is not enlightened.
	verb examine does only
		"You look just as much the archetypal adventurer as
		you always did. Pockets six feet deep and a nose specially
		evolved for poking in where it doesn't belong."
		list inventory.
	end verb.
end actor.

container inventory
	header
		"In your pockets you are carrying"
	else
		"Your pockets are empty."
end container.

object pockets
	name pocket
	name pockets
	in hero
	description
	verb examine does only
		list inventory.
	end verb.
end object.

object remote_control
	name remote control
	name remote
	in inventory
	container
	is takeable.
	verb examine does only
		"It looks like a remote control for a TV or VCR, but it has
		only three buttons, marked SAVE, RESTORE and QUIT."
	end verb.
	verb 'use' does only
		"You'll have to be more specific about how you want to use
		that. Perhaps studying it more closely would help."
	end verb.
end object.

object save_button
	name 'save' button
	name 'save'
	in remote_control
	verb 'use' does only
		save.
	end verb.
end object.

object restore_button
	name 'restore' button
	name 'restore'
	in remote_control
	verb 'use' does only
		restore.
		look.
	end verb.
end object.

object quit_button
	name 'quit' button
	name 'quit'
	in remote_control
	verb 'use' does only
		quit.
	end verb.
end object.

object instructions
	name instruction booklet
	name instructions
	in inventory
	verb 'use' does only
		"This game has only one verb, and that's USE. You'll have to
		think of a way of phrasing whatever you want to do using that.
		Some obvious examples:$n
		$tUSE BUTTON to push it.$n
		$tUSE KNIFE ON BREAD to cut it.$n
		Some less obvious examples:$n
		$tUSE NORTH DOOR to go north.$n
		$tUSE EYES to look around you.$n
		$tUSE EYES ON PAINTING to examine it.$n
		$tUSE EYES ON POCKETS to see what you're carrying.$n
		$tUSE HAND ON SCREWDRIVER to take or drop it."
	end verb.
end object.



object puzzle
	name wire puzzle
	in inventory
	is takeable.
	verb examine does only
		"It's one of those annoying little wire puzzles, good
		only for wasting time."
	end verb.
	verb 'use' does only
		"You fiddle with the puzzle for a short time, frittering
		away a little more of your life."
	end verb.
end object.