location DiningRoom
	name 'Dining Room'
	
	description
		"$tThis room is furnished with a large dining table and chairs. The table
		is laid out with six elaborate place settings, and looks quite normal
		except for the pentagrams and occult runes inscribed in charcoal on
		the tablecloth"
		if candle is not moved then
			"and the large, dribbly candle in the middle of the table."
		else
			"."
		end if.
		"$iThe other notable feature of this room is the fireman's pole that
		descends from a circular hole in one corner of the ceiling.
		$iDoors lead south to the drawing room, and east to the hallway.
		$p"
		
	--exit south to DrawingRoom.
	--exit east to HallwayNorth.
	--exit up to Kitchen
	--	check "The pole is too slippery to climb up."
	--end exit.
end location.

object DiningRoom_table
	name dining room table
	name large dinner table
	at DiningRoom
	container
	description
	verb examine does
		"It's big enough for six people, and made of expensive mahogany."
	end verb.
end object.

object DiningRoom_pole
	name 'fireman''s' pole
	at DiningRoom
	description
	verb examine does only
		"It's made of metal and very smooth."
	end verb.
	verb 'use' does only
		"The pole is too slippery to climb up."
	end verb.
end object.

object DiningRoom_south_door
	name south door
	name south
	at DiningRoom
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at DrawingRoom.
	end verb.
end object.

object DiningRoom_east_door
	name east door
	name east
	at DiningRoom
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at HallwayNorth.
	end verb.
end object.

object candle
	name large dribbly candle
	in DiningRoom_table
	
	is takeable.
	is needing_iobj.
	is not lit.
	
	verb examine does only
		"Rivulets of hot wax have run down its sides and made grotesque
		shapes at its base. It's almost burned down to a stump, but there
		looks to be quite a lot of life left in it."
		if candle is lit then
			"$pThe candle is alight."
		end if.
	end verb.
	
	verb use_on
	
		when dobj does only
			if candle is lit then
				if iobj = emerald then
					"You hold the candle up to the emerald,
					which scatters the candlelight and
					casts flickering green images"
					if shade here then
						"over the apparition."
						make shade illuminated.
						schedule unilluminate_shade after 1.
					else
						"around the walls."
					end if.
				else
					"The candle illuminates the $2 with a
					flickering light."
				end if.
			else
				"If you're trying to illuminate something,
				it might help if you lit the candle first."
			end if.

		when iobj
			does only
				if dobj is ignition_source then
					if candle is not lit then
						"The candle flares into life. It smokes quite a bit, but 
						gives off a usable light."
						make candle lit.
					else
						"The candle is already alight."
					end if.
				else
					"That doesn't seem to do any good to the candle."
				end if.
	end verb.
end object.