location Garden
	description
		"$tThe back garden is large, lush, green and totally
		uninteresting except for a set of stone steps leading
		down into the ground.
		$iThe back door of the house is to the south.
		$p"
	--exit down to Crypt.
	--exit south to HallwayNorth.
end location.

object Garden_steps
	name stone steps
	name stairs
	name staircase
	at Garden
	description
	verb examine does only
		"They lead down to a stone portal. Dank darkness lies beyond."
	end verb.
	verb 'use' does only
		locate hero at Crypt.
	end verb.
end object.	

object Garden_south_door
	name south door
	name south
	at Garden
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at HallwayNorth.
	end verb.
end object.

location Crypt
	description
		"$tThis stone-lined underground chamber is dark, cold and
		damp. There is what appears to be a stone sarcophagus in
		the middle of the floor. Around it is carved a large
		pentagram, surrounded by occult symbols.
		$p"
	--exit up to Garden.
end location.

object Crypt_steps
	name stone steps
	name stairs
	name staircase
	at Crypt
	description
	verb examine does only
		"They lead up into dazzling sunlight, and freedom."
	end verb.
	verb 'use' does only
		locate hero at Garden.
	end verb.
end object.	

object sarcophagus
	name stone sarcophagus
	at Crypt
	description
	verb examine does only
		"Summoning all your courage, you peer over the edge of
		the sarcophagus. There is a human skeleton inside, lying
		with its hands crossed over its chest."
	end verb.
end object.

actor shade
	name shade
	name ghost
	name ghostly apparition
	name face
	name old man
	name Christopher Wren
	is not encountered.
	is not illuminated.
	description
		"$pA ghostly apparition hangs over the sarcophagus."
	verb examine does only
		"The apparition is looking at you with despair
		in its eyes, and maybe a little hope as well."
	end verb.
	script 1.
		step wait until hero at Crypt
			""
		step wait until hero at Crypt
			locate shade at Crypt.
			"$p$tA faint white glow starts to appear in the air above
			the sarcphagus. It brightens, and starts to form itself
			into a human face.
			The apparition opens its mouth and lets out a sound
			like wind wailing through a lonely graveyard.
			$i'Have you come to torment me again?' it says. 'Can you
			not release me after all this time? I have told you everything
			that I know!'
			$iThe face pauses, and squints at you for a moment. 'You
			are not he,' it muses. 'Who might you be?'
			$iYou stammer something incoherent.
			$i'My name is Wren,' the face goes on, 'or at least I am the
			shade of one who was thus called in mortal life. I have been 
			cruelly wrenched from my place of rest and made to serve against 
			my will. Can you release me? Will you release me?'"
			make shade encountered.
end actor.

when note is read and shade is encountered and hero is not enlightened =>
	schedule enlightenment after 0.

event enlightenment
	"$pYour mind reels as the full import of what Schlobbe
	has done begins to sink in. Why did he do it? Just so he
	could get a brain to pick for some architectural inspiration?"
	make hero enlightened.
end event.

event banish_shade
	"The shade begins to glow a bright green, and the emerald starts
	to give off dark orange smoke.
	$i'Thank you,' the shade says as it slowly fades. 'Thank you...
	may you be blessed in all eternity...' Soon only the faintest glow
	remains, and then nothing at all.
	$pThe emerald, too, is no more. All that is left of it is an orange
	cloud drifting away in the air. As you climb the steps out of the
	crypt, your lost dreams of riches are tempered by your spiritual
	reward at having brought happiness to a tormented soul. Or something
	like that, anyway.
	$pTHE END"
	quit.
end event.