location Bedroom
	description
		"$tA magnificent four-poster bed is the centrepiece of this
		room. There was probably other furniture here as well, once,
		but it has since been removed."
		if chest in bed and chest is seen then
			"$pA chest is just visible under the bed."
		end if.
		"$p"
	--exit west to Landing.
end location.

object Bedroom_west_door
	name west door
	name west
	at Bedroom
	description
	verb examine does only
		describe interior_door.
	end verb.
	verb 'use' does only
		locate hero at Landing.
	end verb.
end object.

object bed
	name four poster bed
	at Bedroom
	container
	description
	verb examine does only
		"The coverings are old an rotten. In one place, the fabric
		has crumbled completely away, revealing a chest of some sort 
		under the bed."
		make chest seen.
	end verb.
	verb 'use' does only
		"This is no time for a nap."
	end verb.
end object.

object chest
	name small wooden sea chest
	in bed
	container
	is takeable.
	is not seen.
	is not open.
	mentioned "chest"
	verb examine does only
		"It's a small wooden sea chest, bound with metal straps."
		if chest is open then
			"The lid is open."
			list chest.
		else
			"The lid is held firmly closed with a clasp and padlock."
		end if.
	end verb.
	verb 'use' does only
		if chest is open then
			"It's already open, if that's what you mean."
		else
			"If you're trying to open it, you'll need to use a key."
		end if.
	end verb.
end object.

object closed_chest
	container
end object.

object emerald
	name big large huge enormous emerald
	in closed_chest
	is takeable.
	article "an"
	mentioned "enormous emerald"
	verb examine does only
		"It's the biggest emerald you've ever seen, finely cut and
		smoothly polished. It must be worth a fortune!"
	end verb.
end object.

event unilluminate_shade
	"$pThe green images disappear as you take the candle away
	from the emerald."
	make shade not illuminated.
end event.