#!../bin/jacl

#Prisonbreak
#By Parham Doustdar
#AbilityComp edition

#constants
constant 	game_version	1
constant	game_title		"Prisonbreak"
constant	game_author		"Parham Doustdar"
constant	ifid			"8D05D74B-A997-4C5E-9886-B41001F1C448"
constant easy 1
constant normal 0

string status_text
integer gone_before_eric_comes
integer yesno

attribute lifted

#grammars
grammar spit *held >drop
grammar spit out *held >drop
grammar swallow *present          >eat
grammar consume *present          >eat
grammar wet *present >clean
grammar mode $integer >mode
grammar mode easy >mode_easy
grammar mode normal >mode_normal
grammar mode >mode_check
grammar shoot *here >shoot
grammar throw *here in *here	>throw_at
grammar hurl *here in *here		>throw_at
grammar pitch *here in *here	>throw_at
grammar cast *here in *here		>throw_at
grammar throw *here on *here	>throw_at
grammar hurl *here on *here		>throw_at
grammar pitch *here on *here	>throw_at
grammar cast *here on *here		>throw_at
grammar throw *here at *here	>throw_at
grammar throw *here to *here	>throw_at
grammar cast *here to *here		>throw_at
grammar cast *here at *here		>throw_at
grammar pitch *here to *here	>throw_at
grammar pitch *here at *here	>throw_at
grammar lob *here to *here		>throw_at
grammar lob *here at *here		>throw_at
grammar hurl *here to *here		>throw_at
grammar hurl *here at *here		>throw_at
grammar hurl *here against *here		>throw_at
grammar throw *here against *here		>throw_at
grammar attack *present with *present    >attack_with
grammar hit *present with *present       >attack_with
grammar fight *present with *present     >attack_with
grammar kill *present with *present      >attack_with
grammar murder *present with *present    >attack_with
grammar stab *present with *present      >attack_with
grammar poke *present with *present      >attack_with
grammar breathe through *held >breathe_through
grammar mind raise *present >mind_raise
grammar mind lower *present >mind_lower
grammar mind push *present >mind_push
grammar mind push *present at *here >mind_push_at
grammar mind push *present towards *here >mind_push_at
grammar mind pull *present >mind_pull
grammar credits >credits
grammar author >author

{+intro
clear
write ^^
write "Do you want to play this game in easy mode? The only difference between easy mode and normal mode is that you'll get hints about how to solve the puzzles. The hints are still not direct, however. If you don't want to see any hints at all, answer 'no' now.^"
getyesorno INDEX
if INDEX = 1 #The player has answered yes
set mode = easy
write "^You have selected easy mode.^^"
else
set mode = normal
write "^You have selected normal mode.^^"
endif
more "Press any key to continue"
clear
style bold
write "^^" game_title
style normal
write " by " game_author "^^^"
write "~Humanity is acquiring all the right technology for all the wrong reasons.~^"
write "  --  Buckminster Fuller^^^"
style note
write "Type ABOUT when in the game for more information if this is your first time playing this game. Also, type INSTRUCTIONS if this is your first interactive fiction game. If you want to know which people have had a hand in creating this game, type CREDITS, and if you want to know more about the author himself, type AUTHOR.^^"
style normal
more "Press a key to continue..."
clear
print
You haven't done anything, really. Although this is the same thing you hear over and over from people that are spending a period of their life in prison, no one but the people in this prison understand what you are talking about. You haven't done anything, and that's true. No one here has done anything. All they did was sign a simple, stupid contract; to be held responsible for the results of an experiment they were being paid to participate in.^^
No one said that you were going to be held in a prison. No one ever mentioned that although the chance of success was less than ten percent, there would be those affected, poor damned people that just wanted some money for different things. In your case, it was university. In Mark's case, it was moving to Spain. In Alexander's case, it was a girl. Strange what a guy endures for a girl, isn't it?
But maybe, or, now that you think about it, certainly, he wouldn't have signed that treaty if he knew where he was going to end up. Certainly, he wouldn't have signed it if he knew he was going to end up dead, far from that girl he wanted to marry, far from home, far from anywhere, really. In a place far, far away from any human settlement. In a place that is enclosed in miles of bare, broken patches of earth. In a place made of hardened steel. In hell. And will you give up? No. Will you sit down and cry while cursing your fortune? No. As much as you want to, no. And just to confirm it, you say it aloud. Not too loud, just enough to be heard by yourself. ~No.~^^
As you ponder these, you look around your cell -- the only thing you have done beside eating pills for a long, long time.^^
.
if here hasnt OUTDOORS
   move north_wall to here
   move south_wall to here
   move east_wall to here
   move west_wall to here
endall
move ground to here
look
write "^The plan you and Mark made is simple: drink the water, talk to her and keep her attention away from the scarf as you kick it towards the doorframe to keep the door ajar a fraction of an inch, just enough to let your telekinetic energy reach through and unlock the door. You'd need to get through just one guard and Soyala to get away, and usually this place has at least five guards. Today, the rest have gone away to take care of Alexander's dead body, however.^"
}

location cell103 : cell 103
short name "cell 103"

{look
write "This cell is simple, bare, and you know it down to the smallest detail. Only a bed that is indeed very comfortable occupies one wall, the one behind you. The west side contains a toilet and a sink, and the right side... nothing. Just unbreakable steel that seems to mock you with its hardness.^"
}

integer stage

{eachturn
 if stage = 0
 set stage = 1
 return
 endif
 if stage = 1
 print
^Where is Soyala? It is almost time for you to receive your pills, like the good boy you've been the last... last what? Week? Month? Year? Decade? No, it couldn't have been a decade, or even a year; you are very patient, but not so much to hold on a year. Six months or so. So, yes, you should swallow them down with a cup of water, watched closely by her, like you've done since you have been here, and let them keep you in control. Not that there is any need, really. You can't reach through a door that doesn't have the slightest bit of opening around it's frame, made just to prevent someone like you reaching through and unlocking the door. But are you going to swallow that pill this time? No. Are you going to still be a good boy? Heck no. Are you going to make these bastards suffer? Heck yes, you are. You haven't been mad much, but now you are, and God help them.^
.
set stage = 2
return
endif
if stage = 2
print
^You hear footsteps echoing from somewhere. You remember the very first time you heard her approach. You were so scared as if these were the footsteps of death approaching, coming closer every second, every footstep, every moment. Maybe it was caused by the measured, slow steps that she always takes, or maybe it was because of the way the steel walls recounted the story of every footstep to your ears, your ears that were so used to the noisy life outside that were ringing from the silence, or maybe because it was just that you couldn't expect anything more in such a place than death, coming to claim you of its own. And still, those footsteps approach. But this time, you have a plan, and that is to hide the pill under your tongue and drink the water. No one would expect anything, since you and Mark have never been trouble makers. You have cursed and banged your fist against open hand in frustration of this fate that has befallen you, but you never did anything remotely resembling dangerous, but today, you
 are going to. Yes, you are.^
.
set stage = 3
return
endif
if stage = 3
print
^A series of familiar beeps make you put on that expressionless mask that you have worked on so much. Of course, she is entering the password. The mechanism is built flawlessly, almost. You have recently learnt that the password doesn't need to be reentered to open the door until after the door has completely closed. So much for security, though. At least, you know the password for Mark's cell door. While you are thinking your idle thoughts, trying to keep yourself from fidgeting, the door slides open.^
.
set stage = 4
return
endif
if stage = 4
print
^Soyala smiles and steps in, her every step graceful, calculated, exact. You don't know if the smile is false or not, but it used to be inviting. Comforting. Reassuring. Now, however, it is repulsive. Repulsive to watch her false smile, repulsive to be near her, repulsive to be here, not only because she is here, but because it reminds you of things. Bad things. Very bad things.^
She doesn't speak a word as she steps forward and uncurls her fingers, revealing a golden pill lying on her palm. She hasn't spoken a word since you told her you hate her. It wasn't a noble thing to say, yes, but you really did hate her. You still do, even though you never show it. Let them have it, those who complain of the lack of nobility.^^
The door slowly closes behind her.^
.
set stage = 5
move soyala to here
move pill to here
return
endif
ifall stage = 5 : pill(parent) = cell103 #Soyala is waiting for the player to take the pill.
write "^Soyala is waiting for you to take the pill, her eyes distracted, but her look expectant.^"
endif
ifall stage = 5 : cup(parent) = player #The player has the pill and Soyala is waiting for him to drink it down.
write "^Soyala watches you, urging you to gulp the pill down with that cup of water.^"
endif
if stage = 6 #the gas starts to be pumped into the whole building
write "^You hear the ventilation system coming on with a sound that seems to shake the whole building. Yuck. You hadn't thought of that. The emergency gas."
if mode = easy
write " You need to create an improvised mask before the gas takes effect.^"
else
write ^
endif
set stage = 7
return
endif
if stage = 7 #the gas continues to be pumped in
write "^You feel the gas slowly start to seep into your system.^"
set stage = 8
return
endif
if stage = 8
write "^You start to cough and you can feel your body trying to fight off the gas.^"
set stage = 9
return
endif
if stage = 9
write "^You feel the gas start to reach outside of your lungs and into your blood.^"
set stage = 10
return
endif
 if stage = 10
 write "^Your coughs increase in intencity as you breathe in more of the gas.^"
 set stage = 11
 return
 endif
 if stage = 11
 write "^You start to wobble on your feet, slightly disoriented.^"
 set stage = 12
 return
 endif
 if stage = 12
 write "^You fight to get back your balance, and try not to cough because it hurts your chest.^"
set stage = 13
return
endif
if stage = 13
write "^You start to cough violently and have to lean a hand against the walls to not fall down.^"
set stage = 14
return
endif
if stage = 14
write "^Your feet seem to slip out from under you in slow motion. You don't feel anything as you hit the ground and can't get up. With each breath you have to take, more of the gas enters your body, and at last, your body can't take it anymore. The gas kills you.^"
execute +game_over
endif
 ifall player(status) < 4 : stage = 5 : soyala(parent) = limbo
set player(status) + 1
if player(status) <= 3
write "^You feel your reserves of telekinetic power "
if player(status) = 1
write "start to come back.^"
endif
ifall player(status) > 1 : player(status) < 4
write "continue to increase.^"
endif
endif
endif
if player(status) = 4
write "^You have completely recovered your power."
if mode = easy
write " Now you can open the door.^"
else
write ^
endif
set player(status) = 5
endif
if soyala(status) = 8 #The player hasn't talked to Soyala yet, and she's just wanting to close the door.
set soyala(status) = 6
execute cell103.eachturn
endif
if soyala(status) = 1
print
^~Why what?~ she asks, and surprisingly, exasperatingly, your heart flutters gently in your chest on hearing her voice after such a long time.^
~Why do you do it?~ you ask, with a soft, gentle tone, full of regret, full of hatred, a hatred you've hidden so long.^
.
set soyala(status) = 2
return
endif
if soyala(status) = 2
print
^~Because I have to,~ she replies, with a look at you as if to say, you have asked me a thousand times, and heard the answer an equal number of times, and although you are doing it just to keep her busy, it is for yourself too. For you to end your memories with her once and for all. For you to draw her story with you to a close and put the book away in the very depths of your mind. Although you know that the book will still be pulled out, you at least want to have an ending point for it, a point that ends with you being the hero.^
While she replies, she slowly begins to step towards the control panel beside your cell, not giving you much time to pursue the subject.^
~I know, you've told me a thousand times, but you know that the reason doesn't justify the means, Soyala.~ your voice starts to shake very slightly, and you hate yourself for it. Hate yourself for being weak, being soft, being you. You hate everything. You, the experiment, Soyala... you hate the whole world. The whole Universe. You hate God. Now, isn't that the first point everyone's hatred goes to? God? So be it, let's add your hatred to the list too. What would it hurt the one that has the control of the whole world, steering it whichever way he likes? Let him know that someone, in the middle of nowhere, from amongst tons of steel, hates him.^
.
set soyala(status) = 3
return
endif
if soyala(status) = 3
print
^~It does, sweetheart, it does. I wish you knew how young and inexperienced you are, how innocent you are in the world that wants to devour you in its vastness.~^
She raises her hand slowly, and it hovers a little on the button marked ~close~ as she watches you from the corner of her eye.^
~But aren't you a part of this world? Aren't you one of them? Aren't you?~ you ask, your tone still soft, but wanting to scream at her, to end this game she's started right now and right here, but you wait. You should wait. You have to wait.^
.
if scarf(status) = 0
if mode = easy
write "^You have to kick the scarf now, or she will close the door and you'll be stuck!^"
endif
endif
set soyala(status) = 8
return
endif
if soyala(status) = 4
write "^Satisfied, Soyala takes the cup from you and turns to leave"
if mode = easy
write ". You've got to talk to her to keep her from going out while you kick the scarf near the doorframe to stop the door from closing. Quickly, you try to gather your thoughts as she puts her hand against the scanner. The door obediently hisses open.^"
else
write ", putting her hand against the scanner. The door hisses open.^"
endif
set soyala(status) = 5
return
endif
if soyala(status) = 5
write "^She turns around and starts to walk towards the control panel. She is almost there, and you don't have a clear view of her face."
if mode = easy
write " If you want to stop the door from closing, this is your last chance to start talking.^"
endif
set soyala(status) = 6
return
endif
if soyala(status) = 6
if scarf(status) = 0
write "^The door closes slowly, agonisingly, with a hiss. You weren't quick enough, even to save yourself now that you had the chance. You figure out after this event, that you are not even worth the freedom you wanted to get. Maybe you should suicide just like Alexander did...^"
execute +game_over
else
write "^She pushes the button. The door closes with a hiss and a boom that reverberates through the walls, the floor, through you. After a little while, the clang of the lock mechanism follows, and amongst all that, a smile spreads over your face. You have already won the game. It vanishes, however, when what Soyala mutters drifts to you through the still air and through the door that is not completely sealed: ~Yes. I am.~. For some reason, her voice is soft and regretful, and for once, what she says to you isn't wholehearted enough. What's going on?^"
move soyala to limbo
set soyala(status) = 7
endif
}

{movement
ifall stage > 5 : stage < 15 : destination = corridor1 #The gas is having an effect on the player, so he shouldn't exit yet.
write "You need to take care of the gas first before you exit!"
if mode = easy
write " Why don't you make an improvised mask for yourself, first?^"
else
write ^
endif
set time = false
return
endif
if here(compass) != nowhere #The player can now go out
if here(status) = 1
return false
else
set here(status) = 1 #Don't need this to run if the player has gone through the door once.
print
The door slides shut behind you, probably controlled by the guard in the main control room. He must've seen you come out, though. That means there was a camera hidden in your cell all along. But how? Where? Why didn't you ever find it? As you move into the room, you can hear the sound of what seems to be an argument reach your ears. Actually, just one side of it.^^
~No, Ms Lendry, you shouldn't stay!~^^
Lendry. Soyala. Stay? So she wants to stay, does she?^^
~That is dangerous! He is like an animal!~^^
Animal. Hah. See who that's coming from. It's like you were the one that imprisoned him all along. Hurt him all along. Tortured him all along, just because you could. Now that the ~animal~ is out of it's cage, he wants to run? No way.^^
~He is not? Just look at his eyes!~^^
Ah, so it seems Soyala thinks that you are not an animal either. Yes. She is supposed to know. She used you, after all. She was the one that made you look forward to this end, after all, and as you notice that they can see you, you turn around, shooting a glare at every corner in the room, everything in the room.^^
~Ok then, I'm staying too!~ the guard calls and you hear his running footsteps approach, accompanyed by the scream of the alarm that indicates the prison is in high danger.^^
What a hero. You wish you could warn him that even if he succeeds to kill you, there is no point being with Soyala. You have been there, have seen it. Even if you were offered a billion dollars, you wouldn't go back to that time. Even if you were offered the world. Even if you were offered to do the same thing to her that she did to you. So you wait, calmly, quietly, as the hero approaches, your hands hanging casually by your sides. You won't need them, anyway. You have something much more powerful. More deadly.^^
.
set here(north) = nowhere
set here(out) = nowhere
set destination(south) = nowhere
return false
endif
else
if compass = north : compass = out
ifall soyala(status) >= 1 : soyala(status) <= 6
write "No. If you rebel now and try to run away from her without your powers, there's no chance for you to escape.^"
set time = false
return
else
if stage = 4
write "No. If you rebel now and try to run away from her without your powers, there's no chance for you to escape.^"
set time = false
return
else
write "Yes, I know, you want to escape. However, you need to open this door first. You need to go with the plan to succeed.^"
set time = false
return
endif
endif
endif
return false
endif
}

object bed : comfortable bed sheets mattress bunk
short the "comfortable bed"

{examine
write "It's a bed you've slept on many times. It has a memory foam mattress with white sheets."
if @ = 1
write " It has kept you warm through nights when you were shivering from cold air, which was fixed when they installed the air conditioning. It has also been your companion when you were having nightmares and you woke up screaming just like Mark and Alexander, not knowing why you screamed, but not being able to stop it either.^"
else
write ^
endif
}

{lie_on
write "Come on now. Will you lie down and pretend to be asleep while your chance to get out is slipping away? The chance you've waited to get for so long?^"
}

{break
if bed(status) = 1
write "You have already done that.^"
set time = false
else
if stage > 5
write "You quickly tear up a part of the bed sheets.^"
move sheets to player
set bed(status) = 1
else
write "Why would you need to tear the bed sheets?^"
set time = false
endif
endif
}

{mind_push : mind_pull : mind_raise : mind_lower
if player(status) = 5
write "It's bolted to the floor.^"
else
write "You don't have your power back yet.^"
endif
set time = false
}

{clean
if stage > 5 #The player likely wants to mention the torn sheets
execute sheets.clean
else
write "You have already made your bed. It's tighty and neat.^"
set time = false
endif
}

{look_under
if office has VISITED
write "You reach under your bed and feel around. Your hands find something which looks like a book. As you pull it out, you see that it's Soyala's journal. Seeing her name on the cover makes your eyes go wide.^"
move journal to player
else
if @ = 1
write "You kneel down and look under your bed. There is nothing there, as expected, other than dust. You get up to your feet, disappointed.^"
else
write "You have looked there already. There's nothing there. You are sure of it.^"
set time = false
endif
endif
}

object sheets : torn sheets covers cover
has PLURAL
short the "torn bedsheets"
long "The piece of bed sheets that has been torn away is lying on the ground here.^"
mass 1
parent limbo

{examine
write "It used to be part of a bed sheet. Not anymore, though.^"
}

{clean
if sheets(next) = 1
write "It's already wet.^"
else
if scarf(next) = 1
write "You already have made a mask for yourself.^"
else
write "You wave the torn piece of the bedsheets in front of the infrared motion detector, and water runs out of the faucet, wetting the piece of cloth."
if mode = easy
write " Now you have an improvised mask!^"
else
write ^
endif
set sheets(next) = 1 #Now the sheets are wet
set stage = 15
endif
endif
}

{insert_in_sink
execute this.clean
}

{wear
if sheets(next) = 1 #The player has washed the sheets, so it's wet and can be used as a
#mask
if sheets hasnt WORN
write "You wrap the torn cloth around your face, being careful to make it cover your nose and mouth, and tie it behind your head.^"
ensure sheets has WORN
set stage = 15 #The player is now immune to the gas
else
write "You already have it around your head.^"
set time = false
endif
else
write "You wrap the torn sheet around your head, but can still feel the gas passing through the dry cloth.^"
ensure sheets has WORN
set time = false
endif
}

{remove
if this has WORN 
write "If you remove it, you'll be affected by the gas!^"
set time = false
endif
}

object toilet : toilet
short a "toilet"

{examine
write "It is just a toilet, like all others, and it's simple; no self-flushing or self-heating units or anything.^"
}

{sit_on
if soyala(parent) = here
write "Uh... in front of her? At least wait until she's out of the cell.^"
return false
else
if @ = 1
write "You remove your uniform pants and sit down on the toilet, taking care of your business and flushing the toilet afterwards.^"
set toilet(status) = 1
else
write "You just used that toilet a little while ago!^"
endif
endif
}

{use
execute toilet.sit_on
}

{mind_push : mind_pull : mind_raise : mind_lower
if player(status) = 5
write "It's bolted to the floor.^"
else
write "You don't have your power back yet.^"
endif
set time = false
}

object sink : sink tap
short the "sink"

{examine
write "A motion detector that automatically lets the water run is the only thing that is worthy of notice on this otherwise ordinary sink.^"
}

{turn_on
write "It will activate automatically once you want to use it for washing your hands or anything else.^"        
}

{turn_off
write "It will deactivate automatically once you want to use it for washing your hands or anything else.^"        
}

{open
execute sink.turn_on
}

{close
execute sink.turn_off
}

{mind_push : mind_pull : mind_raise : mind_lower
if player(status) = 5
write "It's bolted to the floor.^"
else
write "You don't have your power back yet.^"
endif
set time = false
}

object detector : motion detector "motion detector"
parent sink

{examine
write "It's made of a lens that seems to watch your every move, waiting until you get close enough to make sure you need the water, then dutifully lets it come through for you.^"
}

object scarf : winter scarf
short a "winter scarf"
mass 2
long function

{long
if scarf has lifted
write "A winter scarf is floating in the air here.^"
return
endif
if here(north) = corridor1
write "The scarf is lying near the doorframe.^"
return
endif
if @this.kick = 1
write "The scarf is kicked near the doorframe"
if soyala(parent) = here
write ", ready to keep the door from completely closing.^"
else
write ", keeping the door slightly ajar.^"
endif
else
write "The scarf you've stolen from a guard, for the purpose of keeping the door very slightly ajar so that your energy can reach through, is lying on the ground near your foot.^"
endif
}

{examine
write "It's the scarf you have stolen from a guard."
if scarf(next) = 1
write " It's dripping wet.^"
else
write ^
endif
}

{take
if stage < 5 : soyala(parent) = here
write "No! That would spoil all your plans!^"
return
else
if here(north) = nowhere
write "The door is not yet open. If you pull out the scarf now, the door will close.^"
set time = false
return
else
return false
endif
endif
}

{kick
if stage < 5
write "No, not yet.^"
return
endif
if scarf(status) = 0
ifall soyala(status) > 0 : soyala(status) <= 3
write "You kick the winter scarf near the doorframe to stop the door from completely closing, allowing your telekinetic energy (when it comes back) to slip through the opening that is less than a fraction of an inch.^"
set scarf(status) = 1
else
if soyala(status) = 8
write "You kick the winter scarf near the doorframe to stop the door from completely closing, allowing your telekinetic energy (when it comes back) to slip through the opening that is less than a fraction of an inch.^"
set scarf(status) = 1
return
endif
write "But Soyala will notice it! Talk to her first, to keep her distracted.^"
set time = false
endif
else
write "It's already where it should be; near the doorframe.^"
set time = false
endif
}

{clean
if stage > 5 #the gas is being pumped so the player needs the mask
if scarf(next) = 1 #The player has washed the scarf once before
write "It's already wet!^"
set time = false
else
if sheets(next) = 1 #the player has already wet the bedsheets, so he doesn't need the
#scarf.
write "You already have an improvised mask!^"
set time = false
else
if scarf has WORN
write "You need to remove it first.^"
else
write "Moving quickly, you "
if scarf(parent) = player #he has already picked it up
write "wave the scarf in front of the infrared motion detector, wetting it."
if mode = easy
write " Now you have an improvised mask!^"
else
write ^
endif
set scarf(next) = 1 #The scarf is wet now
else
write "grab the scarf, waving it in front of the infrared motion detector and letting it get wet by the water coming through the faucet.^"
set scarf(next) = 1 #The scarf is wet now
endif
endif
endif
else
write "Wash it? You don't need to do that yet.^"
endif
}

{insert_in_sink
execute this.clean
}

{wear
if scarf(parent) = player
if scarf(next) = 1 #The player has washed the scarf, so it's wet and can be used as a
#mask
if scarf hasnt WORN #The player isn't wearing the scarf
write "You wrap the scarf around your face, being careful to make it cover your nose and mouth, and tie it behind your head.^"
ensure scarf has WORN
set stage = 15 #The player is now immune to the gas
else
write "You already have it around your head.^"
set time = false
endif
else
write "You tie the scarf around your head, but can still feel the gas passing through the dry cloth.^"
ensure scarf has WORN
endif
else
write "You need to get it first!^"
endif
}

{mind_raise
if stage < 5 #The door is not opened yet
write "But that would spoil all your plans!^"
else
if scarf(parent) = player #It is already on the player
write "You have it already!^"
else
write "The scarf lifts off the floor, guided by your telekinetic power.^"
ensure scarf has lifted
endif
endif
}

{mind_lower
if scarf has lifted
write "You slowly lower the scarf to the floor.^"
ensure scarf hasnt lifted
else
write "You are not lifting it!"
set time = false
endif
}

{insert_under_sink
execute this.clean #The player means to put it under the motion detector.
}

{remove
if this has WORN 
write "If you remove it, you'll be affected by the gas!^"
set time = false
endif
}

{mind_push_at_eric
if eric hasnt DEAD
execute eric.greeting
print
Now I want to make you suffer as you die.~^
As you unwrap the scarf from around your head, you push it towards Eric, and it hits his neck with a wet slap, and wraps around his throat. His eyes widen in alarm as you telekinetically choak him with the scarf, and although you would've never killed some time ago, you feel a kind of pleasure watching this one die. He was the one that hit you, hurt you, humiliated you. He deserves to die. The world should be clean of these monsters and what they have done should be erased from the face of the world. As Eric stops thrashing and his head lols forward, your knees weaken and you fall to your knees. You can't hold Eric in the air anymore and for some reason, your power fails you and the emptiness, the sense of powerlessness returns, and with it comes the realisation; you have failed. You have killed Eric, but you have failed. The gas... you had completely forgotten about it. Now, with the scarf removed, it started to affect you. But at least, Eric is dead, and the sad thing is, you couldn't escape after all. As your face hits the floor, you can hear a ~bang~ from a long distance away, and open your eyes just an inch to see eric's dead body on the ground beside you, making him the last thing you see. Because, since you feel yourself dying, what they have told you should've been wrong. This gas doesn't make you unconscious. It kills you.^
.
execute +game_over
endif
}

{breathe_through
execute this.wear
}

object soyala : girl soyala woman
has ANIMATE FEMALE
short name "Soyala"
long function
mass heavy
parent limbo

{long
if soyala has lifted
write "Soyala is floating in the air near her chair.^"
return
endif
if soyala has DEAD
if @soyala.not_forgive = 0
write "Soyala's body is lying near the wall in a heap.^"
return
else
write "Soyala is sitting on the chair, dead.^"
return
endif
endif
if this(parent) = cell103
write "Soyala is standing in front of you, watching you distractedly.^"
endif
if this(parent) = office
write "Soyala is sitting in a chair, her back turned to you.^"
endif
}

{examine
ifstring command[0] = "search"
if soyala has DEAD
if keyring(parent) = player
write "You find nothing among her clothes.^"
else
write "You find a keyring in her pocket!^"
move keyring to player
endif
return
else
write "I don't think she would appreciate that.^"
set time = false
endif
endif
ifall soyala has DEAD : @soyala.not_forgive = 0
write "Her body has been rendered unrecognisable by the force of your telekinetic push.^"
return
endif
write "Soyala is a girl in her mid twenty's, young and beautiful, with full lips and black hair. Her green eyes "
if soyala has DEAD
write ", now lifeless, used to be intelligent and hard. "
else
write "are intelligent, and the only thing that takes away from the beauty of her face is the hardness in their depths."
endif
if @ = 1
write " Actually, come to think of it, you must not have noticed the hardness, or imagining it right now, because you had fell in love with this woman. With her face. With her eyes. Those hard, intelligent eyes."
endif
 write " She is of avrage height and weight, and wears the same white uniform as everyone else in the prison.^"
}

{attack
write "No. Not yet.^"
}

{attack_with
write "No. Not yet.^"
}

{kiss
write "You would've done it some time ago, but not now. Being close to her disgusts you.^"
}

{talk_to
if soyala has DEAD
write "But she's dead!^"
endif
if soyala(parent) = office
set MENU_MODE = MENU_EXECUTE
set MENU_MODAL = true
if @mark_soyala = 0
execute "+menu_add_option<Ask her about Mark and Alexander.<mark_soyala"
endif
if @past_soyala = 0 #The player haven't asked her about the past yet.
execute "+menu_add_option<Ask her about the events in the past<past_soyala"
else #The player has asked her about the past events.
ifall @forgive_soyala = 0 : @not_forgive_soyala = 0 #The player hasn't picked any choices yet.
execute "+menu_add_option<Tell her that you forgive her<forgive_soyala"
execute "+menu_add_option<Tell her that you don't forgive her and kill her<not_forgive_soyala"
endif
endif
endif
if this(parent) = cell103
if cup(parent) = player : cup(parent) = soyala
write "First you should assure her that you've swallowed the pill. Drink the cup first, then you can talk to her.^"
return
else
if this(status) = 5 : this(status) = 6
if this(status) = 5
set this(status) = 1
write "Nothing comes to your mind to say. Things have been done and said long time ago, but you have to. You have to say something, have to keep her busy, so you try.^~Why?~ you ask her, making her turn around slowly, carefully.^"
endif
if this(status) = 6
set this(status) = 1
write "Nothing comes to your mind to say. Things have been done and said long time ago, but you have to. You have to say something, have to keep her busy, so you try.^~Why?~ you ask her, making her look up at you slowly, carefully, stepping sideways to come into your complete view.^"
endif
else
if @ = 2 #Tell the following to the player just for the first time he does this mistake.
write "You're already talking to her. You have to wait for the conversation to continue.^"
endif
endif
return
endif
}

{mark
if @soyala.past = 1 #The player has asked her about the past first.
write "You try to change the subject, delaying the time you'll have to make your decision at.^"
else
write "You lean down and look into her eyes, which somehow seem to not want to meet your gaze.^"
endif
write "~Why did you kill Mark and Alexander?~ you ask, confused, disgusted, horrified."
if @notebook.read = 1
if @monitors.examine = 1
write " You've seen what they've done to Mark, you know what they've done to Alexander, and it's unbelievable. Unsurprising, but still unbelievable.^"
else
write " You know that they've killed Mark, and you know that they've killed Alexander. Still, even though you should've expected this, it's unnerving. Unexpected. Unbelievable.^"
endif
else
if @monitors.examine = 1
write " You have seen what they've done to Mark. SO now you know it all. It wasn't a suicide attempt. They have probably killed them both. So unexpected. So unbelievable.^"
else
write " You can guess, from the way she looks away, that it was all her doing. It was all her that killed Alexander, that probably she wants to kill you too... now.^"
endif
endif
write ^
write "Strangely, Soyala who was always calm around you, seems to be at a loss for words. She seems to be scared... or maybe not.^"
write "~I did what I was told-~^"
write "~Enough!~ you shout, cutting her off. ~How long are you going to accuse others of dictating what you should do? How long are you going to put your responsibilities on their shoulders? Is it so hard to be responsible for your own actions? Those men have no conscience, but you do! Don't you?~^"
write "~That is actually-~^"
write "~Don't you?~ you prompt her, not letting her stray from the point.^"
write "~I do, but I'm-~^"
write "~But you what? You don't care? You don't want to...~ you trail off as you feel something snap in her. You can see it in her eyes, see it in the way her jaw is set.^"
write "~Stop shouting at me!~ she shouts angrily, looking defiantly at you. ~Who are you to judge me! Who are you to say what is wrong and what is right? "
if eric has DEAD
write "You have killed someone yourself! You have killed a human! Isn't that wrong? Haven't you got a conscience? You did it simply because you had to! You didn't do it because you were a monster, you didn't do it because you were hated by three prisoners. You did it simply because you hated him. Because he was in the way. "
endif
write "I have ordered the execution of both Alexander and Mark, but I was ordered to do so! I was expected to do so! I was paid to do so! Do you understand?~ she waits expectantly for you only a moment. ~No,~ she says, slumping slightly. ~You don't. You never have. You are so sweet, so caring and kind, so loving and comforting, but you are not understanding. Not of my position. You have never been me. You have never been forced to be me.~^"
write "You take a step backward, dumbstruck, but you will your eyes to hold the tears back. You blink a few times, not letting the tears reach your eyes, lest she'd see them.^"
write "Who are you, really? Who are you to judge her? She is so right. She is so right that it breaks your heart just to think about it. Was it you all along? The monster was you? The thing that stopped your relationship from going further, was it you? Now that you think on it, it is not unlikely, and the realization is so unnerving that you don't dare say anything or think about it.^"
if @soyala.past = 1
write "Teary eyed, you look at her, and she looks back. You both know that finally, the dredded time to make the decision has come. Will you forgive her in your heart, or you don't have enough confidence in her yet?^"
endif
}

{past
if @soyala.mark = 1 #The player has asked Soyala about Mark and Alexander.
write "You try to speak, but nothing comes out of your mouth. You are glad that Soyala is not looking at you while you open and close your mouth again and again, as each time it fails you. But then, blinking the tears that have made the world blurry, you put a hand on her shoulder and finally, start to speak.^"
write "~What about our love? The thing between us? Do you still love me?~ you say, too softly perhaps, but she has heard it. You can say it from the momentary twitch in the corner of her eye, the look on her face that means she's gathering the words she has, perhaps, practiced to say again and again.^^"
else
write "You lean your elbow on the desk in front of her and look at her, trying to get her to meet your eyes. She doesn't.^^"
write "~Hello, Soyala. Do you remember me? I think we used to love each other, or rather, I used to love you. I don't think you remember. Do you?~^^"
write "A smile flickers on the corner of her lips and despite your anger, despite your hatred, your heart goes to her. Why does it? Aren't you supposed to hate her, or, perhaps, you want to hate her? Perhaps, you are willing yourself to hate her?^^"
endif
write "~I did love you, Adrian. I have always loved you, but you could never see. You never wanted to see. You hurt me while I held you, while I tried to protect you. You never understood that I had orders and I had to do them, or I'd be killed. I didn't want to manipulate you, I made it seem that way. "
write "Do you really think I would kill you? Didn't you ever guess that you'd have a lisp when you put that pill under your tongue and I'd know? Don't you know that I've been trained to look everywhere at once, and I'd see the scarf you used to stop the door? Even if I didn't see that, how could I ignore that tail of the scarf sticking out from under the door? Your plan would have never worked if I didn't want you to escape. "
write "I was here for you all the time, hovering away just enough to trick my supperiors, but close enough that you'd be able to reach out to me. You didn't. I disabled the cameras in your cell so that we could have a private moment, because i was tired of pretending in front of the cameras, but you didn't even hold me. Now, I will not kill you, I don't even have a gun, but you can decide on your own.~^^"
write "Her eyes raise up to meet yours, and they are clear of emotion like crystal. You see neither love, nore hatred in them, neither the will to die, nore the will to stay alive. You don't even see expectance in her eyes. Just patience. What should you do? You are so confused by the things you've heard that your mind seems to be fuzzy. You think she might be honestly saying the truth, but again she might not be. She might be like the rest of people, saying everything, using every trick to stay alive, saving herself at the last moment and knifing the one she was bowing to in the back once his back is turned, but then again, her words seem too much true. After all, she did come near you a few times in your cell when she gave you the pills, and you stepped back.^"
}

{forgive
if @soyala.past = 1
write "You lean closer to her face and she involuntarily moves back. You hold her gaze as if to say it's alright, but she stays back, still. You wait for her and smile patiently, and then she nods very slightly as if confirming something in her mind and leans in, letting your lips touch after a very long time. There has been so much tention between you that you see her eyes close and greatfully hold her as she leans against you, a tear trickling down from the corner of her eye. You pat her back a few times to say it's alright, but you know that it'd take a lot of time to set things right. As she breaks the kiss, she takes out a keyring from her pocket, stands up and smiles at you, her smile kind and rather desprait, as if like you, she was waiting for this moment, too. "
write "Not as if. She really was. You will yourself to stop being suspicious, but that will have to wait.^^"
write "~I'll go get the helicopter. Please do me a favour and go back to your cell and look under your bed. The password to the door is ~I love you~. Ok?~^^"
if @bed.look_under = 1
write "~But I've looked under-~^^"
write "She places a brief kiss on your lips, probably meaning do not argue and go ahead, and turns around, leaving you alone.^"
move soyala to limbo
else
write "~Alright, I will.~^^"
write "She nods slightly and brushes her lips against yours, turning around and leaving you alone.^"
move soyala to limbo
endif
else
if soyala(parent) = cell103
write "No. If you move towards her, the guard may take it as a gesture of attack and come to her aid.^"
set time = false
else
write "It's too soon to decide now. You have to hear what she's got to say.^"
set time = false
endif
}

{not_forgive
write "You lean close to her and you see a glint of happiness in her eyes, as if she really thought you'd believe her. As your lips touch and her eyes close, you start to telekinetically choak her, watching as her eyes go wide in shock and fear and she breaks the kiss, gasping for the breath that would never come.^"
write "She quickly reaches into her pocket to take out a gun, but you knew that she was lying. You knew she had a gun so you are prepared. But what she takes out isn't a gun. It's a keyring which she holds out to you and you take, confused. But despite your confusion, you don't let go. You won't ever let go. She opens her mouth, trying to say something with the remaining breath in her lungs. You lean closer to hear her last lie, or the only truth she has ever said.^"
write "~The password... to your cell... is ~I love you~, with... without... the period...~^"
write "Her voice trails off and she closes her mouth, smiling at you. You can't find out the meaning of the smile on her lips, but before the life goes out of her eyes, you think you can see a hint of loss in them.^"
ensure soyala has DEAD
ensure soyala hasnt lifted
move keyring to player
}

{mind_raise
if player(status) = 5
if soyala hasnt lifted
if soyala has DEAD
write "You lift soyala's dead body into the air.^"
ensure soyala has lifted
return
else
write "You lift Soyala out of her chair and into the air. "
endif
if @talk_to_soyala = 0
write "She doesn't turn to face you, neither does she make a sound of surprise, as if she already knew. As if she already expected your move.^"
else
write "Soyala looks at you, undisturbed, comfortable as if she was still sitting in the chair.^"
endif
ensure soyala has lifted
else
write "She's already lifted into the air!^"
set time = false
endif
else
write "You don't have your power back yet.^"
set time = false
endif
}

{mind_lower
if player(status) = 5
if soyala has lifted
if soyala has DEAD
write "You lower Soyala's dead body.^"
ensure soyala hasnt lifted
return
endif
write "You slowly lower Soyala onto her chair.^"
ensure soyala hasnt lifted
else
write "But Soyala is already on the ground!^"
set time = false
endif
else
write "You don't have your power back yet.^"
set time = false
endif
}

{mind_push
if soyala has DEAD
write "But she's already dead!^"
set time = false
return
endif
if player(status) = 5
if soyala has lifted
write "You push Soyala around in the room. Soyala stays unperturbed, though.^"
else
write "You push Soyala further into the chair.^"
endif
else
write "You don't have your power back yet.^"
set time = false
endif
}

{mind_pull
if soyala has DEAD
write "But she's dead!^"
set time = false
return
endif
if player(status) = 5
write "You pull Soyala against you telekinetically. Her body goes rigid against yours, so you let her go.^"
else
write "You don't have your power back yet.^"
set time = false
endif
}

{mind_push_at_chair
if player(status) = 5
write "You don't have a reason to attack yet. You are too doubtful.^"
else
write "You don't have your power back yet.^"
endif
set time = false
}

{mind_push_at_north_wall : mind_push_at_south_wall : mind_push_at_east_wall : mind_push_at_west_wall : mind_push_at_wall
if player(status) = 5
if soyala hasnt DEAD
if @soyala.talk_to = 1
write "You don't even bother to decide what she's got to say. You "
if soyala hasnt lifted
say "raise her up into the air and "
endif
write "throw her against the wall. She hits it head-first, then slumps to the floor, dead.^"
ensure soyala has DEAD
ensure soyala hasnt lifted
else
write "You decide that she's lying. You know it. So, you "
if soyala hasnt lifted
say "raise her up into the air and "
endif
write "throw her against the wall. She hits it head-first, then slumps to the floor, dead.^"
ensure soyala has DEAD
ensure soyala hasnt lifted
endif
else
write "But she's already dead!^"
set time = false
endif
else
write "You don't have your power back yet!^"
set time = false
endif
}

{take
if soyala has DEAD
write "But she's dead. It's too late to change your decision.^"
else
execute soyala.forgive
endif
}

object keyring: keyring key ring
short a "keyring"
long "A keyring is on the ground.^"
mass 1
parent limbo

{examine
write "It's a keyring with a key on it tagged ~helicopter~. It's your way out of this prison.^"
}

object door : cell door 103 door1 door103

{examine
write "It's a steel door that is about as thick as you, and it's pure steel... although it seems it must have another substance in it, since your power was not able to reach through when you tried the first day. Anyway, what the door is made of is the last of your worries right now."
if player(parent) = cell103
write " There is a handprint-reader in the center of the door that Soyala uses to open the door from inside.^"
else
write ^
endif
}

{feel
write "There's no point trying. You can't fool that device.^"
set time = false
}

{mind_push
if here(north) != nowhere
write "The door is already open!^"
else
if player(status) = 5
write "Since the door is slightly ajar and not completely sealed, you can get a telekinetic grip on it, and although it's very heavy, you grit your teeth and push with all your might. Finally, it's open enough to let you pass, and you can't help but let out a shout of triumph.^"
set stage = 6 #the gas is now being pumped into the whole building
set here(north) = corridor1
set here(out) = corridor1
else
write "Your power is not back yet. You should wait until it is.^"
endif
endif
}

{open
if mode = easy
execute button.mind_push
else
write "You need to do that manually.^"
set time = false
endif
}

{close
if here(north) = nowhere
write "But the door is already closed!^"
else
write "It's automatic and requires authorised access. You don't have the code.^"
set time = false
endif
}

{unlock
execute door.open
}

{mind_pull
if here != nowhere
if scarf(parent) = here
write "The scarf will prevent the door from fully closing.^"
set time = false
else
write "You telekinetically pull the door closed, giving up on your plans of escape. The odds are just too low, and you don't feel like fighting. What can they possibly do? In the end, they might kill you"
if @monitors.examine = true
write ", like Mark and Alexander,"
endif
write " or they might not. Either way, you don't see it in yourself to go around fighting people. That's just not you. You will stay, and meet the end, whatever it may be.^"
execute +game_over
endif
else
write "The door is not fully open yet.^"
set time = false
endif
}

object reader : handprint fingerprint scanner reader identifier
has NOT_IMPORTANT
parent door

{examine
write "It's a circular device with a transparent surface, bordered by plastic. If you touch the transparent part, it'll open the door. That is, if you have authorised access. You don't.^"
}

{feel
execute door.feel
}

location corridor1 : corridor 1
short the "corridor number one"
west office

{look
write "Stretching from west to east, this corridor is made of hardened steel like the rest of the building. The ceiling is not too high, in fact, it seems to be about ten feet high, and the lights set up in regular intervals illuminate the otherwise bare and lifeless passage, the brightest of them being a red, revolving light that indicates danger. The door behind you leads back to your cell when it's opened, and there is a keypad beside it. On the wall opposite your cell is written the number, ~1~.^"
}

{eachturn
ifall stage = 15 : eric(parent) != here #The player has just come out, and Eric (the guard) should appear in one turn.
set stage = 16
return
endif
ifall stage = 16 : eric(parent) != here #The player has waited one turn, and Eric should appear now.
if gone_before_eric_comes != 1
write "^The one and only guard, the brave hero of the day, walks authoritatively towards you, and it's the one you wished it to be; Eric. As he sees you waiting for him, something seems to fall in his mind with a ~clunk~, and he steps towards you with an expression of one walking to his own doom seeming to be hidden behind his trained, professional, expressionless face.^"
endif
move eric to here
set stage = 16
endif
ifall eric(parent) = here : gun(parent) = eric : eric hasnt DEAD #He should try to shoot the player.
set max_rand = 2
set INDEX = random
if INDEX = 1
write "^Eric shoots a bullet towards you, causing you to wave a dismissive hand, diverting it's course.^"
endif
}

{movement
if compass = east
if office has VISITED #The player has been in the office so the alarm should be off.
if @notebook.read = 1 #The player knows that Mark is dead.
write "There's no point going there. Mark is already dead.^"
else
if @monitors.examine = 1 #The player knows that Mark is dead, he has seen it in the screens.
write "Mark is not alive. There is no point in going to his cell.^"
else
write "You have more important things on your mind than going to see Mark right now.^"
endif
endif
else
write "You can't open any doors, even if you know the password. Rescuing Mark has to wait for now.^"
endif
set time = false
return
endif
if compass = west
if eric has lifted
write "Lowering Eric to the ground, you "
else
write "You "
endif
write "walk westwards through the corridor towards the office"
if chair has lifted
write ", pulling the chair in with you.^^"
move chair to destination
else
write ".^^"
endif
if eric(parent) != corridor1
set gone_before_eric_comes = 1
write "Eric runs passed you as you walk purposefully towards the office, pretending as if he hasn't seen you. His eyes go slightly wide, though, as you offer him a smile.^^"
if soyala(parent) != office
move soyala to office
endif
return false
endif
if eric hasnt DEAD
write "Eric tracks your movements with wide, fearful eyes, from his position in the corridor, paralysed with fear.^^"
endif
move player to destination
if soyala(parent) != office
move soyala to office
endif
endif
if compass = south
if here(south) = nowhere
write "The door to your cell is closed. You need to know the password to open it.^"
return
else
return false
endif
endif
return false
}

object button : open button 
short the "open button"
parent cell103

{examine
if soyala(status) = 7
write "It's a small button marked ~open~."
else
write "You can't see it yet. The door is shut.^"
set time = false
endif
}

{mind_push
if here(north) != nowhere
write "The door is already open!^"
else
if player(status) = 5
write "You reach through the small opening with your mind and send thin tendrils of energy to push the button marked as ~OPEN~. The door slides open, finally letting you have access to corridor number one northwards.^"
set stage = 6 #the gas is now being pumped into the whole building
set here(north) = corridor1
set here(out) = corridor1
else
write "Your power is not back yet. You should wait until it is.^"
endif
endif
}

{push
write "You can't push it by hand. It's on the other side of the door.^"
set time = false
}

object light : red light revolving danger lights
short a "red, revolving light"

{examine
write "This glaring red light is illuminating every shadow, every corner, and it means every door, with or without a password is closed."
if @ = 1
write " It actually means you are in a kind of trouble, since you can't get out. It also means that you can't rescue Mark for now.^"
else
write ^
endif
}

{shoot
if gun(parent) = player
write "You shoot the lights overhead, but nothing happens. The lights are bullet-proof, unsurprisingly.^"
else
write "You have no gun to shoot with!^"
endif
}

object chair : chair
short a "chair"
mass heavy
long function

{long
if chair has lifted
write "A chair is floating in the air.^"
else
write "A chair is here on the ground.^"
endif
}

{examine
if @ = 1
write "This is the chair that the first day Eric was sitting on, keeping a watch on you, Mark, and Alexander. You still remember how harsh he was to you, although he was the only one here that hated you, for no apparent reason.^"
else
write "It's a normal wooden chair, although it brings back the memories of your first day here, when you were trying so hard not to cry in panic.^"
endif
}

{mind_raise
if chair(parent) = player
write "You drop the chair onto the ground so that you can lift it telekinetically.^"
endif
if chair hasnt lifted
write "You stare at the chair which obediently lifts up into the air.^"
ensure chair has lifted
else
write "You are already holding it telekinetically!^"
endif
}

{mind_lower
if chair has lifted
write "You lower the chair gently to the floor.^"
ensure chair hasnt lifted
else
write "You are not lifting it!^"
set time = false
endif
}

{mind_push_at_eric
if eric hasnt DEAD
if chair hasnt lifted
if eric(next) = 0 #His shins aren't already broken.
write "You push the chair towards Eric. Before he can do anything, the chair hits his shins and he shouts in pain as he falls onto the floor with a crunch.^"
set eric(next) = 1
else
write "His shins are already broken!^"
endif
else
execute eric.greeting
write " Now I'm going to hit you as you hit me, only I'm going to gather all of what you did to me in one blow.~^"
write "You hurl it towards Eric's forehead. As the chair gets closer to the wide-eyed Eric, it spins around, and the upper left leg hits him above his right eyebrow, breaking the bone and going into his head. As life seems to leave his eyes, you pull the chair out and allow it to crash to the floor, releasing Eric's dead body to fall with it as well.^"
ensure eric has DEAD
ensure chair hasnt lifted
set eric(status) = 1 #He's been killed by the chair. Useful for the description.
endif
else
write "He's already dead!^"
set time = false
endif
}

{mind_push_at_soyala
execute soyala.throw_at_chair
}

object door103 : door 103 door1 103 door
short the "door leading to cell 103"

{examine
execute door.examine
}

{open
write "You need to operate the keypad to do that.^"
set time = false
}

{close
execute door103.open
}

object keypad : keypad key pad keyboard screen
short the "keypad controlling your cell's door"

{examine
write "It's a keypad installed on the wall beside the door of your cell. It has a complete keyboard with the alt, control, shift, capslock, tab, and stuff like that removed. There are, however, the letters, brackets, parentheses and the numbers left. There's no chance in a thousand years that you can find the password by typing it in again and again. Not that it's important to get back to your cell, anyway.^"
write "The screen is blank, and will be blank until you type the password. You don't know the password, so it will always be blank.^"
}

{type_on
ifstring $string = "i love you"
if @soyala.forgive == 1 : @soyala.not_forgive == 1
write "You type ~I love you~ on the keypad, and the door swings open.^"
else
write "You type ~" $string "~ on the keypad, and before your unbelieving eyes, the door slides open!^"
endif
set corridor1(south) = cell103
set corridor1(in) = cell103
set cell103(north) = corridor1
else
write "You type ~" $string "~ on the keypad, but nothing happens... as expected.^"
endif
}

object eric : eric guard hero
has ANIMATE
short name "Eric"
long function
mass heavy
parent limbo

{long
if eric has DEAD
write "Eric lies on the ground, motionless.^"
return
endif
ifall eric has lifted : gun(parent) = eric
write "Eric is looking down at you from where you're holding him in midair, gripping his gun tightly.^"
return
endif
if gun(parent) = eric
if eric(next) = 1
write "Eric sits on the ground, gun in hand.^"
else
write "Eric stands here, gun in hand.^"
endif
return
else
if eric has lifted
write "Eric is looking down at you from where you're holding him in midair, weaponless, hopeless, doomed.^"
return
else
if eric(next) = 1 #His shins are broken so he can't be standing.
write "Eric sits on the ground"
else
write "Eric stands before you"
endif
write ", his empty hands dropped by his side as he waits for your last move hopelessly.^"
return
endif
endif
}

{examine
ifstring command[0] = "search"
if eric has DEAD
if gun(parent) = eric
write "You find nothing, other than his gun which you pick up.^"
move gun to player
else
write "You search Eric's body, but find nothing useful.^"
return
endif
endif
endif
if eric has DEAD
write "Eric's once hardened face is now set in an expression of surprise. His black eyes, once full of hatred towards you are now empty. Lifeless. Unmoving. "
if eric(status) = 1
write "Above his right eyebrow is a hole; the hole the leg of the chair made when it went through his forehead.^"
endif
if eric(status) = 2
write "His limbs are twisted in an unnatural position, caused by the supernatural force that has pushed him against the wall.^"
endif
if eric(status) = 3
write "He is shot between the eyes.^"
endif
if eric(next) = 4
write "His shins seem to be broken.^"
endif
return
endif
write "Eric's face is hard and expressionless. He has black hair that is cut short, and black, cold eyes. He wears a white uniform, completely in contrast with his character and eyes"
if gun(parent) = eric
write ", and is holding a gunn.^"
else
write ".^"
endif
if @ = 1
write " Do to what he did to you in your first day here, you know that the expression is true; this man doesn't know pitty, doesn't know caring, doesn't know anything. It's pretty strange in itself that he knows love -- although who can say, maybe that's a political move, commanded by his supperiors?  He's nothing but a monster. You feel your anger mount as he stands there, staring at you, reminding you of what he has done in the past. And for the first time, you see a glint of fear in his eyes that satisfies a need deep within your gut. You stare at him challengingly, daring him to attack you, daring him to say anything, anything at all.^"
else
write ^
endif
}

{mind_raise
if eric has lifted
write "You're already holding him in midair!^"
set time = false
else
if eric hasnt DEAD
write "You feel your lips stretch to a smile as you command the energy at your disposal to raise Eric into the air. The energy obeys, and Eric kicks out in surprise as he's lifted.^"
else
write "You lift Eric's corpse into the air.^"
endif
ensure eric has lifted
endif
}

{mind_lower
if eric has lifted
if eric hasnt DEAD
write "You lower Eric to the ground, and he can't hide the look of gratitude that comes over his face.^"
else
write "You lower Eric's dead body to the ground.^"
endif
ensure eric hasnt lifted
else
write "He's already on the ground!^"
set time = false
endif
}

{greeting
write "You look "
if eric has lifted
write "up "
endif
print
at Eric and smile at him. 
~Well hello there, Eric.~ you say, your voice muffled by the scarf, but still audible.^^
He, however, doesn't speak, just stares at you. What would he say? What could he say? That he's sorry? That he would take it all back if he could? He wouldn't if he could, and he doesn't care. No one cares. No one knows. No one wonders.^^
~I know.~ you continue, even though he can't see your smile, even though he can't see your lips. ~You have nothing to say. I expected this, you know. And to be honest, I kind of wished you were the guard that was remaining here. Because, after all, we have some things to settle between us, don't we?~^^
He doesn't speak.^^
~Do you remember what you did to me?~ you ask him and shift your weight from one foot to the other as you wait.^^
He doesn't speak.^^
~Yes, you're right,~ you go on, as if he had answered you. ~You hit me. With this chair. I remember it as if it was yesterday. It was the upper left leg, do you remember? Of course you don't. Because you didn't care. You don't care. But I do. I do remember.~ you pause for a second to give him a chance to say something.^^
He doesn't speak.^^
~I remember the pain, you see,~ you tell him, ~because you hit me right above my right eyebrow. Right here.~ You put your fingertip on the spot, indicating the point. ~And you know what I did? I didn't move, didn't shout, didn't do anything. Just cried. Cried in pain, in frustration, cried because I felt powerless. Cried because I was bound and you were not, I was a prisoner and you were not, I was doomed and you were not. Do you remember, when I entered,~ a sob makes you pause as your body shakes slightly and you continue, ~as I entered, you pushed me to the floor, head-first? Why did you? Did you hate me from the very beginning? Were you jealous? Jealous because of me having a power and you not having one? Jealous because of... because of...~ you stop in midsentence as you remember. The very first sight of Soyala's face, her special, warming smile, her face lighting up, your hopes increasing, threatening to burst, an involuntary smile spreading over your own face, and then, being backhanded by Eric. And 
even then, when you were lying dazed on the ground, from beyond the stars dancing in your vision, you could see concern in her face. And finally, inevitably, you know it. She loved you. She did love you. What went wrong in the middle of the way? What happened? Why did she... you come out of your thoughts and look at him in disbelief. ~Was it because of her loving me that you hurt me so much? Alright then, now I'm going to show you how much it hurt.
.
}

{mind_push
if eric hasnt DEAD
execute eric.greeting
write " Now I'm going to hit you as you hit me, only I'm going to gather all of what you did to me in one blow.~^^"
if eric has lifted
write "You "
else
write "Lifting Eric into the air, you "
endif
write "hurl him with a bone-breaking force against the wall, putting all your fury, all your anger behind the push. He hits the wall and you hear bones break, and you let him silently slip onto the steel floor.^"
set eric(status) = 2
ensure eric has DEAD
else
write "He's already dead!^"
endif
}

{mind_pull
if @ = 1
write "You pull Eric closer.^"
else
write "He's already as close as possible.^"
set time = false
endif
}

{shoot
if gun(parent) = player
if eric hasnt DEAD
execute eric.greeting
print
 Now, I'm going to be kinder towards you and end your life very quickly.~^
 You raise your gun and take aim. When you shoot, the aim is not as you wanted it to be, so you push the bullet slightly to the left to hit him exactly between the eyes. Eric, lifeless, falls to the floor.^
.
set eric(status) = 3
ensure eric has DEAD
else
write "He's already dead!^"
endif
else
write "You don't have a gun.^"
endif
}

{talk_to
if @ = 1
write "~Hi there, Eric!~, you say, smiling good-naturedly.^"
write "Eric stands there, "
if gun(parent) = eric
write "gun in hand, "
endif
write "glaring at you hatefully, and showing no signs of wanting to talk.^"
else
write "He has already shown you that he has no intention of conversing with you.^"
set time = false
endif
}

{move
execute eric.throw_at_wall
}

{attack
write "He'll probably win you in a hand-to-hand fight. You need to use your telekinesis to get rid of him quickly.^"
}

object gun : gun weapon shotgun shot gun "shot gun"
short a "shotgun"
long function
mass 20
parent eric

{long
if gun has lifted
write "A shotgun is floating in the air before your eyes.^"
else
write "A shotgun is lying on the ground.^"
endif
}

{examine
write "It's an ordinary shotgun.^"
}

{mind_pull
if gun(parent) = eric
write "You stretch your hand as if asking for Eric's gun, and it flies out of his hand, landing on your outstretched palm.^"
move gun to player
else
return false
endif
}

{mind_push
if gun(parent) = eric
write "You push the gun out of Eric's hand and into the room behind him.^"
move gun to office
else
write "There's no point in pushing the gun around.^"
set time = false
endif
}

{mind_raise
if gun(parent) = eric
write "You raise the gun into the air and out of Eric's grasp.^"
ensure gun has lifted
else
if gun(parent) = player
write "You are already holding it! You need to drop it first.^"
set time = false
else
write "You lift the gun into the air telekinetically.^"
ensure gun has lifted
endif
endif
}

{give_to_eric
if gun(parent) = player
write "Why would you want to give the gun back to him?^"
set time = false
else
return false
endif
}

location office : office
short the "office"
east corridor1

{look
write "This office is spacious, but everything seems to be neatly in place. "
if notebook(parent) = desk
write "A notebook is on the desk in the center of the room, and the"
else
write "The desk in the middle of the room is bare, and the"
endif
write " northern wall is completely taken by a network of screens, each showing one cell. Other than that, the office doesn't even have a window, let alone anything fancy.^"
if @ = 1
write "As you enter the room, Soyala presses a button and the emergency alarm finally relieves you of it's deafening screams. Soyala, however, doesn't even turn as you approach the desk, seeming to be lost in whatever she's watching on the network of monitors.^"
endif
}

{movement
if compass != east
write "You can only go east.^"
set time = false
else
if eric(parent) != corridor1
move eric to corridor1
endif
return false
endif
}

object monitors : screens cells screen monitor monitors network cell
short a "network of monitors"

{examine
if @ = 1
write "You walk towards the screens installed on the northern wall and look at them.^"
endif
write "On the left screen, you can see your cell, which is, unsurprisingly, empty. The screen on the right of the one showing your cell, the one on the center, shows Alexander's cell, which is, again, empty. The last one, however, shows an occupied cell, Mark's cell."
if @ = 1
write " But something about Mark catches your eye. Leaning to get a closer look at him, you see that there is a nuse around his neck. He's hanged himself. No. He's been hanged. This is the most likely answer. Why would he hang himself? He had no reason to. This was just the day he wanted to escape. Why, then? There is only one explanation. Either Soyala, or Eric have killed him. You take your eyes away from that hanging figure, and look at Soyala, who is, now you can see, looking at the same thing - Mark's dead body.^"
endif
}

object body : mark dead body mark's
short name "Marks' dead body"

{examine
write "Mark is -or rather was- handsome. He has black, short-cut hair with broad shoulders and a powerful build. Like everything else you see in this prison, his uniform is white.^"
if @ = 1
write "Why is everything white around here, anyway? Is it just for the heck of it, or they are meant to keep you happy? How can you be happy when someone comes and kills your two friends, your only friends who understanded you? Maybe they are going to help you speed up in your short journey to the depths of insanity? Who knows? probably even those who govern this prison don't know, why should you even care?^"
endif
}

object desk : desk table
short a "Table"

{examine
write "It's an ordinary desk, without even any drawers. It has, however, a notebook on it.^"
}

object notebook : notebook notes papers
short a "notebook"
long "A notebook is dropped on the ground.^"
mass 1
parent desk

{examine
write "It's a notebook, each paper marked with a certain date, and contains the name of the prisoners and important events.^"
}

{read
write "It reads:^"
print
January 3, 2009: Prisoners have been brought in.^
July 8, 2009: The news about the project's failure has been received. Eliminating the prisoners one by one.^
July 9, 2009: Aaron Milan has been given the task of killing Alexander, the prisoner with mind control abilities.^
July 9, 2009: Milan has succeeded. Mark, the one with electro-magnetic manipulation abilities is next.^
July 10, 2009: Eric Kelsh has succeeded in his task. everyone has agreed that the task of killing the last prisoner, Adrian, be done by me, Soyala Jablonsky.^
.
}

object kryten: myself self me
 has		ANIMATE
 short		name "yourself"
 capacity	42
 parent cell103
 player

{clean
if toilet(status) = 1
write "You wash your hands under the faucet which automatically lets the water run through your fingers.^"
set toilet(status) = 0
else
if soyala(parent) = here
write "No. She'd think you've spat the pill onto your hand or something. You can never know. Just wait until she's out of the cell.^"
else
write "You wash your face in an effort to clear your head and gather your thoughts, nodding slightly to the motion detector which happily sprays water onto your face.^"
endif
endif
}

{examine
write "You'll need a mirror to see how you look. Looking down right now, you can just see the white outfit you have been given to wear.^"
execute "+inventory"
}

{take
write "...seriously?^"
set time = false
}

object pill : pill golden
short the "pill"
long "The golden pill is lying in Soyala's palm, waiting for you to pick it up.^"
mass 1
parent limbo

{examine
if pill(parent) = player
write "You can't look at it right now since it's in your mouth and under your tongue, but you can remember that it was round, and golden yellow.^"
else
write "It has a deep golden color, and is round, like other pills."
if @ = 1
write " The color doesn't remind you of gold, though. It rather reminds you of the times you've swallowed it down, the times that you were tested to see if your body can digest it, and how long it can keep your power at bay. They increased and decreased the doses until they were satisfied, and until then, you were like a lab rat. Come to think of it, weren't you a ~lab rat~ from the beginning? Didn't you bring this fate down on yourself?^"
else
write ^
endif
}

{drop
if soyala(parent) = here
write "Not yet. Wait until she leaves.^"
else
write "You spit out the pill onto the ground and squash it under your shoe. It's gone, completely gone, as you even erase the smeer it left behind with the tip of your shoe.^"
move pill to limbo
endif
}

{insert_in_sink : insert_in_toilet
if soyala(parent) = here
write "Not now... wait until she leaves.^"
else
if noun2 = toilet
write "You drop the pill into the toilet and watch with satisfaction as it dissolves.^"
move pill to limbo
endif
if noun2 = sink
write "You put the pill in the sink and watch with satisfaction as the faucet turns on upon the wave of your hand, washing the pill down with it, to nothingness. To oblivion.^"
move pill to limbo
endif
}

{drink
execute cup.drink
}

{eat
if this(parent) = player
execute this.drink
else
write "You should get the pill first!^"
set time = false
endif
}

{take
if pill(parent) != player
write "You take the pill from Soyala and put it in your mouth, and under your tongue."
if cup(parent) = player
write ^
else
write " She hands you the cup wordlessly.^"
move cup to player
endif
move pill to player
else
if soyala(parent) = here
write "No, you need to let the pill stay in your mouth... for now.^"
set time = false
else
execute pill.drop
endif
}

{throw
execute pill.drop
}

{throw_at
execute this.drop
}

object cup : plastic cup water
short a "cup of water"
mass 1
parent soyala

{examine
write "It's a plastic cup, full of water.^"
}

{drink
if this(parent) = player
write "Being careful to keep the pill under your tongue, you swallow the contents of the cup in small gulps to be able to control the pill that just seems to want to slip out of where it is hidden, then hand the cup to Soyala.^"
move cup to limbo
set soyala(status) = 4
else
write "You need to get the cup first!^"
set time = false
endif
}

{take
if cup(parent) != player
write "You take the cup from Soyala and look down at it."
if pill(parent) = player
write ^
else
write " She hands you the pill wordlessly, and you put it inside your mouth, carefully sliding it under your tongue.^"
move pill to player
endif
move cup to player
}

{drop
if this(parent) = player
write "Come on, now. Why would you need to get rid of the cup?^"
endif
}

{throw
execute this.drop
}

{throw_at
execute this.drop
}

{+no_light
write "It is too dark to see.^"
set time = false
}

{+title
style subheader
write here{The} ^
style normal
if player has SITTING
   write "(sitting)^"
endif
}

{+game_over
write "^"
endgame
}

object journal : journal notebook page
short name "Soyala's journal"
long "A leather-bound book journal is lying on the ground here.^"
parent limbo

{examine
write "This is Soyala's journal, since it has the name ~Soyala~ written on it in a flowing, feminine handwriting.^"
}

{read
if journal(status) = 0
proxy "open journal"
endif
if journal(status) = 1
print
Today they brought them in. The prisoners, I mean. I wish no one would ever be in my position to see the expression on their faces. One stared with hatred, the other had a detached air, as if he was going to die. One smiled, as if determined to fight against his bonds. I knew that boy was going to give us the most trouble. The smile on his lips, the hope in his eyes, the way his face was set in an expression of determination, the way he walked as if he was in his castle, these all stole my heart. From that first moment, I was in love with him. He knew it, too, just as well as I did. He knew it and caught my eye, and smiled at me. My knees weakened. I wanted to sit down on the ground and watch his smile and do nothing else. I wanted to be carefree like other girls my age. I wanted to be loved. I wanted to love. But there were those who were determined not to let it be so. Because, as I was staring helplessly at him, Eric backhanded him across the face. I looked on with horror and disbelief, but quickly hid it, like I was supposed to do. Like I was trained to do. The young man stood up and, much to my surprise, smiled at Eric. How lovely was he. How kind his features were. I couldn't hold my gaze from seeking his, and he knew it, again. He looked at me from the corner of his eye, and again, smiled as he and his other friends were led away. Perhaps they knew each other, or perhaps they didn't, but in either case, they'll be good friends soon. Very soon. I'll look into it.^
.
endif
if journal(status) = 2
print
Today, I went to see him. My man, I mean. Perhaps I'm desperate. Why not? Why shouldn't I be? I've been trained for six years to be what I am. I haven't been allowed to go anywhere, to meet anyone other than the team I was assigned to work with. Why shouldn't I be desperate? With that capturing gaze, with that carefree smile, why shouldn't I be desperate? So I went to see him. I'm assigned to give him his pills. As you have already guessed, Eric was not happy with this decision, but what could he do? And as you have already guessed again, I like it. In fact, I love the opportunity.^
I watched him take the pill as I was supposed to. I didn't talk to him much, as I was supposed to. I did talk to him though. Only a little bit. OK, so I acted against the rules There. But who cares. I love him. I mean, come on, stop it. It was just a ~Where do you come from?~ and a ~How do you like it here?~ and that kind of thing. I didn't ask him ~Do you love me?~ for God's sake! Well, not yet, anyway. That has to wait.^
.
endif
if journal(status) = 3
print
I went to him again. For another pill. Another brief meeting. He had a bruise on his forehead, just above his right eyebrow. I wanted to touch the bruise and tell him that it's OK, I can increase the speed of his recovery from the wound. I wouldn't want him to get hurt. I just want him to smile at me. I just want him to look at me and tell me that we'll somehow, as impossible as it sounds, get out of this, both alive and unscathed, but I could do none of that. Neither could he. So I waited. When it was my shift to keep watch on the prisoners, I slipped into his cell and healed his wound. Not completely, only a bit so that it won't hurt him anymore. I could see the pain in his eyes that morning when I gave him the pills, but he didn't tell me what had happened, no matter how much I insisted.^
.
endif
if journal(status) = 4
print
And another day, another pill, another talk. This time, I went to him in the night for the talk, when no one could watch. It was all hushed whispers and giggles and laughter, but it was the best day of my life. He asked me how long they were going to hold him here. I said I didn't know. I really didn't. I was a prisoner, just like him. The only difference was that he didn't know it. He asked me about how much things have changed outside or how long he's been here. I told him it has not been long and that nothing has changed. Yes, I lied to him. It had been two months, but I could see his resolve weakening. He had to think it wasn't too long. Yes, I lied to him about things not having changed, too. I didn't know, either. I wasn't supposed to go out, wasn't supposed to get a breath of fresh air, just like him. Just like his friends, Mark and Alexander. We seemed to have nothing in common, but yet we have everything in common. Thinking of that, I think it is the main point of the prison. It is a prison for them as much as it is for us. The only thing is that we are like guards that take care of them, and they hate us, while we have nothing to do with it. They have told me that they will pay my mother and sisters more money than they ever needed. I've sacrificed myself for them. My life for them. I told my bosses about my power to heal people so that they would pay my family, and got myself moved to a place that has recycled air, no TV, nothing to do, only pills to give, and monitors to stare at.^
.
endif
if journal(status) = 5
print
Today was the day. I told my team members that I'll make Adrian fall in love with me, so that we can work on him more because he's the most powerful one of them, and his power is the most useful one, so in front of them, I went to his cell, and told him the lie. It seemed to be a lie, but it was true. I loved him. I love him. I will love him.^
After that, I am more free to go to him, in an effort to get him to love me even more. Yes, they think it's an act, but it's not. It's not, and they'll find out soon enough. When we're hand in hand, somewhere far, far away.^
.
endif
if journal(status) = 6
print
I was told to try to manipulate Adrian today, to see how much our plans have worked. I cannot tell him that it's all an act and that he should play along; I'm being watched too closely for that, but I hope he'll understand and play along.^
.
endif
if journal(status) = 7
print
He did understand, fortunately. It seems like he's in love with me and he's following my lead whatever I tell him to promise. I asked him if he will kill people with his powers so that we'll be free and live together. He said yes. I asked him whether he will work for the government. He said yes. I can't believe this! He has really found out! I don't know how, but he knows it's all an act we have to play! Cool!^
.
endif
if journal(status) = 8
print
Reading back through my journal, I think I was wrong. I think he hasn't understood. I think I was the one that hoped he had. Because, despite our kisses and loving embraces, he seems to not like me anymore. When I go close to him I see an expression like a grimace on his face, as if... as if... I don't know. As if someone has said something behind my back. A lie, probably. And he won't tell me what the problem is. I hate it. I hate whoever did it. I'll make them suffer until the end of the world, I swear.^
.
endif
if journal(status) = 9
print
They have told us to kill them. The prisoners, I mean. The bastards want us to kill their toys for them, so they can keep their hands clean. I will resign. As soon as this damn so-called ~project~ is over, I will resign. They will kill me because I know their secrets, but I don't care. I'd rather die than see that expression of hatred on Adrian's face whenever he sees me. I'd rather die than not be able to tell him that it was all an act, all unreal. I want to tell him that I love him. But I can't. He won't believe me. He won't care. Besides, they will hear. They will see. My team members, I mean. And then they'll go to their bosses with information, in the hope of being promoted. I hate them. Both them and their bosses. I hate everyone, I hate everything.^
.
endif
if journal(status) = 10
print
Today they killed Alexander. They are going to go for Mark next. I caught his eye today in the corridor. Mark's, I mean. I told him that I want him to help Adrian create an escape plan. I don't care if he hates me, I want him to get out before it all goes wrong. I told him to tell him not to eat the pill. Of course I could've gave him another pill, but we had none. Besides, I was being watched all the time. They suspected that the ~act~ has become something more, so even if I had things to render the pill useless, I couldn't. I also told Mark to tell Adrian to use Aaron's scarf to keep the door open, and use the keypad to open the door once he's out. I also told Mark that he was going to be killed today. He knew. He told me to be brave. He told me to hope. He told me that Adrian is more clever than he lets to show, so I should believe in him. I should have faith in him to understand. But remembering the hatred in his eyes, the way I seem to disgust him, I can't do it, no matter how I try.^
.
endif
if journal(status) = 11
print
I have nothing more to write. I'm going to put my journal under Adrian's bed, but first I should get Eric occupied. There are no guards left, other than him. He'll probably want to challenge Adrian and try to kill him to improve his place in my eyes, in my thoughts. But I hate him. I've acted sweet around him to keep him handy in case I need him to do something, but honestly, I hate him. So while he's being distracted, I'll open the door and kick the journal under his bed. I'll also set the camera to view somewhere higher than the floor before I go in, so if they review the tape later, they wouldn't see what had happened. So this, I tell you Adrian, if you are reading these words before meeting me, which I think is impossible, since you didn't know the password to your cell, before I told you. I have loved you all along. Look back, and you will see. You were tricked though, just like everyone else. I counted on your intelligence, but I think my expectations were too much. I'm sorry to have failed you, I'm sorry not to have loved you as you wanted me to. But now you know the truth, although I might not be alive. I believe in you, Adrian. Did you know what your name means, by the way?^
The Dark One. Dark, like you. Although those who named you should've been unaware of your loving, caring, and kind side.^
Good luck, with or without me.^
.
if soyala has DEAD
write "You fall to your knees and put your head in your hands, and start to sob. You were wrong all along. You were wrong the whole time. You know it, but too late. You hate Soyala. Why couldn't she tell you earlier? Why did she have to wait until she was dead? Did she really think you were able to know that she was acting just for the benefit of the cameras? You have telekinetic powers, not mind-reading, for God's sake!^"
write "After a long time, maybe hours, or perhaps a day, you realize that the guards should be back soon. Getting to your feet shakily, you reach for the keys to the helicopter, and move towards the helipad."
 if eric hasnt DEAD
 write " Strangely, there is no trace of Eric as you move through the corridors."
 endif
write " Even though you know nothing about flying a helicopter, you think falling to your death with a helicopter is much more convenient than being alive right now. Still crying, you turn the ignition key and start to fly off, without an aim, without a destination, broken. A word from the last lines of what Soyala had written bubbles up through your murky thoughts:^
~Adrian, the dark one.~^"
execute +game_over
else
write "So you did make the right decision after all. You smile as you get to your feet, and break into a run as you hear the sound of the helicopter"
if eric hasnt DEAD
write ", shooting Eric a glare as you pass him"
endif
write ". Maybe she's going to fly off and leave you alone in here. Taking the stairs three at a time, you get there just at the time Soyala jumps down from the helicopter's main cabin to come down and call you. As she sees you, she looks disappointed, as you, again, do not trust her. She motions to you to get into the helicopter and as you do, she starts to fly off. The prison that seems like a normal building from outside, but holds a thousand secrets in it, drops down slowly as the helicopter rises, but the scars it has left on you have yet to heal.^"
execute +game_over
endif
endif
}

{turn
if journal(status) < 11
write "You turn the page.^"
set journal(status) + 1
else
write "You have already reached the last page.^"
set time = false
endif
}

{open
write "You open the journal to the first page.^"
set journal(status) = 1
}

object north_wall: north north wall
 has			NO_TAB
 plural			walls
 short          the "north wall"

object south_wall: south southern wall
 has			NO_TAB
 plural			walls
 short          the "south wall"

object east_wall: east eastern wall
 has			NO_TAB
 plural			walls
 short          the "east wall"

object west_wall: west western wall
 has			NO_TAB
 plural			walls
 short          the "west wall"

object wall : wall steel
plural walls
short the "wall"

object ground: ground floor
 has            SURFACE NO_TAB
 short          the "ground"

{+mind_raise : +mind_lower : +mind_push : +mind_pull
if player(status) != 5
write "You can't use your telekinesis right now.^"
set time = false
return
endif
if noun1 has lifted
write "You are already holding it telekinetically!^"
set time = false
return
endif
if noun1(parent) = player
write "You already have it in your inventory.^"
set time = false
return
endif
if noun1 = player
write "You can't lift yourself up. Many times you wish you could, though.^"
set time = false
return
endif
write "There's no point in doing that.^"
set time = false
}

{+ask_for
write "You should type "
style bold
write "talk to <person>"
style normal
write " to talk to them. There is no ask or tell command in this game.^"
}

{+ask_about
write "You should type "
style bold
write "talk to <person>"
style normal
write " to talk to them. There is no ask or tell command in this game.^"
}

{+tell_about
write "You should type "
style bold
write "talk to <person>"
style normal
write " to talk to them. There is no ask or tell command in this game.^"
}

{+mode
if $integer = 1
execute +mode_easy
else
execute +mode_normal
endif
}

integer mode

{+mode_easy
if mode = 1
write "You are already playing in easy mode.^"
set time = false
else
write "You are now in easy mode.^"
set time = false
set mode = 1
endif
}

{+mode_normal
if mode = 0
write "You are already playing in normal mode.^"
else
write "You are now playing in normal mode.^"
set time = false
set mode = 0
endif
}

{+mode_check
write "You are currently playing the "
if mode = 1
write "easy "
else
write "normal "
endif
write "version of this game.^"
}

{+movement
if here(compass) != nowhere
if chair(parent) = player(parent)
if chair has lifted
write chair{the} " follows you into " destination{list} ".^"
move chair to destination
endif
endif
endif
return false
}

{+shoot
if gun(parent) != player
write "You don't have a gun!^"
set time = false
else
write "There's no point in shooting " noun1{the} ".^"
endif
}

{+eachturn
move north_wall to here
move east_wall to here
move south_wall to here
move west_wall to here
}

{+kick
write "There is no point in kicking " noun1{the} ".^"
}

{+about
print
In this game, the main role (which you are playing) has an usual ability, and that is the ability to lift (and then drop), push and pull objects by thought alone, otherwise called as telekinesis. Because of that ability, you have four new commands you can (and should) use. Remember that you can do these abilities even to the objects others are holding (although there is only one person holding an object, but still).^
.
style bold
print
* mind push <object> - pushes the object.^
* mind pull <object> - pulls the object towards you and depending on the situation, into your hand.^
* mind raise <object> - raises the object into the air.^
* mind lower <object> - Drops the object to the ground. Remember that the object must already be lifted into the air for this command to work.^
.
style normal
write "Happy gaming! If this is your first interactive fiction game, check out the "
style bold
write "instructions"
style normal
write ", and if you are curious as to which people have played a part in the making of this game, check out the "
style bold
write "credits"
style normal
write ".^"
}

{+credits
print
I want to thank you first, for playing this game. Without an audience, this game wouldn't be created. Without a community to support it, there would be no ~Prisonbreak~, although, if you find this game too awful, this game being non-existent might've been for the better. <smile>^
The special thanks, first and foremost, goes to Stuart Allen, for creating JACL and implementing whatever outrageous request the users of his adventure-creation-language had, and helping out with the bugs, and practically going through the game more than a thousand times (I think). To be frank, I think he put more effort into finding Prisonbreak's bugs than he has put into his own game lately (I'm talking about bloody Guns, yes).^
My girlfriend helped too, at the times she made me sit down and write (even though that meant less of our time being spent together... on the phone).^
Robert Osztolykan and Elliott (both in the JACL community) helped with small bugs and story ideas, and their support.^
Also, Paul Livesey contributed to the game with a few fixes and going through the game once or twice. Thanks, Paul!^
Also, I should thank David Fisher for creating the competition -- and the inspiration -- along with the competition being in my favourite field (unusual abilities) that led me to creating this game. Thank you!^
Without these people, any of them, the game wouldn't exist, or wouldn't make it to the competition, or it would be ten times worse than it already is (thought it's not possible, huh?). So, thank you all, again!^
.
}

{+author
print
The author is called (as you already know) Parham Doustdar. He was born and lives in Tehran, Iran. He has recently (at the time of writing) turned nineteen, and English is his second language. If you see that the descriptions are too awful, or too unreal, it is because the author is blind, although the statement is not an excuse, rather a stating of the facts.^
He spent his time studying in the school created for the blind (one of the three in his city, which is the capital of his country), and was the first legally blind to study math and physics in the highschool. He got his diploma, despite all the problems, and entered the university, studying computers; software programming. At the time of writing, he has finished his first term in the university, and is in the middle of the second term. He has also been with his girlfriend for three years now, but since, since all of these aren't related to the game itself, it's kind of irrelivent to go into the details, boring the reader in the process.^
.
}

{+score
write "There is no score in this game.^"
}

{+quit_game
write "Are you sure you want to quit?^"
getyesorno yesno
if yesno = 0
write "Returning to the game.^"
else
if @journal.read = 1
write "Thanks for playing!^"
else
write "You give up on your thoughts of escape, leaving yourself in the hands of fate, to do with you as it pleases.^"
endif
terminate
endif
}

integer status_window 1
integer  OFFSET

{+update_status_window 
style reverse
padstring status_text " " status_width
write status_text
if total_moves = -1
   execute +print_centred<Prisonbreak<0
else
   cursor 1 0
   write here{The}
   setstring status_text "Moves: " total_moves
   execute +print_right<status_text<0
endif
style normal
}

{+prevent_escape
write "No. If you rebel now and try to run away from her without your powers, there's no chance for you to escape.^"
set time = false
}

{+object_info
if noun3 has WORN
   write " (being worn)"
endif
if noun3 has LUMINOUS
   write " (providing light)"
endif
if noun3 has ON
   write " (on)"
endif
ifall noun3 has CLOSABLE : noun3 hasnt CLOSED
   write " (open)"
endif
if noun3 = pill
write " (under your tongue)"
endif
}

#include "menu.library"
#include "utils.library"
#include "verbs.library"
#debug "debug.library"