! _Shade_
! Special source-code edition
! Copyright 2000-2002 Andrew Plotkin <erkyrath@eblong.com>
! http://www.eblong.com/zarf/if.html
!   This source code is provided for personal, educational use only. 
!   See README file for details.


Global fake_counter = 0;

Class Fake
  with
    self_obj 0,
    short_name [;
        print (name) self.self_obj;
        rtrue;
    ],
    parse_name [ obj wd num;
        if (self provides name) {
            wd = NextWord();
            while (WordInProperty(wd, self, name)) {
                num++;
                wd = NextWord();
            }
            return num;
        }
        
        obj = self.self_obj;
        if (obj provides parse_name)
            return obj.parse_name();
            
        wd = NextWord();
        while (WordInProperty(wd, obj, name)) {
            num++;
            wd = NextWord();
        }
        return num;
    ],
    before [;
        Examine, Search:
            "Vous n'arrivez pas vraiment à distinguer quoi que ce soit d'inhabituel.";
        Find:
            "Juste ici.";
        default:
            ! print_ret "[DEBUG] ", (the) self, ".";
            fake_counter++;
            if (action == ##Enter && (noun == fakefuton or fakedesk) 
                && fake_counter == 3) {
                fake_counter = 4;
            }
            switch (fake_counter) {
                1: "Vous faites un pas dans la pièce, mais un mouvement vif
                    vous distrait. Quelque chose vient de courir le long
                    du mur ? Vous ne le voyez plus maintenant.";
                2: "Vous vous avancez vers ", (the) self, " mais vous avez soudainement
                    la tête qui tourne. Sans doute la déshydratation.";
                3: "Il faut vous asseoir.";
                4: 
                    print "Vous tendez la main et touchez ", (the) self,
                        ". ";
                    print "On dirait du verre.^^";
                    print "Le reflet scintille comme de l'eau, mais le miroir
                        n'est formé que de chaleur @{2014} qui s'accumule
                        dans les dunes, remontant des sables.^^";
                    KeyPause();
                    print "^^^";
                    move book to Desert;
                    Desert.startup();
                    PlayerTo(Desert);
                    rtrue;
            }
    ],
  has scenery;

Object FakeApartment "appartement"
  with
    articles "Votre" "votre" "votre",
    seenonce false,
    description [;
        if (~~self.seenonce) {
            self.seenonce = true;
            print "C'est bizarre comme le soleil ne fait que rendre
                votre appartement plus prosaïque.^^";
            print "Ça n'est pas un super appartement, pour être honnête.";
        }
        else {
            print "Vous regardez votre unique et petite pièce.";
        }
        print " Un bureau, couvert de papiers, avec un ordinateur
            poussiéreux enterré sur le côté. Votre canapé. Une chaîne
            stéréo achetée d'occasion posée sur une boîte en carton. Le
            coin cuisine d'un côté et le coin salle de bain de l'autre,
            avec un placard sur le côté. Un miroir large tente de doubler
            la taille de la pièce (ça marche à moitié). Une fenêtre,
            dont le store est relevé, et la porte d'entrée grande ouverte.^";
        print "^Vos bagages sont empilés en désordre vers la porte.
            Une jacinthe est dans un pot près de la fenêtre.^";
        rtrue;
    ],
    before [;
        Vacuum: <<Take fakevacuum>>;
        Go: 
            "Vous avez assez tourné en rond hier soir.";
        Exit:
            "Le taxi n'est pas encore arrivé, même s'il ne devrait pas tarder.";
    ];

Fake -> fakelivingroom
  with
    self_obj apartmentproxy,
    before [;
        Examine, Search: <<Look>>;
        default: "Quoi ?";
    ];

Fake -> fakefrontdoor
  with
    self_obj frontdoor,
    before [;
        Enter: <<Exit>>;
    ];

Fake -> fakewindow
  with
    self_obj window,
 has female;

Fake -> fakewindowshade
  with
    self_obj windowshade;

Fake -> fakedesk "bureau"
  with
    self_obj desk,
  has supporter;

Fake -> -> faketodo
  with
    self_obj todo,
    articles "Votre" "votre" "votre",
  has ~scenery female;
    
Fake -> -> fakebook
  with
    self_obj book,
  has ~scenery;

Fake -> fakeplant
  with
    name 'pot' 'en' 'plante' 'terreau' 'jacinthe',
    short_name "jacinthe",
    self_obj plant,
 has female;

Fake -> fakeluggage
  with
    self_obj luggage,
 has pluralname;

Fake -> fakekitchen
  with
    self_obj kitchen;

Fake -> fakecounter
  with
    self_obj counter;

Fake -> fakecupboard
  with
    self_obj cupboard;

Fake -> fakestove
  with
    self_obj stove,
 has female pluralname;

Fake -> fakekitchensink
  with
    self_obj kitchensink;

Fake -> fakefridge
  with
    self_obj fridge;

Fake -> fakeglass
  with
    self_obj glass;

Fake -> fakebathroom
  with
    self_obj bathroom;

Fake -> faketoilet
  with
    self_obj toilet;

Fake -> fakebathsink
  with
    self_obj bathsink;

Fake -> fakeshower
  with
    self_obj shower,
 has female;

Fake -> fakeshowerhead
  with
    self_obj showerhead;

Fake -> fakefuton
  with
    self_obj futon;

Fake -> fakecloset
  with
    self_obj closet;

Fake -> fakevacuum
  with
    self_obj vacuum;

Fake -> fakejacket
  with
    self_obj jacket;

Fake -> fakepapers
  with
    self_obj papers;

Fake -> fakelamp
  with
    self_obj lamp,
 has female;

Fake -> fakecomputer
  with
    self_obj computer;

Fake -> faketickets
  with
    self_obj tickets;

Fake -> fakestereo
  with
    self_obj stereo,
 has female;

Fake -> fakecrate
  with
    self_obj crate,
 has female;

Fake -> fakemirror
  with
    self_obj mirror;