! ----------------------------------------------------------------------------
!  And when he hath the kernel eat,
!    Who doth not fling away the Shell?  - John Donne, "Community"
! ----------------------------------------------------------------------------

Constant Story "SHELL";
Constant Headline "^An Interactive Skeleton^\
             Copyright (c) 1994 by (your name here).^";

Constant DEBUG;

Include "Parser";
Include "VerbLib";


Object Blank_Room "Blank Room"
  with description "An empty room."
  has  light;

[ Initialise;
  location = Blank_Room;
  print "^^^^^Welcome to the shell...^^";
];

Object cone "green cone" Blank_Room
  with name "green" "cone" "emerald" "marzipan",
       describe
       [; if (cone has moved)
              "^A misshapen cone of green marzipan sits here.";
          "^Nearby is an emerald green cone, one foot high.";
       ],
       description "The cone seems to be made of emerald-coloured \
                    marzipan.",
       before
       [; Eat: if (random(100) <= 30)
               {   deadflag = 1;
                   "Unfortunately, you seem to be allergic to almonds.";
               }
               "You nibble at a corner of the cone.";
       ],
       after
       [; Take: "Taken.  (Your hands are smeared with marzipan.)";
          Drop: cone.description = "The cone is a vague green mess.";
                "The cone drops to the floor and sags a little.";
       ],
  has  edible;



Include "Grammar";
end;