Constant Historia "^The Mimoso Adventure^El montaje del director^";
Constant Titular "(c) Navidad'2003^
Programador,Guionista,Productor: Fan^
Betatester: Urba^";
Release 2;
Serial "000002";

Include "EParser";
Include "betatest";
Include "Acciones";
Include "BajoNivel";

!---------------------------------------------------------------------
!	daemon
!---------------------------------------------------------------------
Object  obrero
with turnoss 2,
     daemon [;
        self.turnoss = self.turnoss - 1;
        if ((self.turnoss == 0) && (mimoso in calle_aceraso))
         {
          parardaemon (obrero);
          give enchufe ~general;
          jugadorA (calle_aceras,1);         
          print "El humano se planta delante tuyo:^";
          style bold;
          print "^- ¡Eh! ¿Has sido tú, gato malo?.-^";
          style roman;
          "^El humano te empuja acera abajo y se vuelve a la estructura.";
         }        
        if ((self.turnoss == 0) && (mimoso in portal))
         {
          parardaemon (obrero);
          give enchufe ~general;          
          "Ves desde tu escondite que el humano de la máscara vuelve a poner la cuerda negra en el objeto blanco y vuelve a subir a la estructura.";
         }
        if (self.turnoss == 0)
          parardaemon (obrero);
];
Object  obrero2
with turnoss 4,
     daemon [;
        self.turnoss = self.turnoss - 1;
        if ((self.turnoss == 2) && (mimoso in calle_aceraso))
         {
          parardaemon (obrero2);
          self.turnoss = 4;
          give enchufe ~general;
          jugadorA (calle_aceras,1);         
          print "El humano te ve y se acerca:^";
          style bold;
          print "^- Fuera de aquí, gato callejero.- ^";
          style roman;
          "^El humano te empuja acera abajo y se vuelve a la estructura.";
         }        
        if ((self.turnoss == 2) && (mimoso in portal))
         {
         give bocadillo general;	
          "Ves que el humano del bocadillo deja este a su lado y se pone a trastear con la cuerda y el objeto blanco.";
         }       	         
	if ((self.turnoss == 0) && (mimoso in calle_aceraso))
         { 
          parardaemon (obrero2);
          self.turnoss = 4;
          give enchufe ~general;
          if (bocadillo in mimoso)
            {
             give bocadillo ~general;
             move bocadillo to calle_aceraso; 
             style bold;
	     print "^- ¡Eh! ¡Ladrón! ¡Mi bocata!.- ^";
             style roman;
             "^El humano te quita el bocadillo y se vuelve a subir a la estructura.";
            }
          else
            {
            jugadorA (calle_aceras,1);         
            style bold;
            print "^- Fuera de aquí, gato callejero.- ^";
            style roman;
            "^El humano te empuja acera abajo y se vuelve a la estructura.";
            }
	 }
        if ((self.turnoss == 0) && (mimoso in portal))
         {
          parardaemon (obrero2);
          self.turnoss = 4;
          give enchufe ~general;
          give bocadillo ~general;
          if (bocadillo notin calle_aceraso)
            {
             print "El humano se levanta y comienza a buscar el bocadillo a su alrededor. Al no verlo, se sube de nuevo a la estructura.^";
             style bold;
             print "^- No te lo vas a creer, me han robado el bocadillo...^";
             style roman;   
             rtrue;          
            }
          else
             "El humano se levanta, coge el bocadillo, y se sube de nuevo a la estructura.";
         }       	         
];
Object  hambre
with comida 40,
     daemon [;
        self.comida = self.comida - 1;
        if (self.comida < 0)
          self.comida = 0;
        if (self.comida == 20)
          "^La barriguita te gruñe. Necesitas comida o te volverás débil y vulnerable.";
        if (self.comida == 1)
          "^Tienes mucha hambre y la debilidad comienza a adueñarse de tí.";
];
Object  d_humo
with turns 20,
     daemon [;
        self.turns = self.turns - 1;
        if (self.turns == 15)
          "^El humo comienza a acumularse en todas las habitaciones.";
        if (self.turns == 10)
          "^El humo es ya muy denso. Comienzas a tener problemas para respirar.";
	if (self.turns == 5)
          "^Estás muy mareado por el humo. Comienzas a boquear y a dar débiles maullidos de impotencia.";
        if (self.turns == 0)
          {
          banderafin = 1;
          "^Finalmente te despatarras por la falta de oxígeno y puedes ver ante tus ojos unas estrellitas que titilan ante tí. Te desmayas, y poco después mueres asfixiado.^";
          }
];
Object  accio_aleat
with daemon [que_pasa;
        if (parent(mimoso)~=localizacion) 
          rtrue;
        que_pasa = random (3);
        if (que_pasa == 1)
         {
          que_pasa = random (5);
          if (localizacion.ubicacion == 0)
           {
            switch(que_pasa)
            {
             1 : "^Levantas tu patita y la lames hasta dejarla reluciente.";
             2 : "^¿Qué es eso que hay detrás tuyo?. Comienzas a dar vueltas persiguiendo tu rabo...";
             3 : "^Te sientas, sacas las uñas, y te rascas la panza.";
             4 : "^Arqueas el lomo y das un gran bostezo.";
             5 : "^Te haces una bola para entrar en calor mientras piensas lo que vas a hacer.";
            }
           }
          if (localizacion.ubicacion == 1)
           {
            switch(que_pasa)
            {
             1 : "^No puedes aguantar más. Miras a tu alrededor y haces pipí en el suelo.";
             2 : "^Erizas los pelos del lomo e intentas sacudirte el agua pero al momento vuelves a estar empapado.";
             3 : "^Intentas dar unos cuantos saltos para entrar en calor.";
             4 : "^Miras hacia arriba y te asustas cuando una gota de lluvia te cae en el ojo.";
             5 : "^¡Que sucio estoy! Intentas limpiarte con la lengua pero es imposible, estás lleno de agua y tierra.";
            }
           }
         }
];  	   
!---------------------------------------------------------------------
!	Localidades
!---------------------------------------------------------------------
!       LIMBO
!------------------------
Object  limbo "limbo"
with descripcion
       "limbo",
has luz;
!------------------------
Object chapa "chapa con tus datos" limbo
with 
    nombre 'chapa',
    articulo "la",
    descripcion 
        "No entiendes lo que pone, pero tu amita te dijo que ponía donde estaba tu casa y como te llamas, por si te pierdes.",
    antes [;
      dejar: "Forcejeas con la correa de la que cuelga la chapa pero no consigues quitártela.";
    ],
has femenino;
!------------------------
Object correa "correa" limbo
with 
    nombre 'correa',
    articulo "la",
    descripcion 
        "Una correa de piel de la que cuelga una pequeña chapa.",
    antes [;
      dejar: "Forcejeas con la correa pero no eres capaz de quitártela.";
      desvestir: "Forcejeas con la correa pero no eres capaz de quitártela.";
    ],
has femenino prenda puesto;
!-------
!------------------------
Object humo "humo"
with 
    nombre 'humo',
    descripcion [;
        if (humo has general)
          "Aunque el humo se está disipando, aún puedes ver muchos retazos como sábanas negras sobre tí.";
        else
          "El humo negro y asfixiante se va acumulando sobre tí amenazándote con ahogarte.";
    ],
    esta_en comedor cocina habitacion
has escenario;
!-------
!------------------------
Object mimoso "Mimoso"
with 
    nombre 'mimoso',
    descripcion [;
       print "Eres un pequeño y chicharachero gatito blanco que no supera el palmo de altura. En tu cuello llevas una correa con una chapa de metal ";
       if (hueso in mimoso)
         print " y en tu boca llevas un hueso";
       if (peluche in mimoso)
         print " y en tu boca llevas un osito de peluche";
       ".";
     ],
    capacidad 2,
    antes [;
      frotar: 
        if (localizacion.ubicacion == 0) 
          "Te pasas la lengua por todo tu cuerpo hasta que te consideras lo suficientemente limpio.";
        else
          "Por mucho que te pasas la lengua, la lluvia vuelve a ensuciarte.";
    ],
has animado;
!------------------------
!       COMEDOR
!------------------------
Object  comedor "Comedor"
with  descripcion [;
       print "Te hallas en el comedor, una gran sala con una mesa de roble, una silla, un gran armario que parece cernerse sobre tí, tu cálida y acogedora cestita, una ventana y tres puertas, al norte, al sur y al este. De la puerta este te llega olor a comida quemada y el ambiente está cargado de humo. La puerta norte esta cerrada, pero el resto parecen entornadas. La puerta sur va a dar a la habitación de tu amita. ";
       if (trozos_jarron in comedor)
          print "En el suelo ves unos trozos de jarrón y unas flores desperdigadas (una de tus travesuras). ";
       if (agua in comedor)
          print "El suelo está lleno de agua derramada. ";       
       " ";
 ],
      ubicacion 0,
      antes [;
           ir:          
           if ((accion == ##salir) && (mimoso in mesa)) 
                "Primero has de saltar a la silla si quieres bajar.";
           oler: "El olor a humo y a quemado llena tu pequeña naricilla.";
 ],
      al_n 0,
      al_e cocina,
      al_s habitacion,
has general luz;
!------------------------
!OBJETOS BÁSICOS
!------------------------
Object cesta "cesta" comedor
with 
    nombre 'cesta' 'cestita',
    determinante "la",
    descripcion "Es tu camita, de mimbre y con ropa suave y aterciopelada.",
    antes [;    
      empujar: 
       if (mimoso notin cesta)
        "Empujas la cesta con el morrito por el comedor sin lograr nada.";
],
has abierto entrable transparente recipiente escenario femenino;
!------------------------
Object flores "flores" comedor
with 
    nombre 'flores',
    descripcion "Unas pequeñas y delicadas flores de color amarillo.",
    antes [;
      probar, comer: "Las flores están amargas y nada apetecibles.";
],
has escenario nombreplural femenino;
!------------------------
Object puertas "puertas" comedor
with 
    nombre 'puerta' 'puertas',
    descripcion "Las tres puertas son mas o menos igual, aunque la de la pared norte parece mas robusta. Es la puerta que usa tu ama cuando te deja solito en casa. Esta cerrada.",
    antes [;
      abrir: "No eres capaz de abrir la puerta de la pared norte. Las otras están abiertas.";
],
has escenario nombreplural femenino;
!------------------------
!MESA
!------------------------
Object mesa "mesa" comedor
with nombre 'mesa',
    articulo "la",
    descripcion [;
        print "La mesa se halla casi pegada a la ventana. En el centro de la mesa hay un papel de color amarillo";
        if (trozos_jarron in limbo)
            " y un jarrón con varias flores algo marchitas.";
        ".";
 ],
    antes [;
        coger, empujar:
           "Eres un gatito, ¿recuerdas?";
        meterse:
               if (mimoso in silla)
                 {
                 jugadorA(self,1);
                 "De un saltito caes sobre la mesa, al lado del papel. Sabes que si te ve tu ama aquí arriba te castigará, pero eres demasiado curioso y travieso para preocuparte.";
                 }
               if (mimoso in repisa)
                 {  
                 jugadorA(self,1);
                 comedor.al_n = 0;
                 "Caes en la mesa de nuevo";
                 }
	       if ((mimoso in comedor) || (mimoso in cesta)) 		
                 "Das un saltito, pero la mesa está demasiado alta y no llegas.";
               if (mimoso in mesa)
                 "Ya estás en la mesa";
    ],
has soporte entrable oculto estatico femenino transparente;

!------------------------
!SILLA
!------------------------
Object silla "silla" comedor
with 
    nombre 'silla',
    determinante "la",
    descripcion
        "La silla está casi pegada a la mesa. Es una vieja silla de madera comida por la carcoma.",
    antes [;
        meterse: 
               if ((mimoso in comedor) || (mimoso in cesta))
                 {
                 jugadorA (silla,1);
                 "Después de varios saltitos infructuosos consigues aferrarte con las uñas al borde de la silla y subirte en ella";  
                 }
               if (mimoso in mesa)
                 {
                 jugadorA (silla,1);
                 "Te dejas caer de la mesa a la silla";
                 }
               if (mimoso in repisa)
                 "Tienes la mesa en medio, y la silla está demasiado lejos";
               if (mimoso in silla)
                 "Ya estás sobre la silla";
        empujar, coger: "La silla pesa demasiado para un gatito como tú.";
    ],
has soporte entrable oculto estatico femenino transparente;
!------------------------
!REPISA
!------------------------
Object repisa "repisa" limbo
with 
    nombre 'repisa',
    descripcion
        "Bajo la ventana, una pequeña repisa de piedra sobresale de la pared.",
    antes [;
        meterse: 
                 if (mimoso in mesa)
                 {
                 jugadorA (repisa,1);
                 print "De un saltito caes sobre la repisa. ";
                 if (ventana has abierta)
                   "Por la ventana abierta te entra el aire frío que te eriza los pelitos del lomo y las gotas de lluvia te mojan el morrito.";
                 else
                   "Las gotas de lluvia golpean el cristal y parece que en la calle debe hacer mucho frío.";
                 }
                 if (mimoso notin repisa)
                 {                 
                 "La repisa está demasiado lejos para llegar de un salto.";
                 }               
               "Ya estás sobre la repisa.";
    ],
has soporte entrable escenario femenino transparente;
!------------------------
!VENTANA
!------------------------
Object ventana "ventana" comedor
with 
    nombre 'ventana',
    determinante "la",
    descripcion [;
       move repisa to comedor;
       print "La ventana se encuentra en la pared norte, al lado de la puerta cerrada. ";
       if (self has abierta)
         "Está abierta y el aire frío entra a través de ella. Justo debajo puedes ver una pequeña repisa de piedra.";
       else
         "Está cerrada y puedes ver las gotas de lluvia golpeando el cristal. Justo debajo puedes ver una pequeña repisa de piedra.";
    ],
    puerta_a [;
        if (mimoso in repisa)
          return calle_aceras;
        else
          "La ventana está demasiado alta.";
    ],
    antes [;
       meterse:
       if (mimoso notin repisa)
          "La ventana está demasiado alta."; 
       if (ventana has abierta)
          {
            print "Saltas por la ventana y caes en la calle despatarrado. Hace mucho frío, humedad, y está lloviendo con fuerza. Inmediatamente tu blanco pelito está totalmente mojado.^";
            jugadorA (calle_aceras,2);  
            rtrue;             
          }
       "La ventana está cerrada.";           
       abrir: 
        if (mimoso in repisa)
	{
          if (ventana has abierta)
            "La ventana ya está abierta.";
          else
          {
            give ventana abierta;
            give humo general;
            parardaemon (d_humo);
            "Copiando lo que hace tu amita cuando tiene calor, le das un golpecito al picaporte y la ventana se abre. Ves como el humo comienza a escaparse por la obertura dejando espacio para que entre el frío y la lluvia de la calle.";
          }
	}
        else
          "La ventana está demasiado alta.";          
    ],
    direcc_puerta al_n,
has abrible puerta escenario femenino ~abierta;
!------------------------
!CALLE
!------------------------
Object calle "calle" comedor
with 
    nombre 'calle',
    descripcion [;
       if (mimoso in repisa)
        "En la calle está lloviendo y hace frio. Desde donde estás puedes ver como los grandes coches pasan velozmente de un lado a otro.";
       else
        "Desde donde estás no puedes ver la calle.";
     ],
has escenario femenino;
!------------------------
!COCHES
!------------------------
Object coches "coches" 
with 
    nombre 'coches' 'monstruos',
    descripcion "Grandes y amenazadores monstruos de metal.",
    esta_en repisa calle_aceras calle_aceraso calle_aceran calle_acerane,
has escenario nombreplural;
!------------------------
!JARRON
!------------------------
Object jarron "jarron con flores" comedor
with 
    nombre 'jarron',
    descripcion 
        "Un jarron de barro con varias flores en su interior.",
    antes [;
      empujar,tirar:
        if (mimoso in mesa)
         {
         remove jarron;
         move trozos_jarron to comedor;
         move agua to comedor;
	 jugadorA (comedor,1);	
         "Golpeas el jarrón con la patita y éste se cae llenando de agua el suelo y rompiéndose en mil pedazos. Te asustas y saltas de la mesa al suelo rodando hasta la pared, donde te quedas quieto mirando el estropicio.^";
         }
        else
         "No llegas para poder moverlo.";
      probar,tocar:
        if (mimoso notin mesa)
          "No llegas para poder hacerlo.";
],
has escenario masculino;
!------------------------
!PAPEL
!------------------------
Object papel "papel amarillo" comedor
with 
    nombre 'papel' 'amarillo',
    descripcion [;
       if (mimoso in mesa) 
        "Es un papel de color amarillo con muchos símbolos que no entiendes nada. Un humano que ha llamado dos veces a la puerta y que llevaba un carro amarillo lo ha traido esta mañana a tu casa.";
       else
        "Desde donde estás no puedes examinar el papel";
 ],
    antes [;
       empujar,tocar,probar: 
       if (mimoso notin mesa)
        "No llegas para poder hacerlo.";
       else
        "Lo haces... sin ningún resultado.";
],
has escenario;
!------------------------
!JARRON ROTO
!------------------------
Object trozos_jarron "trozos de jarrón" limbo
with 
    nombre 'trozos' 'de' 'jarron',
    descripcion 
        "En el suelo, al lado de la mesa, puedes ver los trozos del jarrón que has roto. No tienen nada especial.",    
    antes [;
      empujar: "Desperdigas los trozos por el suelo.";
],
has escenario nombreplural;
!------------------------
!ARMARIO
!------------------------
Object armario "armario" comedor
with 
    nombre 'armario',
    descripcion 
        "Un gran armario que parece cernerse sobre tí. Está cerrado.",
    antes [;
       abrir: 
        if (mimoso notin comedor)
           "No puedes abrir el armario desde aquí";
        else
           "No llegas a la cerradura y la puerta está firmemente cerrada.";
],
has abrible cerrojoechado escenario;
!------------------------
!AGUA
!------------------------
Object agua "agua del suelo" limbo
with 
    nombre 'agua' 'suelo',
    descripcion 
        "Es el agua que se ha caido del jarrón. ",
    antes [;
      beber: 
        if (mimoso in comedor)
          {
          remove agua;
          hambre.comida = hambre.comida + 10;
          "Te bebes el agua del jarrón y sacias un poco tu sed.";
          }
        else
          "Desde donde estás no puedes beberte el agua.";
 ],
has escenario masculino comestible;
!------------------------
!       COCINA
!------------------------
Object  cocina "Cocina"
with  descripcion [;
       print "Te encuentras en la cocina, el lugar donde pasa tu amita la mayor parte del tiempo. La única puerta se halla en la pared oeste. Puedes ver en la pared norte una pequeña ventana blanca que parece cerrada. ";
       if (mesa hasnt general)
          print "En la pared oeste ves una pequeña mesa plegable que está desplegada, y a través de sus patas puedes ver un platito debajo. ";
       else
          print "En la pared oeste ves una pequeña mesa plegada contra la pared y con las patas recogidas. A su lado se encuentra un platito sobre el suelo. "; 
       if (horno hasnt general)
          print "El humo que está inundando la casa proviene de un aparato que se encuentra en la pared este y que es como una caja grande con una puertecita de cristal. ";
       else
          print "El aparato ya no desprende humo, parece que lo has roto... como se entere la amita... ";
       if (escoba hasnt general)
           "En la pared sur ves una escoba apoyada en lo que tu amita llama la nevera.";
       else
           "En el suelo yace la escoba.";
],
       ubicacion 0,
       antes [;
           oler: "El olor a quemado llena tu pequeña naricilla";
],
al_o comedor,
has luz;
!------------------------
!OBJETOS BASICOS
!------------------------
Object ventana_cocina "ventanita" cocina
with 
    nombre 'ventana' 'ventanita',
    descripcion "Es una ventana pequeña, con cristales opacos y cerrada firmemente.",
    antes [;
      abrir: "No puedes llegar a la ventana, pero igualmente parece firmemente cerrada.";
],
has escenario femenino;
!
Object patas_mesa "patas" cocina
with 
    nombre 'patas' 'travesaños',
    descripcion "Son unas anchas patas que si la mesa está abierta tapan toda la parte inferior, y si está cerrada quedan plegadas contra la pared.",
has escenario femenino nombreplural;
!------------------------
!HORNO
!------------------------
Object horno "horno" cocina
with 
    nombre 'aparato' 'horno',
    descripcion [;
        move mandos to cocina;
        print "Tiene como una ventanita que deja ver algo muy grande que está muy negro y muy quemado. Se parece a un pajaro como los que desplumas en la terraza, pero mas grande. Desprende un olor insoportable a quemado. Sobre el aparato, que crees que se llama horno, hay unas ruedecitas con dibujos. ";
        if (horno hasnt general)
          "El aparato está encendido y desprende mucho humo negro.";
        else
          "El aparato está apagado y ya ha dejado de desprender humo.";
        ], 
	antes [;
          apagar, encender: "No puedes llegar a los mandos."; 
          tocar: "El horno está muy caliente.";
          abrir: "Sabes que se puede abrir, pero no eres capaz de conseguirlo.";
],
has escenario;
!------------------------
!MANDOS
!------------------------
Object mandos "ruedas" limbo
with 
    nombre 'ruedecitas' 'ruedas' 'mandos',
    descripcion 
        "Son como unas ruedas con símbolos. Alguna vez has visto a tu amita darles vueltas cuando hace la comida.",
    antes [;
      empujar,tocar,probar: "No alcanzas a las ruedas, está demasiado alto.";
   ], 
has escenario nombreplural femenino;
!------------------------
!PAJARITO
!------------------------
Object pajarito "pajarito" cocina
with 
    nombre 'pajarito' 'pollo' 'pajaro',
    descripcion 
        "A través del cristal ves que está muy negro y muy chamuscado.",
    antes [;
      empujar,tocar,probar: "No puedes, está dentro del horno.";
   ], 
has escenario masculino;
!------------------------
!ESCOBA
!------------------------
Object escoba "escoba" cocina
with 
    nombre 'escoba',
    descripcion 
        "Una escoba de color rojo, vieja y gastada por el uso.",
    antes [;
      empujar: 
        if (escoba has general)
          "Empujas la escoba, que está tirada en el suelo, y no pasa nada.";
        else
         {
          give escoba general;
          give horno general;
          give humo general;
          parardaemon (d_humo);
          "Tocas la escoba con la patita haciéndo que ésta resbale, golpee contra las ruedecitas del aparato y caiga al suelo. La luz del aparato se ha apagado, y la cantidad de humo empieza a desaparecer paulatinamente. Como se entere la amita que lo has roto se va a enfadar un montón...";
         }
   ], 
has escenario femenino;
!------------------------
!NEVERA
!------------------------
Object nevera "nevera" cocina
with 
    nombre 'nevera',
    descripcion 
        "Grande, blanca e inaccesible para tí.",
    antes [;
       abrir: "Imposible, no llegas a la maneta";
],
has escenario femenino;
!------------------------
!MESA
!------------------------
Object mesa_cocina "mesa" cocina
with 
    nombre 'mesa' 'mesita',
    descripcion [;
       if (mesa hasnt general)
        {
        move arito to cocina;
        "Una de esas mesas abatibles que cuando se cierran quedan pegadas a la pared pero cuando se abren unas anchas patas las mantienen firmes. Ahora está abierta. De uno de sus lados sobresale como un pequeño aro de metal.";
        }
       else
        "La mesa está plegada contra la pared.";
],
    antes [;
      meterse: "Aunque das un gran salto no consigues llegar a la mesa.";
],
has escenario femenino;
!------------------------
!ARO
!------------------------
Object arito "aro" limbo
with 
    nombre 'aro' 'arito',
    descripcion 
        "Es un pequeño aro de metal que sobresale de uno de los lados de la mesa.",
    antes [;
      tirar : 
        if (mesa hasnt general)
         {
          give mesa general;
          print "Metes la patita dentro del aro y al tirar hacia atrás la mesa se plega contra la pared con un fuerte golpe. Te pegas un susto muy grande y sales corriendo al comedor.^";
          jugadorA(comedor,1);
          rtrue;
         }
        else
          "Ya no sucede nada al tirar.";
],
has escenario;
!------------------------
!LECHE
!------------------------
Object leche "leche" limbo
with 
    nombre 'leche',
    descripcion 
            "Un poquito de leche blanca en tu plato. Parece que lleva aquí todo el día.",
    antes [;
      beber:
         remove leche;
         hambre.comida = hambre.comida + 10;
         "Te bebes la leche del platito y te quita un poco la sed.";
],
has comestible femenino escenario;
!------------------------
!PLATITO
!------------------------
Object platito "platito" cocina
with 
    nombre 'plato' 'platito',
    descripcion [;
       if (mesa hasnt general)
        "Es tu pequeño plato de plástico. Esta debajo de la mesa pero no puedes acercarte a él porque las anchas patas de la mesa no te dejan espacio suficiente para pasar.";
       else
         {
         if ((leche in cocina) || (leche in limbo))
            {
            move leche to cocina;
            "El plato tiene un poquito de leche";
            }
         else
            "El plato está vacío";
         }
],       
     antes [;
        tocar,empujar:
           if (mesa hasnt general)
             "Intentas pasar la patita entre las patas de la mesa, pero no llegas al plato.";
           else
             "El plato está muy bien donde está.";
],
has escenario;
!------------------------
!	HABITACIÓN
!------------------------
Object  habitacion "Habitación"
with  descripcion "Estás en la habitación de tu amita. Está muy oscuro ya que la persiana de la ventana está cerrada y no deja entrar la luz. Pero eso para tí no es inconveniente, gracias a tu excelente vista. Ves una cama, una mesita, un armario y unas zapatillas de andar por casa a lado de la cama. A través de una puerta en la pared norte, puedes ver un tramo del comedor.",
      ubicacion 0,
antes [;
   dormir: "Tienes demasiada hambre para pensar en dormir.";
   saltar: 
      if (mimoso in cama)
        "Comienzas a dar saltos sobre la cama. Siempre te ha gustado hacer eso, y a tu ama no le gusta que lo hagas.";
   oler: "El olor a humo y a quemado llena tu pequeña naricilla.";
],
al_n comedor,
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object ventana_hab "ventana" habitacion
with 
    nombre 'ventana',
    descripcion "Es una ventana grande, cerrada y con la persiana echada.",
    antes [;
     abrir: 
          "No llegas a la ventana para poder abrirla.";
  ],
has escenario femenino;
!------------------------
Object cajones "cajones" habitacion
with 
    nombre 'cajones' 'cajon',
    descripcion "Los cajones de la mesita están firmemente cerrados.",
    antes [;
     abrir: 
          "Están firmemente cerrados.";
     buscaren:
          "Están firmemente cerrados.";
  ],
has escenario masculino nombreplural;
!-----------------
Object zapatillas "zapatillas" habitacion
with 
    nombre 'zapatillas',
    descripcion "Son las zapatillas que usa tu ama siempre que está en casa. Tienen desgarros y mordiscos de jugar con ellas.",
    antes [;
      meterse: "Aunque eres pequeñito, no lo suficiente para caber dentro de una zapatilla."; 
    ],
has escenario femenino nombreplural;
!-----------------
Object persiana "persiana" habitacion
with 
    nombre 'persiana',
    descripcion "La persiana está echada.",
    antes [;
     abrir: "No sabes como se abren las persianas.";
],
has escenario femenino;
!------------------------
!ARMARIO
!------------------------
Object armario2 "armario" habitacion
with 
    nombre 'armario',
    descripcion "Un armario ropero, donde te gusta esconderte cuando has hecho algo malo y tu ama te busca. ",
    descripcion_dentro "Ves que el abrigo donde te refugias cuando te escondes no está.",
has entrable recipiente abrible abierto escenario;
!------------------------
!CAMA
!------------------------
Object cama "cama" habitacion
with 
    nombre 'cama',
    descripcion "La cama de tu ama. De vez en cuando te gusta subirte a dormir en ella, pero ahora tienes demasiada hambre para dormir.",
    antes [;
     saltar, saltarsobre, meterse: 
      if (mimoso notin cama)
        {
          print "Ayudándote de las sábanas te subes sobre la cama.^";
          jugadorA (cama,1);
          rtrue;
        }
  ],
has entrable soporte transparente escenario femenino;
!------------------------
!MESITA
!------------------------
Object mesita "mesita" habitacion
with 
    nombre 'mesita' 'mesa',
    descripcion [;
        move lampara to habitacion;
        "Una mesita de noche, con una lámpara apagada encima y dos cajones cerrados.";
],
    antes [;
     meterse: "Por mucho que saltas no consigues subir a la mesita.";
],
has escenario femenino;
!------------------------
!LAMPARA
!------------------------
Object lampara "lámpara" limbo
with 
    nombre 'lampara',
    descripcion 
        "Es una lamparita de noche. Esta apagada.",
    antes [;
     encender: "No puedes encenderla, no llegas al interruptor.";
     tocar,probar: "No llegas desde donde estás.";
],
has conmutable escenario femenino;
!-----------------------------------
!	CALLE PRINCIPAL, ACERA SUR
!-----------------------------------
Object  calle_aceras "Calle principal, acera sur"
with  descripcion [;
             print "Estás en la calle. Hace mucho frío y hay humedad, lo que aún te debilita más. Es una ancha calle por donde no paran de pasar grandes coches desde el este y el oeste. Hacia el norte, cruzando la calle, ves la otra acera. Al este y al oeste continúa la acera. ";
            if (semaforo.verde == 0) 
              "Un palo alto a tu lado tiene dibujada una silueta luminosa de un humano de color rojo.";
            else 
	      "Un palo alto a tu lado tiene dibujada una silueta luminosa de un humano de color verde.";
],
      ubicacion 1,
	   antes [;
             ir: 
               if (uno == obj_n)
                {
                 if (hambre.comida == 0)
                   "Estás demasiado débil para intentar pasar corriendo la carretera. Deberías intentar comer algo antes.";
       	         if (semaforo.verde == 0)
                   {
                   print "Te lanzas a la carretera y te giras lo justo para ver un gran coche que se abalanza sobre tí. Sus faros te deslumbran y te quedas paralizado. El coche intenta frenar pero ya es imposible. Te atropella y tu pequeño cuerpecillo sale volando. Es el fin...^";
                   banderafin = 1;                   
                   rtrue;
                   }
                 else
                   {
                   print "Cruzas a la carrera. Los coches parados te observan amenazadoramente, pero ninguno de ellos salta sobre tí. Consigues llegar sano y salvo.^";
                   jugadorA (calle_aceran,2);
                   rtrue;        	  
                   }
                }
],
al_s "Al sur está tu casa, y no puedes volver a entrar por la ventana...",
al_e "Al este ves una obra y unos humanos haciendo mucho ruido con unas maquinas muy grandes. Prefieres volver a la puerta de tu casa.",
al_o calle_aceraso,
has luz;
!------------------------
!SEMAFORO
!------------------------
Object semaforo "semaforo" calle_aceras
with 
    nombre 'semaforo' 'palo' 'alto' 'silueta',
    descripcion [;
        print "Es un palo alto de color naranja con un monigote luminoso de color ";
        if (self.verde == 0)
           "rojo.";
        else
           "verde.";
],
    verde 0, 
    cadencia 3,
    cada_turno [;
      self.cadencia = self.cadencia - 1;
      if (self.cadencia == 0)
        {
         print "La silueta del semaforo cambia de color...^";
         self.cadencia = 3;
         if (self.verde == 0)           
           self.verde = 1;
         else
           self.verde = 0;
        } 
],
has escenario masculino;
!-----------------------------------
!	CALLE PRINCIPAL, ACERA SUR-OESTE
!-----------------------------------
Object  calle_aceraso "Calle principal, acera sur, tramo oeste"
with  descripcion [; 
       print "La acera acaba en un cruce dónde los monstruos de metal pasan de un lado a otro. A la izquierda, junto a la pared, puedes ver una gran estructura de hierro ";
       if (humano_mascara in calle_aceraso)
        {
        print "donde se encuentran dos humanos encaramados sobre ella. Uno de los humanos tiene como una máscara en la cara";
        if (enchufe hasnt general)
          print " y le salen chispas de las manos. ";
        else
          print ". ";
        if (bocadillo in calle_aceraso)
         print "El otro está sentado a su lado comiéndose un apetitoso bocadillo. ";
        else 
         print "El otro está a su lado con cara de pocos amigos. ";
        }
        print "Bajo la estructura ves un objeto blanco ";
        if (enchufe hasnt general)
          print "al que le llega una cuerda de color negro que viene de la parte superior de la estructura. ";
        else
          print "y a su lado un cuerda negra que cuelga procedente de donde están los humanos. ";
        "En la pared, también bajo la estructura, se encuentra un oscuro portal.";
      ],
      ubicacion 1,
      antes [;
       maullar: 
          jugadorA (calle_aceraso,1);
      ],
al_e [;
     give enchufe ~general;
     give bocadillo ~general;
     parardaemon (obrero);
     parardaemon (obrero2);
     jugadorA (calle_aceras,2);
     rtrue;
    ],
al_o "La acera acaba aquí.",
al_n "Por aquí, cruzar la carretera sería un suicidio.",
has luz;
!------------------------
!ANDAMIO
!------------------------
Object andamio "estructura" calle_aceraso
with 
    nombre 'estructura' 'andamio',
    descripcion "Son muchos hierros enganchados unos con otros que llegan hasta el tejado, con pasarelas para que los humanos no se caigan.",
    antes [;
      meterse,trepar: "La escalerilla de mano no está pensada para un gato como tú, y las barras resbalan demasiado. Aunque lo intentas, no puedes subir.";
      mirardebajo: "Bajo la estructura se encuentra el objeto blanco con las cuerdas y el oscuro portal.";
    ],
has femenino escenario;
!------------------------
!HUMANOS
!------------------------
Object obreros "humanos" calle_aceraso
with 
    nombre 'humanos' 'hombres' 'obreros',
    descripcion "Parece que están arreglando la casa, porque están muy sucios y hacen ruido.",
has nombreplural escenario;
!------------------------
!ENCHUFE
!------------------------
Object enchufe "objeto blanco" calle_aceraso
with 
    nombre 'objeto'
    adjetivo 'blanco',
    descripcion [;
      print "Es un objeto cuadrado, blanco, de plástico, con varios agujeros. Del lateral del objeto sale una cuerda blanca que se mete por la pared. ";
      if (enchufe hasnt general)
        "Otra cuerda de color negro llega desde arriba de la estructura y se mete en unos agujeros del objeto.";
      else
        " ";
    ],
    antes [;
      empujar: "Empujas el objeto pero no sucede nada.";
      morder: "Muerdes el objeto pero es muy duro y tus dientes no tan fuertes.";
    ],
has escenario;
!------------------------
!BOCADILLO
!------------------------
Object bocadillo "bocadillo" calle_aceraso
with 
    nombre 'bocadillo',
    descripcion [;
         if (bocadillo in mimoso)
           "Separas los panes con tus garritas y ves que dentro hay una comida que te pone tu ama y que te gusta mucho.";
         else
           "No puedes ver bien desde aquí como es el bocadillo.";
    ],
    antes [;
      coger: 
         if (bocadillo hasnt general)
            "Lo tiene el humano, no puedes quitárselo.";
         else
            {
            move bocadillo to mimoso;
            move mimoso to calle_aceraso;
            "Sales de tu escondite y coges el bocadillo con tu boca.";
            }
      comer: 
         if (bocadillo notin mimoso)
            "Debes cogerlo antes de poder comertelo.";
         else
            {
            remove bocadillo;
            hambre.comida = hambre.comida + 25;
            "Separas los panes y te comes la mezcla de dentro. Por fin dejas de tener hambre, aunque no tardarás mucho en volver a tener.";
            }

    ],
has escenario;
!------------------------
!CABLE NEGRO
!------------------------
Object cable_negro "cuerda negra" calle_aceraso
with 
    nombre 'cuerda' 'cable' 'negra',
    descripcion [;
      print "Es una cuerda de plástico de color negro que viene de donde están los humanos y acaba ";
      if (enchufe hasnt general)
        "en el objeto blanco.";
      else
        "colgando al lado del objeto blanco.";
    ],
    antes [;
      morder: "Muerdes la cuerda pero no consigues nada aparte de dejar tus dientecillos marcados.";
      tirar: 
        if (mimoso in portal)
          "Desde el portal no llegas a la cuerda.";
        if (enchufe has general)
          "Ya has desenganchado la cuerda del objeto blanco.";
        if (humano_mascara notin calle_aceraso)
          {
           give enchufe general;
           "Tiras de la cuerda y la sacas de los agujeros del objeto blanco.";
          }
        if (bocadillo notin calle_aceraso)
          {
           remove humano_mascara;
           remove humano_bocata;
           remove obreros;
           print "Tiras de la cuerda.^";
           style bold;
           print "^- ¡¡Otra vez!! Ya me he cansado, vámonos.-^- Si, y encima me he quedado sin cena.-^";
           style roman;
           "^Lo humanos bajan de la estructura y se van.";
          }
        if (humano_mascara hasnt general)
        {
          give humano_mascara general;
          give enchufe general;
          print "Tiras de la cuerda y la sacas de los agujeros del objeto blanco. Inmediatamente oyes las voces de los humanos sobre ti:^";
          style bold;
          print "^- ¡Vaya hombre! ¿Y ahora que ha pasado? Me he quedado sin corriente, bajaré a ver.-^";
          style roman;
          print "^Ves que el humano que lleva máscara está bajando.^";
          arrancardaemon (obrero);
          rtrue;
        }
        else
        {
         give enchufe general;
         print "Vuelves a tirar de la cuerda, y vuelve a salirse del objeto blanco. Vuelves a oir a los humanos sobre tí:^";
         style bold;
         print "^- ¡Otra vez! ¿Pero que pasa? Volveré a bajar... -^- Espera, ya bajo yo... -.^";
         style roman;
         arrancardaemon (obrero2);
         rtrue;
        }
    ],
has escenario femenino;
!------------------------
!HUMANO SOLDADOR
!------------------------
Object humano_mascara "humano con máscara" calle_aceraso
with 
    nombre 'humano' 'con' 'mascara',
    descripcion "Este humano lleva unas ropas oscuras y sucias y lleva un objeto en la mano que hace chispas. En la cara tiene puesta una mascara también oscura.",
has escenario;
!------------------------
!HUMANO BOCADILLO
!------------------------
Object humano_bocata "humano sin máscara" calle_aceraso
with 
    articulo 'el',	
    nombre 'humano' 'sin' 'mascara',
    descripcion "Camisa de cuadros, ropa vieja, manos sucias. ¡Que humano más feo!.",
has escenario;
!------------------------
!CABLE BLANCO
!------------------------
Object cable_blanco "cuerda blanca" calle_aceraso
with 
    nombre 'cuerda' 'cable' 'blanca',
    descripcion "Es una cuerda de plástico de color blanco que está enganchada al objeto y que se mete por la pared de la casa.",
    antes [;
      morder: "Muerdes la cuerda pero no consigues nada aparte de dejar tus dientecillos marcados.";
      tirar: "Por mucho que tiras, no consigues desprender la cuerda ni del objeto ni de la pared.";
    ],
has escenario femenino;
!------------------------
!PORTAL OSCURO
!------------------------
Object portal "portal" calle_aceraso
with 
    nombre 'portal' 'oscuro',
    descripcion "Es el portal de una casa. Al estar tapado parcialmente por la estructura y además no llegarle bien la luz, está bastante oscuro.",
    ubicacion 0,
has entrable recipiente transparente escenario abierto;
!-----------------------------------
!	CALLE PRINCIPAL, ACERA NORTE
!-----------------------------------
Object  calle_aceran "Calle principal, acera norte"
with  descripcion "Te encuentras en la acera norte de la calle principal. Detrás tuyo, por la carretera, grandes coches como monstruos pasan levantando oleadas de frio. Ante tí, al norte, ves un solitario callejón lleno de cajas de cartón y basura. Al este y al oeste se extiende la acera. Un letrero amarillo con un dibujo y unas letras señala hacia el callejón. La lluvia cae incesantemente sobre tí, empapando tu blanco pelito.",
ubicacion 1,
al_s "Con el miedo que has pasado al cruzar, no piensas volver a intentarlo.",
al_e calle_acerane,
al_o "Hacia el oeste, la acera acaba en un cruce. Los coches no paran de pasar por lo que vuelves a donde estabas.",
al_n callejon,
has luz;
!------------------------
!LETRERO
!------------------------
Object letrero "letrero" calle_aceran
with 
    nombre 'letrero' 'cartel',
    descripcion "Es de color amarillo, con la forma de un flecha. Lleva algo dibujado pero no lo entiendes. Señala al callejón.",
has escenario;
!-----------------------------------------
!	CALLE PRINCIPAL, ACERA NORTE-ESTE
!-----------------------------------------
Object  calle_acerane "Calle principal, acera norte"
with  descripcion [;
           print "La acera acaba aquí, ante un muro de ladrillos. Al sur ves la carretera, con sus monstruos de metal. Al norte se encuentra la puerta de madera de lo que parece una tienda. Del otro lado te llega el agradable aroma de pasteles recién hechos. La puerta parece cerrada.";
           if (cajas hasnt general)
              print " A su lado un montón de cajas se amontonan contra la pared.";
           else
              print " Un montón de cajas se hallan desparramadas por la acera. En la pared, al lado de la puerta, puedes ver un agujero.";
           " La lluvia no deja de caer, empapando las cajas y la acera.";
          ],
    ubicacion 1,
    antes [;
        oler: "Un agradable olorcillo a pasteles recién hechos. Se te hace la boquita agua.";
    ],
al_s "Al sur está la carretera, con los monstruos de metal que no paran de pasar.",
al_e "La acera acaba aquí.",
al_o calle_aceran,
al_n [;
      if (cajas hasnt general)
           "La tienda está cerrada.";
      else
         {
           print "Atraviesas el agujero.^";
           jugadorA (pasteleria,2);
           rtrue;
         }
     ],
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object muro "muro" calle_acerane
with 
    nombre 'muro',
    descripcion "Es un muro de ladrillos que tapa el camino.",
has escenario masculino;
!------------------------
Object carretera "carretera" calle_acerane
with 
    nombre 'carretera',
    descripcion "Por la carretera se desplazan los horribles monstruos de metal.",
has escenario femenino;
!------------------------
Object puerta_tienda "puerta" calle_acerane
with 
    nombre 'puerta',
    descripcion "La puerta de la tienda, de madera maciza y firmemente cerrada.",
has escenario femenino;
!------------------------
Object pared_tienda "pared" calle_acerane
with 
    nombre 'pared',
    descripcion "La pared de la tienda, parcialmente tapada por las cajas.",
has escenario femenino;
!------------------------
!CAJAS
!------------------------
Object cajas "cajas" calle_acerane
with 
    nombre 'cajas',
    descripcion [;
        if (cajas hasnt general)
           "Unas cajas se amontonan contra la pared de la tienda. No parecen tener nada destacable.";
        else
           "Las cajas están desparramadas por el suelo de la acera.";
],
    antes [;
      empujar:           
            if (cajas has general)
              "Juegas con las cajas durante unos segundos, desparramándolas aún más por la acera.";
            else
              {
                give cajas general;
                move agujero to calle_acerane;
                "De repente la montaña de cajas se viene abajo sobre tí y sobre toda la acera. Cuando consigues salir de debajo de una de ellas (por suerte, ileso) puedes ver en la pared un oscuro agujero de unos 15 cm de diametro que ha quedado al descubierto.";
              }
           ],
has entrable soporte abierto transparente escenario femenino nombreplural;
!------------------------
!AGUJERO
!------------------------
Object agujero "agujero" limbo
with 
    nombre 'agujero',
    determinante "el",
    descripcion "Un agujero oscuro en la pared, que parece llevar a algún sitio. Del interior surge un apetitoso olor a pasteles.",
    antes [;
     meterse:
        print "Atraviesas el agujero.^";
        jugadorA (pasteleria,2);
        rtrue;
    ],
has escenario masculino;
!-----------------------------------------
!	PASTELERIA
!-----------------------------------------
Object  pasteleria "Pastelería"
with  descripcion [;
           print "Te alegras de estar a cubierto de la lluvia, pero sobretodo te alegras al ver una larga fila de pastelillos sobre una alta mesa. Al norte ves un pasillo que parece llevar a otra habitación donde se oye a alguien silvando una melodía. Ves mas cajas amontonadas contra las paredes, pero no parece haber nada más. Al sur se encuentra la puerta cerrada y el agujero.^";
           if ((pastel has general) && (pastelillos hasnt general))
              "En el suelo ves un apetitoso pastelillo que se debe haber caído de la mesa.";
          ],
    ubicacion 0,
    antes [;
        oler: "El agradable olor de los pastelillos te inunda la naricilla.";
        maullar: 
          if (pastelero in pasteleria)
           {
            style bold;
            print "^- ¡Deja de maullar!.-^";
            style roman;
            "^Te grita el humano.";
           }
          if (pastel has general)
            "Maullas y oyes al hombre quejarse en la otra habitación.";
          else
           {
            give pastel general;
            give pastelero general;
            move pastelero to pasteleria;
            arrancardaemon(pastelero);
            print "Maullas y oyes unos grandes pasos y a un humano inmenso con un traje blanco que se te queda mirando:^";
            style bold;
            print "^- ¡Un gato en mi pastelería! ¡Fuera de aquí!.^";
            style roman;
            rtrue;
           }           
    ],
al_s [;
       parardaemon(pastelero);
       jugadorA (calle_acerane,2);
       rtrue;
     ],
afuera [;
      parardaemon(pastelero);
      jugadorA (calle_acerane,2);
      rtrue;
     ],
al_n [;
       if (pastelero has general)
         "El hombretón te bloquea el paso.";
       else
         "Cuando te acercas al pasillo ves a un gigantesco humano con un traje blanco en la otra habitación. Tienes miedo y te vuelves atrás.";
     ],
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object cajas_p "cajas" pasteleria
with 
    nombre 'cajas',
    descripcion "Más cajas de cartón vacías.",
    antes [;
      empujar:           
         "Mueves las cajas pero no sirve de nada.";
          ],
has escenario femenino nombreplural;
!------------------------
Object puerta_p "puerta" pasteleria
with 
    nombre 'puerta',
    descripcion "La puerta de la tienda, firmemente cerrada. ",
    antes [;
      abrir:           
         "Está firmemente cerrada.";
          ],
has escenario femenino;
!------------------------
Object agujero_p "agujero" pasteleria
with 
    nombre 'agujero',
    descripcion "El agujero por donde has entrado. ",
    antes [;
     meterse:
        print "Atraviesas el agujero.^";
        jugadorA (calle_acerane,2);
        rtrue;
    ],
has escenario masculino;
!------------------------
Object pasillo_p "pasillo" pasteleria
with 
    nombre 'pasillo',
    descripcion "Un estrecho pasillo que comunica las dos habitaciones. ",
has escenario masculino;
!------------------------
!MESA
!------------------------
Object mesa_past "mesa" pasteleria
with 
    nombre 'mesa',
    descripcion "Una alta mesa de madera con pastelillos. No ves nada por donde puedas trepar. ",
    antes [;
      meterse:           
         "Intentas subir pero te caes una vez tras otra. ";
           ],
has escenario femenino entrable;
!------------------------
!PASTELILLOS
!------------------------
Object pastelillos "pastelillos" pasteleria
with 
    nombre 'pastelillos' 'pasteles',
    descripcion "Una fila de apetitosos pasteles sobre una mesa fuera de tu alcance.",
has escenario masculino nombreplural;
!------------------------
!PASTEL
!------------------------
Object pastel "pastel" limbo
with 
    nombre 'pastel' 'pastelillo',
    descripcion "Un bonito y apetitoso pastel. ",
    antes [;
      comer:   
         give pastelillos general;      
         remove pastel;
         hambre.comida = hambre.comida + 15;
         "Devoras el pastel en un periquete y te quita un poco el hambre. Estaba tan bueno como parecía. ";
],
has comestible masculino oculto;
!---------------------------------------------------------------------
!	daemon pastelero
!---------------------------------------------------------------------
Object  pastelero limbo
with enojo -1,
     nombre 'pastelero' 'humano' 'hombre',
     descripcion "Un enorme humano con un traje blanco y con cara de enfadado.",
     daemon [;
        self.enojo = self.enojo + 1;
        if (self.enojo == 1)
         {
          print "El hombre te mira enojado: ^";
          style bold;
          print "^- ¡He dicho fuera de aquí!.^";
          style roman;
          rtrue;
         }
        if (self.enojo == 2)
         {
          style bold;
          print "^- ¡He dicho que te vayas! ¡Maldito gato!.^";
          style roman;
	  rtrue;
         }
	if (self.enojo == 3)
         {
          print "Ves que el hombre coje una escoba y se acerca hacia tí. ^";
          style bold;
          print "^- ¡Ahora verás!.^";
          style roman;
          rtrue;
         }
        if (self.enojo == 4)
          {     
          give pastelero ~general;     
          move pastel to pasteleria;
          move pastelero to limbo;
          parardaemon(pastelero);
          "El humano intenta golpearte con la escoba pero en el último momento das un salto y te escondes entre las cajas. Oyes un golpe y al humano refunfuñar mientras oyes como se aleja. Sales de tu escondite de nuevo.";         
          }
],
has escenario animado;
!-----------------------------------
!	CALLEJON 
!-----------------------------------
Object  callejon "Callejón"
with  descripcion [;
        if (humano in callejon)
          {
           print "Estás en un oscuro callejón. Sigue lloviendo con fuerza y entre las gotas ves un montón de basura y lo que parece un humano muy sucio y pestilente tumbado en el suelo. Parece dormido. Notas también otro olor, más amenazador, pero que no consigues reconocer. Al norte, al otro lado del humano, el callejón desemboca en una plaza. Al sur oyes los coches de la carretera.^";
           if (perro in callejon)
             "Puedes ver un perro entre la basura. ";
          }
        else        
           "En el callejón solo queda la basura y, donde se encontraba el humano, una especie de bolsa, vieja y raída. Al norte podrás ir a la plaza y al sur volver a la carretera.";         
        ],
        ubicacion 1,
        antes [;
           oler: 
              if (humano in limbo)
                "Aunque se han ido, el olor a humano sucio y a perro perdura.";
              if (perro in limbo)
               {
               move perro to callejon; 
               "Olfateas de nuevo y ahora lo reconoces. ¡Un perro!. Miras entre la basura y por fin lo ves, durmiendo al lado del humano, un enorme perro gris.";
               }
              else
               "El olor del perro y del humano llenan tu naricilla.";
          ],
al_s [;
      if ((hueso in mimoso) && (perro in callejon) && (perro has general))
       {
        remove perro;      
        move humano to limbo;        
        move bolsa to callejon;
        print "El perro, que ha visto el hueso, se levanta y va detrás tuyo. Ves que el humano se despierta y cuando ve que os vais, sale corriendo detrás, coge al perro de una correa y se van acera abajo.^";
       } 
      jugadorA (calle_aceran,2);
      rtrue;
     ],   
al_e 0,
al_o 0,
al_n [;
      if ((perro in callejon) && (perro has general))
       "Cuando pasas por su lado, el perro te gruñe amenazadoramente y vuelves atrás asustado.";
      if ((perro in callejon) && (perro hasnt general))	
       {
       give perro general;
       "Intentas pasar de puntillas por al lado del perro pero de repente se despierta con un gran ladrido. De un salto vuelves atrás.";  
       }
       jugadorA (plaza,2);
       rtrue;
     ],
has luz;
!------------------------
!BOLSA RAIDA
!------------------------
Object bolsa "bolsa raída" limbo
with 
    nombre 'bolsa' 'raida',
    descripcion "Una bolsa de cuero vieja y rota.",
    antes [;
      abrir: 
         if (manzana in limbo)
           {
           move manzana to callejon;
           "Con tus patitas consigues abrir la bolsa y meter el morrito dentro. En el interior encuentras una bonita manzana verde.";
           }
         else
           "La bolsa ya está abierta.";
      cerrar:
         "Pruebas de cerrarla pero no eres capaz.";
      buscaren:
         if (manzana in limbo)
           {
           move manzana to callejon;
           "Con tus patitas consigues abrir la bolsa y meter el morrito dentro. En el interior encuentras una bonita manzana verde.";
           }
         else
           "No encuentras nada más.";
        ],
has abrible femenino escenario;
!------------------------
!HUMANO
!------------------------
Object humano "humano" callejon
with 
    nombre 'humano' 'hombre',
    descripcion "Un humano viejo, sucio y pestilente durmiendo en el suelo.",
    descripcion_dentro "Estás sobre el humano, aunque a él no parece importarle. Sigue durmiendo.",
    antes [;
     atacar,aranyar,morder: "¿Desde cuándo eres un gatito agresivo, con lo bueno que eres?.";
    ],
has escenario animado masculino entrable abierto soporte transparente;
!------------------------
!BASURA
!------------------------
Object basura "basura" callejon
with 
    nombre 'basura' 'bolsa' 'bolsas',
    descripcion [;
         if ((perro in callejon) || (humano in limbo))
           "Un montón de basura, cajas de cartón, suciedad...";
         else
           {
           move perro to callejon;
           "Un montón de basura, cajas de cartón, suciedad... Ves que algo se mueve entre el humano y una caja. ¡Es un perro! ¡Un fiero y sanguinario perro!. Al menos, parece que duerme...";
           }
         ],
    antes [;
      empujar, buscaren, abrir:
          if (perro in limbo)
           {
           move perro to callejon;
           move hueso to callejon; 
           "Al remover la basura rompes una bolsa y... ¡oh! ¡un hueso!. Vaya, ¿y eso que es?, ¡oh! ¡Un enorme y amenzador perro! Por suerte, parece que duerme...";
           }            
          if (hueso notin limbo)
             "No sucede nada al mover de nuevo la basura.";
          if (perro in callejon)
            {
             move hueso to callejon;
             if (perro has general)
              {    
                "Al remover la basura rompes una bolsa y ves un hueso que sobresale de ella.";
              }
             else
              {
                give perro general;
                "Al remover la basura rompes una bolsa y ves un hueso que sobresale de ella. Ves con horror como el perro, molestado por el movimiento, se despierta con un gran bostezo.";
              }
            }          
         ],
has escenario femenino;
!------------------------
!PERRO FEROZ
!------------------------
Object perro "perro" limbo
with 
    nombre 'perro',
    descripcion [;
         if (perro has general)
          "Un enorme y fiero perro te observa con sus rojos ojos escondido entre la basura.";
         else
          "Un enorme y amenazador perro parece dormitar entre la basura."; 
        ],
    antes [;
      aranyar: 
         if (perro has general)
            "Te acercas valientemente al perro con tus uñitas fuera, pero cuando lo ves levantarse y abrir su gran bocaza te vuelves atrás.";
         else
          {
            give perro general;
            "Te acercas al perro cuando de repente se despierta y te mira con sus feroces ojos. Te vuelves atrás.";
          }
        ],
    vida [;
      dar: if (uno == hueso)
             "El perro ignora el hueso y te mira relamiéndose.";
    ],
has escenario masculino animado;
!------------------------
!HUESO
!------------------------
Object hueso "hueso" limbo
with 
    nombre 'hueso',
    descripcion "Parece el hueso del muslo de un pollo.",
    antes [;
      coger: 
         give self ~oculto;
         if (self in localizacion)
            {
             move self to mimoso;
            "Coges el hueso entre tus dientes.";
            }
],
has oculto masculino;
!------------------------
!MANZANA
!------------------------
Object manzana "manzana" limbo
with 
    nombre 'manzana' 'verde',
    descripcion "Una verde y brillante manzana.",
    antes [;
      comer: 
         hambre.comida = hambre.comida + 10;
         remove manzana;
         "Te comes la manzana en pequeños mordiscos.";
       ],       
has comestible femenino oculto;
!-----------------------------------------
!	PLAZA MAYOR
!-----------------------------------------
Object  plaza "Plaza mayor"
with  descripcion [;
         print "Llegas a una gran plaza rodeada de altos edificios. Por aquí no corren los monstruos de metal sino niños y niñas haciendo caso omiso de la lluvia, que empieza a aflojar. Algunos padres se resguardan bajo paraguas y balcones. Al otro lado de la plaza, al norte, ves una edificio alto de color blanco con una cruz de color rojo pintada. En el lado derecho ves un lugar con un cartel amarillo. Una avenida sale hacia el oeste, y hacia el sur se encuentra el callejón. ";     
         if (ninia in plaza)
           "En el centro de la plaza puedes ver una gran fuente, y a su lado una niña de unos cinco años jugando con la fresca y cristalina agua.^"; 
         else
           "En el centro de la plaza puedes ver una gran fuente.^";
       ],
       ubicacion 1,
       antes [;
         maullar:
              if (ninia in limbo)
                 "Miauuuuuuuu";
              if (ninia has general)
                {
                 style bold;
                 print "^¿Qué quieres, gatito bonito?.-";
                 style roman;
                 " pregunta la niña.";
                }
              else
                {
                 give ninia general;
                 style bold;
                 print "¡Oooohhh!¡Que gatito más bonito!¡Y que mojadito estás!¿Que quieres?¿Quieres que te seque?.-";
                 style roman;
                 print " te pregunta la niña, que se agacha a tu lado y te acaricia el lomo.";
                 if (peluche in mimoso)
                  {
                   style bold;
                   print " - ¡Y que peluche mas bonito que tienes!¡Tranquilo, que no te lo voy a quitar! - ";
                   style roman;
                   "añade con una sonrisa en la boca.";
   	 	  }
                 ".";
                }
         ronronear:
              if (ninia in limbo)
                "Rrrrrrrrrr";
              if (ninia has general)
                {
                 hambre.comida = hambre.comida + 10;
                 move ninia to limbo;
		 style bold;
                 print "Uy, que mono. ¿Quieres agüita?.- ";
		 style roman;	
                 print "La niña te levanta y te acerca a la fuente. Bebes un poco de agua que calma un poco tu sed. La niña te deja en el suelo. ^";
		 style bold;
                 print "^- Me tengo que ir, gatito bonito. ¡Adios!.- ";
                 style roman;
		 "La niña se va corriendo al encuentro de una mujer mayor y salen de la plaza.";  
                }
         ],
al_s callejon,
al_e [;
      if (plaza hasnt general)
        {
         give plaza general;
         print "Nada más empezar a andar notas un olor familiar, que te recuerda a tu ama. Te pones delante de la tienda del cartel amarillo donde dos humanos están charlando:^";
         style bold;
         print "^- ¿Qué ha pasado?.^- Una mujer mayor ha venido a buscar un paquete y al salir le ha dado un ataque o algo así y se ha caído al suelo.^- Suerte que el hospital está cerca.^- Pues si. Ahora la deben de estar examinando.-^";
         style roman;
         "^Los hombres se van y tú vuelves a la fuente.";
        }
      else
        "Vuelves a la tienda pero ya no hay nadie. Sigues notando ese olor familiar.";
     ],
al_o avenida,
al_n [;
      if (hambre.comida == 0)
          "Tienes demasiada hambre para pensar en otra cosa que no sea buscar comida o bebida.";
      else
       {
        print "La puerta esta abierta, por lo que entras dentro del edificio blanco.^";
        jugadorA (h_hall,2);
        rtrue;
       }
     ]
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object fuente_pl "fuente" plaza
with 
    nombre 'fuente',
    descripcion "Una gran fuente de piedra con una estatua. De ella surgen unos chorros de agua cristalina.",
    antes [;
     meterse,trepar: "Intentas trepar por la fuente, pero está demasiado resbaladiza.";
    ],
has escenario femenino;
!------------------------
Object agua_pl "agua" plaza
with 
    nombre 'agua',
    descripcion "Una limpia y cristalina agua que mana mansamente de la hermosa fuente.",
    antes [;
      beber: "Das unos saltos, pero no consigues llegar al agua de la fuente.";
    ],
has escenario femenino;
!------------------------
Object edificio_pl "edificio" plaza
with 
    nombre 'edificio',
    descripcion "Un alto edificio blanco con una gran cruz de color rojo pintada. Ves gente con ropa blanca que sale y entra. ",
has escenario masculino;
!------------------------
Object cartel_pl "cartel" plaza
with 
    nombre 'cartel',
    descripcion "Cartel de color amarillo con algo dibujado en rojo. Ves entrar a una mujer con un papel amarillo en su mano.",
has escenario masculino;
!------------------------
Object estatua_pl "estatua" plaza
with 
    nombre 'estatua',
    descripcion "Es un señor con un tridente y larga barba que parece salir del agua.",
has escenario femenino;
!------------------------
!NIÑA
!------------------------
Object ninia "niña" plaza
with 
    nombre 'niña',
    descripcion "Una niña con dos trenzas y un vestidito azul, con un paraguas a juego.",
    vida [;
     dar:
       if (uno == peluche)
        {
         style bold;
         print " - Uy, ¡que bonito!. ¡Pero no me lo des, que es tuyo! - ";
         style roman;
         "dice la niña devolviéndote el osito.";
        }
    ],
has oculto femenino animado;
!-----------------------------------------
!	AVENIDA
!-----------------------------------------
Object  avenida "Avenida"
with  descripcion [;
        print "Una larga y ancha avenida con muchos árboles y banquitos de madera. No se ven monstruos de metal por ningún sitio y la gente pasea bajo la ligera llovizna. Al este vuelves a la plaza mientras que al oeste, norte y sur solo ves altos edificios que parecen todos cerrados. ";
        if (avenida hasnt general)           
           { 
           give avenida general;
           "Ves como a un humano muy pequeño que está dentro de un cochecito se le cae algo de la mano, pero la humana que lo lleva no se da cuenta y se alejan avenida abajo. Te acercas y ves que es un osito de peluche.";     
           }
        else
           {
           give peluche ~oculto;
           " ";
           }
       ],
      ubicacion 1,
al_e plaza,
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object arboles_av "árboles" avenida
with 
    nombre 'arboles' 'arbol',
    descripcion "Altos y frondosos árboles de tronco liso.",
    antes [;
      trepar: "Tiene el tronco demasiado liso para que puedas trepar.";
],
has escenario masculino nombreplural;
!------------------------
Object banquitos_av "banquitos" avenida
with 
    nombre 'banquitos' 'banco' 'bancos',
    descripcion "Bancos de madera de color verde. Ves que hay humanos sentados en ellos.",
    descripcion_dentro "El aspecto de la avenida no varía mucho desde el banco.",
    antes [;
      meterse: 
        jugadorA (banquitos_av,1);
        "Te subes con unos saltos sobre un banco vacío.";
    ],
has entrable soporte abierto transparente escenario masculino nombreplural;
!------------------------
Object edificios_av "edificios" avenida
with 
    nombre 'edificios',
    descripcion "Altos edificios de cristal y metal cerrados.",
has escenario masculino nombreplural;
!------------------------
Object humanos_av "humanos" avenida
with 
    nombre 'humanos' 'hombres' 'gente',
    descripcion "Unos cuantos humanos sentados en los bancos y paseando por la avenida.",
has escenario masculino nombreplural;
!------------------------
!PELUCHE
!------------------------
Object peluche "osito de peluche" avenida
with 
    nombre 'peluche' 'osito' 'oso',
    descripcion "Un pequeño osito de peluche de color marrón con unos ojitos de cristal.",
    antes [;
     coger: give peluche ~oculto;
         if (self in localizacion)
         {
           move self to mimoso;
           "Coges el osito entre tus dientes intentando no dañarlo.";
         }
           
],
has oculto masculino;
!-----------------------------------------
!	HALL-HOSPITAL
!-----------------------------------------
Object  h_hall "Edificio blanco - Entrada"
with  descripcion "Una gran sala con mucha gente sentada en sillas de plástico. Entre la gente pasan humanos con vestidos blancos. Puedes ver sentados a un hombre que tiene el brazo rodeado de una cosa blanca y dura, una anciana dormitando y un niño que no para de toser. A la izquierda ves como una ventana y a una mujer al otro lado mirando papeles. Al norte hay una puerta. Notas el olor familiar de tu ama en el ambiente.",
    ubicacion 0,
    antes [;
      oler: "Entre muchos olores notas el de tu ama. Ella está por aquí.";
      maullar:
        print "Te pones a maullar como un desesperado y un señor vestido de blanco te ve:^-¡Un gato!¿Es de alguien este gato?.-^Nadie contesta, por lo que te coge y te lleva de nuevo a la plaza.^";
        jugadorA(plaza,2);
        rtrue;
    ], 
al_n [;
      print "Te diriges a la puerta, pero un señor vestido de blanco te ve:^";
      style bold;	
      print "^-¡Un gato!¿Es de alguien este gato?.-^";
      style roman;
      print "^Nadie contesta, por lo que te coge y te lleva de nuevo a la plaza.^";
      jugadorA(plaza,2);
      rtrue;
     ],
al_s plaza,
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object sillas_h "sillas" h_hall
with 
    nombre 'sillas' 'silla',
    descripcion "Unas sillas de plástico de color blanco.",
has escenario femenino nombreplural;
!------------------------
Object hombre_h "hombre" h_hall
with 
    nombre 'hombre' 'humano',
    descripcion "El hombre tiene alrededor del brazo una cosa blanca y dura.",
has escenario masculino;
!------------------------
Object ninio_h "niño" h_hall
with 
    nombre 'niño',
    descripcion "El niño no para de toser, y se tapa la boca con la mano.",
has escenario masculino;
!------------------------
Object humanos_h "humanos" h_hall
with 
    nombre 'humanos' 'hombres' 'gente',
    descripcion "Unos cuantos humanos moviéndose de aquí para allí, con trajes blancos. No ves a tu ama entre ellos.",
has escenario masculino nombreplural;
!------------------------
Object ventana_h "ventana" h_hall
with 
    nombre 'ventana',
    descripcion "Es como un hueco en la pared.",
has escenario femenino;
!------------------------
!ANCIANA DEL BOLSO
!------------------------
Object anciana_bolso "anciana" h_hall
with 
    nombre 'anciana',
    descripcion [;
         move bolso to h_hall;
         "La anciana está durmiendo. Lleva un vestido gris y un pañuelo en la cabeza. En el suelo, a su lado, puedes ver un bolso.";
        ],
has escenario femenino animado;
!------------------------
!BOLSO DE ANCIANA
!------------------------
Object bolso "bolso" limbo
with 
    nombre 'bolso',
    descripcion 
         "Es un bolso bastante grande, de color marrón. Está abierto.",
    antes [;
      meterse:
         print "^Miras que no te vea nadie y te metes en el bolso. Dentro se está muy calentito y hay un agradable aroma. Después de mojarte tanto y pasar frío, este lugar te parece un paraíso. Poco a poco empieza a entrarte sueñecillo. Te quedas dormido, acurrucado dentro del bolso.^";
         print "Despiertas al notar un golpe. Sigues dentro del bolso, que parece que acaban de soltar en algún sitio. Asomas la cabeza y ves que ya no estas en el mismo lugar.^";		         
         parardaemon (hambre);
         hambre.comida = 1;
         jugadorA (mesita_ho,2);
         rtrue;
      cerrar: "Intentas cerrarlo, pero la cremallera es demasiado complicada para tí.";
      ],
has escenario entrable masculino;
!-----------------------------------------
!	HABITACIÓN NIÑA-HOSPITAL
!-----------------------------------------
Object  h_habit1 "Habitación"
with  descripcion [;
       if (bolso2 hasnt general)
         "Estás en una habitación que solo tiene una cama, una mesita y una silla. La cama esta ocupada por una niña bien tapadita que duerme. En la silla puedes ver a la anciana, que está inclinada hacia la niña, de espaldas a tí, pero de cara a la única puerta de la habitación, al sur. Estás sobre la mesita, junto al bolso.";
       else
         "Estás en una habitación que solo tiene una cama, una mesita y una silla. La cama esta ocupada por una niña bien tapadita que duerme. También ves una silla y a la anciana arrodillada intentando coger las cosas que has tirado. También ves una mesita vacía. Al sur puedes ver una puerta.";
     ],
      ubicacion 0,
antes [;
     maullar:         
         print "Te pones a maullar y la anciana se gira y te mira con cara de espanto:^";
         style bold;
         print "^-¡Un gato!¡Socorro!¡Enfermera!¡Que mi nieta les tiene alergia!-^";
         style roman;
         print "^Un enfermero entra en la habitación, te coge y te saca de nuevo a la calle.^La lluvia ha vuelto a arreciar, y ha anochecido. Hace mucho frío. Te acurrucas entre unas cajas, tiritando. Ya perdiste la esperanza, nunca volverás a ver a tu ama... ^A la mañana siguiente te encuentran en la puerta del hospital, frio e inerte. Has muerto.^";
         banderafin = 1;
         rtrue;
     salir,salirse,bajar:       
      if (bolso2 hasnt general)
        {
         print "La anciana te ve nada más bajar de la mesita:^";
         style bold;
         print "^-¡Un gato!¡Socorro!¡Enfermera!¡Que mi nieta les tiene alergia!-^";
         style roman;
         print "^Un enfermero entra en la habitación, te coge y te saca de nuevo a la calle.^La lluvia ha vuelto a arreciar, y ha anochecido. Hace mucho frío. Te acurrucas entre unas cajas, tiritando. Ya perdiste la esperanza, nunca volverás a ver a tu ama... ^A la mañana siguiente te encuentran en la puerta del hospital, frio e inerte. Has muerto.^";         
         banderafin = 1;
         rtrue;
        }
      else
        {
         print "Aprovechas que la anciana esta distraída y sales sigilosamente de la habitación para aparecer en un pasillo.^";
         jugadorA(h_pasill1,2);
         rtrue;
        }
     ],
al_s [;
      if (bolso2 hasnt general)
        {
         print "La anciana te ve nada más bajar de la mesita:^";
         style bold;
         print "^-¡Un gato!¡Socorro!¡Enfermera!¡Que mi nieta les tiene alergia!-^";
         style roman;
         print "^Un enfermero entra en la habitación, te coge y te saca de nuevo a la calle.^La lluvia ha vuelto a arreciar, y ha anochecido. Hace mucho frío. Te acurrucas entre unas cajas, tiritando. Ya perdiste la esperanza, nunca volverás a ver a tu ama... ^A la mañana siguiente te encuentran en la puerta del hospital, frio e inerte. Has muerto.^";         
         banderafin = 1;
         rtrue;
        }
      else
        {
         print "Aprovechas que la anciana esta distraída y sales sigilosamente de la habitación para aparecer en un pasillo.^";
         jugadorA(h_pasill1,2);
         rtrue;
        }
     ],
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object cama_ho "cama" h_habit1
with 
    nombre 'cama',
    descripcion "Una cama normal con sábanas blancas. Dentro de ella hay una niña.",
    antes [;
     meterse: "Humm. Deberías bajarte de la mesita primero, si quieres subirte a la cama.";
],
has escenario femenino;
!------------------------
Object mesita_ho "mesita" h_habit1
with 
    nombre 'mesita' 'mesa',
    descripcion "Una simple mesita de madera.",
    antes [;
     meterse: "Ya estás en la mesita.";
],
has entrable soporte abierto transparente escenario femenino;
!------------------------
Object silla_ho "silla" h_habit1
with 
    nombre 'silla',
    descripcion "Una simple silla de madera.",
    antes [;
     meterse: "Está demasiado lejos para llegar desde la mesita.";
],
has escenario femenino;
!------------------------
Object ninia_ho "niña" h_habit1
with 
    nombre 'niña',
    descripcion "Una humana muy joven que tiene mala cara y está en la cama durmiendo.",
has escenario femenino;
!------------------------
!BOLSO
!------------------------
Object bolso2 "bolso" h_habit1
with 
    nombre 'bolso',
    descripcion [;
        if (bolso2 hasnt general)
          "Es el bolso de la anciana. Está junto a tí sobre la mesita.";
        else
          "El bolso está en el suelo, y todo su contenido desparramado.";
        ],
    antes [;
        empujar: 
           if (bolso2 hasnt general)
            {
              print "Empujas el bolso, que se cae al suelo desparramando todo su contenido alrededor de la cama. La anciana se levanta corriendo y, soltando una maldición, comienza a recogerlo todo. No te ha visto.^";
       	  give bolso2 general;
              rtrue;
            }
        meterse: "Ya estás calentito y has dormido un rato. No te apetece meterte de nuevo.";
      ],      
has escenario masculino;
!------------------------
!ANCIANA
!------------------------
Object anciana2 "anciana" h_habit1
with 
    nombre 'anciana',
    descripcion [;
        if (bolso2 hasnt general)
          "Es la anciana que dormía en la otra sala. Ahora está inclinada sobre la niña, de espaldas a tí.";
        else
          "La anciana está en el suelo, intentado recoger todo lo que has tirado. No te ha visto.";
        ],
has escenario femenino animado;
!-----------------------------------------
!	PASILLO1-HOSPITAL
!-----------------------------------------
Object  h_pasill1 "Pasillo"
with  descripcion [;
        if (mimoso in silla_ruedas)
          move ninio_silla to h_pasill1;
        if (mimoso in camilla)
          "Desde la camilla ves que estás en un pasillo que corre de este al oeste. Al norte está la habitación de la niña. Al sur ves otra puerta que parece entreabierta. ";
        else
          "Un pasillo que corre de este al oeste. Al norte está la habitación de la niña. Al sur ves otra puerta que parece entreabierta. Junto a la pared puedes ver una camilla con una sábana encima.";
      ], 
      ubicacion 0,
al_n "Ves que la anciana ya ha recogido sus cosas y ha vuelto a sentarse en la silla. No te atreves a entrar de nuevo.",     
al_s h_habit2,
al_e h_pasill3,
al_o h_pasill2
has luz;
!------------------------
!CAMILLA
!------------------------
Object camilla "camilla" h_pasill1
with 
    nombre 'camilla',
    descripcion "Una camilla de metal con unas sábanas de color verde encima. Está vacía.",
    antes [;
      meterse:
         if (mimoso in silla_ruedas)
           {
            jugadorA (self,1);
            move ninio_silla to limbo;
            parardaemon (d_silla);
            arrancardaemon (d_camilla);
            remove silla_ruedas;
            "Al pasar por el lado de la camilla, das un salto desde la silla sobre ella y te escondes bajo la sábana. No te han visto. Los humanos continúan con la silla pasillo abajo, y el niño se va por el otro lado.";
           }
         else
           "Das un par de saltos pero ves que es imposible, está demasiado alto.";
      salirse:
          if (mimoso in camilla)
            "Está demasiado alto y te da miedo saltar.";
          else
            "¿De dónde quieres bajarte?.";
        ],
has soporte entrable oculto estatico femenino transparente;
!------------------------
!SÁBANAS
!------------------------
Object sabanas "sábanas" h_pasill1
with 
    nombre 'sabanas' 'sabana',
    descripcion "Unas sábanas de color verde sobre la camilla. No tienen nada especial.",
has escenario femenino nombreplural;
!------------------------
!NIÑO
!------------------------
Object ninio_silla "niño" limbo
with 
    nombre 'niño',
    descripcion "Un niño que pasea por el pasillo hacia tí.",
has escenario;
!---------------------------------------------------------------------
!	daemon en la silla
!---------------------------------------------------------------------
Object  d_silla
with cont -1,
     daemon [;
        self.cont = self.cont + 1;
        if (self.cont == 0)
          "^Los humanos te van empujando por el pasillo. Ves un niño que se acerca en dirección contraria.";
        if (self.cont == 1)
          "^El niño se acerca a la silla.";
        if (self.cont == 2)
          {     
          print "^Os cruzais con el niño que te ve y con ojos asombrados exclama: ^";
          style bold;
          print "^- ¡Un gatito!.^";
          style roman;
          print "^El humano que empujaba la silla para y te coge del cogote diciendo: ^";
          style bold;
          print "^- ¿Y tu de dónde has salido?.^";
          style roman;
          print "^Te sacan a la calle.^La lluvia ha vuelto a arreciar, y ha anochecido. Hace mucho frío. Te acurrucas entre unas cajas, tiritando. Ya perdiste la esperanza, nunca volverás a ver a tu ama... ^A la mañana siguiente te encuentran en la puerta del hospital, frio e inerte.";         
          banderafin = 1;
          }
];
!---------------------------------------------------------------------
!	daemon en la camilla
!---------------------------------------------------------------------
Object  d_camilla
with cont -1,
     daemon [;
        self.cont = self.cont + 1;
        if (self.cont == 3)
          {    
          parardaemon (d_camilla); 
          print "Por debajo de la sábana ves que entran un humano y una humana vestidos de blanco y que empiezan a empujar la camilla. Te llevan a la habitación de la niña. Ves que la anciana se levanta y se pone a un lado y que los humanos levantan a la niña, que ya está despierta y, con cuidado, la colocan sobre la camilla. Sales de debajo de la sábana y la anciana te ve:^";
	  style bold;
          print "^- ¡Un gato! - ";
	  style roman;
          print "exclama";
          style bold;
          print " - ¡Mi nieta tiene alergia a los gatos! - ^";
          style roman;
          if (peluche in mimoso) 
            {
             print "^Los enfermeros intentan cogerte pero la niña te abraza y exclama: ^";
             style bold;
             print "^-¡No!¡Es un gatito muy bonito, y a estos gatitos no les tengo alergia!. Además, me ha traído un regalito.- "; 
             style roman;
             print "dice la niña cogiéndote el osito de peluche. ^Un enfermero dice: ^";
             style bold;
             print "^- Es cierto, el pelo de este tipo de gato no le afecta.-^";
             style roman;
             print "^La niña añade: ^";
             style bold;
             print "^- ¿Me puede acompañar?.- ^";
             style roman;
             print "^Los enfermeros se miran unos segundos y unos de ellos dice: ^";
             style bold;
             print "^- Bueno, pero luego te lo guardamos. - ^";
             style roman;
             print "^La niña te abraza fuerte y los enfermeros empujan la camilla fuera de la habitación.^^Pasais un rato recorriendo pasillos hasta que finalmente llegais a una nueva habitación. De repente un olor muy conocido te asalta la nariz, un olor que te recuerda calor, comida caliente y cariño. Miras a tu alrededor y ves que en esta habitación hay dos camas, una vacía y la otra tapada con una cortina alrededor. Parece haber alguien en esa cama.^El enfermero te coge y ponen a la niña en la otra cama.^";
             jugadorA (enfermero,1);             
             remove peluche;
            }
          else
            {
             print "^Los enfermeros te cogen y se te llevan a la calle.^La lluvia ha vuelto a arreciar, y ha anochecido. Hace mucho frío. Te acurrucas entre unas cajas, tiritando. Ya perdiste la esperanza, nunca volverás a ver a tu ama... ^A la mañana siguiente te encuentran en la puerta del hospital, frio e inerte. Has muerto.";         
             banderafin = 1;
	    }	
          }
];
!-----------------------------------------
!	PASILLO2-HOSPITAL
!-----------------------------------------
Object  h_pasill2 "Pasillo"
with  descripcion "Otro tramo de pasillo que continúa hacia el oeste. Ves en el centro del pasillo una silla de metal con unas ruedas debajo. A su lado hay dos humanos de blanco hablando y más al oeste varios humanos más. Al este vuelves al tramo de pasillo anterior.",
antes [;
   maullar: "¿Pretendes que no te echen?¿no?.";
],
      ubicacion 0,
al_e h_pasill1,
al_o "Hay muchos humanos. Si intentas pasar entre ellos te verán y te sacarán fuera."
has luz;
!------------------------
!SILLA DE RUEDAS
!------------------------
Object silla_ruedas "silla de ruedas" h_pasill2
with 
    nombre 'silla' 'ruedas',
    descripcion "Es una silla con unas ruedas debajo. Sobre ella tiene como unas asas para empujarla.",
    antes [;
      meterse:
        if (mimoso in h_pasill2)
         {
          print "Sin que te vean los humanos te subes a los posapies y de aquí a la silla. Te acurrucas en el fondo.^De repente te empiezas a mover. Giras la cabeza y ves que los humanos están empujando la silla y vuelves al tramo de pasillo anterior.^";          
          arrancardaemon (d_silla);
          move silla_ruedas to h_pasill1;
          jugadorA (self,2);
          rtrue;
         }
       salirse:
          if (mimoso in self)
            "Los humanos están mirando. No te atreves a bajar.";
          else
            "¿De dónde quieres bajarte?.";
        ],
has soporte entrable oculto estatico femenino transparente;
!------------------------
!ENFERMEROS
!------------------------
Object enfermeros "humanos" h_pasill2
with 
    nombre 'humanos' 'hombres',
    descripcion "Son unos humanos con trajes de color blanco que están parados en el centro del pasillo.",
has escenario masculino nombreplural animado;
!-----------------------------------------
!	PASILLO3-HOSPITAL
!-----------------------------------------
Object  h_pasill3 "Pasillo"
with  descripcion [;
       print "Otro tramo de pasillo como el anterior pero sin puertas. Ves unos cuantos humanos en medio del pasillo y sentados en sillas. Al oeste vuelves al tramo anterior.";
       if (plantita in h_pasill3)
         " A un lado, junto a la pared, ves una plantita de color verde.";
       else
         "^";
     ],
      ubicacion 0,
antes [;
   maullar: "¿Pretendes que no te echen?¿no?.";
],
al_o h_pasill1,
al_e "Hay muchos humanos. Si intentas pasar entre ellos te verán y te sacarán fuera."
has luz;
!------------------------
!ENFERMEROS
!------------------------
Object enfermeros2 "humanos" h_pasill3
with 
    nombre 'humanos' 'hombres',
    descripcion "Son unos humanos con trajes de color blanco que están parados en el centro del pasillo.",
has escenario masculino nombreplural;
!------------------------
!PLANTITA
!------------------------
Object plantita "plantita" h_pasill3
with 
    nombre 'plantita' 'planta',
    descripcion "Una plantita verde a un lado del pasillo.",
    antes [;
      comer:   
         remove plantita;
         hambre.comida = hambre.comida + 10;
         "Te comes la plantita. Te quita un poco el hambre.";
],
has comestible femenino oculto;
!-----------------------------------------
!	HABIT2-HOSPITAL
!-----------------------------------------
Object  h_habit2 "Habitación"
with  descripcion "Ves una habitación vacía en la que hay una cama, una silla y una mesita. No ves nada interesante.",
ubicacion 0,
al_n h_pasill1
has luz;
!------------------------
!OBJETOS DECORADO
!------------------------
Object cama_h2 "cama" h_habit2
with 
    nombre 'cama',
    descripcion "Una cama normal con sábanas blancas.",
has escenario femenino entrable soporte transparente;
!------------------------
Object mesita_h2 "mesita" h_habit2
with 
    nombre 'mesita' 'mesa',
    descripcion "Una simple mesita de madera.",
    antes [;
     meterse: "Está demasiado alto para subir.";
],
has escenario femenino;
!------------------------
Object silla_h2 "silla" h_habit2
with 
    nombre 'silla',
    descripcion "Una simple silla de madera.",
    antes [;
     meterse: "Está demasiado alto para subir.";
],
has escenario femenino;
!-----------------------------------------
!	HABIT3-HOSPITAL
!-----------------------------------------
Object  h_habit3 "Habitación"
with  descripcion "Ves dos camas. En una está la niña, jugando con el osito de peluche. La otra tiene unas cortinitas alrededor que la tapa. Parece que hay alguien tumbado en esa cama.",
     ubicacion 0,
     antes [;
        oler: "La nariz que se te llena de un olor hartamente conocido.";
     ]
has luz;
!------------------------
!ENFERMERO-SOPORTE
!------------------------
Object enfermero "enfermero" h_habit3
with 
    nombre 'enfermero' 'humano',
    descripcion "Un humano con una bata blanca, de pie al lado de la cama de la niña.",
    antes [;
      salirse:
          if (mimoso in enfermero)
            {
            print "Das un gran salto y te desprendes de las manos del enfermero cayendo al suelo en un fenomenal batacazo.^";
            jugadorA(h_habit3,1);
            rtrue;
            } 
          else
            "¿De dónde quieres bajarte?.";
        ],
has soporte entrable oculto estatico masculino transparente animado;
!------------------------
!CAMA DE LA NIÑA
!------------------------
Object cama_ninia "cama de la niña" h_habit3
with 
    nombre 'cama' 'de' 'la',
    adjetivo 'niña',
    descripcion "Es una cama como todas las que has visto hasta ahora. Sobre ella esta tu amiga.",
    antes [;
       meterse:
         "Intentas subirte, pero no llegas.";
     ],
has escenario femenino;
!------------------------
!CAMA CON CORTINA
!------------------------
Object cama_cortina "cama con cortina" h_habit3
with 
    nombre 'cama' 'con' 'cortina',
    descripcion "La cama tiene unas cortinas alrededor que no permiten ver quien hay acostado.",
    antes [;
       meterse:
         if (mimoso in enfermero)
           "Deberías bajarte primero del enfermero.";
         else
           {
           print " Sales corriendo sin que nadie pueda pararte y de un salto te agarras a la cortina, trepas por ella y saltas sobre la cama.^Miras quién hay acostado y la alegria te inunda. ¡Es tu ama! ¡Es tu amita! ¡Por fin la has encontrado!^ Parece dormida. Intentas despertarla lamiendole la cara pero no despierta. El enfermero te coge en brazos de nuevo, pero comienzas a patalear, maullar y arañar, ¡quieres volver con tu amita!. Un enfermero entra en la habitación:^";
           style bold;
           print "^ - ¡Hey! ¡Este es el gato de la anciana! Llevaba una foto en el bolso.-^";
           style roman;
           print "^El enfermero que te tiene en brazos contesta:^ ";
           style bold;
           print "^- Quizá nos de una pista de quién es, entonces. -^";
           style roman;
           print "^El enfermero te examina y ve la chapa que tienes colgada al cuello.^ ";
           style bold;
           print "^- ¡Calle Principal, número 10!. ¡Ya lo tenemos! ¡Avisa al médico, rápido!-.";            
           style roman;
           print "^^------------------^^";	
           print "^ Por fin vuelves a estar en casa. Han pasado varios días y tu amita está a tu lado, preparándote la comida. La niña del hospital, que se llama Clara, está también a tu lado, jugando contigo. Desde aquel dia viene a verte bastante.^ Dicen que salvaste la vida de la niña y de tu amita. La niña porque dicen que sin la alegria que le diste no habría podido superar la operación. A tu ama, porque necesitaban saber donde vivía ya que no tenía ningún documento cuando se desmayó en la calle y tenían que operarla. Así descubrieron que mi amita tiene alergia a la anestesia. Si no lo hubiesen sabido dicen que se habría puesto muy malita.^Yo no sé nada de esto.^Lo único que sé es que por fin estoy en casa. Que estoy con mi amita. Y que, además, ¡acabo de hacer una amiga nueva!";
           banderafin = 2;
           rtrue;
           }
     ],
has escenario femenino;
!------------------------
!NIÑA
!------------------------
Object ninia2 "niña" h_habit3
with 
    nombre 'niña',
    descripcion "La niña está sobre la cama jugando con el osito de peluche.",
has escenario femenino animado;
!------------------------
!CORTINA
!------------------------
Object cortina "cortinas" h_habit3
with 
    nombre 'cortinas',
    descripcion "Las cortinas, de color blanco semi-transparente, parecen ocultar a alguien acostado en la cama.",
has escenario femenino nombreplural;
!-----------------------
!	RUTINAS
!-----------------------
[ UsarSub;
  "¿Qué quieres usar?";
];

[ MaullarSub maullido;
  maullido = random (5);
  switch(maullido)
   {
    1 : "Miauuuuuuuuuuuu";
    2 : "Marramiauuu";
    3 : "Meaw";
    4 : "Miau miau miauuuu";
    5 : "Meuuuuuuu";
   }
];

[ RonronearSub;
  "Rrrrrrrrrrrrrrr";
];

[ aranyarSub;
if (ObjetoEsIntocable(uno)) return;
if (uno has animado && EjecutarVida(uno,##Atacar)~=0) rfalse;
  M__L(##Atacar,1,uno); 
];

[ MorderSub;
if (ObjetoEsIntocable(uno)) return;
if (uno has animado && EjecutarVida(uno,##Atacar)~=0) rfalse;
  M__L(##Atacar,1,uno); 
];

[ PararDaemonHambreSub;
print "^¡Juro por Dios, que ya no volveré a pasar hambre!^";
PararDaemon(hambre);
rtrue;
];

[ MisDatosSub;
print "^Sergio Martínez García, desde Sant Just Desvern, Barcelona.^";
rtrue;
];

[ LocalInicial inic;
  inic = 0;
  inic = random (3);
    switch(inic)
      {
       1 :  localizacion = cesta;
       2 :  localizacion = cama;
       3 :  localizacion = cocina;
      }
];

!-------------------
! INTRO
!-------------------

[ intro;
  print "Fuiste el tercer hermano de una camada de seis, pero desde el principio fuiste el hijo más hermoso. ";
  print "Naciste en un lugar donde eras la admiración de todos los humanos que iban. Te observaban a través de un cristal, y lo que veían era una bolita de pelo blanco como la nieve y suave como el algodón. ";
  print "Poco a poco tus hermanos se fueron marchando, y finalmente, con apenas un mes de edad, una mujer muy arrugada que se ayudaba de un palo para andar te recogió y se te llevó también. Te dijo que te llamarías ";
  print "Mimoso, que vivirías en una casa muy bonita, y que le harías compañía. Los primeros dias fueron terribles, echabas de menos a tu mamá, a tus hermanos. Pero poco a poco te fuiste adaptando.^Ha pasado ya un mes, y ";
  print "la ama siempre ha estado contigo. Siempre que sale a comprar, te lleva consigo, metido en su gran bolso. En casa siempre juega contigo y te da de comer cada día muchas cosas buenas. Nunca ha dejado que te pase nada. Nunca te ha dejado solo.^Nunca hasta ahora.^";
  print "Despiertas y miras a tu alrededor. La casa está oscura y silenciosa, solo se oye el sonido de la lluvia golpear contra las ventanas. Al momento intuyes que algo va mal. La amita no está, y además, unas nubes de lo que parece humo flotan cerca del techo, y huele a quemado.^";
  print "¿Que ha pasado? ¿Dónde está la amita? Es la primera vez en la vida que estás solo, y estás asustado. Y, además, hace mucho que no comes ni bebes... necesitas a tu ama... ¿dónde estás?.^";
  print "^^^^. . .^^^^";
  EsperarTecla ();
  @erase_window -1;
];

!---------------------------------------------------------------------
!	Inicialización
!---------------------------------------------------------------------
[ Inicializar;
     CambiarJugador (mimoso);
     mimoso.capacidad = 2;
     LocalInicial ();
     move chapa to mimoso;
     move correa to mimoso;
     give comedor general;
     intro ();	
     modomirar = target_zcode;
     modomirar = 2; 
     ArrancarDaemon(hambre);
     ArrancarDaemon(accio_aleat);
     ArrancarDaemon(d_humo);
];

Include "Gramatica";

Verb meta 'artist'
    *                                   -> misdatos;

Verb meta 'ayuno'
    *                                   -> PararDaemonHambre;

Verb 'usa' 'utiliza'
    * multi                          	-> Usar;

Verb 'maulla'
    *                           	-> Maullar;

Verb 'ronronea'
    *                           	-> Ronronear;

Verb 'araña'
    * noun                          	-> aranyar
    * 'a' creature                      -> aranyar; 

Verb 'muerde'
    * noun                          	-> Morder
    * 'a' creature                      -> Morder; 
VerboIrregular "morder" with imperativo 'muerde';