/CTL
_	;El carácter de palabra nula es el subrayado;	-	-	-	-	-	-	-	-	-
/VOC
;
;
##include minvocesp.txp
dorado     12 adjective
azul       13 adjective
;
;
leer       50 verb
lee        50 verb
estud      51 verb
busca      52 verb
local      52 verb
encue      53 verb
corre      54 verb
estir      54 verb
cubrir     54 verb
cubre      54 verb
desco      55 verb
separ      55 verb
retir      55 verb
descubrir  55 verb
abrir      56 verb
abre       56 verb
cierr      57 verb
cerra      57 verb
apaga      58 verb
enciende   59 verb
encender   59 verb
levan      60 verb
mover      61 verb
mueve      61 verb
muevo      61 verb
;
;
candelabro 51 noun
libro      52 noun
libre      53 noun
estan      53 noun
muebl      53 noun
regenta    54 noun
llave      55 noun
tapiz      56 noun
cortina    56 noun
puert      57 noun
trampilla  57 noun
detras     58 noun
tras       58 noun
detrás     58 noun
quijote    59 noun
cid        60 noun
bonos      61 noun
altar      62 noun
lampa      63 noun
lámpa      63 noun
tabla      64 noun
tabli      64 noun
ceril      65 noun
lazar      66 noun
robin      67 noun
mosqu      68 noun
tesis      69 noun
legua      70 noun
trafa      71 noun
biblia     72 noun
;
;
;
;	-	-	-	-	-	-	-	-	-
/STX	;Mensajes del sistema
;
;
;
##include sysmsgesp.txp
;
;	-	-	-	-	-	-	-	-	-
/MTX	;Mensajes
;
;
##include legmens.txp
;
;	-	-	-	-	-	-	-	-	-
/OTX	;Descripciones de objetos
/0
un candelabro encendido.
/1
un libro azul.
/2
una llave pequeña.
/3
unos bonos del estado.
/4
un candelabro apagado.
/5
unas cerillas.
;	-	-	-	-	-	-	-	-	-
/LTX	;Descripciones de lugares
/0 ; Introducción


Madrid, 1880

Tu tío ha muerto. 


El dolor te embarga ... estabais tan unidos ...



Tu tío siempre te dijo que tú heredarías su fortuna ...
y su responsabilidad.


Nunca supiste a qué se refería exactamente con aquella frase, que te decía
cuando eras un niño y jugabas en sus brazos.
Los años pasaron, y tu tío acaba de morir dejándote como herencia su fortuna.
Eso sí, para obtenerla, para ser merecedor de la misma, tendrías que
pasar la noche en la biblioteca de su gran casa, y descubrir
por tí mismo cuánto abarcaba la herencia ... sea lo que sea ...

/1
##define loc biblio 1
Esta biblioteca es la más grande que jamás has visto. Decorada con austeridad,
miles y miles de libros de tamaño y colores variados se agolpan en la vieja
estantería, sobrecargada por el peso de los volúmenes y la edad. En la pared
norte, la única no cubierta por estanterías, hay un tapiz.
Observas que los libros están ordenados por orden alfabético, por lo que podrías
buscar uno en concreto.
Al sur se encuentra el pasillo que conecta la biblioteca con el resto de la casa.
/2
##define loc pasillo 2
El pasillo que conduce a la biblioteca es estrecho y huele a humedad. Está
simplemente encalado en blanco.
/3
##define loc salon 3
Un amplio salón se abre en esta luminosa estancia. Los sobrecargados adornos
contrastan con la sobriedad de la biblioteca y del pasillo que acabas de
abandonar.
/4
##define loc cuarto_oscuro 4
El pequeño cuarto oscuro es tan estrecho que prácticamente no cabes en él. La
tenue luz que se filtra de la biblioteca parece no poder vencer la casi tenebrosa
atmósfera alrededor. Todo está lleno de polvo, que flota en el ambiente.
Hay unos salientes moldeados en la totalidad de una de las paredes, que parecen conducir hacia arriba,
donde la oscuridad, aparentemente, es todavía más densa.
/5
##define loc desvan 5
Encima del cuarto oscuro se abre un trozo de desván. En realidad, no es más 
que uno de los extremos
del tejado, cortado por un tabique. Nunca te habías dado cuenta de que el tejado
era más corto de lo que realmente debería ser, aunque el espacio es realmente
pequeño. Sólo puedes mantenerte de pié al lado contrario de la abertura que
conduce al cuarto oscuro. Estás de pié justo encima de la biblioteca.
/6
##define loc sotano 6
Has accedido a un estrecho pasillo en el sótano, a través de unas escaleras pegadas a la pared. 
Todo es oscuridad aquí dentro, tenebrosamente oscuro y cerrado. Las sombras
se alargan a la luz de tu candelabro. El techo, jalonado de telas de araña y otros
bichos que ni siquiera te atreves a examinar de cerca, es el soporte de la vieja
biblioteca. La soledad y la tristeza se adivinan por doquier. El estrecho pasillo
continúa hacia el este a través de la oscuridad.
/7
##define loc sotano2 7
Continúas por el estrecho pasillo. La oscuridad te rodea y parece envolverte, cada
vez que pretendes dar un paso. La tristeza y abandono del lugar son más patentes aquí.
A duras penas te orientas en el pasillo. Pareciera que el tiempo se ha detenido. Sin embargo,
sabes que hacia el oeste se encuentra la biblioteca -y la luz-, mientras al este ...
/8
##define loc sotano3 8
El estrecho pasillo huele en este punto a humedad. Debes estar debajo de las cocinas  de la
gran casa, deduces. Nunca te ha gustado la oscuridad, pero en este pasillo no puedes
escapar de ella. La biblioteca al oeste te da un poco de tranquilidad, aunque desde
este punto no puedes ver las escaleras hacia el cuarto oscuro, y la biblioteca. La
inquietud te invade lentamente. Al este ...
/9
##define loc cripta 9
De repente, la estrechez del pasillo se abre a una baja pero ancha estancia. No puedes
ver más que lo que hay delante de tí: un altar, y sobre él, una vieja lámpara. La oscuridad es casi impenetrable. Te quedas paralizado, con temor a moverte
demasiado. Sientes contínuamente unas ganas terribles de volver al oeste, por donde
has venido. Pero estás aquí ...
;	-	-	-	-	-	-	-	-	-
/CON	;Conexiones
;/0			; Inicio del juego
;	N	0
/0 ;introducción, no hay conexiones
;
;
;
/&&biblio
      s     &&pasillo
      sal   &&pasillo
/&&pasillo
      entra &&biblio
      sal   &&salon
      s     &&salon
      n     &&biblio
/&&salon
      n     &&pasillo
;
/&&cuarto_oscuro
      sube  &&desvan
/&&desvan
      baja  &&cuarto_oscuro
/&&sotano
      sube &&cuarto_oscuro
/&&sotano2
      oeste &&sotano
      este  &&sotano3
/&&sotano3
      este &&cripta
      oeste &&sotano2
/&&cripta
      oeste &&sotano3
;	-	-	-	-	-	-	-	-	-
/OBJ	;Definiciones de objetos
;num  empieza  peso   conte-  poner/    susta  adjetivo
;obj	en	      nedor   quitar    ntivo
;	-	-	-	-	-	-	-	-	-
/0    1 1      _       _      candelabro _
##define obj candelabro 0
/1    _           1      _       _      libro _
##define obj libro 1
/2    _           1      _       _      llave _
##define obj llave 2
/3    _ 1 _  _ bonos _
##define obj bonos 3 
/4    _ 1 _  _ candelabro _
##define obj candelabro_apagado 4   
/5    CARRIED 1 _ _ cerillas _
##define obj cerillas 5
;
;
;
/PRO	0	;es decir, Tabla de Respuestas
##define flg hay_luz 0
##define flg descubre_mensaje 100
##define flg tapiz_corrido 101
##define flg puerta_cerrada 102
##define flg trampilla_abierta 104
##define flg lo_has_visto 105
##define flg tablas_levantadas 106
;
I	_	INVEN

SUR   _     AT &&cuarto_oscuro
            message &&no_esta_tan_oscuro
            LET &&hay_luz 0
            goto &&biblio
            DONE

SAL   _     AT &&cuarto_oscuro
            message &&no_esta_tan_oscuro
            LET &&hay_luz 0
            goto &&biblio
            DONE

ABAJO _     AT &&cuarto_oscuro
            EQ &&trampilla_abierta 1
            MESSAGE &&esta_realmente_oscuro
            GOTO &&sotano
            DONE

COGER libro message &&libro_no_se_coge
            DONE

COGER quijo message &&libro_no_se_coge
            DONE

COGER	TODO	DOALL	HERE

COGER	_	AUTOG
		DONE

;METE TODO PREP EN
;		NOUN2 BOLSA
;		PRESENT 1
;		doall carried

;METE _ PREP EN
;		NOUN2 BOLSA
;		PRESENT 1
;		AUTOP 1
;		DONE

DEJAR	TODO	DOALL	CARRIED

DEJAR	_	AUTOD
		DONE

EXAMI PUERT at &&biblio
            zero &&tapiz_corrido
            message &&puerta_desc
            ZERO &&puerta_cerrada
            MESSAGE &&puerta_esta_abierta
            DONE

EXAMI PUERT at &&biblio
            zero &&tapiz_corrido
            EQ &&puerta_cerrada 1
            MESSAGE &&puerta_esta_cerrada
            DONE

quita tabla ZERO &&tablas_levantadas
            CREATE &&bonos
            MESSAGE &&encuentras_bonos
            LET &&tablas_levantadas 1
            DONE

levan tabla ZERO &&tablas_levantadas
            MESSAGE &&encuentras_bonos
            LET &&tablas_levantadas 1
            CREATE &&bonos
            DONE

quita tabla EQ &&tablas_levantadas 1
            NOTDONE

QUITAR	TODO	DOALL	WORN
QUITAR	_	AUTOR
		DONE

PONER	TODO	DOALL	CARRIED
PONER	_	AUTOW
		DONE

FIN	_	QUIT
		TURNS
		END

GUARD	_	SAVE

CARGA	_	LOAD

RAMGU	_	RAMSAVE
		DESC

RAMCA	_	RAMLOAD	255		;Recargar todas las variables
		DESC

BUSCA REGEN at &&biblio
            absent &&llave
            message &&hojeas_regenta
            message &&encuentras_llave
            create &&llave
            DONE

BUSCA REGEN at &&biblio
            present &&llave
            message &&hojeas_regenta2
            DONE

BUSCA CID   at &&biblio
            message &&hojeas_cid
            DONE

BUSCA LAZAR at &&biblio
            message &&hojeas_lazarillo
            DONE

BUSCA TESIS at &&biblio
            message &&hojeas_tesis
            DONE

BUSCA ROBIN at &&biblio
            message &&hojeas_robinson
            DONE

BUSCA LEGUA at &&biblio
            message &&hojeas_leguas
            DONE

BUSCA MOSQU at &&biblio
            MESSAGE &&hojeas_mosqueteros
            DONE

BUSCA BIBLI at &&biblio
	    MESSAGE &&hojeas_biblia
	    DONE

BUSCA trafa at &&biblio
	    MESSAGE &&hojeas_trafalgar
	    DONE

BUSCA _     at &&biblio
            message &&no_encuentras_libro
            DONE

BUSCA _     message &&no_buscar
            DONE

EXAMI TRAMP let 34 11 ;convierte trampilla en suelo

EXAMI SUELO AT &&cuarto_oscuro
            MESSAGE &&trampilla_desc
            EQ &&trampilla_abierta 1
            MESSAGE &&trampilla_esta_abierta
            DONE

EXAMI TABLA AT &&desvan
            MESSAGE &&tablas_desvan_desc
            DONE

EXAMI SUELO AT &&desvan
            MESSAGE &&tablas_desvan_desc
            DONE
            
EXAMI SUELO AT &&cuarto_oscuro
            ZERO &&trampilla_abierta
            MESSAGE &&trampilla_esta_cerrada
            DONE

ABRE TRAMP  AT &&cuarto_oscuro
            MESSAGE &&mueves_la_trampilla
            MESSAGE &&trampilla_esta_abierta
            LET &&trampilla_abierta 1
            DONE

CIERR TRAMP  AT &&cuarto_oscuro
            MESSAGE &&mueves_la_trampilla
            MESSAGE &&trampilla_esta_cerrada
            LET &&trampilla_abierta 0
            DONE

EXAMI BONOS present &&bonos
            message &&bonos_desc
            DONE

EXAMI LIBRO at &&biblio
            absent &&libro
            let 34 53 ; convertir LIBRO en LIBRERIA

EXAMI LIBRE AT &&biblio
            ABSENT &&libro
            message &&libreria_desc
            message &&encuentra_libro
            create &&libro
            DONE

EXAMI LIBRE at &&biblio
            message &&libreria_desc
            DONE

EXAMI CANDE present &&candelabro
            message &&candelabro_desc
            message &&candelabro_esta_encendido
            DONE

EXAMI CANDE present &&candelabro_apagado
            message &&candelabro_desc
            message &&candelabro_esta_apagado
            DONE

EXAMI LLAVE present &&llave
            message &&llave_desc
            DONE

EXAMI TAPIZ AT &&biblio
            ZERO &&tapiz_corrido
            message &&tapiz_desc
            message &&tapiz_esta_descorrido
            DONE

EXAMI TAPIZ AT &&biblio
            EQ &&tapiz_corrido 1
            message &&tapiz_desc
            message &&tapiz_esta_corrido
            DONE

EXAMI TAPIZ NOTAT &&biblio
            message &&tapiz_en_biblio
            DONE

MUEVE TAPIZ AT &&biblio
            ZERO &&tapiz_corrido
            message &&corres_tapiz
            LET &&tapiz_corrido 1
            DONE

MUEVE TAPIZ AT &&biblio
            EQ &&tapiz_corrido 1
            message &&descorres_tapiz
            LET &&tapiz_corrido 0
            DONE

CORRE TAPIZ AT &&biblio
            ZERO &&tapiz_corrido
            message &&corres_tapiz
            LET &&tapiz_corrido 1
            DONE

DESCO TAPIZ AT &&biblio
            EQ &&tapiz_corrido 1
            message &&descorres_tapiz
            LET &&tapiz_corrido 0
            DONE

ABRE PUERTA prep con
            noun2 llave
            at &&biblio
            carried &&llave
            ZERO &&tapiz_corrido
            EQ &&puerta_cerrada 1
            message &&has_abierto_puerta
            LET &&puerta_cerrada 0
            DONE

ABRE puerta AT &&biblio
            ZERO &&tapiz_corrido
            message &&puerta_bloqueada
            DONE

ABRE PUERTA AT &&biblio
            EQ &&tapiz_corrido 1
            message &&que_puerta
            DONE

CIERR PUERT ZERO &&puerta_cerrada
            carried &&llave
            at &&biblio
            LET &&puerta_cerrada 1
            message &&puerta_esta_cerrada
            DONE

ENTRA _     at &&biblio
            ZERO &&puerta_cerrada
            goto &&cuarto_oscuro
            let  &&hay_luz 1
            message &&esta_muy_oscuro
            DONE

METET _     prep en
            at &&biblio
            ZERO &&puerta_cerrada
            goto &&cuarto_oscuro
            let  &&hay_luz 1
            message &&esta_muy_oscuro
            DONE

NORTE _     at &&biblio
            ZERO &&puerta_cerrada
            goto &&cuarto_oscuro
            let &&hay_luz 1
            message &&esta_muy_oscuro
            DONE

ESTE _      at &&sotano
            ZERO &&lo_has_visto
            MESSAGE &&paso_a_sotano2
            goto &&sotano2
            DONE

ESTE _      at &&sotano
            EQ &&lo_has_visto 1
            MESSAGE &&estas_cagao
            DONE

MIRA DETRAS prep de
            noun2 tapiz
            at &&biblio
            message &&puerta_desc
            message &&descorre_el_tapiz_hombre
            DONE
            
ESTUD    _  message &&no_estudio
            DONE

EXAMI QUIJOTE at &&biblio
            present &&libro
            let 34 52 ; convertir quijote en libro

EXAMI LIBRO present &&libro
            EQ &&descubre_mensaje 255
            message &&hojeas_quijote2
            DONE

EXAMI LIBRO present &&libro
            ZERO &&descubre_mensaje
            SET &&descubre_mensaje
            message &&mensaje_secreto
            DONE

EXAMI LIBRO present &&libro
            message &&intuyes_sistema
            MINUS  &&descubre_mensaje 1
            done

LEE LIBRO   present &&libro
            ZERO &&descubre_mensaje
            message &&mensaje_secreto
            done

LEE LIBRO   present &&libro
            message &&intuyes_sistema
            MINUS  &&descubre_mensaje 1
            done

encie cande present &&candelabro
            message &&candelabro_esta_encendido
            done

encie cande absent &&candelabro_apagado
            message &&candelabro_nota
            done

encie cande present &&candelabro_apagado
            present &&cerillas
            message &&candelabro_esta_encendido
            swap  &&candelabro_apagado &&candelabro
            done

encie cande present &&candelabro_apagado
            absent  &&cerillas
            message &&necesito_cerillas
            done

apaga cande present &&candelabro_apagado
            message &&candelabro_esta_apagado
            done

apaga cande absent &&candelabro
            message &&candelabro_nota
            done

apaga cande present &&candelabro
            message &&candelabro_esta_apagado
            swap &&candelabro &&candelabro_apagado
            done

exami lampa AT &&cripta
            MESSAGE &&lampara_desc
            DONE

exami ceril PRESENT &&cerillas
            MESSAGE &&cerillas_desc
            DONE

exami altar AT &&cripta
            MESSAGE &&altar_desc
            DONE

encie lampa prep con
            noun2 candelabro
            at &&cripta
            present &&candelabro
            MESSAGE &&te_cagas
            MESSAGE &&te_cagas2
            LET &&lo_has_visto 1
            GOTO &&sotano
            DONE 

encie lampa prep con
            noun2 cerill
            at &&cripta
            present &&cerillas
            MESSAGE &&te_cagas
            MESSAGE &&te_cagas2
            LET &&lo_has_visto 1
            GOTO &&sotano
            DONE 

encie lampa at &&cripta
            message &&con_que
            DONE

EXAMI _     message &&nadaespecial
            DONE

MIRAR	_	DESC
            DONE

;saca todo prep de
;	noun2 bolsa
;	doall 1

;saca _ prep de
;	noun2 bolsa
;	present 1
;	autot 1
;	done

;	-	-	-	-	-	-	-	-	-
/PRO	1	;Despues de describir la localidad
; inicio
_	_	AT 0
            MESSAGE &&nombre
            MESSAGE &&serial
            LET &&descubre_mensaje 3 ; 3 intentos para descubrir el mensaje
            LET &&tapiz_corrido 1 ; Tapiz corrido
            LET &&puerta_cerrada 1 ; La puerta está cerrada
            ANYKEY
		GOTO 1
		DESC

_	_	NEWLINE
		ZERO	&&hay_luz	       ;Si hay luz...
		ABSENT	&&candelabro ;y no esta la fuente de luz...
		LISTOBJ			 ;Listar los objetos

_	_	PRESENT	&&candelabro ;Si esta la fuente de luz...
		LISTOBJ			 ;Listar los objetos

_     _     EQ &&lo_has_visto 1
            MESSAGE &&estas_nervioso

_     _     AT &&salon
            ZERO &&lo_has_visto
            ZERO &&tablas_levantadas
            MESSAGE &&nofin
            TURNS
            END

_     _     AT &&salon
            EQ &&lo_has_visto 1
            EQ &&tablas_levantadas 1
            MESSAGE &&encontraste_todo
            TURNS
            END

_     _     AT &&salon
            EQ &&tablas_levantadas 1
            MESSAGE &&encontraste_pasta
            TURNS
            END

_     _     AT &&salon
            EQ &&lo_has_visto 1
            MESSAGE &&encontraste_vision
            TURNS
            END

_     _     AT &&biblio
            ZERO &&tapiz_corrido
            MESSAGE &&puerta_desc

_     _     AT &&biblio
            ZERO &&tapiz_corrido
            ZERO &&puerta_cerrada
            MESSAGE &&puerta_esta_abierta

_     _     AT &&biblio
            ZERO &&tapiz_corrido
            EQ &&puerta_cerrada 1
            MESSAGE &&puerta_esta_cerrada

_     _     AT &&cuarto_oscuro
            EQ &&trampilla_abierta 1
            MESSAGE &&trampilla_desc
            MESSAGE &&trampilla_esta_abierta

/PRO 2
_     _     GT &&hay_luz 0 ; No hay luz
            PRESENT &&candelabro
            CHANCE 10
            SWAP &&candelabro &&candelabro_apagado
            MESSAGE &&aire_gelido
            MESSAGE &&candelabro_esta_apagado
            
_     _     GT &&hay_luz 0 ; No hay luz
            CHANCE 10
            MESSAGE &&hay_una_rata

_     _     GT &&hay_luz 0 ; No hay luz
            CHANCE 10
            MESSAGE &&hay_arannas