-- Alan Tutorial, Stephen Griffiths, 1998
-- file : library2.ala
-- expanded standard verbs library for Alan tutorial examples

SYNONYMS 
  n=north.
  s=south.


SYNTAX 'quit'='quit'.
SYNONYMS q ='quit'.
VERB 'quit' DOES
 SCORE.
 QUIT.
END VERB.


SYNTAX 'score'='score'.
SYNONYMS sc ='score'.
VERB 'score' DOES
 SCORE.
END VERB.


SYNTAX brief=brief.
SYNONYMS
  b=brief.
  short=brief.
VERB brief DOES
  VISITS 99.
  "$pNow using 'brief' mode - full descriptions will only be
  displayed the first time you visit a location$p"
END VERB.


SYNTAX verbose=verbose.
SYNONYMS 
  v=verbose.
  long=verbose.
  full=verbose.
  f=verbose.
VERB verbose DOES
  VISITS 0.
  "$pNow using 'verbose' mode - full descriptions will be
  displayed each time you visit a location$p"
END VERB.               


SYNTAX 'look'='look'.
SYNONYMS l='look'.
VERB 'look' DOES
  LOOK.
END VERB.


SYNONYMS place=put.
SYNTAX
 put=put (obj1) 'in' (obj2)
WHERE obj1 ISA Object
  ELSE "You don't have that."
AND obj2 ISA Container
  ELSE "You can't put things in there."

VERB put
CHECK Obj1 IN Inventory
  ELSE "You don't have the $1."
DOES
  LOCATE obj1 IN obj2.
END VERB.


SYNONYMS get=take.
SYNTAX
 take=take (obj)*.
VERB take
CHECK Obj IS Takeable
  ELSE "You can't take that."
AND Obj NOT IN Inventory
  ELSE "You already have it."
DOES
  "You take the $o."
  LOCATE Obj IN Inventory.
END VERB.


SYNONYMS throw=drop.
VERB drop
CHECK OBJECT in Inventory
 ELSE "You don't have that."
DOES 
  "You drop the $o."
  LOCATE OBJECT HERE.
END VERB.


SYNTAX list_inventory=inventory.
SYNONYMS i=inventory.
VERB list_inventory
 DOES
  LIST Inventory.
END VERB.