-- Alan Tutorial
-- file : lesson5.ala
-- Lesson 5 example program
-- objects, basic object verbs, 'local' verbs


LOCATION Street NAME A City Street
 DESCRIPTION
   "Either side of the street is full of shops.
   The shops are a typical mixture of old houses converted into
   trendy boutiques and a few new glass-fronted shopping arcades.
   The exception is one house, to the north of you, which looks 
   like a deserted house.  A sign on the front door says $n$tPrivate 
   $n$tThis is my home$n$tDon't Annoy Me!$p"

 EXIT north TO Porch.
END LOCATION.


OBJECT Note AT Street

 VERB eat
  DOES 
   LOCATE Note AT Nowhere.
   "The note is surprisingly tasty.  But, now that you think about it,
   eating it was rather pointless."
  SCORE 5. -- hey how can that be 'pointless'!! (= a sample 'bug')
 END VERB.

END OBJECT.


OBJECT Tin AT Street
END OBJECT.


LOCATION Porch NAME Front Porch
 DESCRIPTION
   "The unpainted wood of the porch is rotting and feels like it
   could crack under your weight at any moment.  The front door of
   the house, however, seems newly installed and very strong."
  SCORE 5.

 EXIT south TO Street.
END LOCATION Porch.


SYNONYMS get=take.
VERB take
 DOES 
  LOCATE OBJECT IN Inventory.
END VERB.


SYNONYMS throw=drop.
VERB drop
 DOES 
  LOCATE OBJECT HERE.
END VERB.


LOCATION Nowhere
END LOCATION.


SYNTAX list_inventory=inventory.
SYNONYMS i=inventory.
VERB list_inventory
 DOES
  LIST Inventory.
END VERB.


$INCLUDE 'library1.ala'


START AT Street.
VISITS 99.