! 125 Man abandoned by ship / swimming in sea pickt up hours later with strange story of undersea region he has visited / mad??


Object pendentif125 "pendentif de corail" InRoulotte
! class ObjetPortail
class ObjetAutel
    with     
        name 'pendentif' 'collier' 'bijou' 'medaillon' 'corail',
        actif 1,
        description [;
            Affichette(50);
            print "Un somptueux bijou lançant ses éclats écarlates, un disque plat de corail rouge vif, rappelant le sang et l'eau de l'éternité des Océans. ^"; 
            give self ~concealed ; 
        ],
        before [;
            Take: 
                if (self.actif == 1 && location == InRoulotte) {
                    give self ~concealed ; 
                    print "Fasciné par le bijou, je l'effleurai d'un doigt...^";
                    Attend();
                    print "^... et je perçus comme une... vibration étrange, qui s'amplifia et en intensité, et en amplitude, jusqu'à devenir une grande houle secouant mon corps, et levant les yeux à nouveau, je n'étais plus dans la roulotte.^";  
                    Demarrer125();
                    rtrue; 
                }
                else {
                    if (location == sub125) {
                        Achieved(3) ; 
                        self.obtenu = 1; 
                        self.actif = 0 ;
                        rfalse ;
                    }
                    else rfalse;
                }
            Touch, Push, Pull: << Take self >> ;
            Wear: print "En passant ce pendentif autour de mon cou, je sentis que quelque chose de terrible était en train de se mettre en place. J'eus des douleurs dans tout le corps, et je sentis ma peau se dessécher, pour ensuite progressivement changer de texture. Ma vision se modifiait également, me donnant un champ de vision plus large, mais dans des gammes de couleurs différentes. Je regardais mes mains avec horreur : palmées, rugueuses, monstrueuses, qu'étais-je donc devenu ?^" ; perdu(); rtrue;
        ],
    has concealed clothing ;

Object Piece125 "En plein Océan" class Lieu
    with 
        scenic_look 
            'visage' 'phosphorescent' 0 "Je ne discernai plus cette vision d'horreur, ce qui pourtant n'aida point à faire diminuer mon angoisse.",
        description [;
            Affiche(51); 
            Joue(1252);
            if (self hasnt visited) {
                print "^Comment pourrais-je oublier cet instant de cauchemar absolu ?^";
                Attend();
                print "^Quand, en plein Atlantique, seul sur mon voilier et abruti de fatigue, un mauvais coup de vent par une nuit sans lune relâcha la baume que je pris en plein visage, me basculant par-dessus bord ?^";
                Attend();
                print "^Comment exprimer l'indicible horreur de se savoir perdu sur une masse d'eau infinie, dans le noir de la nuit, alors que son navire dérive au loin et file sans revenir ?^^";
                Attend();
            }
            print "J'étais perdu dans l'immensité d'un Océan noir, ballotté de vagues en vagues et luttant de mes dernières forces pour me maintenir hors de l'eau.^^Rien autour de moi sinon l'Océan, l'Océan et au-dessus des millions d'étoiles. ^";
        ],
        each_turn [ k ; 
            if (self.nage>4) {
                print "^^Incroyable...^";
                Italique();Attend();
                print "^... Impossible !^";
                Normal();Attend();
                print "^Et pourtant il était bien là : devant moi, un rocher plat, affleurant les eaux, battu par les vagues !^^";
                Attend();
                print "^Avec mes dernières forces, je me hissai sur le rocher dentelé qui m'arracha les chairs, terrifié de l'impossibilité de la chose, et pourtant si heureux de toucher la terre !^^Je me hissai, et sur le dos, la houle venant parfois balancer mon corps agrippé aux aspérités, je reprenais mes forces et mon souffle dans la contemplation paisible des étoiles.^^";Attend();
                print "Ces millions d'étoiles au-dessus de moi, témoins silencieux de mon pauvre destin... après un temps indéfinissable où les étoiles apparaissaient encore, toujours plus nombreuses, je me remis debout pour inspecter les environs.^";
                Attend();
                PlayerTo(rocher125);
            }
            k = random(20); switch(k) {
                1: print "^La houle noire m'enveloppait et m'enserrait comme les bras mous d'une créature insaisissable. ^";
                2: print "^À l'horizon, de nombreux éclairs brisaient le ciel dans une éblouissante clarté. ^";
                3: print "^Le froid gagnait mes membres déjà engourdis par la fatigue... la fin n'était pas loin. ^";
                4: print "^Malgré moi, une vague me balaya et l'eau de l'Océan entra dans mes poumons dans la brûlure du sel. ^";
                5: print "^Une gigantesque vague obscurcit le ciel, et un instant, une terreur cosmique s'empara de moi alors que je me retrouvais dans le noir absolu. ^";
                6: print "^Ma vision tourna au rouge : la blessure à mon front saignait abondamment et coulait sur mes yeux. ^";
                7: print "^Le vent hurlait comme une damnation éternelle. ^";
                8: print "^Le froid et la fatigue provoquaient des éblouissements intermittent et maintes fois je crus perdre connaissance. ^";
                9: print "^L'immensité de l'eau me glaca de terreur. ^";
                10: print "^Dans un instant d'horreur, je crus voir un gigantesque visage phosphorescent apparaître sous les eaux. ^";
                11: print "^Les vagues me lançaient l'une à l'autre comme si elles monnayaient mon âme. ^";
            }
        ],
        before [;
            Smell: "Je ne sentais que l'odeur menaçante du sel.";
            Swim: 
                if (noun) <<Go noun>>; ! "nager à l'est", etc... -- Samuel
                else "Il me fallait indiquer dans quelle direction je voulais aller...";
    ],
    cant_go "C'était malheureusement impossible.",
    n_to [;self.nage++;print "Je levai mes yeux vers Polaris, luttant contre les vagues, et avançai vers le Nord. ^";rtrue;],
    s_to [;self.nage++;print "Fomalhaut brillait dans le ciel, et je donnai mes dernières forces à progresser vers le sud. ^";rtrue;],
    w_to [;self.nage++;print "Je cherchai Cassiopée et son W brillant, nageant vers l'ouest dans une pathétique tentative de rejoindre mon navire. ^";rtrue;],
    e_to [;self.nage++;print "Arcturus au levant me guidait alors que je nageais péniblement dans la houle de l'est. ^";rtrue;],
    nage 0,
has scenery;

Object rocher125 "En plein Océan, sur un affleurement rocheux" 
class Lieu
    with
        scenic_all 
            'sang' 0 "J'avais perdu beaucoup de sang mais c'était le prix à payer pour rester en vie.",
        scenic_look
            'affleurement' 'rocheux' 'atlantique' 'rocher' 'eaux' 'sombres' 0 "Un espace de terre ferme entouré d'eaux agitées.",
        description [;
            ! Affichette(52); : TODO
            print "^Par un biais qui me semblait en tout points ";
            Italique();
            print "impossible";
            Normal();
            print ", je me trouvais sur un rocher affleurant les eaux sombres de l'Océan, en plein milieu de l'Atlantique, là où n'auraient dû se trouver que profondeurs insondables.^^Le rocher était effilé comme un rasoir, maintenant taché de mon sang pour m'y être juché et allongé de fatigue, et aucune algue ni mousse n'y poussait, noir et luisant comme de l'obsidienne ou de l'onyx, on y distinguait dans le ressac l'obscure clarté des étoiles.^";
        ],
        before [;
            Swim: << GoUp >> ;
        ],
        cant_go "Et retourner dans les eaux pour y mourir bientôt ? Je n'étais pas encore si fou.",
    has scenery;

Object ObjOcean125 "éléments naturels" class Decor 
    with
        number 0,
        parse_name [ i ;
            self.number = 0;
            while (true) {
                switch (NextWord()) {
                    'alentours', 'alentour', 'environs', 'paysage', 'environnement', 'extérieur': self.number = 0; i++;
                    'mer', 'ocean', 'eau', 'eaux', 'vague', 'vagues' : self.number = 1; i++;
                    'etoile', 'etoiles' : self.number = 2; i++;
                    'rocher', 'rochers', 'roche' : self.number = 3; i++;
                    default: return (i);
                }
            }
        ],
!       description [;               ],
        before [;
            Take, Search, Drink, Eat, Turn:
                switch (self.number) {
                    0: "Impossible.";
                    1: "Il n'y avait rien de bon à essayer de faire cela.";
                    2: "Impossible.";
                    3: "Impossible.";
                } ;
!                default: "Impossible.";
            Look, Examine:
                switch (self.number) {
                    0: << Look >>;
                    1: << Look >>;
                    2: << Look >>;
                    3:  if (location == rocher125) { << Look >>; } else "Il n'y avait rien de tel ici, seulement des eaux froides et infinies." ;
                }
            default: "J'avais mieux à faire pour le moment.";
    ],
    name 'description',
    found_in Piece125 rocher125,
has pluralname scenery;

Object trappe125 "trappe de bronze" rocher125
    with 
        name 'trappe' 'bronze' 'ouverture' 'porte' 'portail' 'sortie' 'trou' 'oeil' 'motifs' 'tentacules',
        description [;
            ! Affiche(53); ! TODO à rajouter si on trouve une image
            print "Je n'en croyais pas mes yeux... haletant, je m'agenouillais devant une ancienne trappe de bronze sculptée de motifs hideux et mouvants sous la houle et la trouble lumière céleste. Des yeux je devinais un oeil, un oeil primitif entouré de huit tentacules repoussants.^";
        ],
        before [;
            Attack : 
                if (self has locked) {
                    if ((second == couteau86b) || (couteau86b in player)) { 
                        print "D'abord désespéré devant la situation présente, je me ressaisis ensuite et sortis mon couteau pour sonder méthodiquement la trappe sur toute sa surface. Par-delà cette mince issue de bronze j'entendais mes coups se répercuter dans une vaste cavité, j'en entendais les échos, et je crus même perçevoir les pas traînants de quelque cyclopéen geôlier. Quand à la trappe en elle-même, je n'y découvris rien dans un premier temps. ^^Mais tandis que j'allais abandonner, en laissant glisser machinalement une dernière fois la lame le long de la jointure, la trappe s'entrouvrit dans un cliquetis sinistre.^" ;  
                    }
                    else { 
                        print "De rage devant mes efforts vains, je frappai sur la trappe, je frappai encore et encore, et par-delà cette mince issue de bronze j'entendais mes coups se répercuter dans une vaste cavité, j'en entendais les échos, et je crus même entendre les pas traînants de quelque cyclopéen geôlier.^^Et quand j'eus tant frappé que la trappe fut recouverte du sang de mes poings, alors seulement elle s'entrouvrit dans un cliquetis sinistre.^";
                    }
                    give self ~locked;
                    return 2;
                }
            Open : 
                if (self hasnt locked) {
                    print "J'ouvrais alors la trappe alors qu'une vague plus forte que les autres balaya le rocher : aussitôt l'eau noire fut engloutie et dégringola le long d'escaliers impossibles dans des éclaboussements sans fin. Haletant, croyant perdre la raison, je descendis également dans cette obscure issue vers les enfers marins.^";
                    Attend();
                    print "^Dans une obscurité complète, je cherchais à tâtons le long de murs humides ma voie, toujours plus bas sur ces marches d'inégale longueur, parfois hautes comme la moitié d'un homme, et au-dessus de moi, une dernière vague referma dans un claquement sévère la trappe de bronze.^";
                    Attend();
                    print "^J'étais condamné à avancer et à découvrir les merveilles ou les horreurs de cet inexplicable lieu.^"; 
                    PlayerTo(escaliers125);
                    rtrue ;
                }
        ],
    has female openable lockable locked static;

Object escaliers125 "D'interminables escaliers" 
class Lieu
    with 
       scenic_all 
            'escaliers' 'marches' 'marche' 'escalier' 0 "Même si les lieux qui m'attendaient me terrifiaient, je ne voulais pourtant plus remonter d'où je venais.",
        name 'glyphes' 'glyphe' 'antre',
        description [;
            Affiche(54); 
            Joue(1251);
            if (self hasnt visited) {
                print "Aujourd'hui encore je me demande comment je fis pour ne pas basculer dans la folie.^^Peut être mon esprit eut-il ce réflexe de survie de se réfugier loin de ses facultés d'analyse de la situation, ne se concentrant que sur la recherche de chaleur, de protection, d'oxygène, de repos, des besoins élémentaires pour vivre... car y a-t-il plus insondable horreur que celle d'être dans le noir absolu, au milieu et au fond d'un Océan abyssal qui d'un soubresaut ou d'un caprice peut vous briser entre ses doigts ?^^";
            }
            print "Je descendis des escaliers pendant un temps indéfinissable... des heures, des jours... peut-être des minutes seulement. Je ne me souviens que d'une chose : la pierre était froide, parfois striée d'étranges glyphes, parfois les marches faisaient moins d'un demi-pouce, parfois plus. Et autre chose : l'écho de mes pas m'indiquait clairement que je n'étais pas dans un couloir, mais au contraire, dans un antre aux cyclopéennes proportions.^";
        ! j'ai remplacé le centimètre par un demi-pouce, cela me semble plus dans le contexte.
        ! bah, le système métrique... ;-)
        ],
        cant_go "Seule la mort m'attendait par là.",
        d_to gate125,
    has scenery;

Object gate125 "Les Portes Cyclopéennes de la Cité Engloutie" 
class Lieu
    with 
        scenic_all 
            'escaliers' 'marches' 'marche' 'escalier' 0 "Même si les lieux qui m'attendaient me terrifiaient, je ne voulais pourtant plus remonter d'où je venais.",
        description [;
            ! Affiche(55); ! TODO
            print "L'escalier titanesque aboutit enfin à une surface plane de pierre froide et sèche ; une fois encore, aucune limite n'était apparente, et seuls
            quelques cristaux bordant une cyclopéenne porte de métal sculpté émanaient une faible lumière verte tamisant l'obscurité complète. ^";
        ],
        cant_go "L'obscurité m'aurait englouti.",
        n_to [; << GoIn >> ;],
        in_to [;
            if (portes125 hasnt open) {
                print "Les portes étaient fermées.^";
                return 1;
            } 
            else {
                print "Un sentiment d'interdit remuant mes entrailles, je franchis la limite obscure de l'immense porte de bronze.^";
                return city125;
            }
        ],
        out_to [; << GoIn >> ;],
    has scenery;

Object cristaux125 "cristaux" gate125
    with 
        name 'lumiere' 'cristal' 'cristaux' 'lampe' 'verte' 'vert' 'verts',
        description "D'étranges cristaux verts, qui se seraient construits comme l'auraient fait des entités biologiques d'un autre monde, bordaient la monumentale porte de bronze en diffusant une lumière verte et malsaine.",
    has pluralname static scenery;

Object portes125 "monumentales portes de bronze" gate125
    with 
        name 'ouverture' 'porte' 'portes' 'sortie' 'voie' 'oeil' 'runes' 'tentacules' 'vantaux',
        fouille 0,
        adjective 'monumentale' 'monumentales' 'double',
        description [;
            Affiche(55);
            print "Ce que je devinais à travers la diffuse lumière verte des cristaux m'émerveillait et m'effrayait à la fois : une double porte, si grande que seuls des géants auraient pu en avoir l'utilité, se dressait dans des proportions défiant mes capacités d'imagination.^^
            Des runes difformes, entourant dans une dissymétrie dérangeante un nouvel oeil primitif entouré de tentacules striaient les vantaux.^^
            À son toucher, je ressentais une impression si extra-terrestre ou extra-humaine que toutes les horreurs conçues par les hommes, que toutes les incarnations du Diable et des tortures me semblaient presque réconfortantes et familières, car contenant, même de façon infime, et contrairement à ce que je touchais là, une petite fraction d'humanité. ^";
        ],
        each_turn [;
            if (carre125.combi==2 && trapeze125.combi==2 && disque125.combi==1 && self has locked) {
                Joue(1257);
                Joue(1256);
                print "Un déclic résonna alors avec puissance dans la pièce, au-delà des deux grands vantaux monumentaux. ^";
                give self ~locked; 
                Achieved(7) ; 
            }
            if (carre125.combi + trapeze125.combi + disque125.combi >= 6) { 
                print "J'entendis un bruit derrière les vantaux, mais celui-ci fut aussitôt étouffé, comme si un mécanisme était brisé dans son élan. ^" ; 
                carre125.combi = 0;
                trapeze125.combi = 0;
                disque125.combi = 0;
            }
        ],
        before [;
            Attack, Open, Push : 
                if (self hasnt locked) {
                    print "Je poussai de toutes mes forces l'un des vantaux et celui-ci céda de quelques centimètres dans un grincement titanesque, me laissant un mince espace pour m'y glisser. ^";
                    give self open;
                    return 2;
                }
        Close : 
            if (self has open) {
                print "Non, je n'en avais pas la force. ^";
                return 2;
            }
        Touch : 
            "À son toucher, je ressentais une impression si extra-terrestre ou extra-humaine que toutes les horreurs conçues par les hommes, que toutes les incarnations du Diable et des tortures me semblaient presque réconfortantes et familières, car contenant, même de façon infime, et contrairement à ce que je touchais là, une petite fraction d'humanité.";
        Search, LookUnder : 
            if (self.fouille==0) {
                print "Sous la porte se trouvait coincée une feuille de papier jaunie.^"; 
                give papier125 ~concealed ; 
                rtrue ;
            }
    ],
    has female pluralname openable lockable locked static scenery;

! une bete serrure à ouverture sonore... ok, je suis pas en forme niveaux énigmes, le style indiscible me pompe toute mon énergie...

Object carre125 "pierre carrée" gate125
with
    name 'pierre carrée' 'pierre' 'carre' 'carree' 'obsidienne' 'cube',
    description [;
        print "Une étrange pierre d'obsidienne représentant un cube parfait... et dans un éclair, un plissement de paupière, j'y vis un instant d'autres proportions s'étendant dans d'autres dimensions, donnant à l'ensemble une cohérence stellaire et inexplicable. ^";
    ],
    before [;
        Attack, Push, Pull, Touch, Take :  
            print "À peine posai-je la main sur l'étrange cube qu'il émit une vibration sonore grave qui me noua les tripes. ^";
            self.combi++;
            if (self.combi==0) {Joue(1257);}
            if (self.combi==1) {Joue(1257);}
            if (self.combi==2) {Joue(1257);}
            if (self.combi==3) {Joue(1257);}
            if (self.combi==4) {self.combi=0;}
            return 2;
    ],
    combi 0,
has female static;

Object disque125 "disque de pierre" gate125
with 
    name 'disque de pierre' 'pierre' 'disque' 'obsidienne' 'piedestal',
    description [;
        Joue(2);
        print "Une étrange pierre d'obsidienne représentant un disque allongé... d'une proportion équilibrée et apaisante. ^";
    ],
    before [;
        Attack, Push, Pull, Touch, Take :  
            print "À peine posai-je la main sur l'étrange disque qu'il émit une vibration sonore aiguë qui me glaça le sang. ^";
            self.combi++;
            if (self.combi==0) {Joue(1259);}
            if (self.combi==1) {Joue(1259);}
            if (self.combi==2) {Joue(1259);}
            if (self.combi==3) {Joue(1259);}
            if (self.combi==4) {self.combi=0;}
            return 2;
        Listen : "Il ne s'agissait pas de CE genre de disque.";
    ],
    combi 0,
has static;

Object trapeze125 "pierre trapézoïdale" gate125
with 
    name 'pierre trapezoidale' 'pierre' 'trapeze' 'trapéze' 'trapèze' 'trapezoidale' 'trapèzoidale',
    description [; 
        Joue(2); 
        print "Une étrange pierre représentant un trapèze asymétrique... et dans un éclair, un plissement de paupière, j'y vis un instant d'autres proportions malignes s'étendant dans d'autres dimensions, donnant à l'ensemble un chaos terrifiant. ^";
    ],
    before [;
        Attack, Push, Pull, Touch, Take :  
            print "À peine posai-je la main sur l'étrange trapèze qu'il émit une vibration sonore qui me transperça l'esprit. ^";
            self.combi++;
            if (self.combi==0) {Joue(1258);}
            if (self.combi==1) {Joue(1258);}
            if (self.combi==2) {Joue(1258);}
            if (self.combi==3) {Joue(1258);}
            if (self.combi==4) {self.combi=0;}
            return 2;
    ],
    combi 0,
has static female;


Object papier125 "papier jauni" gate125
    with 
        name 'papier' 'feuille' 'portee' 'notes' 'note',
        adjective 'jaune' 'jauni' 'musicale',
        description [;
            print "Un schéma tracé à la va-vite, qui représentait une portée musicale, sur laquelle je pouvais déchiffrer cette simple mélodie : do do mi ré ré...^";
        ],
        before [;
            Lire: << examine self >> ;
            Take: portes125.fouille = 1 ; rfalse ;
        ],
    has concealed ;



! Welcome To Rlyeh, toute ressemblance avec Fate of Atlantis ou encore Bioshock serait un méga hasard 

Object city125 "La Cité sous les Eaux" class Lieu
    with 
        name 'cite',
        scenic_all 
            'hiéroglyphes' 'gravures'  'statues' 0 "Des motifs gravés dans les murs, qui avaient certainement une signification dans une langue que je ne voulais pas connaître."
            'blocs' 'verdatre' 'monolithes' 0 "Ces blocs d'une couleur écoeurante semblaient disposés selon un ordre inconnu et défiant toute harmonie humaine."
            'globes' 'globe' 'argent' 'ombre' 'ombres' 'lumiere' 'claire' 0 "La lumière rassurante de ces globes était sans doute la seule chose tolérable dans ce lieu maudit.",
        scenic_touch
            'hiéroglyphes' 'gravures' 'statues' 0 "Tout ceci était disposé bien trop haut pour ma pauvre taille humaine, et c'était hors d'atteinte.",
        description [;
            Affiche(56); 
            print "Résister à la folie... et contempler, dans leurs insaisissables dimensions, les blocs monolithiques verdâtres, alignés selon une géométrie non euclidienne, des statues gargantuesques et immondes gravées de hiéroglyphes dérangeants, de tous côtés, et même au-dessus sur un plafond lointain que je me refusais d'imaginer.^^Des globes d'argent mouvants diffusaient une lumière claire et projetaient des ombres dansantes tout autour. ^^Errer de part et d'autre dans ce silence de tombe me ramenait inexorablement sur une place centrale, où trônait une titanesque dalle gravée d'un Signe des Anciens scellant Ce Que Je Préférais Ne Pas Connaître. ^";
        ],
        cant_go "Après quelques minutes passées dans l'horreur d'une forêt de statues hideuses, mes pas me reconduisirent sur la place principale de la Cité Engloutie.",
    has scenery;

Object dalle125 "dalle scellée" city125
    with 
        name 'dalle' 'scellée' 'scellee' 'signe' 'anciens' 'ancien' 'sceau' 'oeil' 'etoile',
        description [; 
            ! Affiche(57);  ! TODO !
            print "Cette dalle était si grande que je n'en voyais pas vraiment les contours. Prenant de la distance, je compris qu'un signe étrange, représentant une étoile à cinq branches frappée d'un oeil, de dimensions cyclopéennes, frappait le monument.^^Quelles horreurs devait-il sceller ?^";
        ],
    has static female;

Object cadavre125 "cadavre" city125
    with
        name 'cadavre' 'homme' 'scientifique' 'militaire',
        description [;
            print "Je n'avais pas compris au début qu'il s'agissait d'un corps d'homme... ce qu'il en restait semblait avoir été broyé puis vidé de son suc comme l'on aurait fait d'un fruit juteux - et si je n'étais pas déjà immergé dans toutes les horreurs qui m'avaient accompagnées jusqu'à présent j'en aurais été bouleversé - mais alors que je contemplais chirurgicalement cet homme mort et torturé, j'étais surpris de ma paisible impassibilité. ^^À sa tenue, cet homme était un ancien scientifique, un géologue, un océanologue ?^";
        ],
        before [;
            Search : 
                if (self.fouille==0) {
                    print "Pliée et recouverte de sang, je découvrais une carte pliée en quatre, et que je saisissais avec précautions. ^"; 
                    move carte125 to player;
                    self.fouille=1;
                    return 2;
                } 
                else {
                    return 2;
                } ; 
		Smell: print "Je ne voulais pas mettre mon nez sur ce cadavre, par contre le corps devait avoir été décomposé depuis tellement longtemps qu'il n'y avait plus d'odeur notable qui émanait de celui-ci.^" ; rtrue ;
        ],
        fouille 0,
    has static;

Object carte125 "carte ancienne"
    with 
        name 'carte' 'ancienne',
        description [;
            Affichette(58);
            print "Une étrange carte de cette cité maudite...^";
            if (carte125.lu==0) {
                print "... avec le chemin vers la sortie... mais qui donnerait où ? L'Océan ? Cela méritait l'exploration, d'autant plus que je manquais de forces et que des éblouissements dûs à la fatigue ajoutaient à la folie de l'endroit.^";
                Attend();
                print "^J'avançai entre ces habitations monolithiques et désolées, et un basculement granitique assourdissant vint faire résonner toute la cité, et un tentacule large comme un tronc d'arbre, se tortillant de façon répugnante, surgit de la dalle scellée et traça son chemin, suivant ma trace.^";
                Attend();
                print "^Terrifié, je me mis à courir, enjambant d'autres cadavres, d'autres scientifiques exsudés de leurs chairs, et je passai même une silhouette amaigrie, accroupie et tremblotante, qui hurlait compulsivement : ~Dans la Cité de R'lyeh la morte, le défunt Chtulhu rêve et attend !~^";
                Attend();
                print "^Et puis je repris espoir, traversant un campement de fortune alors que le tentacule écrasait le malheureux que je venais de croiser, pour se lancer à ma poursuite à nouveau : dans une étendue d'eau noire sur un bassin morne, un petit sous-marin scientifique flottait.^^
                Sans attendre, je me hissai à bord.^";
                self.lu=1;
                PlayerTo(sub125);
            }
        ],
        before [;
            Lire: << examine self >> ;
        ],
        lu 0,
    has female;

Object sub125 "Petit sous-marin scientifique" 
class Lieu
    with 
        scenic_all 
            'cabine' 'hublot' 'tentacule' 'eau' 0 "Il me fallait sortir d'ici le plus vite possible.",
        description [;
            Affiche(59);
            print "^C'était un petit sous-marin scientifique, composée d'une seule cabine pouvant accueillir six hommes. Tout le matériel emporté avait été déchargé
            sur la grève, mais tout semblait en état de marche, et même plus, quasiment neuf et de haute technologie.^^Pour la première fois depuis des heures
            qui me semblaient, dans le reflet de mes souvenirs, des années, je me retrouvais enfin dans un univers qui rappelait l'humanité. ^";
        ],
        each_turn [ k ;
            k = self.happen; switch(k) {
                1: print "^Dans un gargouillis mêlé d'éclats métalliques, je devinai qu'à l'extérieur, le tentacule géant était en train de tout écraser. ^";
                2: print "^Le tentacule frôla le sous-marin, le faisant basculer et je tombai brusquement sur le panneau de contrôle. Par un hasard fatal, 
                le sous-marin se mit en marche et commença à s'enfoncer dans les eaux. ^";
                3: print "^Au travers du hublot, je vis le tentacule s'enrouler autour du sous-marin. ^";
                4: print "^Dans un grincement titanesque, le sous-marin souffrait sous la pression du tentacule géant. ^";
                5: print "^Un instant, je vis un oeil démoniaque où ne vivait que le chaos passer devant un hublot, et de ma vie je ne vis vision plus effrayante. ^";
                6: print "^Le tentacule retenait de son étreinte la fuite du sous-marin... étais-je condamné ?^";
                7: print "^Un hublot se fissura sous la pression du tentacule et un filet d'eau surgit à l'intérieur !^";
                8: print "^Un vrombissement cosmique se fit ressentir, et tout autour de moi j'eus la vision de milliers d'étoiles, et d'une créature mi-humaine mi-céphalopode, grande comme les planètes, dominer l'univers et l'humanité dans une puissance inimaginable. ^";
                9: print "^La pression augmentait alors que le tentacule resserait son étreinte.^";
                10: print "^Et le sous-marin explosa enfin, balayant mon corps sans vie dans les pressions sous-marines, alors que la gigantesque créature extra-terrestre se nourrissait de mon âme. ^"; Attend(); print "^... je perdis connaissance...^"; Attend(); print "^... pour me retrouver...^"; Perdu125();
            }
            self.happen++;
        ],
        happen 0,
        cant_go "^Et sortir d'ici ? Non, il y avait cette hideuse créature à l'extérieur, me flairant pour me retrouver et m'anéantir. ^",
    has scenery;

Object profonde125 "Créature Corrompue" sub125
    with 
        name "creature" "corrompue" "femme" "femelle" "profond" "fille" "poisson" "dame" "dagon" "sectatrice" "profonde" "yeux" "visage" "peau" "écailles" "pupilles" ,
        description [;
            !Affiche(60); ! TODO !
            print "Attachée par des chaînes plus solides qu'il n'en paraissait pour les muscles d'un être humain normal, une étrange créature, qui eut pu être une femme, et qui était sans doute une femelle de cette race maudite que l'on nomme ~profond~, accroupie dans un coin du sous-marin.^^Son visage avait comme fondu, puis avait été comme tiré et aplati, sa peau s'était recouverte d'écailles verdâtres, et quant à ses yeux... ses pupilles noires s'étaient diluées et occupaient tout l'espace de ses orbites oculaires.^"; ! pour éviter une répétition  --akien
        ], 
        life [;
            Answer,Ask,Tell: 
                Affiche(60); 
                print "^~Entends l'appel du Rêveur de R'lyeh, mortel ! Viens me prendre le Baiser de Dagon !~^"; 
                rtrue;
            Kiss : 
                print "Terrifié et fasciné, je m'approchai de la créature hideuse alors qu'elle avançait la tête et respectueusement, elle me fit don du Baiser de Dagon. ^Je vis alors qu'elle portait le beau pendentif de corail que j'avais vu tantôt.^"; 
                move pendentif125 to location ; 
                rtrue;
            Attack : 
                print "Je levai une main menaçante, et la créature montra des dents aiguisées et pointues comme celles d'un requin, anéantissant toute velléité en moi.^";
                rtrue;
        ],
        initial "Dans un coin du sous-marin, une créature humanoïde ressemblant vaguement à une femme était enchaînée et s'agitait en tous sens. ",
    has animate female ;

Object   chaine125 "chaine" sub125
    with 
        description "Une chaîne avec des maillons impressionnants.",
        name 'chaine' 'maille' 'maillons',
        before [;
            Take,Attack,Pull,Push:  "Cette chaîne était trop solide pour moi.";
        ],
        has female scenery;

Object   commandes125 "tableau de commandes" sub125
    with 
        description "Le tableau de commande du sous-marin.",
        name 'commandes' 'tableau' 'direction' 'sous-marin' 'sous' 'technologie',
        adjective 'marin' 'scientifique' 'technologique',
            before [;
                Utiliser, Piloter:  print "Je n'avais pas une expérience de ce genre d'engin comme pouvaient l'avoir certains de mes collègues, mais néanmoins ce n'était pas bien sorcier à piloter. Après avoir activé les magnétos pour démarrer le propulseur, je trouvai également la commande pour envoyer une décharge de protection électrique anti-requin. Cela ne fut pas assez puissant pour tuer le monstre qui s'échinait sur la carlingue du sous-marin, mais suffit pour lui faire lâcher prise, et je pus repartir en direction de la surface.^";   
                Gagne125(); 
                rtrue;
            ],
        has scenery;


! Réinitialisation des variables et des objets
[ReInit125 init_tout;
    give Piece125 ~visited;
    Piece125.nage = 0;
    give trappe125 locked ~open;
    give escaliers125 ~visited;
    portes125.fouille=0;
    give portes125 locked ~open;
    move papier125 to gate125; 
    give papier125 concealed;
    carre125.combi=0; 
    trapeze125.combi=0;
    disque125.combi=0;
    cadavre125.fouille=0;
    carte125.lu=0;
    remove carte125;
    sub125.happen=0;

    if (init_tout)
    {
        ! reprendre même les objets que le joueur pourrait emporter
        ! avec lui dans la roulotte s'il avait gagné
        
        ! attention c'est un objet portail atypique
        move pendentif125 to InRoulotte; ! pour éviter de le perdre
        pendentif125.actif=1;  !on le rend à nouveau actif si besoin
        pendentif125.obtenu=0; !on fait comme si on ne l'avait jamais obtenu
    }
];

! Démarrer la scène : initialisation, compte à rebours et position du joueur.
[Demarrer125;
    scene_en_cours = '125';
    scene_125_visitee = true;
    ReInit125(true); ! si le joueur a déjà joué, on lui reprend les objets gagnés.
    PlayerTo(piece125);
];

! Stopper la scène : réinitialisation, arrêt des timers
[Stopper125 init_tout;
    ReInit125(init_tout);
    DeplacerObjetsPortails(); ! si le joueur a perdu des objets "portail" dans la scène, 
                              ! les renvoyer dans la roulotte
];

! Perdu
[Perdu125;
    Stopper125(true);
    Perdu(true); ! affichage message perdu ou retour roulotte
];

! Gagne
[Gagne125;
    Achieved(8); ! on a piloté le sous-marin
    Gagne(); ! stoppe scène en cours et affichage message gagné ou retour roulotte
];