5 print"          african adventure"
6 print"   or,  in search of dr. livingston"
7 print" original version from 'softside' 9/80"
10 print"       by r. & b. fullerton and"
15 print"          c. & k. russell"
25 print"  this version adapted for the pet and"
30 print"       expanded by david malmberg"
49 def fnr(n)=int(n*rnd(1)+.99)
50 x=rnd(-ti):y=1:xg=1:g6$="you don't have it!":g7$="nothing unusual."
51 g8$="with your puny spear ?"
100 g3$="don't be silly!":g2$="you're on our own."
101 g1$="you already have it.":r$=" 'tis done."
102 pm=37:vm=36:nm=60:im=35:dimv$(vm),n$(nm),i$(im),il(im),ip(im),in(im)
103 dimp$(pm),p(pm,5),d(22)
104 gosub50001
105 input"       need instructions  y";q$:ifq$<>"y"andq$<>"n"then105
106 ifq$="y"thengosub60000
107 goto1000
200 gosub490:goto1000
490 ify=1ory=36thenprint"what next ";:goto495
491 print"yes, bwana ";
495 a$="":b$=a$:c$=a$:gv$=a$:gn$=a$:inputa$
500 z=len(a$):ifz=0then490
501 ifz-1then510
502 ifa$="i"thenv=3:n=0:return
503 v=0:c$=a$:goto580
510 gosub600:b$=d$:gv$=g$:ifz1=1thenc$=b$:v=0:goto580
511 v=0:fori=1tovm:ifb$=v$(i)thenv=i:i=vm
512 next:ifv<>0then550
520 v=0:c$=b$:goto580
550 if(z-z1-1)<1then590
551 a$=right$(a$,z-z1-1):z=len(a$):c$=a$
560 ifleft$(c$,1)<>" "then570
561 c$=right$(c$,z-1):z=len(c$):ifz=0then590
562 goto560
570 a$=c$:gosub600:c$=d$
580 gn$=g$:n=0:fori=1tonm:ifc$=n$(i)thenn=i:i=nm
581 next:ifn=60thenn=40
582 return
590 n=0:return
600 i=0:forii=1toz:ifmid$(a$,ii,1)=" "theni=ii:ii=z
601 next:ifi=0theni=ii
610 d$=left$(a$,i-1):g$=d$:d$=left$(d$,5):z1=len(d$):return
1000 print"":j=fre(0):ga$="....neither are seen again."
1001 gb$="the natives take your ":gc$="you are lying in a soft warm bed"
1002 gd$="you are at the closet.":ge$="several natives wave hello."
1003 g4$="that's too dangerous!":g5$="it's nowhere in sight."
1004 g9$="you had better leave, fast!"
1005 printp$(y):print:d$="you can now see "
1006 z=12:z1=y:ify<>1ork<>0then1020
1008 ifil(1)=1thenprintd$;i$(1):goto1080
1009 printd$;g7$:goto1080
1010 d$="you are carrying ":z=16:z1=-1
1020 a$=d$:j=1
1030 fori=1toim:ifil(i)<>z1andil(i)<>-2then1070
1035 b$=i$(i):ifi=5andil(i)=-2thenifz1=yoril(2)>2then1070
1040 ifj=0then1050
1041 j=0:d$=d$+b$:z=len(d$):printd$;:goto1070
1050 print", ";:ifz+len(b$)>40thenprint:z=0
1060 d$=b$:z=z+len(d$)+2:printd$;
1070 next:ifa$<>d$thenprint".":goto1080
1071 printd$;:ifz1=ythenprintg7$:goto1080
1072 print"nothing."
1080 ifxb=1thenprintgc$
1081 kk=0:fori=0to5:ifp(y,i)<>0thenkk=1
1082 next:ifkk=0then1090
1083 print"obvious directions are ";:kk=0
1084 fori=0to5:ifp(y,i)=0then1088
1085 ifkk<>0thenprint",";
1086 printn$(i+7);:kk=kk+1
1087 ifkk=2thenprint""
1088 next:print"."
1090 ifv=3orv=13then1250
1200 xd=xd+1:ify=7then5000
1201 ify=17then5100
1202 ify=34then5200
1203 ify=22ory=27then5300
1204 ify=12then5400
1205 ify<>12thenxq=0
1210 ify1=18ory=18then1250
1211 x7=0
1220 xd=0
1250 zz$="a native throws a spear at you. it just misses. the native runs off."
1251 ifts=1ort<20ory>35ory=7or(y>10andy<14)then1260
1255 printzz$:il(6)=y:ts=1
1260 ifn4<>0then1270
1261 ifil(13)=-1thenn5=n5+1:a$="a charming little flute"
1262 ifn5>16thenprint"after many hours of whittling,your sugar"
1263 ifn5>16thenprint"cane is now "a$".":s=s+5:n4=1
1264 ifn5>16thenil(20)=-1:il(13)=0
1270 ifxe=0and(y=2ory=10)thens=s-50:goto1280
1271 goto1300
1280 print"oh no . . . your feet are bare . . . .  too late!":goto7000
1300 print:gosub490:goto1500
1450 ify=9ory=10thenprint"a fierce black leopard bars the way.":goto1200
1460 ify<>32then1470
1461 iffnr(5)<3theny=34:goto1000
1462 y=31:goto1000
1470 print"that leads to quicksand.":goto1200
1500 t=t+1:ifvthen1600
1501 ifnthen1520
1510 i=fnr(3):ifi=1thenprint"what?"
1511 ifi=2thenprint"huh?"
1512 ifi=3thenprint"what in the world are you talking about?"
1515 goto1200
1520 ifn>12then1550
1521 ifn<7then1525
1522 n=n-6
1525 z=p(y,n-1)
1530 ifz<0then1560
1531 ifz=98then1450
1532 ifz<>0then1540
1533 i=fnr(3):ifi=1thenprint"that direction is sealed off."
1534 ifi=2thenprint"you won't get anywhere going there."
1535 ifi=3thenprint"you can't go that way."
1536 goto1200
1540 y1=y:y=z:goto1000
1550 print"what do you want to do with             the ";gn;"?":goto1200
1560 ifrnd(1)<.5thenz=0:goto1530
1561 y=-z:goto1000
1570 ify=12thenifrnd(1)<.25theny=11
1571 goto1000
1580 ify=22thenifrnd(1)<.5theny=21:goto1000
1581 y=19:goto1000
1585 ifrnd(1)<.38theny=-z:i$(14)="a hungry alligator":goto1000
1586 z=0:goto1530
1600 onvgoto1614,1800,1010,1900,1900,2100,2200,1000,2900,2500
1601 zz=v-10
1602 onzzgoto2600,2700,1010,2400,3000,3100,3200,3300,3400,3500
1603 zz=v-20
1604 onzzgoto2700,3600,3760,3800,3900,3700,3400,4000,4000,4100
1611 zz=v-30
1612 onzzgoto4300,4400,4500,4500,4600,4700
1614 ifn=0thenprint"who knows what a "gn$" is?":goto1300
1615 ifmi>4thenprint"your load's too heavy.":goto1300
1617 ifn=16andv5=1andil(18)=ytheni=18:goto1690
1620 ifv5andn=16then1630
1621 gosub5900:ifx1>0then3710
1625 ifn=11thenn=22:goto2740
1627 ifn<>34then1630
1628 ify=33then3720
1629 goto5960
1630 ifn=24then1700
1631 ii=0:fori=1toim:ifn=in(i)thenii=i:i=im
1632 nexti:ifii=0then1510
1633 i=ii
1635 ifnot(il(i)=-1or(il(2)=-1andil(i)=-2))then1640
1636 ifi=7thenprintleft$(g1$,17)+"him.":goto1200
1637 printg1$:goto1200
1640 ifil(i)<>yor(y=1andk=0andi<>1)then5960
1642 ifxbthenifi<>1thenprint"from bed?":goto1220
1645 ifn=18then3600
1646 ifi=2andil(5)=-2thenmi=mi+1
1650 ifn<>37then1660
1651 ifxf=1then1690
1652 print"it's not free.":goto1200
1660 ifn<>38then1665
1661 print"dr.livingston?":inputa$:ifa$<>"i presume"thengosub500:goto1500
1665 ifn<>48then1670
1666 ifil(29)<>-1then7000
1667 ify=4thenprint"a deadly spider crawls out of the wood  and into the brush."
1670 ifn=49thenprint"it's too hot.":goto1200
1671 ifn<>47then1690
1672 ifil(23)=ytheni=23:goto1690
1673 ifil(26)<>-1thenprint"you need a cage.":goto1200
1674 il(26)=0:il(22)=0:il(23)=y:in(22)=0:mi=mi-1:goto1000
1690 printr$
1695 il(i)=-1:mi=mi+1:goto1200
1700 ifxethenprint"you're wearing them.":goto1200
1705 z=35:ifrnd(1)<.38then1710
1706 ifrnd(1)<.5thenz=25:goto1710
1707 z=27
1710 ifk<>1then1720
1711 print"your feet are now snug in a pair of     hiking boots.":s=s+5:xe=1
1712 il(17)=z:il(7)=0:goto1300
1720 print"what boots?":goto1300
1800 ifn=0then1510
1810 ifn=24thenprint"they're stuck.":goto1200
1811 ii=0:fori=1toim:ifin(i)=nthenii=i:i=im
1812 nexti:ifii=0then1510
1813 i=ii
1820 ifil(i)>-1then5950
1821 ify=1andk=0andi>1thenprint"there's no room.":goto1300
1830 ifil(i)<>-2then1840
1831 ifil(2)=-1then3100
1832 goto5950
1840 ifn=16then3110
1841 ifi=2andil(5)=-2thenmi=mi-1
1890 il(i)=y:printr$:gosub3480
1895 mi=mi-1:goto1200
1900 b$="it's already ":c$=b$+"closed.":a$=b$+"open.":d$="from bed?"
1901 ifn=0then1510
1902 ifv=5then2000
1905 ify-1then1930
1906 ifn-22then1920
1910 ifxb=1thenprintd$:goto1200
1915 ifk=0thenk=1:goto1000
1916 printa$:goto1200
1920 ifn<>20then1930
1921 ifil(1)<>-1then5950
1922 ifxc=0thenprint"the book falls open to an underlined    passage.":xc=1:goto1200
1923 printa$:goto1200
1930 ifn<>13then1940
1931 ifil(2)<>-1then5950
1932 ifil(2)=-1thenprinta$
1933 ifxx<>2thenprint"something fell out."
1934 ifxx=1thenxx=2:il(31)=y
1935 ifxx=0thenxx=1:il(28)=y
1936 goto1200
1940 ifn<>55then1960
1942 ifil(34)<>0thenprint"it's already open.":goto1200
1944 ifil(32)<>0thenprint"it's locked.":goto1200
1946 ifil(33)=-1thenprint"put it down first.":goto1200
1948 ifil(33)<>ythenprint"it's not here.":goto1200
1950 print"ok, it's open.":il(34)=y:in(34)=55:il(33)=0:in(33)=0:il(35)=y
1952 goto1200
1960 ifn<>50then1510
1962 ifil(23)=yoril(23)=-1then3131
1965 ifil(26)=yoril(26)=-1thenprint"ok, it's open.":goto1200
1966 print"it's not here.":goto1200
2000 ify-1then2020
2001 ifn-22then2010
2005 ifxb=1thenprintd$:goto1200
2007 ifk=1thenk=0:goto1000
2008 printc$:goto1200
2010 ifn<>20then2020
2011 ifil(1)<>-1then5950
2012 ifxc=1thenprintr$:xc=0:goto1200
2013 printc$:goto1200
2020 ifn<>13then2030
2021 ifil(2)<>-1then5950
2022 ifil(5)=-2thenprint"the mouse won't escape!":goto1200
2023 print"it'll just fall open again.":goto1200
2030 ifn<>55then2050
2031 tt$="ok, it's closed."
2032 ifil(32)<>0oril(33)<>0thenprint"it's already closed.":goto1200
2034 ifil(34)=-1thenprint"put it down first.":goto1200
2036 ifil(34)<>ythenprint"it's not here.":got1200
2040 ifil(34)=ythenprinttt$:il(33)=y:in(33)=55:il(34)=0:in(34)=0
2045 goto1200
2050 ifn<>50then1510
2055 ifil(26)=yoril(26)=-1thenprint"ok, it's closed.":goto1200
2056 print"it's not here.":goto1200
2100 ify=2then2210
2101 ifil(1)=-1and xb=1thenil(1)=1:mi=mi-1:y=2:xb=0:goto1000
2102 goto1510
2200 ifn>0then1510
2201 ify<>1then2205
2202 y=10:xb=0:ifil(1)=-1thenmi=mi-1:il(1)=1
2203 goto1000
2205 ify<>10then1510
2206 ifil(17)=-1thenil(17)=fnr(33)+2:print"help!":mi=mi-1:forj=1to5000:next
2210 y=1:goto1000
2400 ify<>29then2410
2401 ifn<>40then2420
2402 ifil(4)<>-1then5950
2403 printgb$"groundnuts.":xf=1:il(4)=0:mi=mi-1:s=s+10:goto1200
2410 ify<>17then2420
2411 ifn<>42then2420
2412 ifil(10)<>-1then5950
2413 printgb$"beans, gives you a trinket, then runs away.";:
2414 xg=0:s=s+15:n$(26)="ring":il(10)=0:il(19)=-1:goto1200
2420 print"no way, jose!":goto1200
2500 ify=1thenprint"this may seem absurd but in the book is a magical word":goto1250
2510 ify=23ory=24thenprint"you won't make it with a 'hop' or 'skip'":goto1250
2520 ify=25ory=22ory=12ory=27thenprint"be persistent.":goto1250
2530 if(y=34ory=17)andil(6)=-1thenprint"you look hostile.":goto1250
2535 ify=37thenprint"check pointers!":goto1250
2540 ify=34thenprint"lion traps circle the village.":goto1250
2545 ify=36thenprint"beware of a rom change from commodore.":goto1250
2550 ify=7thenprint"some snakes just can't be charmed.":goto1250
2560 printg2$:goto1250
2600 a$="africa - land of the unknown                  by r.u. redde"
2601 b$="...plorer nodded off to sleep, his      thoughts began to drift..."
2602 b$=b$+"drift...drift"
2605 ifn<>36then2610
2606 ifil(11)=-1thenprint"swami diamond":goto1200
2607 goto5950
2610 ifn<>19then2620
2611 ify=29ory=33thenprint"trading post":goto1200
2612 ify<>31then5950
2613 print"ujiji country --- keep out!!"
2614 print"no heed 'em --- we eat 'em":goto1200
2620 ifnot(n=20orn=25)then1510
2621 ifil(1)<>-1then5950
2622 ifxb<>1thenprint"try reading in bed.":goto1200
2623 ifn<>20then2630
2624 printa$:goto1200
2630 ifxc=1thenprintb$:goto1200
2631 goto5960
2700 ifn=0then1510
2701 ifn<13then1520
2702 ifn=17then3800
2703 ifn=21andy=3theny=2:goto1000
2704 ifn=46andy=17theny=18:goto1000
2705 ifn=56orn=57orn=59then4500
2740 ifn=22andy=1thenprintgd$:xb=0:goto1200
2741 ifn<>23then2760
2742 ify=1thenprintgc$:xb=1:goto1300
2743 print"in darkest africa?":goto1200
2760 ifn=41andy=34theny=35:goto1000
2761 ifn<>29then2770
2762 ify<>16then2765
2763 y=17:goto1000
2765 ify=32thenn=3:goto1525
2770 goto1510
2900 ifn<>35then2910
2901 ifil(16)=-1then2920
2902 goto5950
2910 ifn<>14thenprintg3$:goto1200
2911 ifil(6)<>-1then5950
2920 print"it sails through the air.......and hits the";
2921 ify=2thenprint"water, quickly sinking.":j=0:goto2940
2930 j=y:ify=1thenprint"floor":goto2935
2931 print"ground"
2935 ify=7thenj=6
2940 ifn=14thenil(6)=j
2941 ifn<>14theni(16)=j
2945 ifnot(y=il(14)andrnd(1)<.5)then2950
2946 fori=1to1000:next
2947 print"wait!  that's not ground."
2948 fori=1to1000:next
2949 print"it's alligator":i$(14)="a dead alligator"
2950 goto1895
3000 if(y=17ory=34ory=29)andn=44andil(6)=-1thenprintg8$:goto1200
3001 goto3710
3100 ifn<>18then3110
3101 ifnot(il(5)=-2andil(2)=-1)then5950
3102 ify=9ory=10then3105
3103 print"the mouse jumps out and scampers off.":il(5)=2:goto1895
3105 print"the mouse jumps out and startles the    leopard into flight.";ga$
3106 p(9,4)=10:p(10,5)=9:il(5)=0:s=s+15:goto1895
3110 ifn<>16then3130
3111 ifil(18)<>-1then5950
3112 ify=22then3116
3113 print"the viper slowly slithers away.":il(18)=7:goto1895
3116 print"the viper wakes up and attacks the dog. and both fall into the"
3117 print" quicksand.";ga$:il(18)=0:s=s+15
3120 il(21)=y:print
3121 print"something sparkles in the grass.":goto1895
3130 ifn<>47then1510
3131 print"the lion is free.":il(23)=0:il(22)=y:il(26)=-1:in(22)=47:goto1200
3200 ifn<>16then3710
3201 ifv5<>0thenprint"again?":goto1200
3202 ify<>il(8)thenprintg5$:goto1200
3203 ifil(20)<>-1thenprint"you may have good looks,but....":goto1200
3204 v5=1:s=s+10:printr$:il(18)=y:il(8)=0:goto1210
3300 ifn=43then3310
3301 print"ok - here goes....j u m p !!!":goto1200
3310 ify<23ory>24thenprint"there isn't any quicksand here.":goto1200
3320 print"do you really expect to jump over 30 ft?"
3321 geta$:ifa$=""then3321
3322 ifa$<>"y"thengosub500:goto1500
3330 print"ok - here goes....j u m p !!!":fori=1to1000:next
3360 print"ta da!!!":ify=23theny=24:goto1000
3361 y=23:goto1000
3400 gosub3480
3410 print"your score is "ss" points out of 325"
3411 print"in "t" turns.":ifv<>27then1250
3420 ify=2ory=10ord$="quit"thenend
3425 ifrethenifrnd(1)>.4thenend
3430 print"ready for a miracle...you have recovered":mi=0
3431 fori=2toim:ifil(i)=-1thenil(i)=fnr(32)+3
3432 next
3435 fori=1to8000:next
3440 y=2:re=1:goto1000
3480 ss=0:fori=1toim:ifil(i)=1thenss=ss+ip(i)
3485 nexti:ss=ss+s:ifss<250thenreturn
3492 b$="an ":a$="adventurer":ift<250thenss=ss+15:b$="a talented "
3494 ift<220thenss=ss+10:b$="a skilled "
3496 ift<190thenss=ss+10:b$="a master "
3498 print"you are "b$;a$:d$="quit":v=27:goto3410
3500 ifn=0then1510
3501 ify=1ory>3then3530
3505 ifn=21thenprint"where?":goto1200
3520 ify=2or(y=3and(n=10orn=4))then2700
3530 ify=23ory=24thenprint"on quicksand?":goto1200
3540 print"on land?":goto1200
3600 ifn=47then1670
3601 ifn<>18then3710
3602 ify<>il(5)then5960
3603 ifil(2)=-1then3606
3604 print"you don't have anything to put it in.":goto1200
3606 print"the mouse is now lost in the folds of   your knapsack."
3607 i=0:il(5)=-2:goto1695
3700 ifn=18orn=34thenprint"it just ate.":goto1200
3710 ifn=0then1510
3711 gosub5900:ifx1=1thenprintg4$:goto1200
3712 ifx1=2then5960
3720 ifnot(n=18orn=34)then3730
3721 ifv=17thenprint"rodents are charming enough!":goto1200
3722 print"it's too quick.":goto1200
3730 printg3$:goto1200
3760 ify<>18then1510
3761 y=17:goto1000
3800 ify=6ory=7theny=7:goto1000
3801 goto1510
3900 a$="....ummmmm gooood!"
3901 ifn=18andil(5)=-2andil(2)=-1thenprint"y u k!!!":il(5)=0:goto1895
3920 ii=0:fori=1toim:ifin(i)=nthenii=i:i=im
3921 nexti:ifii=0then3960
3922 ifil(ii)<>-1then5950
3923 ifn=42orn=53orn=40orn=39thenprintr$;a$:il(ii)=0:goto1895
3945 ifn=0then1510
3950 gosub5900:ifx1=1thenprintg4$:goto1200
3960 printg3$:goto1200
4000 ifn<>49then4010
4001 ifil(28)<>-1thenprint"you have no matches.":goto1200
4002 ifil(24)=-1thenprint"prepare the wood.":goto1200
4003 ifil(24)<>ythenprint"you need wood.":goto1200
4004 print"the fire is blazing.":il(24)=0:il(25)=y:goto1200
4010 ifn<>50then1510
4011 ifil(27)<>-1thenprint"you have no tools.":goto1200
4012 ifil(24)<>-1thenprint"you have no wood.":goto1200
4013 il(26)=y:il(24)=0:goto1000
4100 ifn=49orn=48then4001
4101 ifn<>52then4104
4102 print"the matches are blazing brightly.":il(28)=0:il(30)=-1:in(28)=0
4103 goto1200
4104 ifn=50andil(28)=-1thenil(26)=0:goto4004
4105 print"be careful with fire,stupid!":goto1200
4300 rem save
4301 d(1)=t:d(2)=mi:d(3)=k:d(4)=s:d(5)=xe:d(6)=xx:d(7)=ts:d(8)=xf:d(9)=n5
4302 d(10)=n4:d(11)=v5:d(12)=x7:d(13)=xg:d(14)=ss
4303 d(15)=in(22):d(16)=in(23):d(17)=in(28)
4304 d(18)=in(30):d(19)=in(32):d(20)=in(33):d(21)=in(34):d(22)=y
4305 input"tape or disk  d";q$:ifq$<>"t"andq$<>"d"then4305
4306 ifq$="t"then4310
4307 input"drive 1 or  0";q$:ifq$<>"0"andq$<>"1"then4307
4308 dn$=chr$(34)+q$+":"
4310 input"title  *";tl$:iftl$="*"then4310
4320 ifq$="t"thenopen1,1,1,tl$:goto4340
4330 open1,8,1,dn$+tl$+",s,w"
4340 print"writing game data"
4350 fori=1to22:print#1,d(i);chr$(13);:printd(i);:next:print
4360 fori=1toim:print#1,il(i);chr$(13);:printil(i);:next:print
4370 close1:print"game saved---the title was:"tl$
4380 goto1200
4400 rem load
4405 input"tape or disk  d";q$:ifq$<>"t"andq$<>"d"then4405
4406 ifq$="t"then4410
4407 input"drive 1 or  0";q$:ifq$<>"0"andq$<>"1"then4407
4408 dn$=chr$(34)+q$+":"
4410 input"title  *";tl$:iftl$="*"then4410
4420 ifq$="t"thenopen1,1,0,tl$:goto4440
4430 open1,8,0,dn$+tl$+",s,r"
4440 print"reading game data"
4450 fori=1to22:input#1,d(i):printd(i);:next:print
4460 fori=1toim:input#1,il(i):printil(i);:next:print
4470 close1
4471 t=d(1):mi=d(2):k=d(3):s=d(4):xe=d(5):xx=d(6):ts=d(7):xf=d(8):n5=d(9)
4472 n4=d(10):v5=d(11):x7=d(12):xg=d(13):ss=d(14)
4473 in(22)=d(15):in(23)=d(16):in(28)=d(17)
4474 in(30)=d(18):in(32)=d(19):in(33)=d(20):in(34)=d(21):y=d(22)
4499 goto1000
4500 ify=36ory=37then4502
4501 goto1510
4502 ifn=56orn=57theny=37:goto1000
4503 ifn=59thenprint"return everything to the bedroom and say 'score'.":goto1200
4504 goto1510
4600 ifn<>55then1510
4601 tt$="ok, it's unlocked."
4610 ifil(33)<>0oril(34)<>0thenprint"it's already unlocked.":goto1200
4615 ifil(31)<>-1thenprint"you don't have the key.":goto1200
4620 ifil(32)=-1thenprint"put it down first.":goto1200
4630 ifil(32)<>ythenprint"it's not here.":goto1200
4640 ifil(32)=ythenprinttt$:il(32)=0:in(32)=0:il(33)=y:in(33)=55
4650 goto1200
4700 ifn<>55then1510
4701 tt$="ok, it's locked."
4710 ifil(32)<>0thenprint"it's already locked.":goto1200
4715 ifil(31)<>-1thenprint"you don't have the key.":goto1200
4720 ifil(33)=-1oril(34)=-1thenprint"put it down first.":goto1200
4730 ifil(33)=ythenprinttt$:il(33)=0:in(33)=0:il(32)=y:in(32)=55
4740 ifil(34)=ythenprinttt$:il(34)=0:in(34)=0:il(32)=y:in(32)=55
4750 goto1200
5000 ifv5<>0then1210
5001 ifxd=5then5140
5002 ifxd=8then7000
5003 goto1250
5100 ifx7<>0then5110
5101 x7=1:ifil(6)=-1then5130
5102 goto5120
5110 ifil(6)<>-1then5150
5111 ifxd>4then7000
5112 goto5140
5120 ifxg=0then1210
5121 print"a friendly native approaches with some"
5122 print"trinkets.  it appears he wants make a   trade.":goto1220
5130 print"suddenly a volley of spears flies over"
5131 print"your head.  an obvious warning!"
5140 printg9$:goto1250
5150 printge$:goto1220
5200 ifx7then5110
5201 x7=1:ifil(6)-1then5130
5202 goto5150
5300 ify=il(15)andi$(15)="a wild dog"then5303
5301 ify=il(14)andi$(14)="a hungry alligator"then5303
5302 goto1210
5303 ifxd=8then7000
5304 ifxd=3orxd=5thenprintg9$
5310 goto1250
5400 ifxq=1then1250
5401 print"a voice echoes from the mouth of the    cave . . .s w a m i"
5402 xq=1:goto1210
5900 x1=0:ifn=16orn=27orn=32orn=33then5907
5901 return
5907 tt$="badly wounded, he crawls away."
5908 x1=1:ifil(6)=-1oril(16)=-1then5910
5909 return
5910 qq=0:if(n=33andy=27)thenx1=2
5911 ifn=32andy=22thenx1=2
5912 ifn=27and(y=9ory=10)andp(9,4)=98thenx1=2
5913 ifn=16andv5=0andy=7thenx1=2
5914 ifx1=2andrnd(1)<.25thenprinttt$:qq=1:xd=0
5915 ifqq=0thenx1=1:return
5916 ii=0:fori=1toim:ifin(i)=nthenii=i:i=im
5917 next:il(ii)=y+1
5920 return
5950 ifn=38thenprintleft$(g6$,15)+"him.":goto1200
5951 printg6$:goto1200
5960 ifn=38thenprint"he"+right$(g5$,20):goto1200
5970 printg5$:goto1200
7000 print""
7001 ify=2thenprint"a scorpion bit you on the toe."
7002 ify=7thenprint"the viper struck."
7003 ify=27thenprint"the alligator got you."
7004 ify=4thenprint"a deadly spider hidden in the wood bit  you on the hand."
7005 ify=34thenprint"the ujiji had a very good meal.  you    were it."
7008 goto7011
7009 print"a poison-tipped spear got you in the    back."
7010 print:print"another explorer is lost in the wilds   of darkest africa."
7011 v=27:goto3400
50001 p$(1)="you are in a bedroom,wearing pj's.      "
50002 p$(1)=p$(1)+"a nightstand is between the closet and  the bed."
50003 p$(1)=p$(1)+"  the bedcovers are turned down."
50004 p$(2)="you are drifting in a row boat on a big lake."
50005 p$(2)=p$(2)+" there is a beach on the eastern   shoreline."
50020 p$(3)="you are on the eastern shoreline.  a    boat is tied to the dock."
50021 p$(4)="you are on a grassy plain."
50022 p$(5)=""
50023 p$(6)="a trail begins here.  off to one side   is a tree."
50060 p$(7)="you are precariously balanced in a moss -covered tree."
50061 p$(8)="you are on a north-south trail.  cliffs to the east "
50062 p$(8)=p$(8)+"reach up to a plateau."
50063 p$(9)="you are at the foot of a cliff.  a path leads up to an opening."
50110 p$(10)="you are at the mouth of a cave. a trail leads downward."
50111 p$(11)="you are in a tunnel.  a faint glow is tothe west of you."
50112 p$(11)=p$(11)+" a sign on the wall sayscaverns ahead"
50113 p$(11)=p$(11)+"--enter at your own risk"
50130 p$(12)="you are in an immense carvern.  the     walls are covered with"
50131 p$(12)=p$(12)+" an iridescent    glow."
50132 p$(13)="you are in a long east-west passage."
50133 p$(14)=""
50134 p$(15)="the trail here is overgrown with grass."
50135 p$(16)="the trail widens out to a nearby        village."
50140 p$(17)="you are in a native village.  there are several campfires about."
50141 p$(18)="you are in a grass hut."
50142 p$(19)="you are at the edge of the jungle.      a trail leads north."
50143 p$(20)="you are at the edge of the jungle. grasslands extend to"
50144 p$(20)=p$(20)+" the east and south."
50145 p$(17)=p$(17)+" the witch      doctor's hut is to the south."
50160 p$(21)="you are in a jungle.  trails lead off inseveral directions."
50161 p$(22)=""
50162 p$(23)="there is a large body of quicksand here with a trail just beyond.
50163 p$(24)=""
50164 p$(25)=""
50165 p$(26)="you are on a grassy plains. the terrain is becoming marshy."
50170 p$(27)="you are in the marshes.  something is   moving in the grass."
50171 p$(28)="you are in a valley. a small opening    marks the hill beside"
50172 p$(28)=p$(28)+" you. rolling hillsflow southward."
50180 p$(29)="you are at a trading post.  an eager    native smiles at you as"
50181 p$(29)=p$(29)+" he points to hissign."
50182 p$(30)="you are in a field of corn.  the ground drops off to the north."
50183 p$(31)="you are on a grassy plains. two shrunkenheads decorate a sign."
50190 p$(32)="you are on the plains.  a village lies  to the east."
50191 p$(33)="you are behind a hut.  there is a sign  in the ground. a"
50192 p$(33)=p$(33)+" squirrel just ran by."
50200 p$(34)="you are in a ujiji village.  a native   stands near holding a"
50201 p$(34)=p$(34)+" spear.  he looks  excitied."
50202 p$(35)="you are in a pit.  light streams in fromabove."
50210 p$(36)="you are lost inside the pet computer,   somewhere under the crt."
50211 p$(36)=p$(36)+"  strange and   wonderous components are all around."
50220 p$(37)="you are inside an obsolete set of roms. undocumented pointers"
50221 p$(37)=p$(37)+" are all around."
50900 p$(5)=p$(4):p$(14)=p$(10):p$(22)=p$(21):p$(25)=p$(21):p$(24)=p$(23)
50901 fori=1topm:forj=0to5:read p(i,j):nextj,i
52001 data0,0,0,0,0,0
52002 data0,0,3,0,0,0
52003 data0,5,4,2,0,0
52004 data5,6,4,3,0,0
52005 data3,0,6,4,0,0
52006 data-5,8,-4,-5,7,0
52007 data0,0,0,0,7,6
52008 data6,15,9,0,0,0
52009 data0,0,0,8,98,0
52010 data0,0,11,0,0
52011 data98,0,0,12,10,0
52012 data13,-36,-11,-11,-11,-36
52013 data-11,11,0,14,15,0
52014 data0,0,0,0,13,0
52015 data28,0,0,16,8,0
52016 data0,15,19,17,19,0
52017 data0,16,18,0,0,0
52018 data0,17,0,0,0,0
52019 data0,16,22,20,21,0
52020 data0,0,26,26,19,0
52021 data0,21,23,22,21,21
52022 data21,21,22,19,23,22
52023 data22,98,22,98,21,23
52024 data23,24,98,25,98,24
52025 data24,-20,25,-20,24,25
52026 data25,20,27,30,20,0
52027 data0,-26,27,27,27,27
52028 data27,0,30,29,0,14
52029 data0,0,0,0,28,0
52030 data0,28,26,0,31,0
52031 data0,30,32,33,31,0
52032 data0,31,0,98,31,0
52033 data0,0,0,0,31,0
52034 data0,34,34,34,32,0
52035 data35,0,0,36,13,34,0
52036 data0,12,0,35,0,12
52037 data0,0,36,0,0,0
53000 fori=1tovm:readv$(i):next
53001 dataget,drop,i,open,close,drift,swami,look,throw,hint
53002 dataread,go,inven,trade,kill,free,charm,jump,score,row
53003 dataenter,catch,exit,climb,eat,feed,quit,build,make,light
53004 datasave,load,check,chang,unloc,lock
54000 fori=1tonm:readn$(i):next
54001 datan,s,e,w,u,d,north,south,east,west
54002 dataup,down,knaps,spear,flute,viper,tree,mouse,sign,book
54003 databoat,close,bed,boots,passa,"",leopa,diamo,villa,trink
54004 datacane,dog,allig,squir,dagge,note,chain,livin,corn,groun
54005 datapit,beans,quick,nativ,sapph,hut,lion,wood,fire,cage
54006 datatoolk,match,stuff,keys,chest,rom,roms,gold,point,nuts
55000 fori=1toim:readi$(i):next
55001 dataa timeworn book,a faded red knapsack,ears of corn
55002 dataa batch of groundnuts,a tiny grey mouse,a poison-tipped spear
55003 dataa pair of hiking boots,a vicious viper,a sparkling diamond
55004 dataa sack of coffee beans,a crumpled note,a solid silver chain
55005 dataseveral stalks of sugar cane,a hungry alligator,a wild dog
55006 dataa pearl-handled dagger,dr. livingston,a lethargic viper
55007 dataa golden nose ring,a charming little flute,a deep-blue sapphire
55008 dataa rare albino lion,a caged rare albino lion,a pile of wood
55009 dataa blazing fire,a strong wooden cage,a programmer's toolkit
55010 dataa book of matches,some foul-smelling stuff,a book of burnt matches
55011 dataa ring of rusty keys,a locked chest,an unlocked chest
55012 dataan empty chest,king soloman's gold
56000 fori=1toim:readil(i),ip(i),in(i):next
56001 data1,0,20
56002 data1,2,13
56003 data30,5,39
56004 data33,5,40
56005 data2,7,18
56006 data0,3,14
56007 data1,50,24
56008 data7,0,16
56009 data10,15,28
56010 data15,12,42
56011 data18,3,36
56012 data29,15,37
56013 data24,15,31
56014 data27,0,33
56015 data22,10,32
56016 data12,10,35
56017 data35,50,38
56018 data0,0,16
56019 data0,12,26
56020 data0,15,15
56021 data0,10,45
56022 data26,0,47
56023 data0,15,47
56024 data4,0,48
56025 data0,10,49
56026 data0,5,50
56027 data36,10,51
56028 data0,5,52
56029 data18,5,53
56030 data0,0,52
56031 data0,5,54
56032 data37,5,55
56033 data0,5,0
56034 data0,5,0
56035 data0,20,58
56100 return
60000 print"       african adventure"
60010 print"dr.livingston is again 'lost' in the"
60020 print"darkest out-reaches of africa.  his"
60030 print"rescue is your overall objective."
60040 print"to explore the terrain and to rescue"
60050 print"dr.livingston, you need to enter a two"
60060 print"word (verb-noun) command like 'go east'"
60070 print"or 'get book'.  you may also move by"
60080 print"entering just the direction or the "
60090 print"first letter, ie 'e' for east."
60100 print"the computer's vocabulary is limited,"
60110 print"so if a word doesn't seem to work, try"
60120 print"a new word or another approach."
60130 print"in addition to livingston, you will"
60140 print"earn points for each object you 'get'"
60150 print"and return to a secret location. but,"
60160 print"some objects may be put to better use"
60170 print"during your adventure. so, be creative!"
60180 input"press return to continue  *";q$
60190 print"       african adventure"
60200 print"there are several helpful commands to"
60210 print"use during your adventure:"
60220 print"'hint'--not always available"
60230 print"'look'--describes your surroundings"
60240 print"'i' or 'inventory'--lists the items in"
60250 print"your possession"
60260 print"'score'--shows total points earned"
60270 print"'save'--saves a game in progess"
60280 print"'load'--loads a previously saved game"
60290 print"'quit'--ends game and gives final score"
60300 print"your adventure will be filled with"
60310 print"danger and excitement. beasts and gems,"
60320 print"puzzles and quicksand are all about."
60330 print"the jungle is ever changing.  trails"
60340 print"are here today and gone tomorrow."
60350 print"explore!  be persistent! but most of"
60360 print"be adventurous!"
60370 input"press return to continue  *";q$
60380 return