-- ALAN shell v1.

OBJECT ATTRIBUTES
   closed.
   NOT locked.
   NOT openable.
   NOT takable.
   NOT an_actor.
   weight 0.

SYNONYMS
   east = e.
   west = w.
   north = n.
   south = s.

   z = 'wait'.
   i = 'inventory'.

   get = take.

   thru = through.

SYNTAX
   'look' = 'look'.
   'quit' = 'quit'.
   'wait' = 'wait'.
   'score' = 'score'.
   take_inv = 'inventory'.

   take = take (obj) *.
   drop = drop (obj) *.

   turn_on = turn on (obj).
   turn_off = turn off (obj).
   play_with = play with (obj).
   talk_to = talk 'to' (obj).

   give = 'give' (obj) 'to' (recip).

VERB 'look' DOES
   LOOK.
END VERB.

VERB 'quit' DOES
      "Goodbye!"
   QUIT.
END VERB.

VERB 'wait' DOES
   "Time passes..."
END VERB.

VERB 'score' DOES
   SCORE.
END VERB.

VERB take_inv DOES
   LIST inventory.
END VERB.

VERB open
   CHECK OBJECT IS openable
      ELSE "That would be a neat trick, opening the $o..."
   AND OBJECT IS closed
      ELSE "The $o is already open."
   AND OBJECT IS NOT locked
      ELSE "It isn't opening."
   DOES
      MAKE OBJECT NOT closed.
      "The $o opens."
END VERB.

VERB close
   CHECK OBJECT IS openable
      ELSE "You can't even open the $o, much less close it."
   AND OBJECT IS NOT closed
      ELSE "It _is_ closed!"
   DOES
      MAKE OBJECT closed.
      "You close the $o."
END VERB.

VERB take
   CHECK OBJECT IS takable
      ELSE "You can't take that."
   AND OBJECT NOT IN inventory
      ELSE "You did already, remember?"
   DOES
      "Taken."
      LOCATE OBJECT IN inventory.
END VERB.

VERB drop
   CHECK OBJECT IN inventory
      ELSE "But you're not carrying that!"
   DOES
      LOCATE OBJECT HERE.
      "Dropped."
END VERB.

VERB read DOES
   "That isn't something you can read."
END VERB.

VERB examine DOES
   "You see nothing special."
END VERB.

VERB give
   CHECK obj IN inventory
      ELSE "You don't have that."
   AND recip IS an_actor
      ELSE "You can't give a $o to a $2!"
END VERB.

VERB play_with DOES
   "You fiddle with the $o for a while. Gosh, that was fun."
END VERB.

VERB talk_to DOES
   "Talking to a $o is usually taken as a sign of impending mental
    collapse."
END VERB.

VERB turn_on DOES
   "You can't turn that on."
END VERB.

VERB turn_off DOES
   "You can't turn that off."
END VERB.

-- THE WORLD and all its contents.

CONTAINER inventory
   LIMITS
      COUNT 10 THEN
         "$nYou can't juggle any more objects; it slips from your hands."
      weight 20 THEN
         "$nYou can't carry that much weight. It tumbles to the ground."
   HEADER 
      "You are carrying:"
   ELSE
      "You are empty-handed."
END CONTAINER.

-- Where stuff goes when we want to hide it from the player.

LOCATION limbo
END LOCATION.