-- This is a simple use of the DESCRIPTION section to create a
-- room whose description changes depending how many times you've
-- looked at it. It's of dubious utility, but fun.

$include 'shell.alan'

-- The basic room and one object to play with.

LOCATION waiting_room NAME Waiting Room
   DESCRIPTION
      "You're standing in a nondescript, slightly dingy waiting room with white
       painted walls and a tile floor. A corridor leads south."

   EXIT s TO engine_room.

END LOCATION.

LOCATION engine_room NAME Engine Room
   HAS looked 0.

   DESCRIPTION

      INCREASE looked OF engine_room BY 1.

      IF looked OF engine_room = 1 THEN
         "You're in the Improbability Drive chamber. Nothing happens; there
          is nothing to see."
      ELSIF looked OF engine_room = 2 THEN
         "I mean it! There's nothing to see here!"
      ELSIF looked OF engine_room = 3 THEN
         "Okay, okay, there are a FEW things to see here."
      END IF.
      IF looked OF engine_room > 2 THEN
         "This is the room that houses the powerful Infinite Improbability
          Generator that drives the Heart of Gold. An exit lies north of
          here."
      END IF.

   EXIT n TO waiting_room.

END LOCATION.

-- START

START AT waiting_room.