!% +language_name=Slovenian

!=============================================================================================
!
!   ZENIN NA BEGU
!
!   Copyright (c) 2006 by Benjamin Lipovsek
!
!   e-mail:   benolipovsek@yahoo.com
!
!   Release 1:  13. October 2006
!   Release 2:	22. June 2007
!
!
!=============================================================================================
!
! Arhitektura:
! ------------
!
! 1. GLAVNE NASTAVITVE
! 2. VSTOPNE RUTINE
! 3. RUTINE
! 4. SUB-RUTINE
! 5. RAZREDI
! 6. GRAMATIKA
! 7. SVET
!  7.1 SPALNICA
!  7.2 GLASBENA SOBA
!  7.3 GASPER
!  7.4 LEBDECI OBJEKTI
! 8. POMOC
!
!=============================================================================================

!=============================================================================================
! OPOMBA: Ta igra (ob kompilaciji) potrebuje tudi knjiznico menus.h, ki ni sestavni clen
!         osnovnega paketa jezika Inform, dostopna pa je z interneta, in sicer z Informove
!         domace strani (www.inform-fiction.org/inform6.html).
!=============================================================================================

!*********************************************************************************************
!===========================+----------------------+==========================================
!===========================| 1. GLAVNE NASTAVITVE |==========================================
!===========================+----------------------+==========================================
!*********************************************************************************************

Constant Story "   ZENIN NA BEGU^^";

Constant Headline "Mala Sola Interaktivne Fikcije^
	           ^
                   (Priloga h knjiznicama Slovenian.h in SlovenianG.h, slovenskemu
                   prevodu programskega jezika Inform.)^
                   ^
                   Benjamin Lipovsek, (c) 2007^
                   ^
                   e-mail:   benolipovsek@@64yahoo.com^
                   ^
                   (Vtipkaj POMOC za vec informacij.)^^";

Release 2;

Constant AMUSING_PROVIDED;
Constant MANUAL_PRONOUNS;

Constant MAX_SCORE = 300;
Constant OBJECT_SCORE = 25;
Constant TASKS_PROVIDED;
Constant NUMBER_TASKS = 5;
Array task_scores -> 50 50 50 50 25;

Global pkey;				! Cakanje na tipko

Include "Parser";

Object	LibraryMessages
  with	before
  	[;
  	   Wear:
  	      if (lm_o == obleka && lm_n == 4)
  	         "Pazljivo si obleces svecano obleko, pri tem pa se v tebi le se stopnjuje
                  obcutek groze in nemoci.";
           Disrobe:
              if (lm_o == obleka && lm_n == 2)
                 "V naglici in z nepopisnim olajsanjem si sleces obleko.";
  	];

Include "VerbLib";
Include "menus";

!*********************************************************************************************
!===========================+-------------------+=============================================
!===========================| 2. VSTOPNE RUTINE |=============================================
!===========================+-------------------+=============================================
!*********************************************************************************************

[ Initialise;
     location = postelja;
     lookmode = 2;
     player.description = "Nic kaj lep prizor.";
     print
     "~Poslusaj, tvojih neumnosti imam ze vrh glave!~^
      ^
      Njegovi svecani usnjeni skornji trdo odmevajo po mali sobici, ko nejevoljno koraka od
      okna do vrat in spet nazaj.^
      ^
      ~Spodaj te caka cudovita mlada nevesta...~^
      ^
      ~Cudovita?~ osuplo odpres usta. ~Mar si jo sploh videl?!~^
      ^
      Za hip se ustavi in se popraska po nosu.^
      ^
      ~Dobro, ze res, morda ni ravno najlepsi cvet med cvetovi. A vseeno bo dobra zena, le
      verjemi mi, lahko bos ponosen nanjo. In preprican sem, da ji tudi posebnih carov ne
      manjka!~^
      ^
      ~Lepo te prosim, oce, o kakih carih neki vendar govoris?! Se dvornega kuharja bi prej
      zamenjali za zensko!~^
      ^
      Gledas ga, kako nadaljuje s svojim masiranjem po sobi. Deske pod njim skripajo in
      jecijo, kot bi bile same tik pred poroko.^
      ^
      ~Vidis, sin,~ se zopet obrne k tebi, ~tebi preprosto manjka prakticne globine... Saj
      vem, mlad si, nemiren, rad bi videl svet, morda spoznal kaksno brhko kmetico... Toda
      tako ne gre, fant moj, treba je razmisljati z zbrano glavo. Treba je kovati
      prihodnost.~^
      ^
      Odkaslja se. ~Jerca ti bo dobra zena. Rodila ti bo kup otrok, skrbela bo za
      gospodinjstvo in pazila, da ti cesa ne manjka. Postenost in njene ostale vrline te bodo
      napravile za najsrecnejsega moza v dezeli.~^
      ^
      ~Bogastvo njenega oceta torej nima nic opraviti s tem?~ trpko odvrnes.^
      ^
      Oce jezno odkoraka na drugo stran sobe. ~Glej, sin moj! Le dobro si oglej!~ Z roko
      zamahne proti oknu. ~Vse to bo nekoc tvoje!~^
      ^
      ~A zavese?~^
      ^
      ~KRALJESTVO, sin, KRALJESTVO! In kako vraga ga imas namen voditi? S prebiranjem romanov
      in igranjem na lutnjo?!~^
      ^
      Nekaj trenutkov le besno strmi predse.^
      ^
      ~Dovolj mi je teh bedarij,~ koncno le zamrmra in se pretece vrne k tebi. S prstom pokaze
      na elegantno skrlatno obleko, ki lezi poleg tebe na postelji. ~Cez deset minut se vrnem.
      Glej, da bos oblecen in pripravljen! Me cisto nic ne briga, ali se porocis z Jerco ali
      pa z dvornim kuharjem, porocil se BOS! Cez deset minut pridem nazaj, in takrat me BOS
      poslusal!~^
      ^
      Jezno odvihra iz sobe in na ves glas zaloputne vrata za seboj. Hip zatem zaslisis
      kovinsko sklocanje v kljucavnici.^
      ^
      ~Cudovito,~ zavzdihnes. ~Naravnost cudovito.~^
      ^
      ^
      [Prosim, pritisni SPACE.]";
     @read_char 1 -> pkey;
     @erase_window 0;
     "^";
];

[ DeathMessage;
     if (deadflag == 3)
        print
           "   KONEC   ";
];

[ Amusing;
     "Kot zanimivost: Nas dobri okrogli duhec Gasper je tudi izvrsten glasbenik! Me prav
      zanima, kako bi bil kaj spreten s tvojo lutnjo...";
];

!*********************************************************************************************
!===========================+-----------+=====================================================
!===========================| 3. RUTINE |=====================================================
!===========================+-----------+=====================================================
!*********************************************************************************************


[ PrihodOceta;
     switch (turns)
     {
        10: "^Nenadoma zaslisis tezke korake s stopnisca pred vrati. Gotovo prihaja oce,
              da te odpelje na svatbo!";
        11: "^Koraki prihajajo vse blize in blize, nato pa zaslisis skrtanje v kljucavnici!";
        12: if (player in omara && omara hasnt open)
            {
               Achieved(0);
               "^Slisis, kako oce odlocno zakoraka v sobo.^
                ^
                ~Gremo, sin, konec sprenevedanja. Danes se bos ozenil, pa tudi ce te...~^
                ^
                Nekaj trenutkov tisine.^
                ^
                ~Pa kje hudica je ta zmesani fant?~ Njegovi koraki se oddaljijo proti
                glasbeni sobici, nato se spet vrnejo. ~Prekleto, menda se mi ni vrgel
                skozi okno... Straza!~^
                ^
                Vrata se spet zapro, kljuc v kljucavnici se obrne. Cez nekaj trenutkov
                je spet vse tiho.";
            }
            else
            {
               deadflag = 3;
               if (player in omara)
                  print "^Vrata se tedaj sunkovito odpro in oce odlocno zakoraka v sobo.^
                         ^
                         ~Gremo, sin, konec sprenevedanja. Danes se bos ozenil, pa
                         tudi ce...~ Osupel se zastrmi vate. ~Ja kaj hudica pa vendar
                         pocnes v omari?! Spravi se ven! Takoj!~^
                         ^
                         Ponizno zlezes iz omare.^^";
                  else
                     print "^Vrata se tedaj sunkovito odpro in oce odlocno zakoraka v sobo.^
                            ^
                            ~Gremo, sin, konec sprenevedanja. Danes se bos ozenil, pa
                            tudi ce te po vseh stirih spravim pred oltar.~^^";
                  if (obleka has worn)
                     "Osvrkne te s pogledom. ~Dobro, oblecen si ze. Zdaj pa pridi, greva
                      dol. In da si mi cisto tiho! Danes razen besedice 'da' od tebe ne
                      zelim slisati nicesar!~^
                      ^
                      S sklonjeno glavo sledis ocetu iz sobe. Kmalu zatem se porocis z
                      Jerco, in tvoje zivljenje je zapecateno za zmeraj...";
                  "Osvrkne te s pogledom. ~Pa saj sploh se nisi oblecen?! Dobro, dobro, pusti,
                   se bos spodaj. Zdaj se pa zmigaj! In da si mi cisto tiho! Danes razen
                   besedice 'da' od tebe ne zelim slisati nicesar!~^
                   ^
                   S sklonjeno glavo sledis ocetu iz sobe. Kmalu zatem se porocis z Jerco,
                   in tvoje zivljenje je zapecateno za zmeraj...";
               }
            }
];

[ PrintTaskName task_number;
     switch (task_number)
     {
        0: "- skril si se v omaro";
        1: "- dvignil si desko v omari";
        2: "- ocistil si svetilko";
        3: "- od Gasperja si dobil kljuc";
        4: "- odklenil si vrata";
     }
];

!*********************************************************************************************
!===========================+---------------+=================================================
!===========================| 4. SUB-RUTINE |=================================================
!===========================+---------------+=================================================
!*********************************************************************************************

[ IgrajSub;
     "Ne vem, kako tocno si to predstavljas, vem pa, da si doslej igral izkljucno in le na
      svojo priljubljeno lutnjo.";
];

[ MenuSub;
     help_menu.select();
];

!*********************************************************************************************
!===========================+------------+====================================================
!===========================| 5. RAZREDI |====================================================
!===========================+------------+====================================================
!*********************************************************************************************

Class   Room
  has   light;

!*********************************************************************************************
!===========================+--------------+==================================================
!===========================| 6. GRAMATIKA |==================================================
!===========================+--------------+==================================================
!*********************************************************************************************

Include "SlovenianG";

Extend 'izvleci'
       * noun 'z//'/'s//' held 	-> Unlock;

Verb 'privzdigni' 'vzdigni'
       * noun			-> Take
       * noun 'z//'/'s//' held	-> Unlock;

Extend 'ocisti'
       * noun 'z//'/'s//' held  -> Rub;

Verb 'igraj' 'zaigraj' 'brenkaj' 'zabrenkaj'
       * noun			-> Igraj
       * 'na' noun		-> Igraj;

Extend 'prosi'
       * creature 'za' topic	-> Ask;

Verb 'help' 'about' 'info' 'pomoc' 'namig' 'pomagaj'
     * -> Menu;

!*********************************************************************************************
!===========================+---------+=======================================================
!===========================| 7. SVET |=======================================================
!===========================+---------+=======================================================
!*********************************************************************************************

!---------------------------------------------------------------------------------------------
!                             7.1 SPALNICA
!---------------------------------------------------------------------------------------------

Room	spalnica "TVOJA SPALNICA"
with	name 'lestenec' 'lestenca' 'lestencu' 'lestencem',
        description "Nikoli nisi pretirano cenil teh stirih sten, danes pa jih naravnost
                     preziras. Saj ne, da bi bilo karkoli narobe z opremo in pohistvom v sobi
                     -- nasprotno. Postelja v kotu je siroka in udobna, lestenec cudovito
                     blescec v soju vecernih zarkov, velika omara iz hrastovine ob vratih
                     pa je sam testament vrhunske izdelave. In vendar, danes se pocutis kot
                     v kamniti kletki, za vedno ujet v to morbidno in enolicno zivljenje
                     visokega plemstva, povsem brez upov na resitev. Obokan prehod v vzhodni
                     steni ne vodi dalec, ogromna vrata juzno pa ostajajo brezupno zaklenjena.
                     Ujet si, prav res.",
        e_to glasbena_soba,
        before
        [;
           Listen:
              if (okno has open)
                 "Poleg zvrgolenja ptic zunaj ne slisis nicesar.";
        ];

Object  -> prehod_1 "prehod"
  with  name 'prehod' 'prehoda' 'prehodu' 'prehodom',
        sklon "prehoda" "prehodu" "prehod" "prehodu" "prehodom",
        description "Ozek obokan prehod povezuje spalnico s tvojo glasbeno sobico na vzhodu.",
        before
        [;
           Enter:
              <<Go e_obj>>;
        ],
   has  male scenery;

Object	-> postelja "postelja"
  with  name 'postelja' 'postelje' 'postelji' 'posteljo',
        sklon "postelje" "postelji" "posteljo" "postelji" "posteljo",
        description "Siroka in udobna postelja te kar vabi, da se ji prepustis in pozabis
                     na ves cirkus okrog sebe.",
   has  female scenery supporter enterable;

Object  -> -> obleka "porocna obleka"
  with  name 'svecana' 'skrlatna' 'porocna' 'obleka' 'oblacilo'
             'svecane' 'skrlatne' 'porocne' 'obleke' 'oblacila'
             'svecani' 'skrlatni' 'porocni' 'obleki' 'oblacilu'
             'svecano' 'skrlatno' 'porocno' 'obleko' 'oblacilom',
        sklon "porocne obleke" "porocni obleki" "porocno obleko" "porocni obleki" "porocno obleko",
        initial "Tvoje porocno oblacilo -- cudovita skrlatna svecana obleka -- lezi poleg
                 tebe na robu postelje. Ze ob samem pogledu nanjo te zvije v zelodcu.",
        description
        [;
           if (svetilka.ociscena)
              "Tvoja porocna obleka je zdaj povsem umazana, zmeckana, neugledna... in taka
               ti je neprimerno bolj vsec!";
           "Cudovita skrlatna svecana obleka te spominja na zelezne spone v kakem od boga
            pozabljenem zaporu... Kar zmrazi te, ko pomislis na poroko!";
        ],
        after
        [;
           Wear:
              score = score - 10;
           Disrobe:
              score = score + 10;
        ],
   has  female clothing;

Object  -> okno "okno"
  with  name 'okno' 'okna' 'oknu' 'oknom' 'zavese' 'zaves' 'zavesam' 'zavesah' 'zavesami',
        sklon "okna" "oknu" "okno" "oknu" "oknom",
        description
        [;
           if (self has open)
              "Skozi veliko dvojno okno prihajajo glasovi svobode: radostno petje ptic,
               sumenje potokov, tiho zvizganje vetra. Ah, kaj bi dal, da bi bil tam zunaj!";
           if (self hasnt open)
              "Veliko dvojno okno kraljuje v severni steni.";
        ],
        before
        [;
           Search:
              "Zelene doline, cisti potoki, ptice... svoboda! Nekaj, kar se ti zdi v tem
               trenutku nepredstavljivo dalec.";
           Enter:
              if (self hasnt open)
                 "Ne mores vendar skociti skozi zaprto okno!";
              deadflag = 3;
              "~Na svidenje, kruti svet!~ se zadnjic zavpijes, preden se pozenes v globino.^
              ^
              Kako tragicna smrt!!! Se res nisi mogel spomniti nic pametnejsega?";
        ],
   has  neuter scenery openable transparent;

Object  -> vrata "vrata"
  with  name 'vrata' 'vrat' 'vratom' 'vratih' 'vrati',
        sklon "vrat" "vratom" "vrata" "vratih" "vrati",
        description "Mogocna obokana lesena vrata vodijo na vrh dolgega stopnisca, ki
                     povezuje tvoj stolp s preostalim gradom. Stopnisca seveda ne vidis, saj
                     vrata ostajajo brezkompromisno zaprta.",
        before
        [;
           Attack:
              "Pa menda ja nisi mislil, da bo tako preprosto!?";
           Open,Enter:
              if (self has locked)
                 "Zaman. Mogocna vrata so zaklenjena, situacija pa ostaja kratko malo
                 brezupna.";
              deadflag = 2;
              "Mogocna vrata so koncno premagana! Kot bi se zavedala svojega poraza, se
               pocasi odpro v glasnem skripanju in jecanju. Zunaj k sreci ni nikogar, niti
               strazarja ne -- odlicno! Hitro pograbis svojo lutnjo, se se zadnjic ozres okrog
               sebe, in ze te ni vec...^
               ^
               Svoboda caka! Z njo pa ves svet, kopica romanov, dogodivscin... in nobene
               Jerce.";
        ],
        after
        [;
           Unlock:
              Achieved(4);
        ],
        with_key kljuc,
   has  neuter pluralname scenery openable lockable locked;

Object  -> omara "velika omara"
  with  name 'velika' 'omara' 'velike' 'omare' 'veliki' 'omari' 'veliko' 'omaro',
        sklon "velike omare" "veliki omari" "veliko omaro" "veliki omari" "veliko omaro",
        description "Mogocna omara iz hrastovine stoji ob steni nedalec od vrat.",
        skripanje,
        before
        [;
           Enter:
              if (turns < 10)
                 "Zlesti zelis v omaro?! Za to bos pa vsekakor potreboval dober razlog.";
        ],
        after
        [;
           Enter:
              if (self.skripanje == false)
              {
                 self.skripanje = true;
                 move deska_1 to self;
                 "~Saj to niti ni tako slaba ideja,~ pomislis, medtem ko se poskusas stlaciti
                  med vso tisto kramo, ki ze tici v omari.^
                  ^
                  Nenadoma pa pod teboj nekaj zajeci in zacvili. Kaze, da je ena izmed desk
                  v lesenem podu nekoliko razmajana...";
              }
        ],
        each_turn
        [;
           PrihodOceta();
        ],
   has  female scenery openable container enterable;

Object  -> -> krama "razna krama"
  with  name 'razna' 'krama' 'stvari'  'oblacila'  'zvezki'  'cevlji'
             'razne' 'krame'           'oblacil'   'zvezkov' 'cevljev'
             'razni' 'krami' 'stvarem' 'oblacilom' 'zvezkom' 'cevljem'
             'razno' 'kramo'                       'zvezke'  'cevlje'
                             'stvareh' 'oblacilih' 'zvezkih' 'cevljih'
                             'stvarmi' 'oblacili',
        sklon "razne krame" "razni krami" "razno kramo" "razni krami" "razno kramo",
        description "Oblacila, nekaj zvezkov, cevlji... Nic posebnega, skratka.",
        describe "^Raznovrstna krama zapolnjuje omaro.",
        before
        [;
           Take:
              "Prav nicesar od te krame trenutno ne potrebujes.";
        ],
   has  female;

Object  -> -> dnevnik "dnevnik"
  with  name 'dnevnik' 'dnevnika' 'dnevniku' 'dnevinkom' 'zvezek' 'zvezka' 'zvezku' 'zvezkom',
        sklon "dnevnika" "dnevniku" "dnevnik" "dnevniku" "dnevnikom",
        description "Ah, tvoj ljubljeni sopotnik skozi zivljenje! Na ta papir vsak dan
                     izlivas svojo navelicanost in obcutek nemoci, pa tudi nekaj kratkih
                     pesmi se najde v njem.^
                     ^
                     Dnevnik je pravzaprav preprosta majhna knjizica, oblecena v mehko usnje,
                     na sprednji platnici pa je simbolicno izvezen zlat kljuc.",
        initial "V enem kotu omare lezi skrit tvoj dnevnik. Ko bi oce vedel zanj, bi najbrz
                 dobil ospice, ce ne kaj hujsega.",
   has  male scored;

!---------------------------------------------------------------------------------------------
!                             7.2 GLASBENA SOBA
!---------------------------------------------------------------------------------------------

Room	glasbena_soba "GLASBENA SOBA"
  with  description "Ta majcena kamra je nekoc sluzila kot omara z bogato zbirko
                     raznovrstnih kraljevskih oblacil in modnih dodatkov. Nekateri tvoji
                     predniki so vsekakor vedeli, od kod jim modra kri. Ti pa si v gnusu
                     nad takim zivljenjem iz sobice zmetal vse police in stojala ter jo
                     preuredil v droben delovni prostor... vsaj dokler nisi tu notri prvic
                     zabrenkal na lutnjo in se navdusil nad odlicno akustiko prostora.
                     Odslej pa cele dneve posedas na stolu v kotu in s svojim igranjem
                     spravljas oceta ob zivce.",
        w_to spalnica,
        each_turn
        [;
           PrihodOceta();
        ];

Object  -> prehod_2 "prehod"
  with  name 'prehod' 'prehoda' 'prehodu' 'prehodom',
        sklon "prehoda" "prehodu" "prehod" "prehodu" "prehodom",
        description "Ozek obokan prehod vodi nazaj v spalnico na zahodu.",
        before
        [;
           Enter:
              <<Go w_obj>>;
        ],
   has  male scenery;

Object  -> noz "noz"
  with  name 'noz' 'noza' 'nozu' 'nozem',
        sklon "noza" "nozu" "noz" "nozu" "nozem",
        description "Tvoj noz za papir, majhen in ozek.",
        describe
        [;
           if (self hasnt moved)
           {
              print "";
              return;
           }
           "^Tvoj noz za papir se svetlika nedalec stran.";
        ],
   has  male scored;

Object  -> ogledalo "ogledalo"
  with  name 'ogledalo' 'ogledala' 'ogledalu' 'ogledalom',
        sklon "ogledala" "ogledalu" "ogledalo" "ogledalu" "ogledalom",
        describe "^Majhno ovalno ogledalo visi na juzni steni sobice.",
        description
        [;
           if (obleka has worn)
              print "Kar zgrozis se ob pogledu na svoj odsev v gladkem steklu! Ta obleka,
                     ta prihodnost... Je to vse, cesar se smes nadejati?^";
           else print "Tisti dobro znani, zdolgocaseni obraz je se vedno tu.^";
           if (noz hasnt moved)
              print "^V ogledalu nenadoma opazis, da se nekaj svetlika pod stolom na
                     drugi strani sobice. Hm...^";
        ],
        before
        [;
           Attack:
              "Prav res bi potreboval nekaj srece, a tako vrazeveren pa spet nisi.";
           Search:
              <<Examine self>>;
        ],
   has  neuter static;

Object  -> stol "stol"
  with  name 'stol' 'stola' 'stolu' 'stolom',
        sklon "stola" "stolu" "stol" "stolu" "stolom",
        description "Majhen lesel stol stoji v kotu sobice. Tu si presedel in preigral ze
                     toliko ur, da bi lahko o njih napisal knjigo.",
        before
        [;
           LookUnder:
              if (noz hasnt moved)
              {
                 move noz to player;
                 "Hm... Nekaj se sveti pod stolom. Radoveden se spustis na kolena in z roko
                  pogladis oble kamne pod seboj, dokler ne zadanes ob nekaj hladnega.^
                  ^
                  Tvoj nozek za papir! Mislil si, da si ga izgubil!";
              }
              "Ne, nicesar vec ni pod stolom.";
           Take,Push,Pull,PushDir:
              "Povsem brez potrebe.";
        ],
   has  male scenery supporter enterable;

Object  -> -> lutnja "lutnja"
  with  name 'lutnja' 'lutnje' 'lutnji' 'lutnjo',
        sklon "lutnje" "lutnji" "lutnjo" "lutnji" "lutnjo",
        description "Tvoj najljubsi glasbeni instrument!",
        before
        [;
           Igraj:
              "Pocasi in z obcutkom zabrenkas nekaj otoznih akordov.";
        ],
   has  female;

!---------------------------------------------------------------------------------------------
!                             7.3 GASPER
!---------------------------------------------------------------------------------------------

Object	gasper "duh Gasper"
  with  name 'gasper' 'gasperja' 'gasperju' 'gasperjem' 'duh' 'duha' 'duhu' 'duhom',
        sklon "duha Gasperja" "duhu Gasperju" "duha Gasperja" "duhu Gasperju"
              "duhom Gasperjem",
        description "Okrogli Gasper izgleda nadvse dobrodusen duh. Morda kar malce prerad
                     reglja, a po tolikih letih osame ga na nek nacin razumes.",
        govor,
        life
        [;
           Attack:
              "Zakaj le? Gasper je prav prijazen duh.";
           Give,Show:
              if (noun == dnevnik)
              {
                 Achieved(3);
                 move kljuc to player;
                 remove gasper;
                 "Komaj se dobro obrnes k njemu, Gasper ze zacne:^
                  ^
                  ~Naj te ne bo sram, ti kar reci! Karkoli, dobil bos. Le na dan z besedo.
                  Povej, kaj bi rad...~^
                  ^
                  Nato koncno opazi tvoj dnevnik, ki mu ga molis pod nos. Za hip kot da ne
                  ve tocno, kaj bi z njim pocel, nato pa se mu obraz nenadoma razjasni v
                  zmagoslaven nasmeh.^
                  ^
                  ~Ah, v tem je torej rec!~ pomigne proti izvezenemu liku na platnici. ~Ja
                  zakaj pa vendar nisi ze prej rekel? Le besedica bi bila potrebna, in dobil
                  bi. Saj vem, saj vem, najbrz te je bilo nekoliko strah, kaj? Ze res, duh
                  Gasper je silak, da mu ni para. No a le nic ne skrbi, fant, resil si me
                  tiste preklete svetilke, zato ti ne bom storil zalega.~^
                  ^
                  Ponudi ti odprto dlan, v kateri lezi velik zelezen kljuc.^
                  ^
                  ~Le vzemi, fant, le vzemi! To je se najmanj, kar lahko storim zate.~^
                  ^
                  Zahvalis se in tezak kljuc pospravis v zep.^
                  ^
                  ~Tako, tu pa se najine poti locujejo,~ otozno Gasper. ~Obljubo sem izpolnil,
                  bilo mi je v veselje, a cakajo me se ostali opravki in neporavnani racuni.
                  Vso sreco, fant, vso sreco! In ne pozabi na dobrega starega Gasperja!~^
                  ^
                  Okrogli duh nato izgine v prazen nic, in soba se pogrezne nazaj v tisino.";
              }
              if (noun == lutnja)
                 self.govor = false;
                 switch (random(10)-1)
                 {
                    0: "Gasper vzame lutnjo in mojstrsko odigra Beethovnovo Eroico.";
                    1: "Gasper odbrenka Pomlad iz Vivaldijevih Stirih letnih casov.";
                    2: "Lutnja kar zari, ko Gasper igra Wagnerjeve Valkire.";
                    3: "Gasper zaigra Mozartovo Simfonijo st. 39 v Es-duru.";
                    4: "Gasper v ekstazi odbrenka Beethovnovo Simfonijo st. 5 v C-molu.";
                    5: "S solzami v oceh poslusas Gasperjevo interpretacijo Chopinovega
                        Nocturna v Cis-molu.";
                    6: "Gasper odbrenka Nothing Else Matters od Metallice.";
                    7: "Gasper zaigra Stairway To Heaven skupine Led Zeppelin.";
                    8: "Gasper zabrenka Bon Jovijevo Always.";
                    9: "Gasper odigra Thunder Road od Brucea Springsteena.";
                 }
           Ask,Tell,Answer,Order:
              self.govor = false;
              "Ze odpres usta, a Gasper te prehiti:^
              ^
              ~Naj te ne bo sram, ti kar reci! Karkoli, dobil bos. Le na dan z besedo. Kar si
              storil zame, je cudovito, in vedno ti bom hvalzen. Zato pa le povej svojo
              zeljo, le povej, in dobri duh Gasper ti jo bo izpolnil!~";
        ],
        each_turn
        [;
           if (self.govor == false)
           {
              self.govor = true;
              return;
           }
           if (random(2)-1)
              rtrue;
           switch (random(10)-1)
           {
              0: "^~...Toliko let sem prebil v tisti svetilki, toliko let!~ zamrma Gasper...";
              1: "^~...Koliko dogodivscin sem dozivel nekoc,~ zasanjano Gasper, ~o njih bi
                  lahko napisal pravi pravcati roman!...~";
              2: "^~...Kam gre cas, prav res, kam gre cas...~ Gasper zamisljeno.";
              3: "^~...Hej fant,~ z zanimanjem Gasper, ~poznas morda se kakega duha poleg
                  mene?...";
              4: "^~...Dobro so me, dobro,~ se nasmehne Gasper. ~Samo pokukaj v svetilko, so
                  rekli. Samo pokukaj, bos videl, zabavno bo!... Da bi jih vrag!...~";
              5: "^~...Hej fant, si kdaj slisal za 'random' funkcijo?...~";
              6: "^~...Res ne razumem, v cem je stos ubogega duha petsto let imeti zaprtega v
                  navadni oljni svetilki!...~ se razburja Gasper.";
              7: "^~...Hvala ti fant, res hvala!~ zadovoljno Gasper. ~Brez tebe bi bil se
                  vedno ujet v tisti presneti oljenki...~";
              8: "^~...Fant moj, kaj ti bo pa ta obleka?~ Gasper pomigne proti tistemu, kar
                  je nekoc bilo skrlatna porocna oprava. ~Menda je ja ne mislis obleci?! Tako
                  umazanih cunj se svoj zivi dan nisem videl!...~";
              9: "^~...Samo da se vrnem domov, to jim bom pokazal!~ se zarezi Gasper. ~Strasil
                  jih bom, dokler se jim ne bo zmesalo!...~";
           }
        ],
   has  male animate;

!---------------------------------------------------------------------------------------------
!                             7.4 LEBDECI OBJEKTI
!---------------------------------------------------------------------------------------------

Object  deska_1 "razmajana deska"
  with  name 'razmajana' 'deska' 'razmajane' 'deske' 'razmajani' 'deski' 'razmajano' 'desko',
        sklon "razmajane deske" "razmajani deski" "razmajano desko" "razmajani deski"
              "razmajano desko",
        description "Ena izmed desk v spodnji stranici omare cvili in jeci, ko stopas po
                     njej.",
        before
        [;
           Unlock:
              if (second == noz)
              {
                 Achieved(1);
                 remove deska_1;
                 move deska_2 to player;
                 move vdolbina to omara;
                 "Rezilo noza potisnes v ozko spranjo ob robu deske -- odlicno se prilega!
                  Nato ga le se malo zasukas, vzdignes, in deska je koncno prosta.^
                  ^
                  Presenecen obstrmis nad plitvo vdolbino v omari, ki si jo pravkar
                  razkril. Vklesana je naravnost v kamnita tla, v njej pa se skriva drobna
                  kovinska oljenka.";
              }
              "Nemogoce!";
           Take:
              "Z golimi rokami poskusas izvleci desko v dnu, a ti nikakor ne uspe. Spranje
               na obodu so preozke za tvoje prste, in nikakor ne dobis dobrega oprijema.
               Hm...";
        ],
   has  female;

Object  deska_2 "deska"
  with  name 'deska' 'deske' 'deski' 'desko',
        sklon "deske" "deski" "desko" "deski" "desko",
        description "Nekoc del omare, zdaj ponosno tvoja lastnina.",
   has  female;

Object  vdolbina "plitva vdolbina"
  with  name 'plitva' 'vdolbina' 'luknja' 'plitve' 'vdolbine' 'luknje'
             'plitvi' 'vdolbini' 'luknji' 'plitvo' 'vdolbino' 'luknjo',
        sklon "plitve vdolbine" "plitvi vdolbini" "plitvo vdolbino" "plitvi vdolbini"
              "plitvo vdolbino",
        describe "^Drobna vdolbina zeva v dnu omare, pozabljena in zapuscena.",
        description "Skrivnostna vdolbina je vklesana v sama kamnita tla.",
        before
        [;
           Take,Push,Pull,PushDir:
              "Kako hudica si pa to predstavljas?!";
           Open:
              "Zevajoca vdolbina je ze odprta, vse odkar si odstranil tisto presneto desko.";
        ],
   has  female static container open;

Object  -> svetilka "svetilka"
  with  name 'svetilka' 'oljenka' 'svetilke' 'oljenke' 'svetilki' 'oljenki' 'svetilko'
             'oljenko',
        sklon "svetilke" "svetilki" "svetilko" "svetilki" "svetilko",
        ociscena,
        description
        [;
           if (self.ociscena)
              "Cudovita oljna svetilka se sveti kot nova, lahko si upraviceno ponosen na
               svoje delo.";
           "Majhna oljna svetilka je verjetno ena najbolj umazanih reci, kar si jih kdaj
            videl. Strjeno blato, kosi suhe trave, povrh pa se debela plast prahu.";
        ],
        before
        [;
           SwitchOn,Burn:
              "Tezko brez primernega ognja.";
           SwitchOff:
              "Svetilka je vendar ze ugasnjena.";
           Rub:
              if (self.ociscena)
                 "Svetilka se sveti kot nova! Dodatno ciscenje res ni vec potrebno.";
              if (second == obleka)
              {
                 Achieved(2);
                 self.ociscena = true;
                 move gasper to location;
                 move svetilka to location;
                 "Kar smeji se ti, ko to cudovito, brezmadezno obleko ovijes okrog gnusnega
                  strjenega kupa zemlje in trave. ~Naj gre poroka k vragu!~ pomislis. Tkanina
                  pa je ravno prav groba in nezna hkrati, da ciscenje napreduje hitro in brez
                  tezav.^
                  ^
                  In res, v nekaj minutah se oljenka sveti kot nova!^
                  ^
                  Tedaj pa se svetilka zacne tresti, kovina pa postaja cedalje bolj
                  topla. Prestrasen oljenko izpustis na tla, v istem trenutku pa
                  pricne zrak vse okrog tebe cvrcati in se iskriti.^
                  ^
                  Pred teboj se nenadoma pojavi zajetna postava, lebdeca sredi sobe.^
                  ^
                  Debel mozak zbegano mezika okrog sebe, steguje roke in preseneceno strmi
                  v svoje prste, nato pa koncno uzre svetilko na tleh. Usta se mu razlezejo
                  v sirok nasmeh.^
                  ^
                  ~Fenomenalno! Hudicevo fenomenalno! Gasper dragi, resen si! Da, prav res,
                  nekdo se te je po vseh teh letih koncno usmilil. Tristo kosmatih, koliko
                  casa je sploh preteklo? Pa saj sploh ni vazno. Zdaj si prost, prost kot...~^
                  ^
                  Za hip premolkne, ko presenecen ugleda tebe, ki verjetno ravno tako bedasto
                  strmis vanj.^
                  ^
                  ~Fant moj, si me ti izpustil? Ti si bil, kaj? Ti si izpustil dobrega
                  starega Gasperja iz njegove preklete kletke. Tisockrat hvala, fant,
                  tisockrat hvala! Tvoj dolznik sem, prav res. Ce torej kaj zelis, karkoli,
                  le reci -- in dobil bos!~";
              }
              if (second == nothing)
                 "Z golimi rokami bos tezko ocistil svetilko.";
              "S tem bos le stezka ocistil umazano svetilko.";
        ],
   has  female scored;

Object  kljuc "kljuc"
  with  name 'kljuc' 'kljuca' 'kljucu' 'kljucem',
        sklon "kljuca" "kljucu" "kljuc" "kljucu" "kljucem",
        description "Velik in tezak zelezen kljuc ti vraca upanje v zivljenje.",
   has  male;

!*********************************************************************************************
!===========================+----------+======================================================
!===========================| 8. POMOC |======================================================
!===========================+----------+======================================================
!*********************************************************************************************

Menu	help_menu "ZENIN NA BEGU";

Option	-> "KAJ JE INTERAKTIVNA FIKCIJA"
  with 	description
        "Z enim stavkom opisati medij interaktivne fikcije je pravzaprav nemogoce. Gre namrec
         za spoj dveh tako razlicnih disciplin, da jih sprva nikakor ne moremo povezati med
         seboj. Na eni strani stoji literatura, cisto pripovednistvo, na drugi pa svet
         racunalniskih igric. Milo receno nezdruzljivo, a vendar -- ravno za to gre pri vsem
         skupaj.^
         ^
         V obdobju druge polovice dvajsetega stoletja, se preden so osebni racunalniki dosegli
         svojo zlato dobo, je obstajalo na kupe tako imenovanih ~interaktivnih knjig~. V
         slovenscino jih je bilo sicer prevedenih le pescica, morda najbolj znana pa je bila
         desetletje nazaj zbirka ~Casovni stroj~. Znacilnost teh knjig je bila v tem, da se
         niso brale linearno od zacetka do konca, pac pa so se listale po bralcevih zeljah in
         odlocitvah. Na koncu vsakega poglavja je imel namrec bralec (navadno glavni lik) dve
         ali vec moznosti, kaj zeli v zgodbi storiti. Glede na svojo odlocitev je moral nato
         polistati na oznaceno stran ter tam nadaljevati z branjem.^
         ^
         Racunalniska interaktivna fikcija pa tu stori se korak dlje. V bralcevih (igralcevih)
         rokah je namrec vse; bralec ima popolno oblast nad svojim likom, ki je hkrati tudi
         protagonist zgodbe. Lahko raziskuje okolico, se pogovarja z ostalimi liki, lahko
         manipulira s predmeti v svetu. Na podlagi njegovih dejanj pa se zgodba pocasi razvija.^
         ^
         Svoje zelje bralec izraza v obliki povsem naravnih velelnih stavkov, npr. ~vzemi vazo~
         ali ~odpri omaro~ ali ~preberi plakat na steni~ ipd. Zgodba (racunalniski program) pa
         mu prav tako v obliki povedi vraca odgovore, nove informacije, nove opise.
         Interaktivni roman se tako pocasi odvija.^
         ^
         Dela interaktivne fikcije se tudi med seboj lahko mocno razlikujejo. V grobem se
         delijo predvsem na dve skupini: prva je osredotocena na pripovednistvo in globoko
         sporocilo, bralec je tako rekoc voden skozi zgodbo, tu in tam jo mora le vzpodbuditi
         s kaksnim ukazom; primer take igre je cudovita in pretresljiva ~Photopia~ (Adam
         Cadre, 1998). Druga skupina pa prisega na tezke, zanimive in kompleksne uganke, ki
         jih mora bralec (protagonist) najprej razresiti, preden se zgodba odvije dalje; taka
         je na primer mojstrska ~Spider And Web~ (Andrew Plotkin, 1996).^
         ^
         Kljub temu je vsem delom skupno eno: se vedno je bistvena prav zgodba,
         pripovednistvo. Brez besed interaktivna fikcija preprosto ne obstaja. Ravno opisi
         lokacij, stvari, likov in dejanj dajejo delu car, atmosfero. In dobra proza je tisto,
         kar daje interaktivni fikciji tudi znatno umetnisko (literarno) vrednost, ceravno
         to elektronskim medijem vse prepogosto nocemo priznati!^
         ^
         Nenazadnje pa se ta medij od klasicne literature razlikuje se v eni stvari.
         Interaktivna fikcija je naceloma izredno nelinearna, v njej je moznih mnogo poti do
         konca zgodbe. Uganke je prav tako moc resiti na vec nacinov. In tudi samih koncev je
         lahko mnogo, pac odvisno od tega, kako bralec vodi protagonista; lep primer je
         fantasticna igra ~Slouching Towards Bedlam~ (Star C. Foster, Daniel Ravipinto, 2003),
         ki nudi cel vencek razlicnih zakljuckov. Ni torej nujno, da bo vsako branje (igranje)
         istega dela potekalo povsem enako - za razliko od vsakega pisanega romana, ki se vedno
         bere naravnost od zacetka do konca.^";	

Option	-> "NEKAJ BESED O SLOVENSKEM PREVODU JEZIKA ~INFORM~"
  with 	description
        "Inform je leta 1993 napisal Graham Nelson, od tedaj pa je ta programski jezik postal
         tako rekoc standard na podrocju jezikov za pisanje interaktivne fikcije. Jezik je
         nadvse intuitiven in preprost, a kljub temu omogoca izdelavo tudi najtezjih in
         najkompleksnejsih ugank in zgodb.^
         ^
         Obstaja tudi mnogo prevodov programa v tuje jezike (nemscina, italijanscina,
         francoscina), sam pa sem se dobro leto poigraval z idejo, da bi ga prevedel se v
         slovenscino. Naloga se je sprva zdela nemogoca zaradi izjemne pestrosti nasega
         jezika (skloni, dvojina itd.), vendar je navsezadnje cilj prav z izdajo te igre
         koncno le dosezen!^
         ^
         Za programski paket Inform sta bila tako napisani dve knjiznici, ki definirata
         slovenski jezik:^
         ^
         SLOVENIAN.H je t.i. ~language definition~ datoteka. V njej je zapisano prakticno
         vse, kar program izpisuje na zaslon. Smeri neba, stevila, razni privzeti odgovori
         in se in se.^
         ^
         SLOVENIANG.H pa je t.i. ~grammar table~ datoteka. V njej so definirani vsi glagoli
         in njihova gramatika, torej s cim se vezejo, katere predloge uporabljajo itd.^
         ^
         Prevod je zahteval tudi nekaj novih rutin in pomembnih pravil. Natancen opis in
         navodila lahko najdes v pdf knjizici ~Slovenska interaktivna fikcija~, ki se
         nahaja na domaci strani slovenske interaktivne fikcije
         (http://sloif.freehost386.com).^";

Option  -> "V CEM JE POANTA IGRE ~ZENIN NA BEGU~"
  with  description
        "Igra ~Zenin na begu~ je neke vrste demonstrativna igra. Njen glavni cilj
         je predstaviti delovanje slovenskih knjiznic ter nacin igranja slovenske
         interaktivne fikcije.^
         ^
         Prav zaradi tega je kot taka povsem banalna in klisejska. Zgodba je trivialna,
         glavna uganka pa klasicna ~mati vseh ugank~ -- problem zaprtih vrat. Igra tudi
         rahlo spominja na eno izmed scen iz dolocenega filma skupine Monty Python,
         hkrati pa mocno disi se po Aladinu.^
         ^
         Druga funkcija igre pa tici v testiranju omenjenih knjiznic. V tem drobnem svetu
         je namrec kar nekaj predmetov, ki imajo med drugim tudi nekoliko bolj kocljive
         atribute 'container', 'supporter' in 'enterable'. Prav tako predmeti obsegajo vse
         spole in tudi mnozino. Na igralcu je torej, da cim vec eksperimentira s celotnim
         svetom, poskusa cudne kombinacije, polaga stvari eno vrh druge itd. In ce najde
         v igri vsaj enega hrosca, je cilj dosezen!^";

Menu	-> "HITRA SOLA INTERAKTIVNE FIKCIJE";

Option  -> -> "UVOD"
  with  description
        [;
           print
        "Interaktivna fikcija je precej intuitiven medij, ki zahteva le nekaj malega razlage
         in navodil. Bralec (igralec) mora zgolj prebirati opise stvari in dogodkov, ki se
         izpisujejo na zaslonu, nato pa v velelniku vtipkati ukaz protagonistu.^
         ^
         Ko program caka na nov ukaz, je na zaslonu izpisan znak ~>~. Igra takrat povsem
         miruje, ura kot bi bila ustavljena. Sele potrditev novega ukaza premakne cas
         naprej in sprozi reakcije.^
         ^
         V nadaljevanju sledi kratka predstavitev najpomembnejsih glagolov. Zaradi boljse
         preglednosti bodo vsi ukazi napisani z velikimi tiskanimi crkami, ceprav za igranje
         to nikakor ni pogoj. Program pravzaprav sploh ne razlikuje med velikimi in malimi
         crkami.^
         ^
         Omeniti velja se to, da program ne podpira sumnikov. Namesto teh torej pisi zgolj
         navadne 'c', 's' in 'z'.^";
           style underline;
           print

        "^^(Popoln vodnik skozi igro ~Zenin na begu~ najdes v dodatku B pdf knjizice ~Slovenska
         interaktivna fikcija~, ki se nahaja na domaci strani slovenske interaktivne fikcije
         (http://sloif.freehost386.com))^^";
           style roman;
        ];

Option  -> -> "RAZISKOVANJE OKOLICE"
  with	description
        "Raziskovanje sveta okrog sebe je najpomembnejsa stvar pri vsem skupaj. Prav nic namrec
         ne mores poceti s tistim, cesar ne vidis. Dobro opazovanje in raziskovanje prostorov
         je torej bistvenega pomena.^
         ^
         Posebej pomembna sta dva ukaza. Prvi je:^
         ^
         > OPIS LOKACIJE^
         ^
         Oziroma skrajsano:^
         ^
         > O^
         ^
         Ta ukaz izpise polni opis prostora, v katerem se trenutno nahaja protagonist. V
         opisih lokacij so mnogokrat omenjeni predmeti, ki igrajo pomembno vlogo v zgodbi,
         zato jih je priporocljivo vedno pozorno prebrati.^
         ^
         Drugi ukaz pa opise poljuben predmet, na primer:^
         ^
         > POGLEJ ...^
         ^
         (Tropicje predstavlja poljuben predmet v igri.) Tudi ta ima svojo okrajsavo, in
         sicer:^
         ^
         > P ...^
         ^
         Nenapisano pravilo narekuje, naj se vedno pregleda prav vsak objekt v lokaciji. Opis
         namrec mnogokrat skriva dodatne informacije in namige, brez katerih je zgodba vsaj
         manj zanimiva, ce ne celo neresljiva.^
         ^
         Poleg teh dveh standardnih ukazov so na voljo tudi kombinacije s predlogi, ki
         ponujajo se dodatne moznosti:^
         ^
         > POGLEJ V ...^
         > POGLEJ NA ...^
         > POGLEJ POD ...^
         > POGLEJ SKOZI ...^
         ^
         In tako dalje. Natancno raziskovanje prostorov mora igralcu cim prej zlesti pod
         kozo.^
         ^
         Na koncu pa je potrebno omeniti se en pomemben ukaz, to je:^
         ^
         > INVENTAR^
         ^
         Oziroma skrajsano:^
         ^
         > I^
         ^
         Ta ukaz izpise vse predmete, ki jih ima protagonist trenutno v svoji lasti. Nekatere
         igre glavnemu liku ze takoj na zacetku polozijo v narocje dolocene reci, zato je
         ta ukaz smiselno sproziti ze kot cisto prvo dejenje nove igre.^
         ^
         Ukaz ima dve razsiritveni moznosti:^
         ^
         > INVENTAR POKONCNO^
         ^
         Ta ukaz inventar vedno izpisuje v pokoncni, ~drevesni~ obliki. Potem je tu se:^
         ^
         > INVENTAR LEZECE^
         ^
         Ki izpisuje inventar v obliki tekoce povedi. Nobena izmed teh dveh opcij nima
         nikakrsnega vpliva na zgodbo, gre zgolj za kozmeticni detajl.^";

Option	-> -> "PREMIKANJE MED PROSTORI"
  with  description
        "Svet v interaktivni fikciji je navadno razdeljen na vec medsebojno povezanih
         prostorov oziroma lokacij. V zargonu tem lokacijam pravimo kar ~sobe~, ceprav nikakor
         ni nujno, da gre v resnici za stiri stene (soba je npr. lahko tudi gozd, votlina
         itd.).^
         ^
         Med lokacijami se premikamo s pomocjo smeri neba. Ce lezi soba B vzhodno
         od sobe A, potem lahko iz sobe A v sobo B pridemo z naslednjim ukazom:^
         ^
         > POJDI PROTI VZHODU^
         ^
         Ker je premikanja med prostori navadno precej, ima ukaz tudi precej krajso obliko:^
         ^
         > V^
         ^
         Podobno velja za vse ostale smeri (S, J, V, Z, SV, SZ, JV, JZ).^
         ^
         Poleg glavnih osmih smeri pa obstajajo se stiri dodatne, to so GOR, DOL, VEN in
         NOTER, ki prav tako pogosto pridejo v postev.^
         ^
         Za igranje vecjih iger z mnogo sobami je nadvse priporocljivo, da si igralec
         sproti rise zemljevid lokacij. Kvadratek z imenom ene lokacije, crta na pravi
         strani ter kvadratek z imenom druge lokacije ze povsem ustrezajo. Tako je
         zagotovljen dober pregled nad svetom v igri in tudi potovanje med sobami je
         preprostejse.^
         ^
         Dodaten razlog za risanje zemljevida pa predstavlja dejstvo, da se nekatera dela
         ne drzijo tocno geografskih pravil. Ce torej iz sobe A prides v sobo B tako, da
         gres proti vzhodu, ni nujno, da bos iz sobe B prisel nazaj v sobo A tako, da bos
         sel proti zahodu (tak je npr. kultni Infocomov ~Zork~). Ob vecji mnozici lokacij s
         takimi ~zavitimi~ prehodi se torej lahko hitro izgubis.^";

Option  -> -> "INTERAKCIJA S PREDMETI"
  with  description
        "Program vsebuje kar impresivno paleto razlicnih ukazov, ki vedno sprozajo
         reakcije, pa tudi ce te le opominjajo, da izgubljas cas. Nastejmo jih le nekaj:^
         ^
         > ODPRI ...^
         > ZAPRI ...^
         > RAZREZI ...^
         > POTEGNI ...^
         > POTISNI ...^
         > PREBERI ...^
         > PREISCI ...^
         > PRIZGI ...^
         > IZKLJUCI ...^
         > SPLEZAJ NA ...^
         > POJDI V ...^
         ^
         Nekatere zahtevajo tudi dva predmeta, povezana s predlogom:^
         ^
         > ODKLENI ... Z ...^
         > ZAKLENI ... Z ...^
         > IZVLECI ... IZ ...^
         > VSTAVI ... V ...^
         > POSTAVI ... NA ...^
         > POSTAVI ... V ...^
         > PREBERI O ... V ...^
         ^
         In tako dalje. V dobro programirani interaktivni fikciji bi naceloma morala
         delovati vsaka logicna stvar. Prav tako lahko nastopa tudi kak glagol, ki je sicer
         nepoznan v vecini ostalih del, zato pa v doticni situaciji zelo smiseln (npr.
         FOTOGRAFIRAJ, PRIPNI ali kaj podobnega).^
         ^
         Na koncu pa sta tu se dva posebna ukaza, ki ne spadata dobro v nobeno od kategorij.
         Prvi ponovi katerokoli predhodno dejanje:^
         ^
         > PONOVI^
         ^
         Oziroma krajse:^
         ^
         > N^
         ^
         Drugi pa enostavno ne naredi nicesar, a vseeno porabi svojo potezo:^
         ^
         > CAKAJ^
         ^
         Oziroma krajse:^
         ^
         > C^
         ^";

Option  -> -> "INTERAKCIJA Z ZIVIMI BITJI"
  with  description
        "Pravila za interakcijo z zivimi bitji so podobna tistim za predmete, s tem da tu
         nastopa se nekaj dodatnih ukazov.^
         ^
         Od ostalih likov v igri navadno prejemamo informacije, zato je najvaznejsi ukaz:^
         ^
         > VPRASAJ (NPC) O ...^
         ^
         (NPC predstavlja poljubno zivo bitje.) Podobno lahko informacije tudi ponujamo:^
         ^
         > POVEJ (NPC) O ...^
         ^
         Vcasih lahko zivim bitjem tudi ukazujemo, pri cemer moramo uporabiti naslednjo
         obliko:^
         ^
         > (NPC), ...^
         ^
         Vejici sledi povsem enak ukaz, kot bi ga normalno vtipkali protagonistu. Ce bi torej
         hoteli, naj Marija zleze na stol, bi vtipkali:^
         ^
         > MARIJA, STOPI NA STOL^
         ^
         Koncno pa lahko ostalim likom v igri tudi podarimo oziroma pokazemo kak predmet:^
         ^
         > DAJ ... (NPC)^
         > POKAZI ... (NPC)^
         ^";

Option  -> -> "METAUKAZI"
  with  description
        "Interaktivna fikcija vsebuje tudi mnozico tako imenovanih ~metaukazov~.
         Ti ukazi niso namenjeni protagonistu zgodbe, pac pa bralcu
        (igralcu). Prav tako ne porabijo nobene poteze oziroma casa.^
        ^
        a) Z igranjem lahko kadarkoli koncamo in zacnemo od zacetka z ukazom:^
        ^
        > ZACNI ZNOVA^
        ^
        b) Potem sta tu ukaza:^
        ^
        > SHRANI^
        > NALOZI^
        ^
        Prvi shrani trenutno pozicijo v zgodbi, ce zelimo na primer prekiniti z igranjem,
        drugi pa jo kasneje priklice nazaj. Tako nam velikih zgodb ni treba odigrati naenkrat
        od zacetka do konca, pac pa si jih razbijemo na manjse etape.^
        ^
        c) Kadarkoli sredi igre si lahko ogledamo trenutno stevilo tock z ukazom:^
        ^
        > TOCKE^
        ^
        Podroben seznam tock ponuja ukaz:^
        ^
        > TOCKOVNIK^
        ^
        d) Opombe tockovanja, ki jih prejemamo med igro, lahko po zelji izkljucimo oziroma
        vkljucimo z ukazoma:^
        ^
        > OPOMBE IZKLJUCENE^
        > OPOMBE VKLJUCENE^
        ^
        e) Spremenimo lahko tudi nacin prikazovanja opisov lokacij. Prvi nacin vedno izpise
        polne opise lokacij. Drugi nacin izpise polni opis le takrat, ko vstopimo v novo,
        se nepoznano lokacijo. Tretji nacin pa polnih opisov sploh nikoli ne izpisuje
        (seveda lahko opis kadarkoli priklicemo tudi z ukazom OPIS). Omenjeni trije nacini
        po vrsti so:^
        ^
        > GOSTOBESEDNO^
        > OPISNO^
        > OKRNJENO^
        ^
        f) V igri ima vsak objekt prirejeno svojo mnozico ustreznih zaimkov, ki se jih
        lahko posluzujemo namesto daljsih imen. Trenutna nanasanja zaimkov si ogledamo z:^
        ^
        > ZAIMKI^
        ^
        g) Nazadnje pa je tu se ukaz, s katerim povsem zapustimo igro in se vrnemo v operacijski
        sistem:^
        ^
        > IZHOD^
        ^";

Option  -> -> "KORISTNI NAPOTKI IN NAMIGI"
  with  description
        "Program naceloma razume tudi bolj kompleksne ukaze, kot je na primer:^
        ^
        > VZEMI VSE IZ VELIKE KOSARE RAZEN JABOLKA IN HRUSKE NATO POJEJ SLIVO^
        ^
        Vendar pa je bolje, da so ukazi cim bolj kratki in preprosti. Prav tako je dobro,
        da se uporabljajo predvsem glavna imena predmetov (~velika bela miza~ naj se klice
        zgolj kot ~miza~ itd.).^
        ^
        Kadar program cesa ne razume, poizkusi ukaz zapisati drugace. Uporabi kak drug glagol,
        ki bi lahko prav tako ustrezal. Resitve so pogosto nadvse preproste.^
        ^
        In ce obticis pri kaki uganki, ne obupaj. Vcasih pomaga, da enostavno pojdes stran od
        igre za nekaj casa. Pocni kaj drugega -- ideja se ti morda utrne nekje cisto drugje.^";

Option	-> "LOV NA HROSCE"
  with  description
        "Kot receno, ta igra je med drugim namenjena tudi testiranju novih slovenskih knjiznic
         Slovenian.h in SlovenianG.h. V njih se gotovo skriva se nekaj hroscev raznih
         oblik in velikosti.^
         ^
         Najprej so tu napake v crkovanju.^
         ^
         Potem je morda kje implementiran napacen sklon.^
         ^
         Morda tu in tam odpove tudi glagol 'biti' v razlicnih stevilih (je/sta/so).^
         ^
         Ce torej naletis na eno izmed zgornjih napak, ali pa sploh na karkoli cudnega,
         prosim, poslji porocilo na avtorjev e-naslov oziroma na naslov uradne spletne strani
         prevoda (sloif@@64yahoo.com). Napisi tudi, kako si do napake prisel (katere ukaze si
         uporabljal in v povezavi s katerimi predmeti).^
         ^
         Hvala!^";

Option  -> "ZAHVALE"
  with  description
        "V prvi vrsti gre zahvala GRAHAMU NELSONU, avtorju odlicnega programskega jezika
         INFORM.^
         ^
         Nadalje cast in slava vsem originalnim implementorjem iz INFOCOMA (Bob Bates,
         Steve Meretzky, Brian Moriarty...), ki so prakticno iznasli medij interaktivne
         fikcije.^
         ^
         Nenazadnje pa najlepsa hvala tudi moji sestri FRANJI za vso pomoc in
         vzpodbudo!^";