@title Reencuentro
@start Inicio
[[PUNTAJE]]:
| {seccion} |
Puntaje: {puntaje} |
[[Encabezado textadventures]]:
Reencuentro
Visita su página web
[[Inicio]]:
@set mision=0
@set sistema=0
@set traje=0
@set advertencia=0
@set registro=0
@set criatura_laguna=0
@set inteligencia=0
@set puntaje=0
@set muerte=0
@set textadventures=0
{if textadventures=0:Reencuentro
}{else:{Encabezado textadventures}}
versión 01.01.02
El camino al reencuentro
No siempre es corto
Y a veces es difícil
Pero es un camino hermoso
Y merece ser andado
Comienza, pues, a [[recorrerlo]](astronave)...
[[descripcion mision]]:
Nos costó un par de desastres el aprenderlo, pero cuando una colonia llega a un cierto número de habitantes se hace obligado buscar nuevos mundos habitables para crear nuevas colonias o de lo contrario las condiciones de vida se vuelven agobiantes en cosa de un par de siglos.
[[astronave]]:
@clear
@set seccion=Astronave
{PUNTAJE}
La [computadora de a bordo] me despertó del [criosueño] hace algunas horas, sabiendo que me tomo [mi tiempo] para ponerme razonablemente alerta.
Es la tercera parada de [mi turno] en [misión de exploración] y espero que sea algo mejor que las dos [anteriores].
Con algo de ansiedad, me aproximo a uno de los visores. Podría comenzar pidiéndole a la computadora una [[vista externa]] o bien ir directamente a la [[vista de datos]](promisorio).
[computadora de a bordo]:
Una inteligencia muy considerada y amable, por cierto, pero más bien inflexible a la hora de cumplir con los parámetros de la misión.
[criosueño]:
Los viajes estelares son demasiado [prolongados] y las distancias demasiado largas como para que sea práctico o sano hacer la travesía despiertos.
[prolongados]:
No espero al volver encontrar vivo a nadie que yo recuerde, ni siquiera los niños. A mi regreso estoy cierto que se me acogerá y respetará como un miembro valioso de la comunidad, pero socialmente tendré que partir de cero.
[mi tiempo]:
No importa si es sueño normal o criosueño, recién despierto no sirvo para nada... haya [ingerido] algo no.
[ingerido]:
Acabo de tomar algunos [alimentos] y como sea que mi estómago no se ha comportado mal, creo que estoy listo para ver dónde nos hemos detenido.
[alimentos]:
Sólo se recomiendan líquidos los primeros días después del criosueño y la verdad es que nunca me ha gustado demasiado la comida... ejem... sólida.
[mi turno]:
Aunque se supone que hay algo de azar, la verdad es que los individuos que destacamos en ciertos campos damos por sentado que en algún momento nos ha de tocar participar en una o más misiones de exploración. Si todo sale bien, tendré un buen pasar y algo de tranquilidad volviendo a casa... entre misiones, claro está.
[misión de exploración]:
@inc mision
{descripcion mision}
[anteriores]:
Uno de los mundos resultó tener vida inteligente en estado neolítico y el otro planeta estaba comenzando a desarrollar su agricultura. Nada de eso podía saberlo la computadora y tuve suerte en descubrirlo antes de haber cambiado la mitología o, peor aún, la historia local.
[[vista externa]]:
@clear
{PUNTAJE}
El visor se aclara gradualmente y veo que estamos en un sistema con un [sol amarillo]. Resulta algo [chocante] a primera vista, pero no es desagradable de ver, aunque me costaría acostumbrarme a vivir en un lugar así.
La estrella local es lo de menos, en todo caso, pues el conjunto planetario es sumamente particular: algunos planetas [gaseosos gigantes], un nutrido [cinturón de asteroides](asteroides) y algunos cuerpos menores en órbita cercana al sol, uno de los cuales debió [parecerle interesante](interesante) a la computadora, pues estamos orbitándolo.
Y la verdad es que, teniendo en cuenta los objetivos de la {if mision=0:[misión](mision)}{else:misión}, parece [[promisorio]].
[sol amarillo]:
Vaya. Pensaba que eso de las estrellas amarillas eran puras fábulas, pero se ve que los astrofísicos no bromeaban cuando nos prepararon para la misión.
[mision]:
@inc mision
{descripcion mision}
[chocante]:
Sé que el universo es un lugar muy grande y todos los lugares son diferentes, pero la colonia en que me crié tenía un sol verde y para mi eso es lo normal. En fin...
[gaseosos gigantes]:
Hay no menos de cuatro, número más bien elevado para un sistema planetario típico.
[asteroides]:
Probablemente restos de otro planeta, cosa que he visto en algunas simulaciones de escenarios posibles de la misión. Curioso, en todo caso, que aun subsista en compañía de los gigantes de gas.
[interesante]:
Los protocolos de selección de mundos de la misión son demasiado complejos para que yo los entienda. La computadora prescinde de la tripulación para esas y otras decisiones... y nos costaron las vidas de muchas tripulaciones el llegar a implementar estas directivas.
[[promisorio]]:
@clear
{PUNTAJE}
Es un mundo con muchísima [agua] y con unos continentes que apenas están [algo separados].
Por los [datos flotantes] en el visor, hay mucha vida animal y vegetal allí abajo, pocos desiertos y, cosa importante, ningún indicio de [tecnología] de ningún tipo.
Un mundo candidato para colonizar, entonces: la computadora [no se equivocó] al despertarme, pues será necesario que haga un reconocimiento en terreno.
Hay un pequeño problema, por supuesto.
Y es que, por más que [manipulo] los datos del visor, no parece que haya un sitio idóneo para descender con la nave: la gravedad es más bien intensa y la atmósfera no es especialmente tenue, para no hablar del clima, que lo es todo [menos tranquilo].
No queda otra que bajar en un [[módulo individual]](capsula)
[agua]:
Varios océanos cubren más de tres cuartas partes de la superficie. No es muy habitual encontar mundos tan bien provistos de agua.
[algo separados]:
La deriva continental debe ser muy reciente, así que se trata de un mundo más bien joven.
[datos flotantes]:
He preferido holografías a implantarme sensores oculares. Es algo más trabajoso para leer los datos, pero al menos así me pican menos los ojos...
[tecnología]:
Si hay agricultura, está muy hábilmente oculta en la vegetación natural.
[no se equivocó]:
Rara vez se equivoca, pero cuando lo hace... mejor no pensar en eso.
[manipulo]:
Los toco, los huelo, los volteo... nada, las lecturas no cambian.
[menos tranquilo]:
Hay hasta huracanes y tornados aquí y allá.
[[descripcion traje]]:
Una sola pieza cubre todo excepto el rostro. Permite sortear toda clase de terrenos y climas extremos, aunque no incluye propulsores para {if seen quebrada:volar}{else:volar} o {if seen laguna:nadar}{else:{if seen cienaga inicio:nadar}{else:nadar}}. Se supone que en caso de tragedia consume al usuario y no deja rastro alguno, pero prefiero no pensar en eso.
[[capsula]]:
@clear
{PUNTAJE}
No se ve particularmente riesgoso, en principio: la atmósfera es respirable, la gravedad no se ve [muy desafiante] y el terreno en que descenderé [no parece malo].
Con un suspiro, tomo uno de los [trajes de campo](traje) y mientras me lo pongo le pido más detalles del itinerario a la computadora.
Por lo visto, tendré que recorrer una llanura y acercarme a los lindes de un bosque y de un pantano, lo que en principio debiera permitir tomar datos de las distintas formas de vida típicas.
Si algo de lo que encontremos no resulta [auspicioso], se marcará el mundo como reserva natural y sólo será posible visitarlo bajo estrictas condiciones de preservación. Por el contrario, si todo sale bien, se programará un [misión beta] para hacer una exploración más profunda de cara a una posible colonización.
Ya vestido, me tiendo en el suelo y, con un suspiro, la cubierta [me envuelve](materialidad) formando una [[cápsula de aterrizaje]](aterrizaje).
[muy desafiante]:
Al menos podré caminar normalmente: resulta agotador eso de controlar los pasos para no salir volando o tener que arrastrarse casi aplastado por el peso del aire...
[no parece malo]:
Desde la órbita, por supuesto, nada parece malo. Una vez abajo, las cosas suelen cambiar.
[traje]:
@inc traje
{descripcion traje}
[auspicioso]:
No todas las plantas serán necesariamente inocuas, para no hablar de la fauna local, que ha causado más de algún problema aquí y allá. De hecho, se dice que... pero no, no hagamos caso de [rumores].
[rumores]:
El universo es un lugar peligroso de veras y no diré más.
[misión beta]:
La mía es una de las tantísimas {if mision=0:[misiones alfa](mision)}{else:misiones alfa} de exploración inicial, con los recursos justos para observar y notificar. Con un solo tripulante está fuera de discusión el análisis y la investigación que se requieren para llegar a considerar un mundo como posible colonia.
[mision]:
@inc mision
{descripcion mision}
[materialidad]:
La materialidad del interior de la nave es sumamente fluida, lo que permite al explorador y a la computadora [adaptar] su configuración a múltiples perfiles de funcionamiento.
[adaptar]:
El desgaste o pérdida de material se repone con prácticamente cualquier cosa, pero no será mala idea recoger más tarde un par de asteroides y reciclarlos.
[[aterrizaje]]:
@set seccion=Aterrizaje
@clear
{PUNTAJE}
Despierto algo dolorido: la cápsula hizo su trabajo y sigo entero, pero el color de las luces que [parpadean] a mi alrededor no parecen augurar nada bueno.
Al menos estoy en posición horizontal y en contacto con el suelo: podría haber [sido peor].
Me apoyo para levantarme y la cápsula se abre para dejarme salir.
Doy [mi primer paso] en un mundo nuevo... y noto que el suelo está algo caliente pero, a juzgar por lo que veo al erguirme, es lo de menos.
Por lo visto, los retrocohetes y el sistema antigravedad no sirvieron de nada, pues la cápsula hizo contacto con el suelo y se arrastró lo suyo antes de detenerse.
Bueno, no es más que un mal comienzo: más vale empezar la {if mision=0:[misión](mision)}{else:misión}, así que me dispongo a salir del [[surco que dejó la cápsula]](surco).
[parpadean]:
Son luces de alerta, aunque no parece que haya peligro inmediato.
[sido peor]:
En la última misión desperté al borde de un barranco. No fue divertido, la verdad.
[mi primer paso]:
Se supone que debo decir algo memorable, pero francamente no estoy de humor.
[mision]:
@inc mision
{descripcion mision}
[[descripcion sistema]]:
Mi sistema de información personal es sumamente sencillo pero es funcional y muy robusto, cosa que en este momento es de agradecer.
[[surco]]:
@clear
{PUNTAJE}
Mientras me alejo, la cápsula comienza a desmoronarse y pronto no queda sino [un polvillo] que apenas se distingue del suelo.
Tras andar un trecho, descubro que efectivamente he aterrizado en una llanura...
...pero el [módulo de ascenso] que debió bajar conmigo no se ve por parte alguna.
Preocupado, doy un vistazo a [mi muñeca] y, con alivio, veo que hay una señal de advertencia encendida: el módulo está intacto aunque, al igual que la cáspula, tuvo un aterrizaje "fuera de los parámetros de descenso".
Según me informo, el vehículo está a una buena distancia de mi posición actual y deberé hacer un viaje [no menor] para reencontrarme con él.
Bueno, mi objetivo de descenso era precisamente hacer reconocimiento del terreno y recoger información de la flora y fauna, cosa que sin duda deberé hacer si quiero llegar hasta el módulo de ascenso.
Así pues, me pongo a andar resueltamente y, dejando atrás el surco del aterrizaje, comienzo a avanzar por la llanura.
Se trata de un enorme pastizal que se extiende en todas direcciones, aunque pareciera que [hay algo] más adelante.
Conforme avanzo por la planicie, titubeo entre [[recorrerla rápidamente]](llanura rápido) o bien ir con calma y [[disfrutar del paisaje]](llanura lento).
[un polvillo]:
Al igual que el {if traje=0:[traje]}{else:traje} que llevo puesto, toda la tecnología usada en las exploraciones planetarias está diseñada para no dejar rastro alguno de nuestro paso.
[traje]:
@inc traje
{descripcion traje}
[módulo de ascenso]:
Las primeras {if mision=0:[misiones de exploración](mision)}{else:misiones de exploración} usaron vehículos únicos para aterrizar y despegar. La experiencia demostró que era más seguro separar los componentes del transporte de descenso según la función.
[mision]:
@inc mision
{descripcion mision}
[mi muñeca]:
@inc sistema
{descripcion sistema}
[no menor]:
Tengo ante mí por lo menos unas 6 horas de caminata, salvo alguna pausa o demora.
[hay algo]:
Una masa importante de vegetación, parece. Estoy demasiado lejos aún para distinguir detalles.
[[descripcion vibracion]]:
Me ha estremecido de pies a cabeza: la sacudida es muy eficaz, pero algo incómoda.
[[llanura rápido]]:
@clear
@set seccion=Llanura
{PUNTAJE}
Me ha costado muy poco entrar en el régimen mental de exploración profunda: aunque sigo avanzando y [hablando] de manera clara y ordenada, mi mente comienza a divagar y a establecer ideas [muy complejas], casi como si estuviera soñando despierto.
Tan ensimismado estoy que, sin darme apenas cuenta, ha pasado una hora y el traje me "despierta" con una [vibración seca], llamando mi atención a que hemos llegado al [[final de la llanura]](llanura mitad).
[hablando]:
@inc registro
Nuestro entrenamiento tiene mucho de habilidades narrativas, ya que los dispositivos de registro de información del {if traje=0:[traje]}{else:traje} siguen tanto la voz como los movimientos del explorador. Menuda tarea sería si, además de sortear el terreno, tuviera que estar tomando notas o capturando imágenes...
[muy complejas]:
En el entrenamiento me dieron a entender que esto también queda registrado en el sistema de información del {if traje=0:[traje]}{else:traje}, aunque no supieron explicarme como... ni para qué.
[traje]:
@inc traje
{descripcion traje}
[vibración seca]:
@inc advertencia
{descripcion vibracion}
[[llanura lento]]:
@clear
@set seccion=Llanura
{PUNTAJE}
Mientras voy caminando, observo atentamente y [comento en voz alta](hablando) todo lo que me parece de interés: la forma y colores de las hojas de hierba, textura y apariencia de las piedras, el aspecto de algunos insectos que salen volando o arrastrándose a mi paso... en fin, el paisaje según se despliega a mi alrededor.
El aire, por cierto, está límpido y es particularmente [estimulante] el respirarlo; otro tanto ocurre con el cielo, de un [color azul] de intensidad tal que pareciera tener sobre mí una [bóveda](boveda) casi sólida.
Me ha costado muy poco entrar en el régimen mental de exploración profunda: aunque sigo avanzando y hablando de manera clara y ordenada, mi mente comienza a divagar y a establecer ideas [muy complejas], casi como si estuviera soñando despierto.
Tan ensimismado estoy que, sin darme apenas cuenta, ha pasado una hora y el traje me "despierta" con una [vibración seca], llamando mi atención a que hemos llegado al [[final de la llanura]](llanura mitad).
[hablando]:
@inc registro
Nuestro entrenamiento tiene mucho de habilidades narrativas, ya que los dispositivos de registro de información del {if traje=0:[traje]}{else:traje} siguen tanto la voz como los movimientos del explorador. Menuda tarea sería si, además de sortear el terreno, tuviera que estar tomando notas o capturando imágenes...
[estimulante]:
En nuestras colonias, los ambientes están demasiado cuidados y sanitizados, al punto de resultar algo sosos. Aquí, el ataque olfativo llega a ser casi embriagador.
[color azul]:
Es una tonalidad muy distinta al violeta anaranjado de mi colonia natal, pero no es repulsivo. Tiene, cosa curiosa, un efecto más bien relajante.
[boveda]:
Algunas colonias son de hecho abovedadas, pero es que en esto de la higiene se han llegado a veces a extremos rídiculos.
[muy complejas]:
En el entrenamiento me dieron a entender que esto también queda registrado en el sistema de información del {if traje=0:[traje]}{else:traje}, aunque no supieron explicarme cómo... ni para qué.
[traje]:
@inc traje
{descripcion traje}
[vibración seca]:
@inc advertencia
{descripcion vibracion}
[[llanura mitad]]:
@clear
{PUNTAJE}
La llanura me ha llevado hasta el borde exterior de un bosque inmenso y sumamente tupido. Se ve poca luz más allá de los lindes exteriores, así que los árboles han de estar muy apretados y altos. Un terreno [difícil de penetrar](penetrar), sin duda.
Por el costado exterior de la foresta se ve un extenso pantano al que le llega buena luz, aunque aquí y allá se ven algunos bancos de niebla... o de gas, no hay que descartarlo. Es un camino algo menos accidentado, aunque [ha de tener sus riesgos](riesgos).
Hay que decidirse, entonces: atravesar el [[bosque]](bosque inicio) o avanzar por la [[ciénaga]](cienaga inicio).
[penetrar]:
Se nos adivirtió repetidamente en nuestro entrenamiento que hay que desconfiar de los lugares de vegetación densa, tanto por las plantas en sí mismas como por los animales que suelen esconderse en ellas. Estar alerta todo el tiempo se vuelve vital... y agotador.
[riesgos]:
Mis instructores decían que una ventaja de avanzar por un pantano es que los peligros están debajo o delante, pero se los ve venir de lejos y rara vez son una sorpresa. No sé porqué, pero eso no me tranquiliza ahora mismo.
[[bosque inicio]]:
@clear
@set seccion=Bosque
{PUNTAJE}
Al poco andar por el lugar comienzo a reevaluar mi apreciación inicial: esto, más que bosque, parece una verdadera [selva].
Los [árboles] son imponentes, hay [arbustos] por todas partes y [lianas] colgando de las [ramas altas]. La luz, por otra parte, es [escasa], hace bastante calor y hay no poca humedad, pero no llega a ser [desagradable].
Un [[movimiento]](lemures) en uno de los árboles atrae mi atención, pero por otra parte parece haber algo más de claridad allá adelante y quizás sería mejor seguir [[avanzando]](laguna).
[selva]:
He echado mano a mi entrenamiento para identificar este bioma: jamás he estado en un lugar así y muy pocas colonias tienen estos paisajes.
[árboles]:
Crecen muy altos, con troncos ora gruesos o delgados.
[arbustos]:
Los llamo así para distinguirlos de los árboles, pero algunos son el doble de altos que yo.
[lianas]:
Algunas son tan gruesas como ramas, pero cuelgan de maneras más bien antojadizas y se mueven con el aire.
O eso parece.
[ramas altas]:
Las ramas más elevadas apenas se distinguen más arriba y se adivinan por las sombras y poco más.
[escasa]:
Aunque aquí y allá se ve algún rayo de sol, en general camino en una especie de penumbra.
[desagradable]:
El {if traje=0:[traje]}{else:traje} hace lo que puede con las condiciones del clima, pero no es perfecto. Sin embargo, me encuentro extrañamente a gusto...
[traje]:
@inc trajeV
{descripcion traje}
[[lemures]]:
@clear
@inc puntaje
{PUNTAJE}
En las ramas de uno de los árboles distingo un grupo de animales que están comiendo algo que podrían ser [frutas].
Son más o menos del porte de mi brazo, con cuerpo, miembros y cola más bien [delgados], todo cubierto de [pelos]. Sus ojos están hacia el frente y tienen unas bocas y narices algo pequeñas. El efecto del conjunto resulta divertido, pero no se me ocurriría [acercarme demasiado] para saber más.
Mientras he estado relatando esto {if registro=1:en voz alta}{else:[en voz alta](hablando)} para el registro, las criaturas se han quedado muy quietas y me han dedicado unas miradas decididamente [inquisitivas].
Contento por mi descubrimiento, decido volver a moverme hacia [[la claridad más adelante]](laguna).
[frutas]:
O eso parecen.
Salvo mi entrenamiento y algún registro documental antiguo, nunca había visto una.
[delgados]:
Usan sus extremidades con mucha destreza, valiéndose alternativamente de una u otra para coger fruta o aferrarse a las ramas.
[pelos]:
Aparte de la cara y bajo las manos y pies, no hay epidermis a la vista. El pelaje es de un color uniforme, salvo la cola, que tiene unas curiosas manchas casi como anillos.
[acercarme demasiado]:
Las instrucciones del entrenamiento son sumamente claras y explícitas: salvo auto preservación, evitar a toda costa el contacto con seres vivos, máxime si están en grupos.
[hablando]:
@inc registro
Nuestro entrenamiento tiene mucho de habilidades narrativas, ya que los dispositivos de registro de información del {if traje=0:[traje]}{else:traje} siguen tanto la voz como los movimientos del explorador. Menuda tarea sería si, además de sortear el terreno, tuviera que estar tomando notas o guardando imágenes...
[traje]:
@inc traje
{descripcion traje}
[inquisitivas]:
Por lo visto, en este mundo ya hay especies en el camino de la elevación a la inteligencia. Será cosa de algunos millones de años, pero es un fenómeno que una vez iniciado, rara vez [se detiene].
[se detiene]:
Salvo algún evento masivo de extinción, claro está. Nosotros mismos, de hecho, apenas escapamos de una catástrofe sideral y eso fue lo que nos lanzó a las estrellas.
[[laguna]]:
@clear
{PUNTAJE}
He llegado a la orilla de una laguna bien ancha.
Las aguas son más bien [verdosas] y turbias, pero a la fauna local han de resultarle atractivas, pues nada más entrar he visto movimientos en las plantas colindantes, con ruidos que sólo hacen los animales cuando [huyen asustados].
Me he acercado a la orilla más próxima para ver qué tan profunda es el agua, pero una {if advertencia=1:vibración seca}{else:[vibración seca]} del {if traje=0:[traje]}{else:traje} me detiene oportunamente: bajo la superficie del líquido se adivinan algunos [movimientos inquietantes](criatura laguna)... y yo retrocedo rápido unos cuantos pasos.
Así las cosas, no queda otra opción que rodear la laguna, ya sea por la [[espesura izquierda]](ribera izquierda), particularmente a oscuras o bien por [[unos pastos a la derecha]](ribera derecha), algo más iluminados pero {label:1=muy tupidos}.
[vibración seca]:
@inc advertencia
{descripcion vibracion}
[traje]:
@inc traje
{descripcion traje}
[verdosas]:
Uno como explorador ya está hecho a estas cosas, pero conozco a varios allá en casa que se habrían puesto del mismo color del agua ante la sola idea de tocarla, para no hablar de beberla...
[huyen asustados]:
Cuesta creer que algo pueda tenerme miedo pero, bueno, mi apariencia ha de causarles algo de espanto. No es que entre mi gente se me considere un ejemplar muy feo, pero claramente no soy fauna local.
[criatura laguna]:
@inc criatura_laguna
@replace 1=no faltos de peligros
Algo parece nadar en la laguna, alejándose a la ribera a mi derecha. Es más grueso que mis dos piernas juntas y casi tan largo como yo soy alto.
De pronto, creo que paso de meterme al agua o incluso de acercarme más a la orilla.
[[ribera derecha]]:
@clear
@inc muerte
{PUNTAJE}
Avanzo con algo de dificultad, pues la hierba es más alta que yo y sumamente húmeda. Intentando abrirme paso, trato de apartar los tallos con un brazo...
...pero pierdo el equilibrio, resbalo y caigo de espaldas entre la hierba. Trato de ponerme en pie, pero no hago más que mover el pasto a mi alrededor, sin lograr apoyarme lo suficiente para levantarme.
¡Algo está saliendo de la laguna a mi izquierda!
Mientras escucho ruidos de un cuerpo pesado que se mueve en la orilla, intento aferrarme desperadamente de los tallos, pero mis manos resbalan inútilmente, pese a que el traje intenta compensar.
¡Siento que tiran brutalmente de mis pies!
...y tengo una visión fugaz de fauces dentadas...
{Final Muerte}
[[ribera izquierda]]:
@clear
{PUNTAJE}
La espesura de este lado de la laguna es bastante densa, pero el suelo al menos está razonablemente sólido y puedo avanzar sin grandes problemas.
Estoy a punto de llegar al final de la laguna, cuando del otro lado escucho un [chapoteo violento] seguido de un chillido que termina bruscamente. {if criatura_laguna=0:Algo parece nadar en la laguna, alejándose despacio de la orilla opuesta. Es más grueso que mis dos piernas juntas y casi tan largo como yo soy alto}{else:Diviso a la criatura que entreví en la orilla, alejándose despacio de la orilla opuesta}. De pronto se hunde... y unas gruesas burbujas revientan en la superficie, dejando unas [manchas oscuras] flotando en el agua.
Felicitándome por mi afortunada escogencia de ruta, sigo caminando a paso vivo y en breve dejo atrás la laguna, para continuar [[bosque adentro]](bosque fin).
[chapoteo violento]:
Algo pesado que se mueve en la otra orilla.
[manchas oscuras]:
Confieso que he contenido la respiración: no tengo mal olfato y preferiría no saber a qué huelen esas manchas.
[[bosque fin]]:
@clear
@inc puntaje
{PUNTAJE}
No ha pasado mucho rato cuando los árboles comienzan a espaciarse cada vez más y el nivel de luz ambiental va gradualmente en aumento.
Compruebo, aliviado, que he llegado al final del bosque y que nuevamente tengo frente a mí la llanura.
Llevo poco menos de la mitad del camino recorrido, así que, con renovados bríos, [[sigo adelante]](llanura continuacion).
[[cienaga inicio]]:
@clear
@set seccion=Ciénaga
{PUNTAJE}
Comienzo a avanzar por el pantano, tarea que resulta no demasiado difícil aunque sí algo penosa: el suelo es muy húmedo y en algunas partes se ha [reblandecido]. El {if traje=0:[traje]}{else:traje} me mantiene seco, en todo caso.
El lugar está lejos de estar deshabitado: hay múltiples plantas creciendo junto o a veces dentro de [pequeñas pozas], además de una población no menor de [insectos] que vuelan o se arrastran por doquier. He visto también algunos [anfibios] que se dan un festín con ellos... cuando no es al revés, por cierto.
Llevo andando una media hora cuando me enfrento a un cambio drástico en el paisaje: la ciénaga se divide en dos zonas muy distintas y no hay manera de seguir adelante si optar por uno u otro camino.
Debo tratar de sortear un largo trecho de [[fango]](fango1) o bien aventurarme en una zona muy extensa de [[pastos largos]](pastos).... y ninguno de estos "caminos" se ve demasiado seductor, la verdad.
[reblandecido]:
Hay sitios en los que mi pie se ha hundido completamente y me ha costado lo suyo sacarlo.
[traje]:
@inc traje
{descripcion traje}
[pequeñas pozas]:
No son más que charcos de agua fétida, fáciles de esquivar pero imposibles de no oler, por desgracia.
[insectos]:
Algunos son pequeños y forman verdaderos enjambres. Otros son tan grandes como mi brazo aunque se mueven perezosamente.
Procuro evitarlos a todos por igual.
[anfibios]:
Los hay tan pequeños que cabrían de a diez en mi mano y otros más grandes que mi cabeza, con unas tremendas bocotas. Algunos tiene colores muy encendido y brillantes.
Ninguno es tan bonito que me les quiera acercar ni mucho menos [tocarlos].
[tocarlos]:
Nuestro entrenamiento hace hincapié en que algunos de estos animales son en extremo tóxicos al tacto, algunos incluso letales.
[[descripcion fango]]:
No llevo más que algunos pasos andados por este... me resisto a llamarlo terreno... cuando estoy deseando haberme ido por cualquier otro sitio. Me cuesta mucho moverme y cada paso es una verdadera lucha:
Doy un paso... y mi pie se hunde.
Libero ese pie... y el otro resbala o patina.
Intento pisar donde parece estar más seco el suelo... y me hundo también.
[[descripcion hojas]]:
Las hojas, de superficie más bien brillante, son muy grandes y anchas: tanto, que podrían servirme incluso para caminar sobre ellas.
Curiosamente, de las hojas parece emanar un perfume algo dulzón...
[[fango1]]:
@clear
{PUNTAJE}
{descripcion fango}
Sencillamente, es agotador.
Llevo "andado" así por espacio de una hora cuando por fin el fango empieza a ceder a un medio más líquido pero, al menos bajo el agua, más sólido para el andar: indescriptiblemente [fétido], pero se puede pisar sin daño. Olor aparte, el problema es que conforme avanzo el agua está empezando a subir más y más de nivel...
...y ya con el agua a la cintura la situación se vuelve [preocupante].
Algo más adelante hay unas piedras sobresaliendo del líquido, aunque se ven algo [peligrosas]: entre las piedras hay unas [hojas redondas] que parecen ser más estables.
En todo caso, no es viable proseguir el avance sin algún apoyo, así que es cuestión de escoger si [[seguir por las piedras]](piedras){label:1= o} [[continuar por las hojas]](hojas carnivoras){label:2=.}
[fétido]:
Una de las cosas para las que se nos entrena es para tener una cierta resistencia sensorial, ya que debemos aprovechar todas las fuentes de informacion cuando estamos en el campo.
Dicho esto: qué peste horrible...
[preocupante]:
El {if traje=0:[traje]}{else:traje} que llevo puesto, por versátil que sea, no está realmente preparado para buceo.... ni yo tampoco creo que sea buena idea nadar por aquí.
[traje]:
@inc traje
{descripcion traje}
[peligrosas]:
@replace 1=, de difícil travesía o
Las piedras están cubiertas de un vegetación muy fina y húmeda: material deslizante, seguro.
[hojas redondas]:
@replace 2=, de embriagante perfume.
{descripcion hojas}
[[descripcion frases]]:
Me da igual si quedan o no registradas en la bitácora. Y si alguien quiere saber más al respecto, se puede comer la transcripción de mi informe.
[[piedras]]:
@clear
{PUNTAJE}
Me paro con mucho cuidado en la primera piedra a mi alcance y la piedra parece moverse debajo de mí: trato de quedarme quieto hasta que el movimiento se detiene más o menos por completo.
Con un suspiro de alivio, doy un paso hasta la piedra más próxima...
¡Y girando sin control hago la primera [vuelta en el aire] desde que salí de mi colonia!
Hago pie como buenamente puedo y, mientras muevo los brazos en todas direcciones, espero a que la piedra en que aterricé se estabilice de una buena vez, mientras mascullo un [par de frases].
Con mucha desconfianza, considero la [[siguiente piedra]](cienaga fin) junto a mí y me pregunto si no sería más sencillo optar por [[una de las hojas aquí cerca]](hojas carnivoras)...
[vuelta en el aire]:
El entrenamiento de gravedad cero me ha salvado la vida.
[par de frases]:
{descripcion frases}
[[hojas carnivoras]]:
@clear
@inc muerte
{PUNTAJE}
Me apoyo con cuidado en la hoja más cercana, pero resiste bien mi peso, así que decido pararme encima con los dos pies.
Un olor dulzón, que parece emanar de la hoja, me envuelve como un arrullo embriagante. Como en un sueño, intento moverme para caminar hacia otra hoja, pero mis pies están pegados...
...y la verdad es que ya no quiero moverlos, ni seguir andando: sólo quiero dormir, así que me dejo caer suavemente...
...y la hoja me envuelve por completo.
{Final Muerte}
[[pastos]]:
@clear
{PUNTAJE}
Avanzo con algo de dificultad, pues la hierba es más alta que yo y sumamente húmeda. Intentando abrirme paso, trato de apartar los tallos con un brazo...
...pero pierdo el equilibrio, resbalo y caigo de espaldas entre la hierba. Trato de ponerme en pie, y lo consigo tras un par de intentos fallidos.
Vuelvo a dar unos pasos y, por supuesto, resbalo nuevamente...
...y asi unas diez veces más: la última, me voy de bruces hacia adelante, aterrizando en un trecho breve de ciénaga "normal", pero ya me da igual. Mientras me pongo de pie e intento recuperar el aliento (y mi dignidad) mascullo un [par de frases].
Algo más compuesto, considero el terreno más adelante: en una dirección la ciénaga se vuelve un terreno fangoso mientras que para el otro lado se ve una zona inundada, en la que flotan unas [hojas redondas] que parecen ser estables.
Con mucha desconfianza, considero si [[voy a enfrentarme al lodo]](fango2) y me pregunto si no sería más sencillo optar por [[el camino de las hojas]](hojas carnivoras){label:1=...}
[par de frases]:
{descripcion frases}
[hojas redondas]:
@replace 1=, de embriagante perfume...
{descripcion hojas}
[[fango2]]:
@clear
{PUNTAJE}
{descripcion fango}
Sencillamente, es agotador.... pero ni pensar en regresar y desperdiciar todo el esfuerzo invertido para llegar aquí...
...donde sea que esté ahora mismo.
Tras un breve descanso, miro con más calma hacia adelante y me parece distinguir que el suelo está algo menos enlodado, así que vuelvo a ponerme (es un decir) [[en marcha]](cienaga fin).
[[cienaga fin]]:
@clear
@inc puntaje
{PUNTAJE}
{if seen piedras:Tras un par más de volteretas y aterrizajes en falso, consigo dejar atrás las piedras}{else:Después de aplicar no poco esfuerzo, dejo por fin el fango atrás} y llego a una parte más "normal" de la ciénaga: terreno blando y pozas de agua hedionda.
Vamos, un alivio comparado con lo que he tenido que atravesar antes.
No llevo mucho rato andando cuando compruebo ¡con placer! que el suelo está cada vez más seco: he llegado al final de la ciénaga y nuevamente tengo frente a mí la llanura.
Llevo poco menos de la mitad del camino recorrido, así que, con renovados bríos, [[sigo adelante]](llanura continuacion).
[[llanura continuacion]]:
@clear
@set seccion=Llanura
{PUNTAJE}
La llanura se extiende frente a mi, como un vasto océano de pastos cuyas aguas mansas agita el viento como una [suave caricia].
Ya no sé si estoy o no en régimen mental de exploración profunda, pues tras andar apenas unos pasos me veo caminando casi como si estuviera [dormido].
No estoy comentando nada lo que veo ni estoy fijando la vista en aspecto alguno del paisaje.
Pierdo la noción del tiempo...
...y simplemente [[avanzo]](animales).
[suave caricia]:
El aire se siente fresco y tibio, casi como si estuviera en un [baño de relajación].
[baño de relajación]:
Espero poder tomar uno cuando vuelva a la nave: restauran el equilibrio químico del cuerpo y la mente.
[dormido]:
Apenas siento el {if traje=0:[traje]}{else:traje} que llevo puesto, cosa que sería alarmante en otro caso.
Ahora podría importarme menos...
[traje]:
@inc traje
{descripcion traje}
[[animales]]:
@clear
{PUNTAJE}
El sueño no dura demasiado, en todo caso, pues el {if traje=0:[traje]}{else:traje} me "despierta" con una {if advertencia=1:vibración seca}{else:[vibración seca]}: hay alguna cosa más adelante que requiere mi atención consciente.
De hecho, son varias cosas.
A un costado, hay varios [animales grandes] ocupados en comer hierba; junto a ellos, a un trecho corto, se ve un grupo de [animales pequeños] que están, aparentemente, descansando.
No es [buena idea] pasar entre ambos grupos, así que es cuestión de rodearlos: ya sea por el lado de las [[grandes bestias]] que {label:1=ramonean en paz} o bien intentando esquivar a las... [[criaturitas]] que {label:2=no parecen estar molestando a nadie}.
[vibración seca]:
@inc advertencia
{descripcion vibracion}
[traje]:
@inc traje
{descripcion traje}
[animales grandes]:
Son cuadrúpedos el doble de altos que yo y más bien corpulentos, todos cubiertos de pelos... excepto por unos [enormes dientes], con los que escarban el suelo para soltar la hierba que devoran.
No parecen interesados en niguna otra cosa, mucho menos en los otros animales aquí junto... ni en mí, de momento.
[enormes dientes]:
@replace 1=no están exactamente indefensas
Son gruesos, curvos y se ven más bien afilados.
[animales pequeños]:
Son... bueno, parecen ser bípedos, pues figuran casi como si estuvieran sentados. Salvo la cara, tienen el cuerpo completamente cubierto de un pelaje con manchas alargadas. En la boca les asoman unos [dientes pequeños]. Están con la vista fija en los otros animales aquí junto: a mí no me han hecho caso... hasta ahora.
[dientes pequeños]:
@replace 2=pueden ser un gran problema
Muy cortos y muy agudos.
[buena idea]:
No se me ocurre una mejor manera de llamar su atención, vaya.
[[criaturitas]]:
@clear
@inc muerte
{PUNTAJE}
Me alejo un buen trecho antes de comenzar a rodearlos, procurando meter el menor ruido posible.
Pero algo debo haber pisado en la hierba, pues escucho un fuerte ¡CRAK!...
...y todos los animalitos giran su rostro hacia mí para enseguida ponerse a andar, dando pequeños saltos, con los brazos colgando a los costados.
¡Vienen hacia mí!
Alarmado, me pongo a caminar más rápidamente, ante lo cual las bestezuelas comienzan a dar saltos más largos, a la par que abren sus bocas, repletas de dientecillos afilados.
Francamente asustado, empiezo a correr desesperadamente...
...pero ya siento la respiración de mis cazadores cerca mío.
{Final Muerte}
[[grandes bestias]]:
@clear
{PUNTAJE}
Me alejo un buen trecho antes de comenzar a rodearlos, procurando meter el menor ruido posible.
Los animales me ignoran completamente y siguen tragando plantas.
Con un suspiro de alivio, continúo andando hasta [[perderlos de vista]](quebrada).
[[quebrada]]:
@clear
@set seccion=Quebrada
{PUNTAJE}
Tras caminar por una media hora o así, el {if traje=0:[traje]}{else:traje} me anuncia con una {if advertencia=1:vibración seca}{else:[vibración seca]} que he llegado al borde de una quebrada muy ancha y profunda.
Doy un vistazo a {if sistema=0:[mi muñeca]}{else:mi muñeca} y, con alegría, veo que hay una señal de orientación encendida: el módulo de descenso está justo adelante "en una cota vertical marcadamente inferior a la actual".
Habrá que llegar, entonces, [al fondo de la cuestión], je.
Bromas aparte, no se ve que sea trivial bajar hasta el fondo de la quebrada: el traje es bueno, pero no está hecho para resolver esto sin algo de esfuerzo por mi parte.
Tendría que [[acercarme al borde de la quebrada]](quebrada borde) y ver si es practicable un escalada de descenso o bien [[seguir caminando junto al borde]](quebrada al llano) hasta encontrar terreno llano y una vez ahí recorrer la quebrada hasta encontrar el módulo.
[traje]:
@inc traje
{descripcion traje}
[vibración seca]:
@inc advertencia
{descripcion vibracion}
[mi muñeca]:
@inc sistema
{descripcion sistema}
[al fondo de la cuestión]:
Mis instructores decían que yo tenía un sentido de humor algo fastidioso, pero yo les respondía que, ante problemas de gravedad, había que saber tener un poco de [levedad]...
[levedad]:
No que a mis instructores les faltara algo de [razón], je...
[razón]:
Broma esta que les gustaba todavía menos, pues siempre se ha dicho que los exploradores somos gente con tendencia a llevar a cabo [acciones arrojadas]...
[acciones arrojadas]:
Lo que en el caso de esta quebrada...
Se entiende ¿no? "arrojadas"...
Bueno, lo dejo, sin audiencia ya no tiene gracia.
[traje]:
@inc traje
{descripcion traje}
[[quebrada al llano]]:
@clear
{PUNTAJE}
Camino a buen ritmo durante una hora o así, siempre siguiendo el borde de la quebrada, un límite al que no he querido {if seen quebrada borde:[volver a acercarme](riesgo)}{else:[acercarme más](riesgo)}: el terreno es muy parecido al de la llanura y no supone mayor esfuerzo... especialmente al compararlo con mi paso por {if seen bosque inicio:el bosque}{else:la ciénaga}.
Al cabo de un rato, noto que al lado mío el terreno se ensancha a la par que disminuye la profundidad de las paredes que dan forma a la quebrada, a cuyo extremo más llano por fin me estoy acercando.
De hecho, un afloramiento de agua entre los pastos se ha concentrado en el declive del suelo a la entrada de la quebrada, formando un hilo de agua que, en la distancia, da lugar a un río que corre todo lo largo del fondo de la quebrada y cuyo curso [[ahora empiezo a seguir]](rio).
[riesgo]:
Bastantes peligros he enfrentado ya como para, justo ahora que estoy llegando al tramo final, empezar a correr riesgos.
[[quebrada borde]]:
@clear
{PUNTAJE}
Asomándome desde el borde puedo ver que el muro de la quebrada es sumamante escarpado y casi totalmente vertical, pero [no imposible] para un descenso: simplemente más arriesgado... como ha sido hasta ahora buena parte de mi reconocimiento, por lo demás.
La pared tienen dos rutas más bien marcadas: podría descender por una [[zona rocosa]](muro rocas), donde no hay mayor asidero que algunos trozos de piedra salientes o alternativamente bajar por un sector muy [[abundante en vegetación]](muro plantas), aunque sólo se ven plantas pequeñas: nada de árboles.
Todavía puedo, si lo prefiero, optar por [[seguir caminando junto al borde]](quebrada al llano) hasta encontrar terreno llano... pero una vez que descienda por el muro ya no habrá vuelta atrás.
[no imposible]:
Nuestro entrenamiento ciertamente consideraba esta posibilidad y fuimos preparados arduamente para ello... y entonces no lo aprecié lo suficiente.
No podré agradecerlo a mis instructores, pero si se me da la oportunidad, tendré un par de cosas que decirles a otros candidatos a exploradores.
[[muro inicio]]:
Comienzo a bajar por el muro, aferrándome con cuidado a {if seen muro plantas:las plantas}{else: las piedras salientes} y evitando cargar demasiado mi peso.
Al principio voy lento pero según voy bajando mi entrenamiento se hace presente y mi ritmo de descenso va aumentando.
Llevo un cuarto de camino recorrido cuando {if seen muro plantas:algo cae sobre mi cabeza}{else: observo algo interesante en la pared}.
[[muro plantas]]:
@clear
@inc muerte
@set seccion=Muro
{PUNTAJE}
{muro inicio}
Sacudo la cabeza y descubro que lo que me cayó encima era una planta.
Preocupado, miro hacia arriba...
...donde se ve que varias plantas que usé recién como apoyo están separándose del muro.
¡Y desde más arriba, veo una autentica lluvia de plantas que viene hacia mí!
Asustado, intento acelerar el ritmo de mi bajada...
...pero las plantas a las que me aferro se sueltan ya del muro...
{Final Muerte}
[[muro rocas]]:
@clear
@set seccion=Muro
{PUNTAJE}
{muro inicio}
Un poco más abajo, se ve la [entrada de una caverna](entrada) en la pared del muro.
No me costaría demasiado desviarme un poco para [[explorarla]](caverna), aunque probablemente lo menos arriesgado sería continuar [[el descenso]](rio) y llegar así al suelo al pie del muro.
[entrada]:
No se distingue gran cosa desde aquí, pero estoy seguro de que podré hacer pie en el borde y entrar sin demasiados problemas
[[nuevos parametros]]:
Esto cambia completamente los parámetros de la misión, pues es un indicio clarísimo de que hay {if seen lemures:otros seres}{else:seres} inteligentes en este mundo{if seen lemures: con un grado de inteligencia mucho más avanzado que lo que mi encuentro en el bosque me dió a entender}{else:, pese a la falta de evidencia observada hasta aquí en mi reconocimiento}.
[[caverna]]:
@clear
@inc puntaje
@inc inteligencia
@set seccion=Caverna
{PUNTAJE}
Una vez en la entrada de la cueva, me apoyo en la pared y me tomo unos momentos para que mi vista se acostumbre a la penumbra... y para [descansar un poco], no lo niego.
Una vez que percibo mejor las cosas, hago un recorrido visual del lugar, no demasiado distinto a [otras cavernas] que he visitado en mi colonia o en las paradas anteriores de la misión.
Estoy disponiéndome ya a retomar la escalada cuando veo algo extraño en una esquina al fondo de la cueva: se trata de un pequeño apilamiento de piedras.
Me acerco a mirarlas en más detalle y constato, perplejo que el apilamiento no es natural: sigue un patrón alargado y angosto sumamente preciso y que ya he visto antes.
Sin darme cuenta, he entrado a una tumba.
{nuevos parametros}
Compruebo que no he perturbado nada del lugar y me retiro con cuidado, retomando a continuación [[el descenso]](rio).
[descansar un poco]:
Mi entrenamiento me preparó en lo técnico, pero nunca jamás había hecho un descenso tan prolongado.
[otras cavernas]:
Artísticas o naturales, todas suelen parecerse bastante.
[[rio]]:
@clear
@set seccion=Río
{PUNTAJE}
{if seen muro rocas:Llegando al suelo, me encuentro junto a}{else:Voy ahora avanzando por} la ribera de un río que recorre todo a lo largo el fondo de la quebrada.
Sus aguas, limpias y brillantes, {if seen caverna:sólo sirven como contraste a la desazón que tengo, pese a estar ya en el}{else:reflejan el entusiasmo con que acometo este} tramo final de mi arduo periplo de reconocimiento. En efecto, pronto estaré de vuelta en mi nave y {if seen caverna:tendré que reportar que este mundo no puede ser}{else:podré reportar que este mundo puede ser} candidato a una nueva colonia.
Con el ánimo {if seen caverna:apesadumbrado, avanzo lento y cabizbajo}{else:en alto, voy con paso ligero} bordeando la orilla del río, que corre {if seen caverna:indiferente}{else:alegremente} junto a mí.
Un poco más adelante, me parece {if seen caverna:distinguir}{else:ver unas [[piedras de formas curiosas]](piedras talladas) en la orilla del río: casi las he pasado por alto pues, a poco andar, se divisa} la silueta redondeada del módulo de ascenso, al que [[finalmente he llegado]](modulo ascenso).
[[piedras talladas]]:
@clear
@inc puntaje
@inc inteligencia
{PUNTAJE}
Me acerco a mirar las piedras con más detalle y constato, perplejo, que las formas que atrajeron mi atención no son naturales: se trata de piedras talladas a mano, algunas enteras y otras rotas.
He dado con unas herramientas abandonadas.
{nuevos parametros}
Compruebo que no he perturbado nada del lugar y me retiro con cuidado, retomando el andar hacia [[el módulo de ascenso]](modulo ascenso).
[[modulo ascenso]]:
@clear
@inc puntaje
@set seccion=Módulo de ascenso
{PUNTAJE}
Por fin tengo ante mí el módulo para ascenso orbital, del que me ví accidentalmente separado y con el que por fin he logrado reencontrarme.
Sus formas redondeadas, que [conozco bien], se me antojan ahora muy hermosas, {if inteligencia=1:pese a tener un gusto amargo por}{else:especialmente dado lo fructífero de} mi reconocimiento planetario: en verdad, {if inteligencia=1:no}{else:ya} estoy deseando estar de regreso en la nave para entregar mi reporte.
Aunque podría [[abordarlo]](contacto) ya mismo, [la prudencia] aconseja realizar una [[revisión general]](inspeccion) antes del despuegue y evitar así algún problema, justo ahora.
[conozco bien]:
En el entrenamiento debo haber hecho no menos de diez aterrizajes y despegues en distintas partes de mi colonia.
[la prudencia]:
En realidad, es más entrenamiento que otra cosa. No guardo buenos recuerdos de lo que me hicieron pasar los instructores en las ocasiones en que, durante el entrenamiento, no he cumplido con este pre chequeo...
[[inspeccion]]:
@clear
{PUNTAJE}
Camino en torno al módulo, buscando escoraciones o trozos faltantes: el ingreso a la atmósfera es de lejos la parte más dura de la misión y sólo la [robustez y autosuficiencia] de estos aparatos me da algo de tranquilidad, después de un recorrido accidentado [como pocos].
Todo parece estar en orden, así que, con {if inteligencia=1:algo de resignación}{else:con la satisfacción del trabajo bien hecho} me dispongo a [[subir a bordo]](contacto).
[robustez y autosuficiencia]:
Al igual que la astronave, el módulo puede aprovechar casi cualquier material para reparar partes desgastadas o perdidas: agua, arena, tierra, polvo... todo se puede reutilizar para hacer reparaciones o reconstrucciones.
[como pocos]:
No tengo recuerdo de ningún perfil de misión, histórico o simulado, que incluyera todo lo que me ha pasado en este mundo.
[[contacto]]:
@clear
{PUNTAJE}
Estoy alargando la mano al fuselaje para generar una compuerta cuando, entre mi mano y el módulo, surge un holograma tenue, como una nubecilla azul.
Desconcertado, retrocedo un par de pasos pues esto nunca había pasado en ninguna misión, simulación o entrenamiento... y el módulo de ascenso no está programado para nada más sofisticado que, en una emergencia, solicitar un vehículo de reemplazo a la nave, la que ciertamente no puede generar hologramas a esta distancia.
Es totalmente incomprensible pero, curiosamente, no siento en este momento temor alguno: al contrario, siento una cierta alegría expectante, como si el holograma... cómo decirlo... me estuviera extendiendo una invitación.
Así que, no sabiendo qué esperar, me acerco al holograma y [[lo toco]](reencuentro).
[[reencuentro]]:
@clear
@set seccion=Reencuentro
{PUNTAJE}
Como en un sueño, el paisaje a mi alrededor se desvanece y en su lugar se materializa bajo mío, como en los cuentos de mi infancia, una hermosa loma de arena, en la que estoy lánguidamente tendido.
Descubro que ya no tengo el traje puesto y siento en mis escamas el tacto sensual de los gránulos, suaves y tibios, invitándome a extender y a hundir bajo la arena cada uno de mis cuatro dedos, como cuando era un niño y volvía al nido comunal al final del día.
Giro la cabeza para acomodarme y descubro que no estoy solo, pues junto a mi está tendido uno de mis antiguos preceptores, cosa imposible pues todos ellos habían muerto mucho antes de que yo saliera en misión.
Lo miro desconcertado, pero mi antiguo maestro se limita a mirarme y entonces escucho su voz, aunque no parezca [[estar hablando]](desde el pasado).
[[desde el pasado]]:
@clear
{PUNTAJE}
Te saludo desde tu futuro, viajero de nuestro pasado.
Me presento ante ti usando la forma de alguien por ti conocido: he tomado prestada esta imagen pues no quiero alarmarte o atemorizarte con mi verdadera apariencia. Mucho ha cambiado nuestra corporalidad; tanto así que incluso a ti, que conoces otros mundos, te resultaría algo chocante.
El mundo en que te encuentras no es un mundo nuevo, sino más bien uno que, en nuestra huida a las estrellas, olvidamos y perdimos en la memoria y la distancia.
Estás en el Nido Original, nuestro planeta nativo, un planeta hermoso que incluso nosotros, gentes de los tiempos por venir, jamás hemos querido volver a visitar.
Supimos reencontrarlo en nuestros largos viajes, pero decidimos apartarnos, pues una vez más había sido fuente de vida y dado lugar a otras criaturas inteligentes: gentes diferentes a nosotros, pero que también estaban iniciando su propio [[camino a las estrellas]](hacia el futuro).
[[hacia el futuro]]:
@clear
{PUNTAJE}
Cuando reencontramos el Nido, habían pasado océanos de tiempo desde el tuyo al nuestro.
Y navegando esos mares descubrimos que el tiempo y las realidades que crea son como un río.
Un río cuyo curso a veces se bifurca y se vuelve a encontrar, pero no siempre del mismo modo.
Remontándolo en viaje de memoria y recuerdo, no queríamos cambiar nuestra propia historia, pero tampoco deseábamos que, por algún accidente o error, se trastocara el devenir de este mundo, que fue nuestra cuna y lo será de muchas otras gentes por venir.
Gentes distintas a nosotros, con otros cuerpos y otras mentes: con su propia sabiduría, que no necesariamente compartimos y [[no deseábamos influenciar]](despedida).
[[despedida]]:
@clear
{PUNTAJE}
Este mensaje quedará en tu mente y podrás comunicarlo a tus hermanos y hermanas, quienes no dudamos sabrán cuidar este planeta, alejándose cuando sea necesario, para dar lugar a los muchos pueblos que de aquí surgirán y que lo llamarán con muchos nombres: Oceánica, Nido, Jardín, Tierra, Acqua...
...muchos nombres para muchos pueblos que desde aquí, con mejor o peor fortuna, dieron y darán sus primeros pasos a la inteligencia, en el tiempo y en las estrellas.
Nosotros deseamos que este planeta sea preservado y esperamos que sea también vuestro deseo y el de todos quienes lleguen a habitarlo.
Lo que esas gentes decidan hacer con este mundo, según el brazo del río del tiempo que decidan navegar... eso no es nuestro para cambiarlo.
Desde tu futuro a nuestro pasado, nos despedimos con un [[abrazo de paz]](Final).
[[Final Muerte]]:
Aquí terminan mi misión y mi vida
Puedes revisar tu [[puntuación]](Puntuacion) o {label:1=[[reiniciar]](Reiniciar)} el relato.
[[Puntuacion]]:
@replace 1=[[reiniciar]](Reiniciar)
Puntuación:
Has conseguido {puntaje} punto{if puntaje=1: }{else:s }de 4 así que calificas como
{if puntaje=0: pisaverde
Te limitaste a pasear por el lugar...}
{if puntaje=1: explorador novato.}
{if puntaje=2: explorador avanzado.}
{if puntaje=3: explorador experto.}
{if puntaje=4: instructor de exploradores.}
{if seen lemures:+1 Descubriste primates camino a la inteligencia
}
{if seen bosque fin:+1 Atravesaste el bosque
}
{if seen cienaga fin:+1 Atravesaste la ciénaga
}
{if seen caverna:+1 Encontraste evidencia de vida inteligente nativa
}
{if seen piedras talladas:+1 Encontraste evidencia de vida inteligente nativa
}
{if seen modulo ascenso:+1 Llegaste al módulo de ascenso
}
[[Final]]:
@clear
@set seccion=Despegue
{PUNTAJE}
Me encuentro de vuelta frente al módulo de ascenso, mirando este mundo como si hubiera salido nuevamente del huevo y estuviera abriendo los ojos por vez primera.
Todo está como antes pero es a la vez distinto, pues aunque me he reencontrado con el Nido, ya no puedo quedarme en él.
Otros {if inteligencia=1:han venido ya}{else:han de venir} a desovar aquí y criarán sus propios polluelos.
Y como nosotros, querrán tener un lugar limpio para crecer en paz.
Con un suspiro, el módulo se abre a mi contacto y me recibe, cerrándose suavemente en torno a mí.
Y mientras me adormezco para el despegue, pienso en el río del tiempo y en los océanos a los que nos llevará...
F I N
Puedes revisar tu [puntuación](Puntuacion), leer los [agradecimientos](Agradecimientos), mirar las [curiosidades](Curiosidades), saber más [acerca de la creación de "Reencuentro"](Acerca de) o [[reiniciar]](Reiniciar) el relato.
[Puntuacion]:
Puntuación:
Has conseguido {puntaje} punto{if puntaje=1: }{else:s }de 4 así que calificas como
{if puntaje=0: pisaverde
Te limitaste a pasear por el lugar...}
{if puntaje=1: explorador novato.}
{if puntaje=2: explorador avanzado.}
{if puntaje=3: explorador experto.}
{if puntaje=4: instructor de exploradores.}
{if seen lemures:+1 Descubriste primates camino a la inteligencia
}
{if seen bosque fin:+1 Atravesaste el bosque
}
{if seen cienaga fin:+1 Atravesaste la ciénaga
}
{if seen caverna:+1 Encontraste evidencia de vida inteligente nativa
}
{if seen piedras talladas:+1 Encontraste evidencia de vida inteligente nativa
}
{if seen modulo ascenso:+1 Llegaste al módulo de ascenso
}
[Agradecimientos]:
Agradecimientos:
El autor quiere agradecer a:
* A Comely por su testing.
* A Jade, por los consejos que me llevaron de vuelta a la autoría.
* A Alex Warren, por crear Squiffy, con el que pude construir este hiperrelato.
* A los exploradores de todos los mundos, en todos los tiempos.
[Curiosidades]:
Curiosidades:
* Has llegado a un sistema solar muy particular, obsérvalo con cuidado usando la vista externa.
* Tu traje es muy especial, estate atento a sus particularidades.
* El bosque esconde secretos que dan pistas sobre el destino de este mundo, no te apures y los descubrirás.
* El protagonista tiene un sentido de humor... particular: explóralo.
* Cuando estés en el acceso a la quebrada, independiente del camino que tomes, no dejes de observar todo cuanto te rodea.
[Acerca de]:
Acerca de "Reencuentro"
Sobre la creación de la obra
Este trabajo se creó originalmente para participar en la competencia "Rayuela de Arena", durante Mayo del 2023.
Tenía entonces entre manos un proyecto sumamente desarrollado para crear una aventura conversacional, pero no había avanzado hacia la programación por cuestiones creativas y de tiempo libre.
Cuando se abrió el periodo creativo de la "Rayuela" terminó de cuajar en mi mente (y en una libreta de apuntes: ¡Gracias, Jade!) una idea para un relato que podía alcanzar a desarrollar, probar y publicar en el plazo de la jam.
Me lancé a escribir y programar, que en Squiffy es todo casi la misma cosa...
...y el resultado es lo que tiene el lector en sus manos.
Sobre el tema de la obra
Uno de los tópicos favoritos de la ciencia ficción es la exploración del espacio en búsqueda de nuevos mundos y el encuentro con especies inteligentes extraterrestres.
Esos relatos suelen enfocarse desde la perspectiva de los seres humanos como exploradores, por lo que la inteligencia hallada y el contacto, amén de la cooperación o competencia por recursos extra planetarios, son posibles (o no) desde un punto de vista narrativo que suele ser, también, estrictamente humano.
En cuanto a la búsqueda de inteligencia no humana en nuestro propio mundo, visitas extraterrestres aparte, poco y nada hay que no se cirscunscriba a mamíferos percibidos como algo más que hábiles... siempre bajo la óptica humana, claro está.
Que otras especies hayan llegado a la inteligencia en nuestro mundo antes que nosotros rara vez suele plantearse, en la ficción o fuera de ella, argumentando la falta de evidencia arqueológica, evidencia que, lo habrá adivinado el lector, suele buscarse con nuestros criterios humanos.
¿Hay espacio en los millones de años de historia de nuestro planeta para otras inteligencias, con otros desarrollos tecnológicos que no hayan dejado huella alguna de su paso en nuestro planeta?
¿Y si nos aventuramos a comparar los cientos de millones de años de los reptiles en nuestro mundo con la escasa carrera evolutiva de los primates que dieron origen a nuestra humanidad?
Los moluscos, mucho antes de los dinosaurios y durante mucho más tiempo que ellos ¿fueron también necesariamente un callejón sin salida?
Quiera el lector reflexionar sobre estas y otras supuestamente irrefutables "verdades" que hemos construido en nuestro ¡tan comparativamente breve! paso por este mundo.
Pues el tiempo y las realidades que crea son como un río, cuyo curso a veces se bifurca y se vuelve a encontrar.
Pero no siempre del mismo modo.
Santiago de Chile, 26 de Mayo, 2023
[[Reiniciar]]:
squiffy.story.restart();