! Stick it to the man
!	Miscellaneous stuff:
!		The player object (Iris)
!		GoSolo
!		Limbo room (Limbo)
!		Yes/No/Maybe constants
!		AfterGameOver

! The player object (Iris)
	Object Iris "me"
has animate proper
with name 'Iris' 'Flora' 'Flo',
description [;
if (Handcuffs has worn) "I'm naked and handcuffed.  Come to think of it, I wouldn't mind being in this state again, under better circumstances.";
"I'm stunning.  Really.";
],
before [;
	Attack: "I have every reason to live.";
	Buy: "I am not a slave!";
	Consult: "I already am.";
	Pull,Push: "Hmm, wonder why I can't get any leverage.";
	Listen: "I can hear my heartbeat, if I listen hard.";
	Search: 	if (IrisClothes hasnt worn) "What, now I'm strip-searching myself?";
			else "I'm clean -- well, metaphorically speaking.";
	Smell: "Hey, I bathe regularly.";
	Squeeze: "That's Brad's department.";
	SwitchConversation: "I don't talk to myself -- well, not out loud.";
	SwitchOff: "I'd have to be, um, turned on first.";
	SwitchOn: "Rrrowr.";
	Taste: "Brad says I taste like cookie dough; I'll take his word for it.";
	Tie: "Hey, kinky -- but I'm not in the mood.";
],
after NULL, life NULL, each_turn NULL, time_out NULL, describe NULL,
lastspoke -1,
eaten 0, drankmilk 0,
stickTogether Maybe,
violence Maybe,
number 0;

! GoSolo	-- handles when Iris tries to go solo
	Object GoSolo "[GoSolo]"
with
execute [part;
		switch (part) {
	1: if (self hasnt general) {
give self general; "I sort of want to just give the finger to the gang and head out there myself -- I mean, you gotta get up early to stop capitalism -- but it just won't work.  We can't fight together if we're not together.  Division is what they want, and we can't provide them with that.  We need community.  Solidarity, unity.  If we fight ourselves we always lose.";
	}
	else "It's tempting, but fuck -- it's not the right choice.";
		}
];

! Limbo	-- A holding place for stuff
	Room Limbo "limbo"
with name 'limbo',
description "[<a>BUG</a>: You shouldn't be here.]";

Constant Yes "Yes";
Constant Maybe "Maybe";
Constant No "No";

[ AfterGameOver i;
print "^^^<s>The end</s>^^";
   .RRQPL;
   L__M(##Miscellany,5);
   .RRQL;
   print "<i>></i> ";

	! Begin OKB Modification: Forget Last Input
parse-->1=0;
	! End OKB Modification

#ifdef TARGET_ZCODE;
   #IFV3; read buffer parse; #ENDIF;
   temp_global=0;
   #IFV5; read buffer parse DrawStatusLine; #ENDIF;
#ifnot; ! TARGET_GLULX
   KeyboardPrimitive(buffer, parse);
#endif; ! TARGET_
   i=parse-->1;
   if (i==QUIT1__WD or QUIT2__WD) 
   {
#ifdef TARGET_ZCODE;
       quit;
#ifnot; ! TARGET_GLULX
       quit;
#endif; ! TARGET_
   }
   if (i==RESTART__WD)
   {
#ifdef TARGET_ZCODE;
       @restart;
#ifnot; ! TARGET_GLULX
       @restart;
#endif; ! TARGET_
   }
   if (i==RESTORE__WD)      { RestoreSub(); jump RRQPL; }
   if (i==FULLSCORE1__WD or FULLSCORE2__WD && TASKS_PROVIDED==0)
   {   new_line; FullScoreSub(); jump RRQPL; }
   if (deadflag==2 && i==AMUSING__WD && AMUSING_PROVIDED==0)
   {   new_line; Amusing(); jump RRQPL; }

	! Begin OKB Modification: EXTRA Deadflags
if (i==EXTRA1__WD or EXTRA2__WD or EXTRA3__WD or EXTRA4__WD &&
AuthorsChoice(-1)==8)
   {   new_line; AuthorsChoice(deadflag); jump RRQPL; }
	! End OKB Modification

   #IFV5;
   if (i==UNDO1__WD or UNDO2__WD or UNDO3__WD)
   {   if (undo_flag==0)
       {   L__M(##Miscellany,6);
           jump RRQPL;
       }
       if (undo_flag==1) jump UndoFailed2;
#ifdef TARGET_ZCODE;
       @restore_undo i;
#ifnot; ! TARGET_GLULX
       @restoreundo i;
       i = (~~i);
#endif; ! TARGET_
       if (i==0)
       {   .UndoFailed2; L__M(##Miscellany,7);
       }
       jump RRQPL;
   }
   #ENDIF;
   L__M(##Miscellany,8);
   jump RRQL;
];