REM ALIEN.AGT

command pull body
present [body]
changepassageway [enter] [nursery]
turnflagon [alien alive]
end_command

command examine ovoid
nounpresent
flagoff [alien alive]
destroy [egg]
printmessage
The bone dry ovid splinters open revealing the body of a tiny starfish
shaped alien.  Unfortunately it just quivers slightly and then shrivels into
nothingness.
end_printmessage
donewithturn
end_command

command examine ovoid
flagoff [in ship]
not nounislocated [evac bag]
printmessage "The jell surrounding the ovoid appears to be drying out quickly."
end_command

command examine ovoid
flagoff [in ship]
nounislocated [evac bag]
isopen [evac bag]
printmessage "The jell surrounding the ovoid appears to be drying out quickly."
end_command

command examine ovoid
countergt [hatching] 20
printmessage
The ovoid appears to be hardening slightly.
end_printmessage
end_command

command examine ovoid
countergt [hatching] 30
printmessage
The ovoid is rocking back and forth.
end_printmessage
end_command

command examine starfish
present [starfish]
nounislocated [sludge]
printmessage "The tiny starfish is happily rooting about in the sludge."
end_command

command examine starfish
inroom [starfish]
not iscarrying [starfish]
counterlt [hunger] 15
wearit [starfish]
printmessage
As you lean over to examine the creature, the tiny starfish quickly crawls
up your arm and settles onto your shoulder.
end_printmessage
end_command

command examine starfish
iswearing [starfish]
printmessage 
The tiny starfish is clinging to your shoulder making a quiet rasping sound.
end_printmessage
end_command

command shoot alien with handgun
present [wounded alien]
iscarrying [gun]
flagoff [two hits]
turnflagon [two hits]
printmessage
A beam of raw energy lashes out at the alien, which writhes in agony.
end_printmessage
donewithturn
end_command

command shoot alien with handgun
present [wounded alien]
iscarrying [gun]
printmessage
A beam of raw energy lashes out at the alien, which writhes in agony.
The alien shudders, and expires.
end_printmessage
destroy [wounded alien]
turnflagon [alien destroyed]
putincurrentroom [body]
donewithturn
end_command

command shoot starfish with handgun
iswearing [starfish]
iscarrying [gun]
printmessage
In panic you aim the gun at the alien and pull the trigger.  
A beam of raw energy lashes out at the alien.  
Unfortunately, since the alien is sitting on your shoulder, you manage to
shoot yourself in the head!
end_printmessage
destroy [starfish]
killplayer
donewithturn
end_command

command shoot starfish with handgun
present [starfish]
iscarrying [gun]
printmessage
A beam of raw energy lashes out at the alien, which writhes in agony.
The alien shudders, expires, and crumbles into dust.
end_printmessage
destroy [starfish]
donewithturn
end_command