Constant Story "Sploosh!!";
Constant Headline "^An Interactive Mess^";

Constant DEBUG;

Include "Parser";   
Include "WaterElement";
Include "Verblib";   
 
	
!-----------------------------------------------------------------------------------------------
! Rooms
!-----------------------------------------------------------------------------------------------
Class Room,
	has light;
	
Room Lab "Laboratory",
	with
	description [;
		"A long, somewhat dilapidated room in which you and your colleagues
		have taken to brewing up all sorts of strange materials.  High windows
		give a vague, watery light.  Along each wall are charts of chemical
		interactions, recipes for soups, lists of specific gravities, and so on.";
	],
	has light; 

Object InfiniteDitch "very deep ditch" Lab,
	with
	initial [;
		"A very deep ditch runs along one side of the room.";
	],
	name "very" "deep" "ditch",
	leak_cap [;
		!	Whatever its apparent size, it will keep on accepting liquids
		!	virtually forever.
		return 10000;
	],
	has container  open ~openable;

Object table "table" Lab,
	with name "table",
	has scenery supporter;
	
Object large_jar "large jar" table,
	with
	name "large" "jar",
	has container open ~openable;

Object bottle "bottle" lab,
	with
	name "bottle",
	has container ~open openable transparent;
	
Leaky basin "cracked basin" lab,
	with name "cracked" "basin",
	drip 50,
	has open ~openable;

Object rubber_duck "rubber duck" lab,
	with name "rubber" "duck" "yellow" "adorable",
	describe [;
		if (self has floating)
			"^Your beloved rubber duck floats to and fro.";
		"^Your beloved rubber duck lies discarded at your feet.";
	],
	description [;
		"An adorable rubber duck that has somehow managed to avoid being
		plunged into a vat of acid.  So far, anyway.";
	],
	has floater;
 
!-----------------------------------------------------------------------------------------------
!  Initialization
!-----------------------------------------------------------------------------------------------

[ Initialise; 
	location = Lab;    
	move water to large_jar;	!	put the sample objects from the library into play
	move sponge to player;
	move wine to bottle;
	move leaky_container to table;
	Water_Init();			!	Set up all the watery objects in the game
	"";
]; 

!-----------------------------------------------------------------------------------------------
!  Grammar and extensions
!-----------------------------------------------------------------------------------------------

Include "Grammar";       
Extend 'squeeze' * noun 'into'/'in'/'on'/'onto'/'over' noun -> SqueezeInto;