COMMAND ANY ANY
NewLife      
TurnFlagON 1 
TurnFlagON 2 
TurnFlagON 3 
TurnFlagON 4 
TurnFlagON 5 
TurnFlagON 6 
TurnFlagON 8 
TurnFlagON 10
SetVariableTo 1 2 
SetVariableTo 2 4 
SetVariableTo 3 13
END_COMMAND

COMMAND ANY ANY
FlagON 1 (* Elizabeth Frost is going to start moving around *)
TurnsGT 75
Chance 3  
TurnFlagOFF 1
TurnCounterON 1 (* Elizabeth Frost's movement counter *)
DoneWithTurn 
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 1  (* Elizabeth's counter equals the number *)
SendToRoom 307 35  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 3 (* Elizabeth's counter equals the number *)
SendToRoom 307 37  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 7 (* Elizabeth's counter equals the number *)
SendToRoom 307 39  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 10  (* Elizabeth's counter equals the number *)
SendToRoom 307 12  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 13  (* Elizabeth's counter equals the number *)
SendToRoom 307 11  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 16 (* Elizabeth's counter equals the number *)
SendToRoom 307 15  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 18 (* Elizabeth's counter equals the number *)
SendToRoom 307 16  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 21  (* Elizabeth's counter equals the number *)
SendToRoom 307 17  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 24  (* Elizabeth's counter equals the number *)
SendToRoom 307 18  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 30   (* Elizabeth's counter equals the number *)
SendToRoom 307 17  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 33  (* Elizabeth's counter equals the number *)
SendToRoom 307 19  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 36  (* Elizabeth's counter equals the number *)
SendToRoom 307 20  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 40  (* Elizabeth's counter equals the number *)
SendToRoom 307 19  (* Send her to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 1 43  (* Elizabeth's counter equals the number *)
SendToRoom 307 17  (* Send her to room xx. *)
TurnFlagON 1  (* Let her come out again later *)
TurnCounterOFF 1  (* Turn her counter off *)
END_COMMAND

COMMAND ANY ANY
FlagON 2  (* Gavin's allowed to move around *)
TurnsGT 120
Chance 2
TurnFlagOFF 2  
TurnCounterON 2  (* Turn Gavin's counter on *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 1  (* Gavin's counter equals the number *)
SendToRoom 315 37  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 3   (* Gavin's counter equals the number *)
SendToRoom 315 39  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 6  (* Gavin's counter equals the number *)
SendToRoom 315 12  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 9  (* Gavin's counter equals the number *)
SendToRoom 315 11  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 12  (* Gavin's counter equals the number *)
SendToRoom 315 10   (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 15   (* Gavin's counter equals the number *)
SendToRoom 315 4  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 18  (* Gavin's counter equals the number *)
SendToRoom 315 6  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 21  (* Gavin's counter equals the number *)
SendToRoom 315 8  (* Send Gavin to room xx. *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 2 24  (* Gavin's counter equals the number *)
SendToRoom 315 9  (* Send Gavin to room xx. *)
END_COMMAND
 
COMMAND ANY ANY
CounterEquals 2 74  (* Gavin's counter equals the number *)
SendToRoom 315 36  (* Send Gavin to room xx. *)
TurnCounterOFF 2
TurnFlagON 2  (* Let Gavin come out again later *)
END_COMMAND

COMMAND ANY ANY
FlagON 6  (* Ballon vendor is able to come to park *)
Chance 6
SendToRoom 322 8 (Send him to the park *)
TurnFlagOFF 6  (* He's in the park *)
TurnCounterON 4 (* Turn his counter on *)
END_COMMAND

COMMAND ANY ANY
CounterGT 4 45  (* He's been there more than 45 turns *)
Chance 12
TurnFlagON 6  (* Make it so he can come back later *)
TurnCounterOFF 4  (* Turn his counter off *)
Destroy 322  (* Send him to room 0 *)
END_COMMAND 

COMMAND ANY ANY
AtLocationLT 9 
AtLocationGT 4
TurnsGT 200
Chance 3
PrintMessage 1  (* Someone brushes against your arm. You whirl around, but *)
SendTreasuresToRoom 47 4  (* Thief steals your stuff and hides it at dam *)
VariableGT 1 8
SubtractFromVariable 1 8
END_COMMAND

COMMAND ANY ANY
AtLocation 171  (* At the fortune teller's shop *)
NOT Present 323  (* Fortune teller *)
InRoom 284  (* Crystal ball *)
Chance 25
SendToRoom 323 171 (* Fortune teller enters the room from the back *)
PrintMessage 2  (* There is a rustling of cloth, and a gypsy woman enters *)
END_COMMAND

COMMAND ANY ANY
NOT AtLocation 171  (* You aren't at the fortune teller's shop. *)
IsLocated 323 171  (* Fortune teller's in her shop *)
Destroy 323  (* Send her to room 0 *)
END_COMMAND

COMMAND ANY ANY
AtLocation 32  (* You're in the park at the fountain *)  
Present 305  (* The magician is in the room *)
Chance 41
RandomMessage 16 19  (* The magician does some tricks *) 
END_COMMAND

COMMAND ANY ANY
AtLocation 32  (* You're in the park at the fountain *)
Present 305  (* The magician is in the room *)
Chance 7
PrintMessage 20  (* Do you want to step into the disappearing box? *)
PromptForYES
GoToRandomRoom 2 30  (* Teleport around the town *)
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
FlagON 7  (* Final storm's happening *)
FlagON 8  (* Test for locking doors *)
TurnCounterON 5  (* Storm counter *)
TurnFlagOFF 8  (* All the stores have been closed *)
END_COMMAND

COMMAND ANY ANY
FlagON 7  (* Final storm is occuring *)
FlagOFF 9  (* Test flag is off *)
Destroy 320  (* Send old man to Room 0 *)
Destroy 312  (* Send guard at Winterborn mansion to Room 0 *)
Destroy 305  (* Send magician to Room 0 *)
Destroy 265  (* Send crowd to Room 0 *)
TurnFlagON 9
END_COMMAND

COMMAND ANY ANY
FlagON 7  (* The final storm is occuring *)
NOT IsWearing 262  (* You're not wearing the moon pendant *)
Chance 20
RandomMessage 13 15  (* Player is struck by lightning, hit by hail, etc. *)
KillPlayer  (* Send player to limbo *)
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
FlagON 7  (* The final storm is occuring *)
Chance 33
RandomMessage 8 12  (* Storm plays out its fury *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 5 80  (* Storm counter equals 80 *)
PrintMessage 25  (* The storm seems to be increasing in intensity! *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 5 125  (* Storm counter's reached max limit *)
PrintMessage 13  (* You are hit by a piece of debris *)
TurnCounterOFF 5  (* Turn the storm off *)
KillPlayer  (* Send player to limbo *)
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
TurnsEquals 240
SendToRoom 320 28  (* Send the old man to the graveyard *)
END_COMMAND

COMMAND ANY ANY
FlagON 15  (* The continuation flag is on *)
PrintMessage 68  (* The panel begins to emit a high-pitched BEEP. You *)
GoToRoom 143  (* Go to jail, go directly to jail, do not pass go, do not *)
TurnFlagOFF 15
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
IsNowhere 269  (* Pear is gone *)
Chance 2 
SendToRoom 269 5  (* Put the pear on the tree in the park *)
END_COMMAND

COMMAND ANY ANY
VariableLT 3 2  (* Wand has less than 1 charge in it *)
IsSomewhere 280  (* Wand is somewhere *)
Destroy 280  (* Send the wand to room 0 *)
PrintMessage 102
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
FlagOFF 24
TurnCounterON 6 
SetVariableTo 4 7
TurnFlagON 24
END_COMMAND

COMMAND ANY ANY
CounterEquals 6 0
TurnCounterON 6
END_COMMAND

COMMAND ANY ANY
VariableEquals 4 11
CounterEquals 6 60
FlagOFF 25
TurnFlagON 25
END_COMMAND

COMMAND ANY ANY
VariableEquals 4 12
CounterEquals 6 60
SetVariableTo 4 1
END_COMMAND

COMMAND ANY ANY
CounterEquals 6 60
VariableLT 4 12
TurnCounterOFF 6
AddToVariable 4 1
END_COMMAND

COMMAND ANY ANY
VariableEquals 4 11
CounterEquals 6 2
FlagON 25  (* 11:03 P.M. *)
PrintMessage 131
END_COMMAND

COMMAND ANY ANY
VariableEquals 4 11
CounterEquals 6 30
FlagON 25  (* 11:30 P.M. *)
PrintMessage 130
EndGame
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
FlagON 27  (* Match is lit *)
PrintMessage 139  (* You are holding a lit match *)
END_COMMAND

COMMAND ANY ANY
CounterEquals 7 4  (* Match is burned out *)
PrintMessage 138
TurnFlagOFF 27  (* Turn off lit match *)
END_COMMAND

COMMAND ANY ANY
FlagON 30  (* You've breathed helium *)
CounterEquals 10 14  (* Helium counter *)
TurnFlagOFF 30  
TurnCounterOFF 10
PrintMessage 158
END_COMMAND

COMMAND ANY ANY
CounterEquals 11 38
SwapLocations 230 317  (* Swap locations with the real cat and china cat *)
TurnCounterOFF 11
Present 230  (* The green cat *)
PrintMessage 181
END_COMMAND

COMMAND ANY ANY
Present 237  (* Glass orb *)
Present 317  (* Green cat *)
FlagON 7  (* Storm is on *)
FlagON 35  (* WB's been arrested *)
Present 316  (* Professor Nightshade *)
PrintMessage 198
PrintMessage 220
EndGame
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
Present 237  (* Glass orb *)
Present 317  (* Green cat *)
FlagON 7  (* Storm is on *)
FlagON  (* WB'S been arrested *)
NOT Present 316  (* Professor Nightshade *)
PrintMessage 198
PrintMessage 222
EndGame
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
Present 237  (* Glass orb *)
Present 317  (* Green cat *)
FlagON 7  (* Storm is on *)
FlagOFF 35  (* WB Hasn't been arrested *)
NOT Present 316  (* Professor Nightshade *)
PrintMessage 198
PrintMessage 221
EndGame
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
Present 237  (* Glass orb *)
Present 317  (* Green cat *)
FlagON 7  (* Storm is on *)
FlagOFF 35  (* WB Hasn't been arrested *)
Present 316  (* Professor Nightshade *)
PrintMessage 198
PrintMessage 246
EndGame
DoneWithTurn
END_COMMAND

COMMAND ANY ANY
TurnsEquals 4
PrintMessage 216  (* You are feeling faintly ill *)
END_COMMAND

COMMAND ANY ANY
FlagOFF 199  (* Peanuts sick flag *)
TurnsEquals 9
OR
TurnsEquals 16
OR
TurnsEquals 21
OR
TurnsEquals 26
PrintMessage 217  (* You are feeling strongly ill *)
END_COMMAND

COMMAND ANY ANY
FlagOFF 199  (* Peanuts sick flag *)
TurnsEquals 29
PrintMessage 218  (* You die of food poisoning! *)
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 5  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 32  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 9  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 25  (* On Hensings road; trying to enter bank *)
PrintMessage 22  (* The bank is closed for the day *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 18  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 3  (* Trying to enter flower shop *)
FlagOFF 8  (* Stores are closed *)
PrintMessage 37  (* The store is closed *)
DoneWithTurn
END_COMMAND

COMMAND NORTH 
AtLocation 22  (* Trying to enter museum *)
FlagOFF 8  (* Stores have been closed *)
PrintMessage 38  (* The museum is closed *)
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 46  (* You're at the front of the Tower Dam *)
Present 272  (* The padlock's secured on the gate *)
PrintMessage 75  (* The gate is locked by a padlock. *) 
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 23  (* Pheauzalt Blvd. *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 4  (* Creek/Fleming *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND NORTH 
AtLocation 14  (* Greymist Road *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 39  (* Hallway of Stars Hotel *)
PrintMessage 110  (* You quickly walk up the stairs. *)
END_COMMAND

COMMAND NORTH
AtLocation 88  (* Entry hall *)
Present 321  (* Butler *)
PrintMessage 164
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 68  (* Trying to enter music room *)
FlagOFF 19  (* Music room is locked *)
PrintMessage 78  (* The door is locked *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 5  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 32  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 18  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 14  (* Trying to enter antique store *)
FlagOFF 8  (* Stores have been closed *)
PrintMessage 37  (* The shop has been closed due to the storm *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 154  (* Trying to leave Winter Creek *)
PrintMessage 43  (* You aren't finished in Winter Creek yet. *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 35  (* Trying to enter Elizabeth's room *)
IsLocated 307 34  (* Elizabeth's in her room *)
PrintMessage 47  (*  The door is locked. *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 37  (* Trying to enter Gavin Temple's room *)
IsLocated 315 36  (* Gavin Temple's in his room *)
PrintMessage 47  (* The door is locked. *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 105  (* At WM, in front of black bedroom *)
FlagOFF 17  (* The door's locked *)
PrintMessage 78  (* The door is locked. *)
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 13  (* Greymist road, on corner *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 10  (* Fleming Avenue *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 15  (* Fleming Avenue *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 142  (* Police Station *)
PrintMessage 119
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 32  (* At the park *)
PrintMessage 21   (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 7  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 9  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 20  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 18  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 21  (* Trying to enter library *)
FlagOFF 8  (* Stores have been closed due to storm *)
PrintMessage 39  (* The library is closed *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 143  (* Jail cell *)
PrintMessage 70  (* The cell door has been bolted shut *)
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 26  (* End of Hensings *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 14  (* Greymist Road *)
PrintMessage 85
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 84  (* Trying to enter library *)
FlagOFF 18  (* Library's locked *)
PrintMessage 78  (* The door has been locked *) 
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 51  (* Hall of museum *)
FlagOFF 26  (* The door is locked *)
PrintMessage 78  (* The door has been locked. *) 
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 88  (* Entry hall *)
Present 321  (* Butler *)
PrintMessage 164
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLOcation 10
FlagOFF 8  
PrintMessage 37
DoneWithTurn
END_COMMAND

COMMAND SOUTH 
AtLocation 6  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH 
AtLocation 8  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH 
AtLocation 9  (* At the park *)
PrintMessage 21  (* Your way is blocked by an iron fence *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 13  (* On corner of Greymist Road, trying to enter restaurant *)
PrintMessage 23  (* The restaurant is closed *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 19  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 20  (* At the amusement park *)
PrintMessage 24  (* Why would you want to wander around in the ruins of the *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 2  (* Trying to enter police station *)
FlagOFF 8  (* Stores have been closed due to storm *)
PrintMessage 40  (* Police station is closed *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 3  (* Trying to enter post office *)
FlagOFF 8 (* Stores have been closed due to storm *)
PrintMessage 41  (* Post office is closed *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 172  (* Trying to enter fortune teller's shop *)
FlagOFF 8  (* Stores have been closed due to storm *)
PrintMessage 42  (* The fortune teller's door is locked. *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH 
AtLocation 154  (* Trying to follow road *)
IsCarrying 257  (* You've got the antique mirror *)
PrintMessage 45  (* Lightning bounces off of mirror *)
END_COMMAND

COMMAND SOUTH 
AtLocation 154  (* Trying to follow road *)
NOT IsCarrying 257  (* You don't have the antique mirror *)
PrintMessage 44  (* You're struck by lightning *)
KillPlayer  (* Send player to limbo *)
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 37  (* Hotel hall *)
PrintMessage 109  (* You quickly walk down the stairs. *)
END_COMMAND

COMMAND SOUTH
AtLocation 88  (* Entry hall *)
Present 321  (* Butler *)
PrintMessage 164
DoneWithTurn
END_COMMAND

COMMAND UP
AtLocation 81  (* Stairs *)
FlagON 5  (* Trap door flag *)
PrintMessage 173
DoneWithTurn
END_COMMAND

COMMAND INVENTORY
ShowInventory  (* Show current inventory *)
BlankLine
PrintMessage 60  (* You have VAR1 dollars *)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND STATUS 
PrintMessage 61 (*  *****  *)
ShowInventory
Blankline
ShowScore 
BlankLine
PrintMessage 60  (* You have VAR1 dollars *)
PrintMessage 62 (*  *****  *)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND VERSION
PrintMessage 73  (* STORMS  ***  Version Number xxx *)
DoneWithTurn
END_COMMAND

COMMAND GET MIRROR
AtLocation 129  (* Hall of mirrors *)
OR
AtLocation 132  (* Hall of mirrors *)
OR
AtLocation 130  (* Hall of mirrors *)
OR 
AtLocation 133  (* Hall of mirrors *)
OR
AtLocation 134  (* Hall of mirrors *)
OR 
AtLocation 135  (* Hall of mirrors *)
OR
AtLocation 136  (* Hall of mirrors *)
DescribeThing 286  (* It's not important *)
DoneWithTurn
END_COMMAND 

COMMAND GET MIRROR
AtLocation 137  (* Hall of mirrors *)
OR
AtLocation 138  (* Hall of mirrors *)
OR
AtLocation 139  (* Hall of mirrors *)
OR
AtLocation 140  (* Hall of mirrors *)
OR
AtLocation 131  (* Hall of mirrors *)
DescribeThing 286  (* It's not important *)
DoneWithTurn
END_COMMAND

COMMAND GET POT
AtLocation 120  (* Kitchen in Winterborn Mansion *)
FlagON 4  (* Cook won't let you get the pot *)
PrintMessage 26  (* "QUIT LOOKING OVER MY SHOULDER!" booms the cook. You *)
DoneWithTurn
END_COMMAND

COMMAND GET STATUE
AtLocation 50  (* Winter Museum *)
FlagON 10  (* Museum alarm is ON *)
PrintMessage 27  (* Better not touch the statue. You don't want to set *)
DoneWithTurn
END_COMMAND

COMMAND GET STATUETTE
AtLocation 53  (* Winter Museum *)
FlagON 10  (* Museum alarm is ON *)
PrintMessage 27  (* Better not touch the statuette. You don't want to set *)
DoneWithTurn
END_COMMAND

COMMAND GET PAINTING
AtLocation 54  (* Winter Museum *)
FlagON 10  (* Museum alarm is ON *)
PrintMessage 27  (* Better not touch the painting. You don't want to set *)
DoneWithTurn
END_COMMAND

COMMAND GET PAINTING
AtLocation 54  (* Winter Museum *)
FlagOFF 10  (* Museum alarm is OFF *)
IsNowhere 262  (* Moon pendant hasn't been found yet *)
PrintMessage 28  (* You lift the painting, and are startled by a loud clink *)
PutInCurrentRoom 262  (* Drop the moon pendant in the room *)
DoneWithTurn  
END_COMMAND

COMMAND GET FLOWER
AtLocation 31   (* Flower shop *) 
FlagOFF 11  (* You haven't bought the flower yet *)
PrintMessage 31  (* "Please do not handle the merchandise," says the clerk *)
DoneWithTurn
END_COMMAND

COMMAND GET URN
AtLocation 40  (* Etta's Antique Shop *)
FlagOFF 14  (* You haven't bought the antique urn yet *)
PrintMessage 32  (* "Don't pick up any of the antiques, please," says the *)
DoneWithTurn
END_COMMAND

COMMAND GET MIRROR
AtLocation 40  (* Etta's Antique Shop *)
FlagON 23  (* You can't get the mirror *)
PrintMessage 32  (* "Don't pick up any of the antiques, please," says the *)
DoneWithTurn
END_COMMAND

COMMAND GET ENVELOPE
AtLocation 141  (* At the post office *)
NOUNPresent  (* The letter's there *) 
FlagOFF 16  (* You can't get the letter *)
PrintMessage 71  (* The clerk won't let you *)
DoneWithTurn
END_COMMAND

COMMAND GET STACK
AtLocation 58
FlagOFF 50
PrintMessage 212
AddToVariable 1 20
TurnFlagON 50
DoneWithTurn
END_COMMAND

COMMAND GET STACK
AtLocation 58
FlagON 50
PrintMessage 213
DoneWithTurn
END_COMMAND

COMMAND GET ALL
PrintMessage 237  (* You must get everything one at a time here. *)
DoneWithTurn
END_COMMAND

COMMAND LIFT PAINTING
ReDirectTo GET PAINTING
END_COMMAND

COMMAND LIFT ANY
NOUNPresent 
PrintMessage 29  (* You don't need to lift anything! *)
DoneWithTurn
END_COMMAND

COMMAND OOPS
PrintMessage 30  (* Screwed up again, did you? *)
DoneWithTurn
END_COMMAND

COMMAND STEAL
PrintMessage 33  (* How absolutely amusing... *)
DoneWithTurn
END_COMMAND

COMMAND BUY FLOWER
AtLocation 31  (* Flower Shop *)
VariableGT 1 4  (* You have more than four dollars *)
InRoom 202  (* The rose is there *)
FlagOFF 11  (* You haven't bought it yet *)
PrintMessage 34  (* The clerk looks interested for the first time. "That *)
PromptForYES
PrintMessage 35  (* "Very well, sir. " The clerk takes your money. *)
SubtractFromVariable 1 5  (* Take five dollars from your finances *)
TurnFlagON 11  (* You may now take the rose *)
DoneWithTurn
END_COMMAND

COMMAND BUY FLOWER
AtLocation 31  (* Flower Shop *)
VariableLT 1 5  (* You don't have five dollars *)
InRoom 202  (* The rose is there *)
FlagOFF 11  (* You haven't bought it yet *)
PrintMessage 34  (* The clerk looks interested for the first time. "That *)
PromptForYES
PrintMessage 36  (* "I am afraid that you don't have enough money," states *)
DoneWithTurn
END_COMMAND

COMMAND BUY BALLOON
Present 322  (* Balloon vendor's in the room *)
IsNowhere 282  (* Balloon is in room 0 *)
VariableGT 1 2  (* You've got more than three dollars. *)
PrintMessage 48  (* Do you really want to buy the balloon? *)
PromptForYES  
PrintMessage 49  (* "Thanks!" Vendor gives you balloon *)
SubtractFromVariable 1 3  (* Take three dollars away from you *)
GetIt 282  (* Get the balloon *)
DoneWithTurn
END_COMMAND

COMMAND BUY BALLOON
Present 322  (* Balloon vendor's in the room *)
IsNowhere 282  (* Balloon is in room 0 *)
VariableLT 1 3  (* You don't have three dollars *)
PrintMessage 48  (* Do you really want to buy the balloon? *)
PromptForYES
PrintMessage 50  (* You don't have enough money to buy the balloon. *)
DoneWithTurn
END_COMMAND

COMMAND BUY BALLOON
Present 322  (* Balloon vendor's in the room *)
IsCarrying 282  (* You've got the balloon *)
PrintMessage 53  (* You've already got one! *)
DoneWithTurn
END_COMMAND

COMMAND BUY URN
AtLocation 40  (* You're at the antique shop *)
FlagOFF 14  (* You haven't bought the urn yet *)
VariableGT 1 149  (* You've got more than 149 dollars *)
PrintMessage 54  (* The urn is priced at 150 dollars *)
PromptForYES
PrintMessage 55  (* "Very good." She takes your money. *)
SubtractFromVariable 1 150  (* Take 150 dollars away from you *)
TurnFlagON 14  (* You've now bought the urn *)
DoneWithTurn
END_COMMAND

COMMAND BUY URN
AtLocation 40  (* Antique shop *)
FlagOFF 14  (* You haven't bought the urn yet *)
VariableLT 1 150  (* You don't have 150 dollars *)
PrintMessage 54  (* The urn is priced at 150 dollars *)
PromptForYES
PrintMessage 56  (* You don't have enough money to purchase the urn *)
DoneWithTurn
END_COMMAND

COMMAND BUY FORTUNE
AtLocation 171  (* In the fortune teller's shop *)
Present 323  (* Fortune teller *)
VariableGT 1 3 (* You have more than 3 dollars *)
SubtractFromVariable 1 4  (* It cost you 4 dollars *)
PrintMessage 114  
RandomMessage 115 117
DoneWithTurn
END_COMMAND

COMMAND BUY FORTUNE
AtLocation 171  (* In the fortune teller's shop *)
Present 323  (* Fortune teller *)
VariableLT 1 4  (* You have less than 4 dollars *)
PrintMessage 118  (* You don't have enough money *)
DoneWithTurn
END_COMMAND

COMMAND BUY ANY
NOUNIsCarrying  (* You're carrying it *)
PrintMessage 53  (* You've already got one! *)
DoneWithTurn
END_COMMAND

COMMAND BUY ANY
PrintMessage 98  (* Interesting thought. *)
DoneWithTurn
END_COMMAND

COMMAND DROP BALLOON
IsCarrying 282  (* You've got the balloon. *)
PrintMessage 52  (* The balloon soars up into the air *)
Destroy 282  (* Send balloon to room zero. *)
DoneWithTurn
END_COMMAND

COMMAND DROP NEEDLE
AtLocation 142  (* Police station *)
IsCarrying 277  (* You're carrying the needle *)
Present 314  (* The sleeping officer is there *)
PrintMessage 58  (* You drop the pin. It lands with a slight *clink* and *)
Destroy 314  (* Move the sleeping officer to room 0 *)
DropIt 277  (* Drop the needle in the room *)
PutInCurrentRoom 313  (* Send the awakened officer to the station *)
PlusScore 5  (* Add 5 points to your score *)
DoneWithTurn
END_COMMAND

COMMAND DROP CAT
IsCarrying 230
PrintMessage 72  (* The cat breaks *)
Destroy 230  (* Send cat to room 0 *)
DoneWithTurn
END_COMMAND
COMMAND POP BALLOON
ReDirectTo BREAK BALLOON
END_COMMAND

COMMAND BREAK BALLOON
Present 282  (* You've got the balloon. *)
PrintMessage 51  (* The balloon pops with a sudden explosion *)
Destroy 282  (* Destroy balloon *)
DoneWithTurn
END_COMMAND

COMMAND BREAK POT
Present 249  (* Flower Pot *)
Destroy 249  (* Send flower pot to room 0 *)
PutInCurrentRoom 210  (* Send the ornate key to your current room *)
PrintMessage 63  (* You smash the pot into a million cheap pottery shards. A *)
DoneWithTurn
END_COMMAND

COMMAND BREAK MIRROR
IsCarrying 212   (* Round stone *)
FlagOFF 40
AtLocation 136  (* Hall of mirrors *)
ChangePassageway 1 135
PrintMessage 170
TurnFlagON 40
DoneWithTurn
END_COMMAND

COMMAND BREAK MIRROR
IsCarrying 212   (* Round stone *)
FlagOFF 41
AtLocation 136  (* Hall of mirrors *)
ChangePassageway 3 130
PrintMessage 170
TurnFlagON 41
DoneWithTurn
END_COMMAND

COMMAND BREAK MIRROR
IsCarrying 212   (* Round stone *)
FlagOFF 42
AtLocation 130  (* Hall of mirrors *)
ChangePassageway 3 131
PrintMessage 170
TurnFlagON 42
DoneWithTurn
END_COMMAND

COMMAND BREAK MIRROR
IsCarrying 212  (* Round stone *)
AtLocationGT 128
AtLocationLT 141
PrintMessage 170
DoneWithTurn
END_COMMAND 
COMMAND BREAK MIRROR
AtLocationGT 128
AtLocationLT 141
PrintMessage 169
DoneWithTurn
END_COMMAND 
COMMAND ATTACK ANY
PrintMessage 33  (* How absolutely amusing... *)
DoneWithTurn
END_COMMAND

COMMAND CUT PADLOCK
AtLocation 46  (* At gate in front of dam *)
InRoom 272  (* The padlock is secured to the gate *)
IsCarrying 259  (* You've got the metal cutters *)
Destroy 272  (* Send the padlock to room 0 *)
PrintMessage 228
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND AWAKEN OFFICER 
AtLocation 142  (* Police station *)
Present 314  (* The sleeping officer is present *)
PrintMessage 59  (* You shake the officer several times, but nothing *)
DoneWithTurn
END_COMMAND

COMMAND TURN DIAL
AtLocation 52  (* You're in the museum back room *)
TurnFlagON 15  (* Test flag for combination *)
GetNumberInput 1 1000  (* Get number input, one to 1000 *)
NumberEquals 367  (* The number equals the combination *)
ToggleFlag 10  (* Turn the alarm either OFF or ON *)
TurnFlagOFF 15  (* Turn the test flag OFF *)
PrintMessage 69  (* You hear a click come from the alarm panel *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK GATE
AtLocation 46  (* At the dam gate *)
PrintMessage 76  (* You can't unlock the gate *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 51  (* Hallway of museum *)
FlagOFF 26
IsCarrying 248  (* Master museum key *) 
PrintMessage 81  (* You have now unlocked the door. *)
TurnFlagON 26
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 51  (* Hallway of museum *)
FlagON 26  
PrintMessage 79  (* The door is already unlocked! *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 51  (* Hallway of museum *)
FlagOFF 26
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 52  (* Storage room in museum *)
PrintMessage 83  (* There is no lock on this side of the door *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 35   (* Hallway of Stars Hotel *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 37  (* Hallway of Stars Hotel *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
IsCarrying 210  (* You have the ornate key *)
PrintMessage 81  (* You unlock the door. *)
TurnFlagON 17  (* The room is now unlocked *) 
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
FlagON 17  (* The room is unlocked *)
PrintMessage 79  (* The door is already unlocked! *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
NOT IsCarrying 210  (* You've don't have the ornate key *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR 
AtLocation 102  (* Inside the black bedroom in WM *)
PrintMessage 83  (* There is no lock on this side of the door. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 84  (* Study in NM *)
IsCarrying 275  (* You've got the black key *)
FlagOFF 18  (* The library is locked *)
TurnFlagON 18  (* Unlock the door *)
PrintMessage 81  (* The door is now unlocked *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 84  (* Study in NM *)
IsCarrying 275  (* You've got the black key *)
FlagON 18  (* The library is unlocked *)
PrintMessage 79  (* The door is already unlocked! *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 84  (* Study in NM *)
NOT IsCarrying 210  (* You've don't have the black key *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR 
AtLocation 85  (* Library in NM *)
PrintMessage 83  (* There is no lock on this side of the door. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 68  (* Hall in front of Music Room *)
IsCarrying 250  (* Music Room Key *)
FlagOFF 19  (* Music room is locked *)
PrintMessage 81  (* The door is now unlocked *)
TurnFlagON 19  (* Unlock the door *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 68  (* Hall in front of Music Room *)
IsCarrying 250  (* Music Room Key *)
FlagON 19  (* The Music Room is unlocked *)
PrintMessage 79  (* The door is already unlocked! *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR
AtLocation 68  (* Hall in front of Music Room *)
NOT IsCarrying 250  (* You've don't have the Music Room key *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK DOOR 
AtLocation 64  (* Music Room *)
PrintMessage 83  (* There is no lock on this side of the door *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK MAUSOLEUM 
AtLocation 29  (* At the Cemetary near mausoleum *)
PrintMessage 77  (* You don't have anything that will unlock it. *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
IsCarrying 210  (* You've got the ornate key *)
FlagON 17  (* The room is unlocked *)
PrintMessage 82  (* The door is now locked. *) 
TurnFlagOFF 17  (* Lock the door *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
FlagOFF 17  (* The room is locked *)
PrintMessage 80  (* The door is already locked! *) 
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 68  (*  In hallway in front of Music Room *)
IsCarrying 250  (* Music room key *)
FlagON 19  (* The Music Room is unlocked *)
PrintMessage 82  (* The door is now locked. *)
TurnFlagOFF 19  (* Lock the Music Room *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 68  (* In hallway in front of Music Room *)
FlagOFF 19  (* Music Room is locked *)
PrintMessage 80  (* The door is already locked! *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 105  (* In the hallway of Winterborn Manor, in front of bedroom *)
IsCarrying 210  (* You've got the ornate key *)
FlagON 17  (* The room is unlocked *)
TurnFlagOFF 17  (* Lock the room *)
PrintMessage 82  (* The door is now locked. *) 
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 105  (* In the hallway of WM, in front of the bedroom *)
FlagOFF 17  (* The room is locked *)
PrintMessage 80  (* The door is already locked! *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR 
AtLocation 102  (* Inside the black bedroom in WM *)
PrintMessage 83  (* There is no lock on this side of the door. *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 84  (* Study in NM *)
IsCarrying 275  (* You've got the black key *)
FlagON 18  (* The library is unlocked *)
TurnFlagOFF 18  (* Lock the door *)
PrintMessage 82  (* The door is now locked *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 84  (* Study in NM *)
FlagON 18  (* The library is locked *)
PrintMessage 80  (* The door is already locked! *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 85  (* Library in NM *)
PrintMessage 83  (* There is no lock on this side of the door. *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 64  (* Music Room *)
PrintMessage 83  (* There is no lock on this side of the door *)
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 51  (* Hallway of museum *)
IsCarrying 248  (* Master museum key *)
FlagON 26 
PrintMessage 82  (* You have now locked the door. *)
TurnFlagOFF 26
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 51
FlagOFF 26
PrintMessage 80
DoneWithTurn
END_COMMAND

COMMAND LOCK DOOR
AtLocation 52
PrintMessage 83
DoneWithTurn
END_COMMAND

COMMAND PUSH DEVICE
IsCarrying 273  (* Push the figure eight on the Moebius Device *)
FlagON 20  (* It's been charged *)
FlagOFF 7  (* The final storm hasn't started *)
DropIt 273  (* Drop the Moebius Device *)
PrintMessage 91  
GoToRoom 170  (* Ethereal Void *)
TurnFlagOFF 20  (* Uncharge Moebius Device *)
DoneWithTurn
END_COMMAND

COMMAND PUSH DEVICE
IsCarrying 273  (* Device *)
FlagOFF 20  (* Has not been charged *)
PrintMessage 93  (* You hear a clicking noise *)
DoneWithTurn
END_COMMAND

COMMAND PUSH BUTTON
AtLocation 47  (* Power Room in dam *)
ToggleFlag 29  (* Power in Nightshade Manor is on if ON *)
PrintMessage 248
DoneWithTurn
END_COMMAND

COMMAND PUSH CLEAR BUTTON
NounIsNumber 238
Present 237  (* Glass orb *)
FlagON 29  (* The flag is on *)
PrintMessage 193 
DoneWithTurn
END_COMMAND

COMMAND PUSH WHITE BUTTON
NounIsNumber 239
Present 237  (* Glass orb *)
FlagON 29  (* The flag is on *)
PrintMessage 194 
DoneWithTurn
END_COMMAND

COMMAND PUSH BLUE BUTTON
NounIsNumber 240
Present 237  (* Glass orb *)
FlagON 29  (* The flag is on *)
PrintMessage 195 
DoneWithTurn
END_COMMAND

COMMAND PUSH RED BUTTON
NounIsNumber 241
Present 237  (* Glass orb *)
FlagON 29  (* The flag is on *)
PrintMessage 196 
DoneWithTurn
END_COMMAND

COMMAND PUSH BLACK BUTTON
NounIsNumber 242
Present 237  (* Glass orb *)
FlagON 29  (* The flag is on *)
PrintMessage 197 
TurnFlagON 7
TurnFlagOFF 29
DoneWithTurn
END_COMMAND

COMMAND PUSH BUTTON
Present 237  (* Glass orb *)
FlagOFF 29
PrintMessage 192  (* You hear a loud click *)
DoneWithTurn
END_COMMAND

COMMAND PULL LEVER
AtLocation 48  (* Mausoleum *)
IsLocated 230 270  (* The cat is inside the machine *)
Destroy 230  (* Get rid of the cat *)
PrintMessage 250
SendToRoom 317 48 (* Green cat *)
TurnCounterON 11
DoneWithTurn
END_COMMAND

COMMAND PULL LEVER
AtLocation 48  (* Mausoleum *)
PrintMessage 249
DoneWithTurn
END_COMMAND

COMMAND PUT ROSE IN VASE
AtLocation 28  (* You're at the cemetary *)
IsCarrying 202  (* Rose *)
Destroy 202  (* Send the rose to room 0 *)
PrintMessage 132  (* You hear a clicking noise *)
TurnFlagON 21  (* Open the mausoleum -- kind of *)
DoneWithTurn
END_COMMAND

COMMAND PUT PEAR IN DEVICE
Present 273  (* Device *)
Present 269  (* Pear *)
PrintMessage 92  (* You put the pear in the Moebius Device *)
Destroy 269  (* Destroy the pear *)
TurnFlagON 20  (* Charge the Moebius Device *)
DoneWithTurn
END_COMMAND

COMMAND PUT ANY IN DEVICE
Present 273  (* Device *)
NOUNPresent   (* The ANY to put into the device *)
PrintMessage 94  (* It dosen't fit *)
DoneWithTurn
END_COMMAND

COMMAND DAMBANI
AtLocation 29  (* You're at the mausoleum *)
FlagON 21  (* The rose has been put into the vase *)
PrintMessage 133  
ChangePassageway 11 48  (* ENTER The mausoleum *)
TurnFlagOFF 21  (* Rose flag is OFF *)
DoneWithTurn
END_COMMAND

COMMAND DAMBANI
PrintMessage 95  (* Nothing happens. *)
DoneWithTurn
END_COMMAND

COMMAND NEVERMORE
AtLocation 81  (* Top of stairs *)
FlagON 5  (* You can't enter the tower *)
PrintMessage 174
TurnFlagOFF 5  (* You may now enter the tower *)
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND GIVE URN
AtLocation 32  (* Fountain *)
IsCarrying 208  (* Urn *)
Destroy 208  (* Send urn to room 0 *)
GetIt 280  (* White wand *)
PrintMessage 97
PlusScore 5  (* Add 5 points to your score *)
DoneWithTurn
END_COMMAND

COMMAND GIVE LICENSE
AtLocation 141  (* Post Office *)
FlagOFF 16  (* You can't get the letter *)
Present 267  (* The license *)
TurnFlagON 16
PrintMessage 129
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND GIVE FORM
AtLocation 40  (* Antique shop *)
Present 252  (* Request form *)  
PrintMessage 136 
Destroy 252
PlusScore 5
TurnFlagON 14
DoneWithTurn
END_COMMAND

COMMAND GIVE LETTER
AtLocation 88  (* Entry hall *) 
Present 321  (* Butler *)
Present 281  (* Letter *)
PrintMessage 165
SendToRoom 321 72  (* Send butler to bedroom *)
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND GIVE LETTER
AtLocation 72  (* Bedroom *)
Present 321  (* Butler *)
Present 281  (* Letter *)
PrintMessage 166
DoneWithTurn
END_COMMAND

COMMAND GIVE LETTER
AtLocation 142  (* Police station *)
Present 313  (* Awake officer *)
Present 281  (* Letter *)
PrintMessage 167
TurnFlagON 35  (* Winterborn in jail flag *)
TurnFlagON 200
TurnFlagOFF 3
Destroy 308  (* Winterborn *)
SendToRoom 308 143
Destroy 281  (* Letter *)
DoneWithTurn
END_COMMAND

COMMAND SELL ANY
PrintMessage 135
DoneWithTurn
END_COMMAND

COMMAND WAVE WAND AT PADLOCK
AtLocation 46  (* Gate *)
IsCarrying 280  (* ivory wand *)
Present 272  (* The padlock *)
SubtractFromVariable 3 3  (* Take lots of energy from the wand *)
Destroy 272  (* The padlock *)
PrintMessage 103
DoneWithTurn
END_COMMAND

COMMAND WAVE WAND AT WALL
AtLocation 9  (* Brick wall *)
IsCarrying 280  (* ivory wand *)
FlagOFF 22  (* Money flag is off *)
PrintMessage 105  (* You find money! *)
AddToVariable 1 10  (* Give you a $10 bill *)
SubtractFromVariable 3 2  (* Take medium energy from the wand *)
TurnFlagON 22  (* You've found money *)
DoneWithTurn
END_COMMAND

COMMAND WAVE WAND AT WOODPILE
AtLocation 97  (* Woodpile *)
IsCarrying 280  (* Ivory Wand *)
IsNowhere 273  (* Moebius Device is in room 0 *)
PrintMessage 100  
SendToRoom 273 97  (* Put the Device in the room *)
SubtractFromVariable 3 4  (* Take lots of energy from the wand *)
DoneWithTurn
END_COMMAND

COMMAND WAVE WAND
IsCarrying 280 (* Ivory Wand *)
GoToRandomRoom 2 30  (* Go somewhere in town *)
SubtractFromVariable 3 2  (* Take medium energy from the wand *)
PrintMessage 104  (* The wand begins to glow with a bright silver light. *)
DoneWithTurn
END_COMMAND

COMMAND WAVE WAND AT ANY
IsCarrying 280  (* Ivory wand *)
PrintMessage 101
DoneWithTurn
END_COMMAND

COMMAND TIME
FlagOFF 25
CounterLT 6 10
PrintMessage 122
DoneWithTurn
END_COMMAND

COMMAND TIME
FlagOFF 25
PrintMessage 120
DoneWithTurn
END_COMMAND

COMMAND TIME
FlagON 25
CounterLT 6 10
PrintMessage 123
DoneWithTurn
END_COMMAND

COMMAND TIME
FlagON 25
PrintMessage 121
DoneWithTurn
END_COMMAND

COMMAND SEARCH UNDER BED
ReDirectTo LOOK UNDER BED
END_COMMAND

COMMAND LOOK UNDER BED
AtLocation 38  (* Your bedroom *)
IsNowhere 267  (* Driver's license *)
PrintMessage 124
GetIt 267  (* Driver's license *)
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND SEARCH STACK
AtLocation 58  (* Library *)
FlagOFF 50
PrintMessage 212
AddToVariable 1 20
TurnFlagON 50
DoneWithTurn
END_COMMAND

COMMAND SEARCH 
PrintMessage 125  (* You discover nothing. *)
DoneWithTurn
END_COMMAND
COMMAND OPEN DOOR
PrintMessage 126  (* That would be useless. *)
DoneWithTurn
END_COMMAND

COMMAND OPEN MAUSOLEUM
PrintMessage 128  (* You can't open the door *)
DoneWithTurn
END_COMMAND

COMMAND OPEN PADLOCK
AtLocation 46  (* Dam gate *)
PrintMessage 126  (* That would be useless. *)
DoneWithTurn
END_COMMAND

COMMAND OPEN BOX
AtLocation 120  (* Kitchen of WM *)
IsCarrying 253  (* Small box *)
PrintMessage 171
Destroy 253  (* Small box *)
Destroy 310  (* Cook *)
TurnFlagOFF 4  (* You may now get the pot *)
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND OPEN BOX
Present 253  (* Small box *)
PrintMessage 172
Destroy 253  (* Small Box *)
DoneWithTurn
END_COMMAND

COMMAND OPEN ENVELOPE
AtLocation 141  (* Post office *)
FlagOFF 16
PrintMessage 211
DoneWithTurn
END_COMMAND

COMMAND CLOSE MAUSOLEUM
PrintMessage 126
DoneWithTurn
END_COMMAND

COMMAND LIGHT MATCH
IsCarrying 255  (* Small matchbook *)
VariableGT 2 0
PrintMessage 134
TurnCounterON 7  (* Match counter *)
TurnFlagON 27  (* Match is lit - Flag *)
SubtractFromVariable 2 1
DoneWithTurn
END_COMMAND

COMMAND LIGHT MATCH
IsCarrying 255  (* Small matchbook *)
VariableLT 2 1
PrintMessage 137
Destroy 255  (* Small matchbook *)
DoneWithTurn
END_COMMAND

COMMAND LIGHT TORCH
FlagON 27 (* Match is lit *)
Present 288  (* Burned torch *)
PrintMessage 149
SwapLocations 288 289 
TurnCounterON 8
DoneWithTurn
END_COMMAND

COMMAND LIGHT TORCH
FlagON 27  (* Match is lit *)
Present 289  (* Lit torch *)
PrintMessage 150
DoneWithTurn
END_COMMAND

COMMAND LIGHT TORCH
FlagOFF 27  (* Torch is out *)
Present 288  (* Burned torch *)
PrintMessage 152
DoneWithTurn
END_COMMAND

COMMAND LIGHT ANY
NOUNPresent
PrintMessage 156  (* It's not flammable *)
DoneWithTurn
END_COMMAND

COMMAND TALK TO FROST
Present 307
PrintMessage 199  
DoneWithTurn
END_COMMAND

COMMAND TALK TO TEMPLE
Present 315
PrintMessage 200
DoneWithTurn
END_COMMAND

COMMAND TALK TO TALBOT
Present 320
PrintMessage 201
DoneWithTurn
END_COMMAND

COMMAND TALK TO WINTERBORN
Present 308
PrintMessage 203
DoneWithTurn
END_COMMAND

COMMAND TALK TO FREEMAN
Present 321
PrintMessage 204
DoneWithTurn
END_COMMAND

COMMAND TALK TO TELLER
Present 323
PrintMessage 205
DoneWithTurn
END_COMMAND

COMMAND TALK TO PROFESSOR
Present 316
PrintMessage 240
DoneWithTurn
END_COMMAND

COMMAND TALK TO VENDOR
Present 322
PrintMessage 226
DoneWithTurn
END_COMMAND

COMMAND TALK TO OFFICER
Present 313
PrintMessage 207
DoneWithTurn
END_COMMAND

COMMAND TALK TO OFFICER
Present 314
PrintMessage 168
DoneWithTurn
END_COMMAND

COMMAND TALK TO ANY
FlagON 30  (* You've breathed helium. *)
PrintMessage 159
DoneWithTurn
END_COMMAND

COMMAND TALK TO ANY
FlagON 30  (* You've breathed helium *)
AtLocation 171  (* Fortune teller's shop *)
PrintMessage 160
DoneWithTurn
END_COMMAND

COMMAND SCREAM 
AtLocation 171  (* Fortune teller's shop *)
FlagON 30  (* Helium flag *)
Present 323  (* Fortune teller *)
PrintMessage 161
DoneWithTurn
END_COMMAND

COMMAND SCREAM
AtLocation 171  (* Fortune teller's shop *)
FlagON 30  (* Helium flag *)
Present 284  (* Crystal ball *)
PrintMessage 229
SwapLocations 284 291  (* Swap crystal ball with crystal shards *)
AddToVariable 1 146
PlusScore 5
DoneWithTurn
END_COMMAND

COMMAND SCREAM
FlagON 30  (* Helium flag *)
PrintMessage 162
DoneWithTurn
END_COMMAND

COMMAND UNTIE BALLOON
ReDirectTo BREATHE HELIUM
END_COMMAND

COMMAND BREATHE HELIUM
IsCarrying 282  (* Orange balloon *)
TurnCounterON 10  (* Helium counter *)
TurnFlagON 30  (* Helium flag *)
PrintMessage 157
Destroy 282  (*  Orange Balloon *)
DoneWithTurn
END_COMMAND
COMMAND COMPLETE THE MOVE
AtLocation 85  (* Library *)
Present 223  (* Chess piece *)
PrintMessage 187
ChangePassageway 5 93  (* Open passageway to Bottom of Stairs in tower *)
Destroy 223  (* Chess piece *)
DoneWithTurn
END_COMMAND
COMMAND COMPLETE THE MOVE
AtLocation 85  (* Library *)
PrintMessage 188
DoneWithTurn
END_COMMAND
COMMAND PET CAT
Present 317  (* Green cat *)
PrintMessage 189
DoneWithTurn
END_COMMAND
COMMAND EAT PEAR
Present 269  (* Pear *)
FlagOFF 199  (* Peanuts sick flag *)
Destroy 269  (* Pear *)
PrintMessage 219  (* Yay! *)
PlusScore 3
TurnFlagON 199
DoneWithTurn
END_COMMAND