Message "[Including <smtuc-characters2>]";

! http://www.spacemoose.com
!
! If you liked this game, you'll love Space Moose
StiffyMan screen_moose "Space Moose"
    with name "Space" "Moose" "cervoid" "badger" "bionic" "billy",
    picture pic_smandb,
    counter 0,
    InitQuips [;self.QuipsOn(3,1,2,3);],
    SayQ [line;
	interlocutor = self;
	DrawObjectPic(self);
	switch (line) {
     1: "~Identify yourself.  This is Captain Stiffy Makane of the
	Starship ",(italics) "Turgidity",", NCC 69105-DD.~";
     2: "~Are you a good moose or a bad moose?~";
     3: "~Who's that with you?~";
     4: "~You want to come aboard for a beer?~";
     5: "~Sure.  Permission granted.~";
     6: "~Permission denied.~";
     7: "~No.~";
     8: "~Hell no.~";
     9: "~Shit no.~";
     10: "~Fuck no.~";
    }
    ],
    Respond [line;
	interlocutor = 0;
	if ((self.counter > 1) && (line ~=4)) {
	    self.QuipsOff(4,1,2,3,4);
	    self.QuipsOn(6,5,6,7,8,9,10);
	    self.counter = 0;
	    print "~Hey, can we come on board your ship?~^^";
	    <<TalkTo self>>;
	}
	switch(line) {
     	 1: self.QuipOff(1);
	    self.QuipOn(4);
	    self.counter++;
	    print "~I'm Space Moose, Cabin Boy and Chief Engineer of the good
	    ship ", (italics) "Mauve Armadillo",".  I mean
		you no harm.  Quite the contrary.~^^";
	    <<TalkTo self>>;
     	 2: self.QuipOff(2);
	    self.counter++;
	    self.QuipOn(4);
	    print "~I'm a very, very bad moose.  Or maybe I mean: when
		I'm good, I'm very, very good.  But when I'm bad, I'm ",
		(italics) "better",".~  He leers disquietingly.^^";
	    <<TalkTo self>>;
     	 3: self.QuipOff(3);
	    self.QuipOn(4);
	    self.counter++;
	    print "~Allow me to introduce my associate, Billy the Bionic
	    Badger.~^^The creature in the background belches, wipes his
	    mouth with a grimy paw, and nods aimiably.  ~Howzitgoin'?~ it
	    mumbles.^^";
	    <<TalkTo self>>;
     	 4: print "~Hell yeah!  Par-TEE!~^^~Oh, that's sweet of you!~
	    	chirps a voice from behind you.  Lieutenant Barcelona
	    	licks her lips.  ~The short one's really cute, huh?~^^";
	    self.nextscene(line);
     	 5: print "The moose leers in a faintly terrifying fashion.
	    	Hoping it's not aimed at you, you look over your shoulder
	    	and notice, with some relief, that Lieutenant Barcelona
	    	has entered the bridge.^^";
	    self.nextscene();
     	 6 to 10: print "Space Moose looks disappointed and a little hurt.  But
		then, suddenly, a high perky voice comes from behind you.^^
		~Tee Hee!  Of ",(italics) "course"," you can come aboard, you
		silly Space Moose.  As long as you bring your hot little
		friend.~^^";
	    self.nextscene();
	}
    ],
    nextscene [line;
	move self to limbo;
	viewscreen.picture = pic_stars;
	PlaySound(gg_forechannel,snd_transporter,0,1,1);
	print "Space Moose and Billy the Bionic Badger materialize on the
	bridge.  Almost instantly, Billy and Barcelona lock, in quick
	succession, eyes, lips, and hips.  They dash off aft.^^Space
	Moose shrugs.  ~Looks like it's you and me,~ he opines,
	slouching into a chair.";
	if (line == 4) print "  ~I wasn't sure you had any decent beer,
	so...~ he tosses you a Pabst Blue Ribbon.";
	else print "~This always happens.  So I brought some beer.~
	    He tosses you a Pabst Blue Ribbon.";
	print "^^Then he sparks up a truly enormous joint, takes a giant
	toke, and passes it over.  Many hours of masculine cameraderie
	later, you pass out.^^Some time after that...^^";
	PressKey();
	print "^^";
	remove self;
	move dark_moose to darkroom;
	give dark_moose ~moved;
	give uniform ~worn;
	move uniform to bridge;
	object_obj = NULL;
	object_pic = NULL;
	penis.setStatus(20);
	PlaySound(gg_backchannel,mus_dark,1);
	back_mus = mus_dark;
	PlayerTo(darkroom);
	"You are not alone";
    ],
    has scenery, 
    ;

StiffyMan dark_moose "Space Moose"
    with name "Space" "Moose",
    description "Well, it's too dark to see, but you can tell from the
    smell that Space Moose is in here.",
    InitQuips[;self.QuipOn(1);],
    SayQ [line;
	interlocutor = self;
	switch(line) {
	 1: "~Space Moose, I can tell you're there.  What's going
	    on?~";
	 2: "~Uh, OK.~";
	 3: "~Well...as long as you don't try anything
	    funny.~";
	 4: "~No.~";
	 5: "~It's a laugh riot.~";
	 6: "~No!  Not funny at all!~";
	 7: "~I know I'm going to regret this, but, um, what is
	    that?~";
	 8: "~You go first.~";
	 9: "~Me!  Me!  Pick me!~";
	 10: "~How about we 69 each other?~";
	 11: "~Wait a goddamn minute here, Space.  I'm not about to
	    have sex with you!~";
	}
    ],
    Respond [line;
	interlocutor = 0;
	switch(line) {
	 1: self.QuipOff(1);
	    self.QuipsOn(3,2,3,4);
	    ! Our first clue to Stiffy's true identity, for the true
	    ! aficionado.
	    print "~Hey, buddy.  I just shat my bed.  Can I sleep with you
	    tonight?~^^";
	    <<TalkTo self>>;
	 2: self.QuipsOff(3,2,3,4);
	    move moosecock to self;
	    self.QuipOn(7);
	    "~Thanks, pal.~  Space Moose settles down next to you.
	    Something large, warm, and hairy presses against your leg.";
	 3: self.QuipsOff(3,2,3,4);
	    self.QuipsOn(2,5,6);
	    print "~Do you consider aggravated homosexual assault funny?~^^";
	    <<TalkTo self>>;
	 4: self.QuipsOff(3,2,3,4);
	    self.QuipOn(7);
	    "~Aww, that's not very friendly.~  Ignoring your protests,
	    Space Moose lies down.  Something large, warm, and hairy
	    presses against your leg."; 
	 5: self.QuipsOff(2,5,6);
	    self.QuipOn(7);
	    move moosecock to self;
	    "~Hmmmm.  Well, maybe you need a little cheering up.~
	    Space Moose lies down next to you.  Something large, warm,
	    and hairy presses against your leg.";
	 6: self.QuipsOff(2,5,6);
	    self.QuipOn(7);
	    move moosecock to self;
	    "~Well, alrighty then.~  Space Moose settles in, and
	    something large, warm, and hairy presses against your
	    leg.";
	 7: self.QuipOff(7);
	    print "~It's one of ",(italics) "these",".~  Space Moose says,
		    as he grabs your cock.";
	    
	    if (penis.getStatus() < GREASY) {
	     	print "  ~Except it's hard.~";
	    }
	    penis.changeStatus(4);
	    self.QuipsOn(4,8,9,10,11);
	    give self on;
	    print "  You have to admit, it feels pretty good.  ~So, do you
	    want to go first, or should I?~ asks Space Moose.^^";
   	    <<TalkTo self>>;
	 8: self.QuipsOff(4,8,9,10,11);
	    print "~Well, don't let me stop you.~^^";
	    self.feelmoose();
	 9: self.QuipsOff(4,8,9,10,11);
	    self.blowplayer();
	    print "~Guess what?  Your turn.~^^";
	    self.feelmoose();
	 10: self.QuipsOff(2,10,11);
	    print "~Um, the antlers get in the way,~ says Space Moose
	    apologetically.^^"; 
   	    <<TalkTo self>>;
	 11: self.QuipOff(11);
	    print "~Actually, you are. Unless you just want to sit here in 
	    the dark, sulk, and refuse to advance the plot because 
	    of your rampant homophobia. So: who's first, me or you?~^^";
   	    <<TalkTo self>>;
	}
    ],
    react_before [;
     Smell: if (noun == nothing) <<Smell self>>;
     Taste: if (noun == nothing) <<Taste self>>;
     Listen: if (noun == nothing) <<Listen self>>;
    ],
    before [;
     Smell: if (self hasnt on) 
	 "The unmistakable pungency of unwashed moose scrotum hangs
	 heavy in the room.";
	"There's the warm, earthy smell of unwashed moose
	scrotum.";
     Rub,Touch: if (self hasnt on) 
	 "Your groping hand clutches something warm, firm,
	 resilient, and furry.  Space Moose chuckles.";
	self.feelmoose();
	rtrue;
     Listen: "You hear heavy breathing.";
     Taste,Blow: if (self hasnt on)
	 "You stick out your tongue, but encounter nothing.";
	self.suckmoose();
	rtrue;
     Fuck: "~I don't feel like catching today,~ says Space Moose.
	~Pitching, on the other hand...~";
     Kiss: if (self hasnt on) 
	 "~That's pretty darn romantic!~ exclaims Space Moose.";
	self.suckmoose();
	rtrue;
    ],
    feelmoose [;
	if (self has general)
	    "Oh, you're feeling him all right.  Feeling him
	    knock-knock-knocking at your back door.";
	print "You reach out and tentatively stroke Space Moose's cock.
	It's covered in downy fur.  He purrs with pleasure and then
	    grabs you by the ears.  Firmly but gently he forces your
	    head toward his crotch.^^";
	self.suckmoose();
	rtrue;
    ],
    suckmoose [;
	if (self has general)
	    "It isn't your mouth Space Moose wants.";
	print "Fearing the worst, you tentatively lick Space Moose's
	    thick, meaty cock.  It doesn't taste half bad, actually,
	    and you give the glans an experimental swipe with your
	    tongue.  Space Moose shudders.^^
	    You know, this isn't so difficult after all.  You take a
	    little of the shaft into your mouth.  No gag.  The scent
	    of aroused-moose sweat is making you ";
	if (penis.getStatus() < GREASY)
	    print "horny";
	else
	    print "hornier";
	penis.changeStatus(5);
	print ".^^Experimentally, you try deep-throating the moose
	    dick.  Hey, this isn't so difficult after all!  What are
	    the women always complaining about?  ", (italics) "A guy
	    could get used to this", ", you think, as you grind your
	    throat up and down on Space Moose's penis.^^";
	print "Just as you're really getting into your rhythm, Space
	    Moose withdraws, and a huge hand forces you flat on your
	    stomach.^^~Open wide,~ leers Space Moose, and you feel
	    something poke against your sphincter.";
	darkroom.cant_go = "Space Moose has you firmly pinned.";
	self.QuipsOff(5,1,2,3,4,5);
	self.QuipsOff(5,6,7,8,9,10);
	self.QuipOff(11);
	give self general;
	"";
    ],
    blowplayer [;
	print "~How about a little Moosehead?~ chuckles Space.^^
	    Without waiting for a reply, he engulfs your ";
	    if (penis.getStatus() < GREASY) print "limp dick, rapidly
	    stimulating it to its full throbbing glory";
	    else print "rampant stiffy";
	print ", rolling it between his thick, cervoid tongue and
	    his palate.  With finely-honed skill, he deep-throats
	    you, and, incredibly quickly, brings you to
	    orgasm.  As the first squirt of cum hits his tongue,
	    Space Moose pulls your cock out of his mouth and rubs
	    it against his velvety antlers.  The feeling is
	    exquisite, and you express your appreciation by
	    delivering what feels like a quart of semen onto Space
	    Moose's face.^^";
	penis.ejaculate();
	PressKey();
	print (italics) "^^***SPLORT***";
	print "^^~Damn,~ you moan.  ~That was the best blowjob I've
	    ever had.~^^~Think about it,~ says Space Moose,
	    licking the sperm from his antlers.  ~I'm a guy.  I
	    have a dick too.  Of ",(italics) "course"," I know
	    what feels good better than any woman could.  Well,
	    except for women who used to be guys.  But we don't
	    have any of those in this game.~^^";
	! I believe that I have coined the term "antler job"
	print "~And, of course,~ he preens, ~any man can blow you.
	    But for an antler job, it takes a moose.~";
	give self visited;
	"";
    ],
    daemon [;
	if (player has general) {
	    give player ~general;
	    print "^~Uuuuuhhhhhhhh!~ moans Space Moose, as he rams his
	    	throbbing cock into your ass.  He's right!  It really
	    	doesn't hurt, and does, in fact, feel like taking a big
	    	dump.  But in reverse.  Still, it's not unpleasant.  In
		fact, you're really starting to enjoy yourself when
		Space Moose shouts
		~Aaaaaaaaaaaahhhhhhhhhhhhahhhhhhhhhh!~ and empties
		about a gallon of moose sperm into your rectum.^^";
	    if (self hasnt visited) {
		print "~Okay, your turn!~ exclaims Space Moose.^^";
		self.blowplayer();
	    }
	    print "Utterly drained, you fall asleep.^^";
	    give self moved;
	    PressKey();
	    remove self;
	    StopSound(gg_backchannel);
	    back_mus = 0;
	    ClearWindow(gg_mainwin);
	    Achieved(TASK_SPACEMOOSE);
	    tasks_done->TASK_SPACEMOOSE = 1;
	    give nightstand open;
	    move fiver to nightstand;
	    move uniform to junction;
	    move morningmoose to bridge;
	    scene = 4;
	    PlayerTo(bed);
	} else {
	    "^~Relax!~ orders Space Moose, as his choad presses against
	    your tightly clenched anus.  ~It doesn't even hurt.  It
	    just feels like taking a big dump.~  His weight presses
	    you down.";
	}
    ],
    ;

StiffyPenis moosecock "moose penis"
    with name "moose" "large" "warm" "hairy",
    before [;
     Rub,Touch: dark_moose.feelmoose();
	rtrue;
     Taste,Blow,Kiss: dark_moose.suckmoose();
	rtrue;
     Smell: "It has the unmistakeable tang of moose scrotum.";
     FucK: "Little problem there, Captain.  Two outies.  No innies.";
     Examine,Look: "You can't see it, but you're sure you know where it
    	is.";
    ],
     has scenery,
    ;

StiffyMan morningmoose "Space Moose"
    with name "space" "moose",
    description "Space Moose lounges here, looking dapper.",
    picture pic_moosehead,
    InitQuips [;self.QuipsOn(2,1,2);],
    SayQ[line;
	interlocutor = self;
	DrawObjectPic(self);
	switch(line) {
     	 1: "~Uh, hi.~";
     	 2: "~You sonofabitch!  You raped me!  Get your filthy paws off
	    me, you damn dirty moose!~";
     	 3: "~Sore!  Damn you and your meaty moose choad!~";
     	 4: "~Oooh baby, it hurts so good.~";
     	 5: "~Yes.~";
     	 6: "~Yes.~";
     	 7: "~Yes.~";
     	 8: "~Goddamn it!  This isn't fair!  The fucking game author will
	    only let me answer 'yes!'  This sucks!  No!  I hated
	    it....AUGH!  I have no free will!  YES!~";
     	 9: "~Hey, Space, you shouldn't smoke.  It's bad for you.~";
     	 10: "~Put that out.  Secondary smoke could hurt me.~";
    	}
    ],
    Respond [line;
	interlocutor = 0;
	switch(line) {
     	 1: self.QuipsOff(2,1,2);
	    self.QuipsOn(2,3,4);
	    print "~Hey!  How's the ol' poop chute, Stiffy?~^^";
	    <<TalkTo self>>;
     	 2 to 3: self.QuipsOff(4,1,2,3,4);
	    self.QuipsOn(4,5,6,7,8);
	    print "~Yeah, well, yeah, but you enjoyed it, didn't you?";
	    <<TalkTo self>>;
     	 4 to 7: self.QuipsOn(2,9,10);
	    self.QuipsOff(6,3,4,5,6,7,8);
	    move cigarette to morningmoose;
	    "Space Moose preens, grins, and lights a cigarette.";
     	 8: self.QuipsOn(2,,9,10);
	    self.QuipsOff(5,4,5,6,7,8);
	    move cigarette to morningmoose;
	    "Mimesis cries!^^A hollow voice intones, ~This destruction
	    of the fourth wall brought to you by a grant from Big
	    Boy's Steel Erection, St. Louis, Missouri.~^^
	    Space Moose, on the other hand, just laughs
	    and lights a cigarette.";
     	 9: self.QuipsOff(2,9,10);
	    print "Space Moose laughs.  ~It's sweet that you're concerned
	    	about my health.~  He takes a long drag.^^";
	    self.boringcutscene();
     	 10: self.QuipsOff(2,9,10);
	    print "Space Moose snorts.  ~The unprotected anal sex, I'm
	    	thinking, is maybe a bit more of a risk factor.~^^";
	    self.boringcutscene();
    	}
    ],
    boringcutscene [;
	PlaySound(gg_forechannel,snd_transporter);
	print "From the hall comes the pitter-patter of little feet, 
	    biological and bionic, and a furtive giggling. Then the 
	    noise of the transporter energizing, followed by the ", (italics)
	    "Mauve Armadillo", " suddenly blasting away and 
		    vanishing into space.^^Space Moose moans. ~That 
		    fucking badger.~^^";
	junction.w_to = "The door will not open for you.  Scrawled
	    across it in bright red lipstick are a big heart with ~B+T~
	    written in the middle, and a short manifesto: ~Gone to
	    Risa.  Tee Hee!  Love, Billy and Terri~.";
	give self general;
	if (olmak has general)
	    "~I guess I'll have to ride along to Olmak with you.~";
	else
	    "~Would you mind dropping me off at Olmak?  I kinda need
	    to get back there.~";
    ],
    has transparent,
    ;

! Thank you, Matt Fendahleen
StiffyMan kaak "K'aa'k"
    with name "kaak" "klingon" "k^aa^k",
    description "K'aa'k, Dread Rear Admiral of the Klingon Fleet.
    K'aa'k, Destroyer of Worlds.  K'aa'k, Scourge of the Spaceways.
    K'aa'k.",
    counter 0,
    state 0,
    picture pic_kaak,
    daemon [;
	self.counter++;
	if ((self.counter > 10) && (self.state < 5)) {
	    deadflag = true;
	    "^K'aa'k yawns hugely.  ~Your procrastination has become
	    tiresome.~^^He gestures, and the crowd leaps from the
	    stands upon you, raping, eating, and disembowelling you,
	    not necessarily in that order.";
	}
	switch (self.state) {
	 0: if (self.counter > 4) {
	     self.counter = 0;
	     self.state = 1;
	     remove trousers;
	     self.picture = pic_kaak_nude;
	     DrawObjectPic(self);
	     move kaak_cock to kaak;
	     move kaak_ass to kaak;
	     "^K'aa'k grins hugely and peels off his trousers to reveal
	     a titanic dick, even larger than Space Moose's.^^
	     Effortlessly, he smashes you to the ground and begins to
	     press his penis against your anus.";
	 }
	    switch (self.counter) {
	     1: "^K'aa'k bows to the crowd.";
	     2: "^K'aa'k ostentatiously rubs his erection through his
		trousers.";
	     3: "^K'aa'k slowly strokes his bulging crotch.";
	     4: "^K'aa'k laughs maniacally.";
	    }
	 1: if (player has general) {
	     self.state = 2;
	     self.counter = 0;
	     "^K'aa'k suddenly plunges full length into your distended
	     asshole.  He seems surprised that you're not howling in
	     pain.  He thrusts a few times experimentally, growls ~No
	     friction!~ and withdraws.^^
	     Giving you a calculating look not untinged with
	     respect, he gets on his hands and knees on the arena
	     floor.  ~Over to you, Captain Makane.~";
	 }
	    if (self.counter > 5) {
		deadflag = true;
		"^With a shout, K'aa'k thrusts right through your
		sphincter, tearing muscle, flesh, and bone, and in
		fact causing you to explode like a sledgehammered
		watermelon.";
	    }
	    if (self.counter > 4)
		"^K'aa'k shoves hard at your puckered ringpiece, nearly
		penetrating it.  ~Arrr!~ he snarls piratically.";
	    if (self.counter > 2)
		"^The pressure is becoming more insistent.  K'aa'k's
		forehead beads with sweat as he pushes.";
	    "^K'aa'k growls, ~Quit struggling, little one,~ as he tries
	    to gain entry.";
	 2: if (penis.getStatus() < GREASY)
	     "^K'aa'k sneers.  ~You'll have to do better than ",
		 (italics) "that", ", little man.";
	    if (self.counter == 2) "^K'aa'k helpfully points out, ~Open
	    for business.~";
	    if (self.counter == 5) "^K'aa'k growls, ~What are you
	    waiting for?~";
	    if (self.counter == 8) "^K'aa'k checks his watch.";
	    "^K'aa'k shifts his weight impatiently.";
	 3:if (self.counter > 1) {
	     switch(random(5)) {
	      1: "^K'aa'k tosses his erection from one hand to the
	     	 other.";
	      2: "^K'aa'k grumbles, ~Hurry up!  It isn't chess!~";
	      3: "^K'aa'k beats you about the face with his penis.";
	      4: "^K'aa'k whistles the theme from ~Jeopardy.~";
	      5: "^K'aa'k yawns hugely.";
	     }
	 }
	 4: if (player hasnt open) {
	     switch (self.counter) {
	      1: "^A ghostly voice in your head says, ~Suppress your gag
	     	 reflex, Stiffy!~";
	      2: "^You can't breathe!";
	      3: "^The ghostly voice becomes more insistent: ~Look, you
	     	 moron, suppress your gag reflex, or you're gonna choke to
	     	 death.~";
	      4: "^You begin gagging and choking, your arms and legs
	     	 flailing wildly.  K'aa'k howls in triumph.";
	      5: deadflag = true;
	     	 "^You asphyxiate.  As everything goes dark, the last thing
	     	 you hear is K'aa'k's hyena-like laughter ringing in your
	     	 ears.";
	     }
	 }
	    switch (self.counter) {
	     1: "^K'aa'k blinks in surprise.";
	     2: "^K'aa'k growls, grabs you by the ears, and thrusts
		the entire length of his cock down your throat.  No
		problem.  In fact, the way it tickles your esophagus
		feels kind of good.";
	     3: penis.changeStatus(2);
		"^Wow, the ridges on K'aa'k's dick are creating some
		really neat sensation as they rub against the back of
		your throat.  He's now bucking furiously.";
	     4: "^The head of K'aa'k's boner hits your pyloric
		sphincter, which is surprisingly erotic.  He looks
		puzzled and perhaps concerned, in a
		very-close-to-orgasm sort of way.";
	     5: self.state = 5;
		self.counter = 0;
		self.QuipOff(10);
		self.QuipsOn(2,1,2);
		"^Finally, K'aa'k cums, cutting loose with a blast of
		rancid Klingon spooge.  You've tasted worse things.
		It is no trouble at all to gulp it all down, while
		continuing to massage the head of his penis with your
		throat muscles.  His knees tremble, and then buckle as
		he falls to the floor.  Shakily, he stands.^^
		~Wait!~ he cries.  ~There is something I must tell
		you first.~";
	    }
	 }
    ],
    InitQuips [;self.QuipOn(9);],
    SayQ [line ;
	DrawObjectPic(self);
	interlocutor = self;
	switch (line) {
	 1: "~Talk, K'aa'k.  But make it snappy.~";
	 2: "~Wait, wait, let me guess: you're my father.~";
	 3: "~No!  That's not true!  That's ",
	    (italics)"impossible","!~";
	 4: "~Yeah, like I didn't see that one coming.~";
	 5: "~How can that be, when ",(italics) "I"," am ",
	     (italics)"your"," father?~";
	 6: "~K'aa'k, blow me.~";
	 7: "~Like father, like son.  Blow me.~";
	 8: "~Like fath...um, no, wait...like son, like father.  Blow
	    me, and always remember: ",(italics) "Who's Your Daddy?","~";
	 9: "~Er, is this really necessary?~";
	 10: "~Mmmmpghgh!~";
	}
    ],
    Respond [line;
	interlocutor = 0;
	self.QuipOff(line);
	switch (line) {
	 1: self.QuipOff(2);
	    self.QuipsOn(3,3,4,5);
	    print "~Stiffy...", (italics) "I am your father",".~^^";
	    <<TalkTo self>>;
	 2: self.QuipsOn(2,4,5);
	    self.QuipOff(1);
	    print "K'aa'k looks very embarassed.  ~Er...yeah,~ he
		mutters.^^";
	    <<TalkTo self>>;
	 3: self.QuipsOff(2,4,5);
	    self.QuipOn(6);
	    print "~Your perception does you great credit.  Indeed, it is
	    not possible.~^^";
	    <<TalkTo self>>;
	 4: self.QuipsOff(2,3,5);
	    self.QuipOn(7);
	    print "K'aa'k shrugs.  ~It's not easy being a pastiche.  So,
	    you're not an incestuous pervert, are you, my darling
		boy?~^^";
	    <<TalkTo self>>;
	 5: self.QuipsOff(2,3,4);
	    self.QuipOn(8);
	    print "~Daddy!~ shrieks K'aa'k.^^";
	    <<TalkTo self>>;
	 6 to 8: self.QuipsOff(3,6,7,8);
	    self.blowstiffy();
	    rtrue;
	 9: "~No chitchat!  Ro-Sham-Bo!~";
	 10: "K'aa'k laughs uproariously.";
	}
    ],
    blowstiffy [;
	print "K'aa'k's nostrils flare and his eyes widen as you put
	    your feces-smeared stiffy into his mouth.  He grimaces in
	    disgust, but begins to gamely fellate your ";
	if (penis.getStatus < GREASY)
	    print "limp ";
	else
	    print "hard ";
	print "dick.  He may have you beat in the size category, but
	    you have had Jedi Tantric Training that he has,
	    apparently, forgotten.  You toy with him a while, and then
	    summon your powers for a mighty Jedi Sperm Bolt.^^";
	penis.ejaculate();
	PressKey();
	print "^^",(italics) "****SPLORT****";

	! This is the first of two less-violent changes I made in the
	!  wake of the September 11 terrorism.  Even cartoonish
	!  violence didn't seem as funny anymore, and I figured I'd
	!  make the game gayer rather than grimmer.
	
!	print "^^The force of your ejaculation rips K'aa'k's head
!	    completely from his body.  It rolls to the edge of the
!	    arena and bounces off the wall, a comical expression on
!	    its face, semen leaking from not only the mouth and nose,
!	    but ears, neck stump, and ruptured eye sockets.^^
!	    The crowd goes wild.^^
!	    You are treated as a hero at the victory banquet,
!	    consuming bowl after bowl of qagh and cheap Orcish gin.
!	    Attractive young warriors offer to satisfy your every
!	    desire.  Everything is wonderful right up until the gin
!	    catches up with you, and without warning, the world
!	    suddenly goes black.^^";
	print "^^K'aak's eyes roll back in his head, and he collapses
	    backwards, unconscious.^^
	    The crowd goes wild.^^
	    You are treated as a hero at the victory banquet,
	    consuming bowl after bowl of qagh and cheap Orcish gin.
	    Attractive young warriors offer to satisfy your every
	    desire.^^
	    When K'aa'k comes to, he repents his vicious piratical
	    ways, and he and his crew decide to abandon the
	    space-privateering business to form a colony of interior
	    decorators devoted to the art of zero-G ",(italics)"Feng
	    Shui",".^^
	    They hastily beam you back to your ship and depart in a
	    flutter of enthusiasm.  You collapse on your bed, full of
	    goodwill and gin.^^";
	! Cheap Orcish gin is also "cheap roadside intertextuality."
	PressKey();
	print "^^";
	move self to limbo;
	StopSound(gg_backchannel);
	object_obj = 0;
	object_pic = 0;
	scene = 6;
	Achieved(TASK_KAAK);
	tasks_done -> TASK_KAAK = 1;
	move uniform to quarters;
	give uniform ~worn;
	penis.setStatus(0);
	move tattoo to player;
	give tattoo worn;
	computer.speed = 0;
	DrawStiffyPic(pic_uniform);
	ClearWindow(gg_objectwin);
	move excretus to bridge;
	viewscreen.picture = pic_excretus;
	PlaySound(gg_forechannel,snd_alert,0,3,1);
	print "^You are awakened by the sound of the alert klaxon.^^The
	computer snaps at you: ~We've got a situation, Captain.
	Report to the bridge, pronto.  And put on some fucking
	pants.~^";
	! Notice that I went to lots of trouble to make
	! >PUT ON SOME FUCKING PANTS
	! work OK.
	PlayerTo(bed);
    ],
    before [;
     Kiss, Taste, Rub, Touch: "K'aa'k backhands you.  ~Foreplay is
	dishonorable!~";
     Smell: "K'aa'k reeks of testosterone.";
     Fuck: switch(self.state)
     {
      0 to 1:
	 "~You misunderstand Ro-sham-bo!~ shrieks K'aa'k.  ~I go
	 first!~";
      2: if (penis.getStatus() < GREASY) "You'd love to, but your
	 penis simply isn't hard enough.";
	 self.counter = 0;
	 self.state = 3;
	 penis.setStatus(45);
	 "You jam your stiffy into K'aa'k's waiting ass.  It's
	 awfully loose, and you don't get a whole lot of friction,
	 although it doesn't feel bad.  Then K'aa'k clamps down.^^
	 If Space Moose hadn't taught you the Jedi Tantric
	 Secrets, you would have folded over in pain right then
	 and there.  Instead, you counter with a penile throb that
	 makes K'aa'k's eyes widen.  He scurries forward off your
	 dick, leaving it besmeared with Klingon klingons, and
	 stands up.^^
	 Smiling grimly, he forces you to your knees.  ~Suck!~ he
	 commands.";
      default:
	 "~We've done that already!~ K'aa'k yells.";
     }
     Blowjob: switch(self.state) {
      0 to 1:
	 "~Your eagerness does you credit.  But fellatio is not my
	 desire!~";
      2: "~That is not,~ K'aa'k warns, ~how Ro-sham-bo is played.~";
      3: self.counter = 0;
	 self.state = 4;
	 self.QuipOff(9);
	 self.QuipOn(10);
	 ! cf. DM4, p. 169, again
	 "With a great deal of trepidation, you slowly take the head
	 of K'aa'k's gigantic penis into your mouth.  The stench of
	 shit is overpowering and nearly makes you gag, even with all
	 your training.  Good thing you and Space Moose were giving
	 each other narcotic enemas right before you got here.^^
	 K'aa'k smiles evilly, and thrusts; his choad clogs your
	 throat, cutting off your windpipe.  You can feel that you're
	 about to gag and choke!";
      4: "Let's see.  Can't breathe, Klingon dick massaging tonsils,
	 Klingon scrotum slapping chin...what do you think you're
	 doing ", (italics) "now",", if I may ask?";
      default: "Once was quite enough.";
     }
    ],
    has transparent,
    ;

MyObject -> trousers "trousers"
 with 	name "trousers" "pants" "culottes" "uniform" "crotch"
	    "bulging" "erection" "choad" "cock" "dick",
	description "Although standard-issue Klingon uniform pants, they
	    reek of menace.  Especially across the tightly-stretched,
	    bulging crotch.",
	before [;
	 Smell:  "Whoa!  Menacing.";
	],
        picture pic_trousers,
 has 	scenery	pluralname,
	;

Orifice kaak_ass "ass"
 with 	name "ass" "butt" "asshole" "anus",
	description "Nasty Klingon ass.",
	before [;
	 Kiss, Rub, Touch, Taste, Smell: "Upon reflection, you decide
	    you don't want to go there.";
	 Fuck: <<Fuck kaak>>;
	 default: "K~aa~k snarls at you, baring his incisors.";
	],
	;

StiffyPenis kaak_cock "K'aa'k's cock"
 with 	name "kaak" "k^aa^k" "kaaks" "kaak^s" "k^aa^k^s",
 description "Like his forehead, K'aa'k's cock is ridged.  It is also
	    veiny, purple, and utterly gigantic.",
    picture pic_kaak_cock,
    before [;
     Blowjob,Taste,Kiss: <<Blowjob kaak>>;
     Fuck: "The ridges aren't deep enough";
     Smell: "Powerfully funky.";
     Rub, Touch: <<Rub kaak>>;
    ],	
 has 	proper,
	;

StiffyMan excretus "Borg",
    with name "excretus" "of" "borg" "moose" "space",
    description "The Borg looks kind of like Space Moose in tight
    black leather, with a funky monocle and a scary laser gun.",
    counter 0,
    picture pic_excretus,
    InitQuips [;self.QuipOn(1);],
    SayQ[line ;
	interlocutor = self;
	DrawObjectPic(self);
	switch(line) {
     	 1: "~Identify yourself.  This is Captain Stiffy Makane of the
	    Starship ",(italics) "Turgidity",", NCC 69105-DD.~";
	 2: "~Say, do you know a guy named Space Moose?  Are you his
	    cousin?  You look kinda like him.~";
	 3: "~Can you say anything else?~";
	 4: "~All righty, then.~";
	}
    ],
    Respond[line;
	interlocutor = 0;
	self.QuipOff(line);
	if (line<4) {
	    self.QuipOn(line+1);
	    switch(line) {
	     1: print "~I am ",(italics)"Excretus"," of Borg! ";
		if (PlayerIsNaked())
		    print "Put on some fucking pants! ";
	     default: print "~";
	    }
	    print "You will be ",
	    	(italics) "ASS","imilated!~^^";
	    <<TalkTo self>>;
	} else {
	    print "~You will be ",
	    	(italics) "ASS","imilated!~^^";
	    remove self;
	    ClearWindow(gg_objectwin);
	    object_obj = 0;
	    object_pic = 0;
	    viewscreen.picture = pic_borg;
	    master_daemon.counter = 0;
	    print "The screen goes dark as Excretus severs the
	    communication link.^^";
	    give self general;
	    "The computer clears its throat nervously.  ~Um,~ it
	    begins. ~Borg attempting takeover of computer
	    systems. Success in approximately ten minutes.  I
	    suggest,~ it continues, ~that you give any final
	    orders to me quickly.  If you wish to retain control
	    of the ship, proceed to the biobed and engage it, to
	    establish a direct brain-computer connection.  Be
	    aware that doing so will expose your mind to the
	    Borg's brain-control techniques.  Additionally, it
	    will void your warranty.  Have a nice day.~";
	}
    ],
    has scenery ~proper,
    ;

StiffyActor borg "Borg ship",
    with name "borg" "ship" "excretus" "ass" "hot" "sexy" "waiting",
    description "The Borg ship is a cube about a mile on a side.  Of
    course, to you it also occasionally looks like a hot, waiting,
    ass.  Funny thing, the interpretation your mind brings to things.",
    picture pic_borg,
    before [;
     Fuck: if (penis.getStatus() < GREASY)
	 "You lack the erection, metaphorically speaking.  Maybe that
	 means none of the ship's weapons are armed?";
	scene = 8;
	print "Well, it's perfectly obvious what to do.  You simply
	    plunge forward into the center of the Borg Ship/Hot Borg Ass,
	    and summon up a Jedi Sperm Blast.^^";
	Achieved(TASK_BORG);
	tasks_done -> TASK_BORG = 1;
	snd_magic = THROBBING;
	back_mus = 0;
	penis.ejaculate();
	PressKey();
	StopSound(gg_backchannel);
	print "^^",(italics) "*****SPLORT*****";
	deadflag = 2;
	scene = 9;	
	dummy.picture = pic_excretus;
	DrawBigPic(dummy);
	dummy.picture = pic_smcolor;
	DrawObjectPic(dummy);
	print "^^You cum, and the ",(italics) "Turgidity's", "weapons
	    fire; the Borg Cube, attacked from the inside, where its
	    defenses are weak, 	shudders and convulses.^^
	    A voice speaks inside your head: ~So, human,
	    ",(italics)"this"," is what you mean by sex!  That's much
	    more fun than assimilation!  I must ponder...aha!~^^
	    You listen in shock as the Borg describes its plans to
	    abandon galactic conquest and start a fashion empire,
	    ~House of Borg,~ specializing in sexy, tight black leather
	    clothing.^^
	    The Borg cube, now gaily rainbow-painted, spits out the
	    ",(italics)"Turgidity"," like 
	    a watermelon seed, and the sudden acceleration causes you
	    to black out.^^";
	! Here comes the DFC reference....hang on tight
	print "You awaken to the feel of a strangely familiar hairy
	    penis on your lips.  ~Hi,~ says Space Moose.  ~It didn't
	    seem like you were doing anything more important, so...~
	    He tousles your hair affectionately.  ~You little
	    sperm-burping gutter-slut, you.~^^
	    After some heartfelt fellatio, you determine that in fact
	    Space Moose had teleported away into Borg Space to avoid
	    K'aa'k's light sabre, and had only been freed from
	    thralldom when the Borg decided to pursue fashion design
	    rather than galactic conquest.^^^^^^^^^";
	PressKey();
	ClearWindow(gg_mainwin);
	dummy.picture = pic_dwarf;
	DrawObjectPic(dummy);
	dummy.picture = pic_teacher;
	DrawBigPic(dummy);
	"^^The storyteller closes her book.  ~And that, children,~ she
	concludes, ~is the story of how Space Moose met Bald Dwarf.~";
    ],
    react_before [;
     Xyzzy: "A Hollow Voice says, ~This is a bit beyond my powers.
	Sorry.~"; 
     Suppress, Relax: "That might work very well on your physical
	body; in fact, since you can monitor its vitals, you can
	see that it ", (italics) "does", " work very well.  But
	that does nothing to ease the insistent throbbing in your
	brain, or the pressure on the ship.";
     Fuck, Masturbate: rfalse;
     Rub, Touch, Pull: if (noun == penis) {
	 if (penis.getStatus() < GREASY) {
	     give torpedo general;
	     penis.setStatus(GREASY + 2);
	     "You masturbate, and feel your photon torpedos arm.";
	 } else if (penis.getStatus() < THROBBING) {
	     give torpedo general;
	     give phaser general;
	     penis.setStatus(THROBBING + 5);
	     "You stroke yourself.  All weapon systems are now
	     armed.";
	 } else {
	     "All weapon systems are already armed.  But it does feel
	     good.";
	 }
     }
	"You can't seem to do that without a body.";
     Inv,Look,Examine: rfalse;
     default: "You can't seem to do that without a body.";
    ],
    has scenery,
    ;