{ synonyms of calyx2.adl verbs }

tell = TELLER; say = TELLER; whisper = TELLER; mumble = TELLER;
	explain = TELLER;

shut = close;
destroy = break; annihilate = break; crush = break; vaporize = break;
	smash = break; kill = break;
clean = rub; polish = rub;
decypher = read;
inspect = examine; look at = examine; look in = examine; look on = examine;


{ verbs for da }

VERB	commercial,		{ about the Shareware costs }
        count,			{ for counting men and army strength }
	drink,
	eat,
	fuck,			{ curses ! }
	help,			{ general info }
	jump,
	kick,
	score,			{ how high can you go ? }
	kiss,
	lie,
	sit,
	show,
	give,
	play,			{ in instrument, a game }
	pull,
	push,
	laugh,
	cry,
	spit,
	use,			{ the main usage of an obj }
        recruit,		{ recruiting into the army }
	army,			{ info about the army }
	bite,
	dig,
	cut,
	tie,
	hug,
	rape,
	torture,
	hit;

copyright = commercial; shareware = commercial;
gulp = drink; swallow = drink; quaff = drink;
crunch = eat; chew = eat;
shit = fuck; motherfucker = fuck; asshole = fuck;
hint = help; clue = help;
hop = jump;
smile = laugh; giggle = laugh; cackle = laugh; chuckle = laugh; grin = laugh;
sob = cry; weep = cry;
press = push;
offer = give;
chomp = bite;
severe = cut;
bind = tie;
pet = hug; stroke = hug;
punch = hit; strike = hit; jab = hit;
rip = pull;

{ See the commentary in da.adl }
INCLUDE "da.o.adl";



MESSAGE "army, ";
army(PREACT) = (Expect NO_OBJ NO_OBJ);
army(ACTION) =
	($say
"Your army consists of " ($str @ArmyNum) " men. Its current strength is "
($str @ArmyStr) ".\n"
	)
;

MESSAGE "bite, ";
bite(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
bite(ACTION) = ($say "Nothing happens.\n");

{ Forget the message. Dark Army is, in its current state, Freeware. I just
  left the messages in for the sake of completeness. }
MESSAGE "commercial, ";
commercial(PREACT) = (Expect NO_OBJ NO_OBJ);
commercial(ACTION) =
	($say
"  Perhaps you should know that I really spent a lot of time on this "
"game. -- Not that I didn't like it, but sometimes I just couldn't seem "
"to find the damn bug, and that's really a drag.\n"
"  So if you love it (or, in fact, like it) you can send me some money "
"to encourage me writing more of that stuff.\n"
"  I release the game as Shareware, but I don't want to estimate what my "
"work is worth to you. So I suggest that you send me any amount you think "
"I deserve.\n"
"  \"Dark Army\" is copyrighted 1992, 1996 by Miron Schmidt.\n"
"  It was written using ADL, which is copyrighted 1987 by Ross Cunniff.\n"
"  If you want to send money, send it to:\n"
"	Miron Schmidt\n"
"	Eibischstr. 9\n"
"	12357 Berlin\n"
"	GERMANY\n\n"
	)
;

MESSAGE "cry, ";
cry(PREACT) = (Expect NO_OBJ NO_OBJ);
cry(ACTION) = ($say "Well well. Everything will be alright.\n");

MESSAGE "count, ";
count(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
count(ACTION) =
	(IF ($eq ($prop @Dobj NUMPEOP) 0) THEN
		($say "You can't count that !\n")
	 ELSE
		($say "You count " ($str ($prop @Dobj NUMPEOP)) " of them.\n")
	)
;

MESSAGE "cut, ";
cut(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) ($or NO_OBJ ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
cut(ACTION) = ($say "You can't cut that.\n");

MESSAGE "dig, ";
dig(PREACT) =
	(Expect ($or NO_OBJ ONE_OBJ PLAIN_OBJ)
		($or NO_OBJ ONE_OBJ PLAIN_OBJ)
	)
	(CheckAvail)
;
dig(ACTION) = ($say "You have nothing to dig with.\n");

MESSAGE "drink, ";
drink(PREACT) =
	(Expect ($or ONE_OBJ MULT_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
drink(ACTION) =
	($say "You can't drink the " ($name @Dobj) ".\n")
;

MESSAGE "eat, ";
eat(PREACT) =
	(Expect ($or ONE_OBJ MULT_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
eat(ACTION) =
	($say "You can't eat the " ($name @Dobj) ".\n")
;

MESSAGE "fuck, ";
fuck(ACTION) =
	($say
"  Yeah ! That's the deal ! Fucking spoil my game by using words like "
"this. Hope you feel better now, anyway ...\n"
	)
;

MESSAGE "give, ";
give(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) ($or ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
give(ACTION) = (Silly);

MESSAGE "help, ";
help(PREACT) = (Expect NO_OBJ NO_OBJ);
help(ACTION) =
	($say
"  To recruit persons into your army, the verb \"recruit\" is used. "
"Otherwise you can count people (I found no simpler way to represent the "
"number), or do nasty things.\n"
"  The command \"army\" will give you some info about your current army.\n"
"  \"Commercial\" gives a little message about ... (guess what).\n"
	)
;

MESSAGE "hit, ";
hit(PREACT) = (Preact);
hit(ACTION) = ($say "Nothing happens.\n");

MESSAGE "hug, ";
hug(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
hug(ACTION) = ($say "Sweet. The " ($name @Dobj) " really needed that.\n");

MESSAGE "jump, ";
jump(PREACT) =
	(Expect ($or NO_OBJ ONE_OBJ PLAIN_OBJ) ($or NO_OBJ ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
jump(ACTION) = ($say "Geez, that was fun !\n");

MESSAGE "kick, ";
kick(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
kick(ACTION) = ($say "Nothing happens.\n");

MESSAGE "laugh, ";
laugh(PREACT) = (Expect NO_OBJ NO_OBJ);
laugh(ACTION) =
	($say "You are nice, indeed. Now go on and get your army.\n")
;

MESSAGE "lie, ";
lie(PREACT) =
	(Expect ($or NO_OBJ ONE_OBJ PLAIN_OBJ) ($or NO_OBJ ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
lie(ACTION) =
	(IF ($and ($not @Dobj) ($not @Iobj)) THEN
		($say "You lie down.\n")
	ELSE
		($say "You can't lie on that.\n")
	)
;

MESSAGE "play, ";
play(PREACT) = (Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ) (CheckAvail);
play(ACTION) = ($say "You can't play that.\n");

MESSAGE "pull, ";
pull(PREACT) = (Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ) (CheckAvail);
pull(ACTION) = (Silly);

MESSAGE "push, ";
push(PREACT) = (Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ) (CheckAvail);
push(ACTION) = (Silly);

MESSAGE "rape, ";
rape(PREACT) = (Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ) (CheckAvail);
rape(ACTION) = ($say "Pervert ! Besides, you got a job to do.\n");

MESSAGE "recruit, ";
recruit(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
recruit(ACTION) = ($say "That's never to be recruited !\n");

MESSAGE "score, ";
score(PREACT) = (Expect NO_OBJ NO_OBJ);
score(ACTION) =	(Skore);

MESSAGE "show, ";
show(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) ($or ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
show(ACTION) = (Silly);

MESSAGE "sit, ";
sit(PREACT) =
	(Expect ($or NO_OBJ ONE_OBJ PLAIN_OBJ) ($or NO_OBJ ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
sit(ACTION) =
	(IF ($and ($not @Dobj) ($not @Iobj)) THEN
		($say "Where do you want to sit ?\n")
	ELSE
		($say "You can't sit on that.\n")
	)
;

MESSAGE "spit, ";
spit(PREACT) =
	(Expect NO_OBJ ($or NO_OBJ ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
spit(ACTION) =
	(IF @Iobj THEN
		($say "You hit the " ($name @Iobj) ". Some saliva runs down.\n")
	ELSE
		($say "Ptuey!\n")
	)
;

MESSAGE "TELLER, ";
TELLER(PREACT) =
	(Expect ($or ONE_OBJ STR_OBJ) ($or ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
	($say "You don't expect an answer, do you?\n")
	($exit 1)
;
TELLER(ACTION) =
	($delact @Iobj)
	($actor @Iobj @Dobj FALSE)
;

MESSAGE "tie, ";
tie(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) ($or ONE_OBJ PLAIN_OBJ))
	(CheckAvail)
;
tie(ACTION) = ($say "You simply can't tie it.\n");

MESSAGE "torture, ";
torture(PREACT) = (Preact);
torture(ACTION) = ($say "You're really sick, you know that ?\n");

MESSAGE "use, ";
use(PREACT) =
	(Expect ($or ONE_OBJ PLAIN_OBJ) NO_OBJ)
	(CheckAvail)
;
use(ACTION) =
	($say
"Try to express how you intend to use the " ($name @Dobj) " exactly.\n"
	)
;

MESSAGE "... done!\n";
{ EOF verbs.adl for  D a r k  A r m y }