Constant Story "RUINE";
Constant Headline "^Ein interaktives Beispiel^\
		    Copyright (c) 1996 by Tinic Uro.^";

Constant MAX_SCORE    10;
Constant NUMBER_TASKS 4;

Array task_scores --> 3 2 2 3;

Include "gParser";
Include "gVerbLib";

Object Pfad_Ruine "Pfad zur Burgruine"
    with
    g_artikel_was 'der',
    description
	"Am Rande des Pfad, der in noerdlicher Richtung bis vor das Burgtor fuehrt, \
	finden sich die fuer diese Gegend typischen Fichten. Der Pfad selber laesst vermuten \
	dass wir hier auf der Alb sind, denn der Belag ist aus Kalkstein. Die Luft riecht \
	nach dem Harz der Baeume und der Himmel ist voellig wolkenfrei.",
    n_to Tor_Ruine,
    cant_go "In dieser Richtung kannst du keine menschlichen Behausungen entdecken und \
    du hast keine Lust mehrere Stunden zu Laufen.",
has  light;

Nearby kalkstein "Kalkbrocken"
    with
    g_artikel_was 'der',
    name "kalkstein" "brocken" "grosser kalkbrocken" "kalkbrocken",
    initial "Ein grosser Kalkbrocken liegt mitten auf dem Pfad.",
    description "Der Kalkbrocken ist gross, schneeweiss und sehr kantig.",
    after
    [; Take: "Du nimmst den Brocken. Er ist sehr leicht, scheint aber recht stabil zu sein.";
       Drop: "Du laesst den Brocken fallen. Du vernimmst ein Geraeusch wie von klingendem Porzellan.";
       Insert: if(kalkstein in Gwenn_Nische) Achieved(3);
	       if(Kohle in Du_Nische) "Du hoerst ein dumpfes Geraeusch.";
    ],
has edible;

Object Tor_Ruine "Burgtor"
    with description
	"Das Burgor ist etwa zweimal so hoch wie du. Es ist von Moos und Gras fast voellig bedeckt. \
	 Zwei Holzpforten behindern dich daran, zu sehen, was dahinter ist. Ein Pfad fuehrt in Richtung Sueden.",
    s_to Pfad_Ruine,
    n_to Tor_Pforten,
    cant_go "Keine gute Idee. Oder willst du dich 20m herunterstuerzen?",
has light;

Nearby Tor_Pforten "Pforten"
    with
    g_artikel_ind 'zwei',
    g_artikel_was 'die',
    g_artikel_wen 'die',
    g_artikel_wem 'den',
    g_pronomen 'sie',
    name "pforten",
    g_plural      1,
    description "Sie sind aus massiver Eiche, einfach aber sehr stabil gehalten. \
	 Eine rostige Kette haelt die Pforten geschlossen.",
    before
    [; Open: if(kette has concealed)
	     "Eine Kette haelt die Pforten zusammen.";
	      else { give self open; "Du oeffnest die Pforten."; }
       Close: "Die Kette ist doch nurnoch Staub.";
    ],
    door_to
    [;
	 print "Die Pforten lassen sich sehr leicht aufdrueckenn. So leicht, dass sie \
	 gegen die Burgmauern knallen um sogleich wieder zurueckzuspringen. \
	 Das Holz verkeilt sich und deine Versuche die Pforten wider oeffnen \
	 scheitern. Gefangen!^^^Hier scheinen rauschende Feste abgehalten \
	 worden zu sein, die gestapelten Baenke und Tische deuten darauf hin.\
	 Der Besitzer will wohl noch mehr Feste hier abhalten, deshalb hatte \
	 er die Pforten verriegelt. Pech nur, dass du wegen dieser \
	 Sicherheitsmasnahme nun nicht mehr hier herauskommst!^^^^";
	 return Hof_Ruine;
    ],
    door_dir n_to,
has static door openable ~open scenery;

Nearby kette "Kette"
    with
    g_artikel_was 'die',
    name "ketten" "kette",
    description "Die Kette ist voellig verrostet und sieht sehr bruechig aus.",
    before
    [; Attack:
	if(kalkstein notin player) "Mit was soll ich den die Kette zerbrechen? \
	    Etwa mit den nackten Haenden?";
	else if(self has concealed) { give self ~concealed; print "Nicht grad die \
	    Feinste Art die Kette mit dem Kalkbrocken zu zerstoeren, der Besitzer hatte \
	    bestimmt einen Grund, die Ruine verschlossen zu halten, aber zu schaffst es... \
	    Die Kette faellt ab."; Achieved(1); }
    ],
has static concealed scenery;

Object Hof_Ruine "Burghof"
    with
    g_artikel_was 'der',
    description
	"Hier zeigt sich der Charme einer Ruine. Das Moos und das Gras bedecken die \
	zerfallenen Mauern fast gaenzlich. Trotzdem, der Boden ist voellig \
	festgetreten. In der einen Ecke des Hof finden sich typisch \
	deutsche, zusammenklappbare und orange Baenke und Tische.",
    d_to Treppe_Ruine,
    w_to Treppe_Ruine,
has light;

Nearby Holzkiste "Holzkiste"
    with
    g_artikel_was 'die',
    name "kiste" "holzkiste",
    initial "Eine Holzkiste steht neben den gestapelten Baenken.",
    description "Die Holzkiste ist etwas alt, dient wohl aber noch dazu Dinge trocken zu halten.",
has static container openable;

Object Lampe "Petroleumlampe" Holzkiste
    with
    g_artikel_was 'die',
    name "lampe" "petroleumlampe" "leuchte",
    description "Eine ganz normale Petroleumlampe, allerdings mit Piezozuendung.",
    before
    [;
       Drop: if(location==thedark) "Das halte ich nicht fuer sinnvoll. \
       In dieser Dunkelheit wuerdest du sie nie wieder finden...";
    ],
    after
    [; SwitchOn:  give self light;
       SwitchOff: give self ~light;
    ],
has ~light switchable;

Object Kohle "Holzkohlenstueck" Holzkiste
    with
    g_artikel_was 'das',
    name "kohle" "holzkohle" "holzkohlenstueck",
    description "Die Kohle wurde wohl fuer's Grillen benutzt. Sie ist pechschwarz.",
    after
    [; Insert: if(Kohle in Du_Nische) Achieved(2);
	       if(kalkstein in Gwenn_Nische) "Du hoerst ein dumpfes Geraeusch.";
    ],
has ~light;

Object Treppe_Ruine "Wendeltreppe zum Verliess"
    with
    description
	"Ein dunkle feuchte Wendeltreppe fuehrt weiter nach unten, nach oben siehst du \
	den Ausgang. Heller Sonnenschein reflektiert sich an den dunkel glaenzenden Wanden.",
    u_to Hof_Ruine,
    e_to Hof_Ruine,
    d_to Gang_Verlies,
    w_to Gang_Verlies,
has light;

Object Gang_Verlies "Kreuzung im Verlies"
    with
    initial
    [;  if((kalkstein in Gwenn_Nische)&&(Kohle in Du_Nische)) "Du bemerkst, dass sich im \
	Westen eine geoeffnet hat.";
	else "Als du die Kreuzung betritts ueberkommt dich ploetzlich ein schauerliches Gefuehl....";
    ],
    description
	"Diese Kreuzung fuehrt Richtung Norden und Sueden in die Dunkelheit, Richtung Osten befindet \
	sich eine steinernde Wendeltreppe.",
    u_to Treppe_Ruine,
    e_to Treppe_Ruine,
    w_to
    [; if((kalkstein in Gwenn_Nische)&&(Kohle in Du_Nische))
       {
	   Achieved(4);
	   print "Gratuliere. Du hast den vorlaeufigen Ausgang gefunden. Eigentlich fuehrt \
	    dieser Weg ja in neue Abendteuer, allerdings sind die noch nicht ganz fertig. \
	    Ein wenig Geduld, mehr wird bald kommen... 8-))";
	   deadflag=2; return thedark;
       }
       rfalse;
    ],
    n_to Gwenn_Ecke,
    s_to Du_Ecke,
has ~light;

Object Gwenn_Ecke "Gwenn's Nische"
    with
    description
	"Hier siehst du eine eingelassene Nische in der Wand. Die Nische erscheint heller \
	zu reflektieren als die Umgebung, ja sie scheint sogar selber zu leuchten. \
	In Richtung Sueden und Suedwesten verlaufen Gaenge in die Dunkelheit.",
    s_to  Gang_Verlies,
    sw_to Maros_Ecke
has ~light;

Nearby Gwenn_Nische "Nische des Gwenn"
    with
    g_artikel_was 'die',
    name "nische",
    description
	"Die Nische ist gerade so gross um kleinere Gegenstaende aufnehmen zu koennen.",
has static container ~openable open;

Object Du_Ecke "Du's Nische"
    with
    description
	"Eine eingelassene Nische ist hier das einzig nennenswerte. Komischerweise scheint sie \
	das Licht deiner Lampe zu verschlucken. In Richtung Norden und Norwesten geht es weiter.",
    n_to  Gang_Verlies,
    nw_to Maros_Ecke,
has ~light;

Nearby Du_Nische "Nische des Du"
    with
    g_artikel_was 'die',
    name "nische",
    description
	"Die Nische ist gerade so gross um kleinere Gegenstaende aufnehmen zu koennen.",
has static container ~openable open;

Object Maros_Ecke "Ankou's Nische"
    with
    description
	"In der westlichen Ecke ist eine Nische eingelassen. In der Nische befindet sich eine \
	kleine Statue. Die Stille und Einsamkeit hier laesst dich erschaudern. Zureuck kannst \
	du suedoestlich oder nordoestlich.",
    se_to Du_Ecke,
    ne_to Gwenn_Ecke,
has ~light;

Nearby statue "Statue des Ankou"
    with
    g_artikel_was 'die',
    name "ankou" "statue" "figur",
    description
	"Es ist die Darstellung des Sensemanns, dem Symbol des Todes. Seltsamerweise \
	erscheint dir die Darstellung nicht grade typisch fuer diese Region, da es
	ein reines Skelett mit Sense und ohne Umhang und Kapuze zeigt. Sie stammt \
	wohl eher aus dem Westen Europas. Die Statue selber ist aus schwarz-weissem
	Granit herausgearbeitet und scheint fest in der Nische fixiert zu sein.",
has static;

[ Initialise;
  location = Pfad_Ruine;
  "^^^^^Der Ausflug mit der Freundin war mal wieder ein totaler Reinfall. Trotz \
  guten Wetters und Laune dauerte es nicht lange und wir stritten uns. Sie hatte \
  vor nicht all zu langer Zeit herausgefunden, dass ich nicht nur Kaffee mit meiner \
  Kollegin getrunken hatte. Als ob man als Mann was dafuer kann! \
  Naja, jedenfalls ab einem gewissen Punkt schnappte sie sich die Schluessel vom \
  Wagen und bemerkte: Laufe dud dir au a mol gut, nu schau wie de heimkemmst! \
  Bevor ich reagieren konnte war nurnoch eine Staubwolke meines Autos zu sehen. \
  Hoffentlich wuerde sie ihn bei mir abstellen!";
];

Include "gGrammar";
end;