!================================================================
! El personaje taquillero
!
! El taquillero; no hace nada, sólo tiene un demonio para que oigas
! cosas que dice de vez en cuando; también te manda al guardia
!

Personaje taquillero "oficinista" Oficinas
! *** Propiedades simples de la biblioteca
with
    nombre_m 'oficinista',
    genero G_MASCULINO,

! *** Variables de estado
    
! *** Variables para variedad en respuestas
    numConversOidas 0,

! *** Respuestas
with
    inicial NULL,
    descripcion [;
        if (jugador.enCola)
            "Las cabezas de delante te impiden ver al oficinista.";
        else if (~~jugador.enPrincipioCola)
            "No lo ves bien desde aquí, estás demasiado lejos.";
        else
            "El oficinista es un señor delgado con gafas pequeñas. ",
            "Está hablando con el primero de la cola.";
    ],

! *** Atributos
    nombre_may [;
        print "Oficinista";
    ],
    printHabla [ frase;
        printHablaGen( self.nombre_may, 2, frase, false);
    ],

    daemon [ accionCola;
        if (jugador.enPrincipioCola || cola.turnoSinGritos)  return;

        accionCola = random (10);
        switch (accionCola) {
            2:  print "^";
                self.printHabla( "¡Siguieeeenteeee!", false);
        }
    ],

    ! *** Escuchar
    reaccionar_antes [;
        Escuchar:
            if (jugador.enPrincipioCola) {
                switch (self.numConversOidas) {
                    0:  self.printHabla( "... varios delitos cometidos ...");
                    1:  self.printHabla( "... comportamiento vulgar ...");
                    2:  self.printHabla( "... buen padre ...");
                    default:
                        self.cabreo ();
                }
                self.numConversOidas++;
                rtrue;
            }
    ],

    ! *** Se cabrea si intentas hablar con él
    vida [;
        self.cabreo ();
        rtrue;
    ],
    antes [;
        HablarCon:
            self.cabreo ();
            rtrue;
    ],
	InicializarQuips [;
	],

    ! *** Las "cosas" que sabe hacer este buen hombre
    cabreo [;
        if (self.checkNoCercano())  return;
        self.printHabla(
            "Pero... ¿¿¿SE PUEDE SABER QUÉ HACE USTED AQUÍ???.
            ¡VUELVA A SU SITIO!. ¡SEGURIDAAAAD!");
        print "Aparece un mastodóntico guarda que te agarra por un brazo y
            te lleva de nuevo a tu sitio en la cola.^";
        move guardia to Oficinas;
        jugador.enCola = true;
        jugador.enPrincipioCola = false;
    ],
    checkNoCercano [;
        if (~~jugador.enPrincipioCola)
            "El oficinista está demasiado lejos, no te oye desde aquí.";
        else
            rfalse;
    ],
    
has
    escenario
; ! End object