!================================================================
! El objeto cola
!
! Se considerará como objeto cola cualquier referencia a "alguien"
! genéricamente. También manejará las acciones generales de la propia
! cola. Sin embargo, no se considerará "contenedor de personas".
! Tampoco manejará a "la persona de delante" en la cola (objeto elDeDelante)
!

Personaje cola "gente en la cola" Oficinas
! *** Propiedades simples de la biblioteca
with
    nombre_f 'cola' 'gente' 'fila' 'persona',
    nombre_m 'alguien' 'cualquiera' 'cualquier' 'uno' 'hombre' 'señor' 'alma',
    nombre_fp 'cabezas' 'personas' 'almas',
    genero G_FEMENINO,
    adjetivos 'en' 'detras' 'otra' 'mujer',

! *** Variables de estado

! *** Variables para variedad en respuestas
    nPreguntadoDonde 0,
    turnoSinGritos false,

with
    inicial NULL,

    descripcion [;
        "No encuentras ninguna pauta común en la gente de la cola, hay
        hombres y mujeres, niños y ancianos, gente adinerada
        junto a mendigos...";
    ],
    
    daemon [ accionCola colorCola;
        if (self.turnoSinGritos) {
            self.turnoSinGritos = false;
            return;
        }
        accionCola = random (11);
        colorCola = random (3) + 2;
        switch (accionCola) {
            1:  print "^";
                printHablaGenConst ("Alguien en la cola", colorCola,
                "¡Señora, mueva el culo!", false);
            2:  print "^";
                printHablaGenConst ("Alguien en la cola", colorCola,
                "¡Oiga, listillo, no se cuele!.
                ¡Espere su turno como todo el mundo!", false);
            3:  print "^";
                printHablaGenConst ("Alguien en la cola", colorCola,
                "¡No me pise!, ¿es que no ve por dónde va?", false);
        }
    ],

    nombre_may [;
        print "Tú";
    ],
    printHabla [ frase pensando;
        printHablaGen( nombre_may, 1, frase, pensando);
    ],
    
    ! ****** Conversación por menús
	Enunciado [linea msg;
	    msg = self.msgEnunciado (linea);
        print (string) msg, "^";
    ],
    msgEnunciado [linea msg;
	    switch (linea) {
            0: msg = "Pregunta dónde estais.";
            default:
                msg = "Otro";
        }
        return msg;
    ],
    msgEnunciadoFinal [linea msg;
	    switch (linea) {
            0:  switch (self.nPreguntadoDonde) {
                    0: msg = "Por favor, ¿podría alguien decirme
                        para qué exactamente
                        estamos haciendo esta cola?";
                    1: msg = "Supongo que no me han entendido bien.
                        ¿Puede decirme alguien dónde estamos?.";
                    2: msg = "¡¡¡JODER!!!, ¿¿QUÉ SITIO ES ESTE??";

                    default:
                        msg = "¿¿¿SE PUEDE SABER QUÉ DEMONIOS ME QUIEREN OCULTAR???";
                }

            default:
                msg = self.msgEnunciado (linea);
        }
        return msg;
    ],
	Respuesta [linea;
        jugador.printHabla (self.msgEnunciadoFinal (linea), false);
        print "^";

	    switch (linea) {
	        ! Dónde estamos ?
            0:  switch (self.nPreguntadoDonde) {
                    0:  RealPause(); print "Nadie contesta.^";
                    1:  print "La gente mira hacia otro lado, parece incómoda.^";
                    2:  print "Buscas los ojos de la gente, desesperado.
                        Encuentras algunos de ellos, reconoces sus miradas...
                        miradas de lástima.^";

        	        default:
                        print "La gente en la cola baja la cabeza avergonzada y
                            apesadumbrada.^";
                        print "^";
                        jugador.printHabla( "¡Está bien!, ninguno quiere ayudarme,
                            ¿no?. ¿¿QUIÉN LES NECESITA??");
                        print "^";
                        jugador.printHabla( "... quién les necesita...");
                	    self.QuipOff (0);
        	    }
        	    self.nPreguntadoDonde++;
        	    self.turnoSinGritos = true;
	    }
	],
	inicializarQuips [;
	    self.QuipsOn (1, 0);
	],

    ! ****** Conversación por temas
    vida [;
        "La gente en la cola no parece hacerte demasiado caso.";
    ],

    buscarGente [hablaGuardia tema;
        tema = AveriguarTema (TemasRecuerdos);
        if (jugador.recuerdaTodo
                && ((tema == Esposa) || (tema == Mujer_ambigua))) {
            jugador.printHabla (
                "Espera... Carmen murió también y muy poco antes que yo,
                así que puede que esté en esta misma cola. Aunque puede que
                no funcione, será su palabra contra la mía...", true);
            print "^";
            print "Vuelves a recordar la imagen de la muerte de tu esposa,
                cómo la golpeaste... y cómo quedó la nota del chantaje en
                sus manos...^";
            print "^";
            jugador.printHabla (
                "¡Hubiera sido una prueba fantástica de mi inocencia, pero
                ya habrá tenido tiempo de romperla!. De todas formas, tengo
                que intentarlo", true);
            print "^";
            if (hablaGuardia) {
                jugador.printHabla( "Perdone, pero mi mujer podría estar aún en esta
                        cola. ¿Me deja que la busque o...?", false);
                print "El guarda se retira y te permite pasar.^";
            } else {
                print "El guarda hace ademán de pararte, pero al comprender lo que
                    quieres hacer, se retira.^";
            }
            print "Comienzas a buscar entre la cola. Vas repasando una a una
                a cada persona en la cola. En varias ocasiones, crees haberla
                encontrado por fin, para después comprobar que no es así.^";
            print "^";
            RealPause();
            print "Por fin... parece que la encuentras. Es increible, pero
                   aún conserva el papel en las manos.^";
            print "^";
            jugador.printHabla (
                "¡Por fin te encontré!, dame ese papel o...");
            print "^";
            print "Carmen se para y te mira. Ya no son aquellos ojos fríos
                y despectivos que solían mirarte habitualmente, no... ahora
                la mirada es tranquila, sosegada... incluso inocente.^";
            print "^";
            printHablaGenConst( "Carmen", 3,
                "Tome este papel, si es suyo. Por cierto, ¿le conozco?, es
                usted muy guapo, ¿sabe?. Espero que podamos vernos después,
                sea lo que sea lo que estemos esperando", false);
            print "^";
            print "Agarras la nota, te disculpas y te diriges hacia el
                guarda. Mientras te alejas, no puedes evitar el volver a
                mirar a Carmen. Ahora la aprecias enormemente bella, y recuerdas cómo
                era cuándo comenzó vuestra relación, cuando te sentías el
                hombre más feliz del mundo a su lado y ella llenaba tu vida
                de alegría... Y sientes lástima... mucha lástima.^";
                
            banderafin = 2;     ! Fin del juego, has ganado!
            rtrue;

        } else if (jugador.recuerdaTodo && (tema == Novia)) {
            "No tiene sentido buscar a Linda en la cola. Precisamente ella
            fue la única que salió viva...";

        } else {
            print "No entiendo qué quieres buscar en la cola.^";
            rtrue;
        }
    ],
    alDescubrirLugar [;
        self.QuipOff (0);
    ],

! *** Atributos
has
   escenario;
! End object