!================================================================
Constant Historia "^^La Sentencia";
Constant Titular "^(c) 1999 Pedro Ángel Ala.^^";
!================================================================

Constant ADMITIR_INFINITIVOS;
Constant HAY_CURIOSIDADES;


[ Curiosidades;
    "Este juego es una adaptación casi literal del relato ~El pozo y 
    el péndulo~ de Edgar Allan Poe. Las diferencias con el relato se 
    deben a las limitaciones de la mini-comp. Si no has leído ese 
    relato, leelo ahora y disfruta comparándolo con el juego.^^
    El nombre del autor ~Pedro Ángel Ala~ es falso. Se trata de un 
    seudónimo construido mediante el cambio de orden de las letras 
    de ~Edgar Allan Poe~. Si quieres conocer el nombre del verdadero 
    autor del juego, salta al pozo siendo un pirata (si no entiendes 
    esta frase mistificadora, observa la lista de opciones del 
    programa Frotz).^^
    Aunque el juego en sí es bastante lineal 
    (sólo hay una solución posible a cada rompecabezas), el orden en 
    que ejecutas los comandos afecta a las descripciones. Intenta 
    jugarlo de nuevo y probar otras cosas o en otro orden. El texto de
    respuesta a una misma acción puede variar.^^
    Existen cinco muertes diferentes ¿las has descubierto todas?";
];


! Constantes para identificar diferentes estados del jugador
Constant TIRADO_AL_PRINCIPIO = 1;
Constant DE_PIE_AL_PRINCIPIO = 2;
Constant JUNTO_A_LAS_PAREDES = 3;
Constant JUNTO_AL_POZO       = 4;
Constant ATADO_A_LA_TABLA    = 5;
Constant LIBERADO_DE_TABLA   = 6;
Constant EN_CELDA_MENGUANTE  = 7;

! Estados de las ratas
Constant RATAS_APARECIENDO = 1;
Constant RATAS_OLIENDO     = 2;
Constant RATAS_ACERCANDOSE = 3;
Constant RATAS_COMIENDO    = 4;
Constant RATAS_TERMINANDO  = 5;
Constant RATAS_ALEJANDOSE  = 6;
Constant RATAS_DESAPARECIDAS = 7;
Constant RATAS_NO_HAY      = 8;
Constant RATAS_MERODEANDO  = 9;
Constant RATAS_ROYENDO     = 11;
Constant RATAS_ESPERANDO   = 12;
Constant RATAS_HAN_HUIDO   = 13;

!****************************************************************
! Inclusion del parser y definicion de una nueva rutina para dibujar
! la linea de estado.
Replace DibujarLineaEstado;
Include "EParser";
! Una linea de estado que simplemente pone centrado el titulo de la
! habitación, sin puntuación ni movimientos 
[ DibujarLineaEstado j width;
    width = 0->33; if (width == 0) width = 80;
    font off;
    @split_window 1; @buffer_mode 0; @set_window 1;
    style reverse; @set_cursor 1 1; spaces(width);
    texto_impreso-->0 = 64;
    @output_stream 3 texto_impreso;
    print (name) localizacion;
    @output_stream -3;
    j=(width-(texto_impreso-->0))/2;
    @set_cursor 1 j; print (name) localizacion; spaces(j-1);
    style roman;
    @buffer_mode 1; @set_window 0; font on;
];

!****************************************************************
! El objeto MensajesLibreria sirve para modificar las respuestas por
! defecto de la libreria. Debe escribirse entre el Include "EParser" y
! el include "Acciones"
Object 	MensajesLibreria
 with 	antes[;
	 Miscelanea:
	    switch(ml_n)
	    {
	     26: rtrue;
	     30: "Hasta donde alcanza tu entendimiento, no hay nada 
		aquí que responda a ese nombre.";
		! COGE XADI
	     39: "No puedes ocuparte de eso ahora.";
		! Actuar sobre lo irrelevante
	     44: "No hay nada a tu alrededor.";
		! "Coge todo" si no hay nada
	    }
	 Mirar:
	    if (ml_n>4)
	    {
		if (localizacion ofclass CeldaOscura)
		    print "^Sabes que ";
		else print "^Ves que ";
		if (ml_o~=localizacion)
     		{   if (ml_o has soporte) print "sobre "; else print "en ";
	    	    print (el) ml_o;
		}
		else print "aquí ";
		if (n==5) print "también ";
		print "hay ";
		EscribirListaDesde(child(ml_o),
                      		   ESPANOL_BIT + BANDERAUX_BIT +
				   RECURSIVO_BIT + INFOPARCIAL_BIT +
				   BREVE_BIT + OCULTAR_BIT);
		if (ml_o~=localizacion) ".";
		".";
    	    }
	 Tocar: if (ml_n==3) ! Tocarse a sí mismo
	     <<Examinar jugador>>;
	 Dormir:
	    "Tu cuerpo te pide dormir, pero temes que si cedes a 
	    esta necesidad fisiológica tus verdugos aprovechen para 
	    tenderte alguna trampa más insidiosa aún.";
	 Cantar:
	    "La demencia empieza a apoderarse de tu mente. Tienes que
	    hacer grandes esfuerzos por controlarla.";
	 Trepar:
	    "Las paredes son lisas y resbaladizas. No consigues
	    nada.";
	 Tacos:
	    "Lo desesperado de la situación te hace perder tu normal
	    compostura y jurar de forma innoble.";
	 Nadar:
	    "No puedes nadar sin agua.";
	 Quemar:
	    "No hay nada aquí con lo que hacer fuego.";
	 MirarDebajo:
	    if (localizacion ofclass CeldaOscura)
		"No ves nada en esta oscuridad.";
	    "No hay nada que pueda servirte.";
	 Frotar:
	    "Frotas ", (el) ml_o, " con las manos, sin lograr
		resultado alguno.";
	 PonerSobre, Meter:
	    if (ml_o==tabla) "Para poner la tabla en otro lugar 
	    tendrías que levantarla, pero pesa demasiado. Sin 
	    embargo parece factible empujarla.";
	 Puntuacion:
	    if (banderafin==1)
		 "La inquisición ha terminado contigo.";
	    if (banderafin==2)
		 "Has logrado sobrevivir a tu condena.";
	    "En este juego no hay puntuación. Trata de seguir 
		vivo el máximo tiempo posible.";
	];
! Proporcionamos una funcion ImprimirRango, antes de incluir Acciones,
! para sustituir a la que venia por defecto, que escribia "." La
! nuestra no escribirá nada de nada.
[ ImprimirRango;
];

! Finalmente, reemplazamos la rutina de la accion Lugares. Normalmente
! esta rutina produce una lista de los lugares en que el jugador ha
! estado, pero en este juego resulta inadecuado.
Replace LugaresSub;
[ LugaresSub;
    "Has visitado muchos lugares antes de venir a parar a esta lúgubre
    mazmorra. Probablemente no visitarás ningún lugar más.";
];
! Inclusion de los restantes ficheros de cabecera
Include "Acciones";
Include "Gramatica";

!****************************************************************
! COMIENZA EL LISTADO PRINCIPAL
!****************************************************************
!
! La filosofia de diseño gira en torno a los diferentes estados en que
! puede hallarse cada objeto del juego, incluyendo al propio
! jugador. El cambio de un estado a otro se produce, bien automáticame
! con el paso del tiempo (a través de daemon o cada_turno), o bien
! ante ciertas acciones del jugador.
!
! Cada objeto debe proporcionar diferentes respuestas según el estado
! en que se halle el jugador y el propio objeto. Por esto la
! codificación de algunos objetos es extraordinariamente larga.
!

Global desc=1;  ! Contador de descripciones diferentes para la celda
Global respiracion=1; !Contador de numero de veces que el jugador RESPIRA


! La clase CeldaOscura, permite compartir código entre las localidades
! CeldaOscura1 y CeldaOscura2, que son casi idénticas. La primera es
! el inicio del juego, y la segunda es una vez que el jugador ha
! descubierto el pozo.
Class CeldaOscura 
 with	irrelevante 'corazon' 'uñas' 'oxido' 'olor' 'mano' 'manos'
	    'pie' 'pies' 'miembros' 'miembro' 'pecho' 'espalda'
	    'pierna' 'piernas',
	antes [;
	    if (uno==obj_abajo) return EjecutarRutinas(suelo,antes);
	    if (uno==obj_arriba) return EjecutarRutinas(techo, antes);
	 Excavar:
	    "Intentas cavar con tus manos en la fría piedra, pero
	    sólo logras hacerte sangrar las uñas.";
	 Escuchar:
	    "No oyes nada, salvo el latir de tu agitado corazón.";
	 Oler:
	    if (~~uno)
	    	"Olfateas el aire, tratando de obtener una pista de tu 
		localización. Percibes el característico olor del 
		moho y la tierra, junto con otro olor más acre, como 
		de óxido.";
	],
	no_puedes_ir
	    "Es imposible saber dónde está el norte o el sur en esta 
	    prisión. Si quieres explorar la celda, todo lo más que 
	    puedes hacer es caminar al azar.",
 has 	luz; ! Jeje



!================================================================
! El lugar inicial
!================================================================
Object 	CeldaOscura1 "En las tinieblas"
class CeldaOscura
 with	inicial "^^Finalmente, con una loca angustia en el corazón,
	    abres los ojos. Tu espantoso pensamiento hallase, pues,
	    confirmado. Te rodea la negrura de la noche eterna.",
	descripcion [;
	    switch(desc++){
	     1: "Permaneces tendido en el suelo, en medio de la 
	    	oscuridad más absoluta. La intensidad de las tinieblas 
	    	te oprimen y sofocan. La atmósfera es intolerablemente 
	    	pesada.";
	     2:
		if (jugador.estado<DE_PIE_AL_PRINCIPIO)
		    print "Sin levantarte, f";
	     	else print "F";
		"uerzas de nuevo la vista
		inútilmente. Tratas de serenarte y emplear tu razón.";
	     3: "La negrura que te rodea es tan impenetrable que te
		asusta. ¿Te han llevado a un calabozo para aguardar en
		él el próximo sacrificio que habrá de celebrarse
		meses más tarde? Por otra parte, tu primer calabozo,
		como todas las celdas de los condenados, en Toledo,
		estaba empedrado y había en él alguna luz.";
	     default:
		desc=4;
		"No puedes ver absolutamente nada. Es evidente
		que el lugar en que te hallas está perfectamente
		sellado.";
	    }
	],
	anduvo 1,
	antes[;
	    ! Cada vez que el jugador pone ANDA (o CAMINA) se muestra
	    ! un mensaje diferente, e incluso puede cambiarse el
	    ! estado de algunos objetos. Para llevar la cuenta de qué
	    ! mensaje hay que mostrar, usamos la propiedad anduvo.
	 IrAmbiguo:
    	    if (jugador.estado<DE_PIE_AL_PRINCIPIO)
		"No podrás caminar mientras estés tendido en el suelo.";
	    switch (self.anduvo++)
	    {
	     1: print "A la larga, se te hace intolerable la agonía de la
		incertidumbre, y avanzas con precaución, extendiendo
		los brazos y con los ojos fuera de tus órbitas, con la
		esperanza de hallar un débil rayo de luz. Das algunos
		pasos, pero todo está vacío y negro.^";
		if (camison notin jugador)
		{
		    give camison general;
		    remove camison;
		    print "^Has perdido toda referencia del lugar 
			donde dejaste tu ropa.^";
		}
	     2: move paredes to celdaoscura1;
		jugador.estado=JUNTO_A_LAS_PAREDES;
		print "Tus manos extendidas encuentran por fin un 
		    sólido obstáculo. Es una pared que parece 
		    construida de piedra, muy lisa, húmeda y fría.^";
		if (camison notin jugador)
		{
		    give camison general;
		    remove camison;
		    print "^Has perdido toda referencia del lugar donde
		    dejaste tu ropa.^";
		}
		
	     3:
		if ((camison notin jugador)&&(camison hasnt general))
		    return LaVueltaAlRuedo();
		self.anduvo--;
		if (camison in jugador)
		    print "No te atreves a alejarte de la pared, que 
			es tu único punto de referencia en las 
			tinieblas.^";
		else 
		{
		    banderafin=1;
		    print "Echas a andar de nuevo, tratando de volver al 
		    punto donde dejaste tu ropa, pero estás 
		    completamente desorientado. A medida que pasa el 
		    tiempo, tu desesperación crece y empiezas a 
		    correr, sin importarte ya el golpearte contra 
		    las paredes.^^ Pero en medio de una carrera, el 
		    suelo desaparece bajo tus pies.^^ ¡En el centro 
		    de la celda había un pozo! ¡Esta era la muerte 
		    que te estaba reservada y tú has corrido a su 
		    encuentro! Tras una interminable caída, llegas 
		    finalmente al fondo del pozo. La pequeña 
		    cantidad de agua que contenía no sirve para 
		    amortiguar tu caída.^";
		}
	    }
	    rtrue;
	];


! Otro detalle de realismo, por si el jugador se piensa que está
! ciego.
Object ojos "ojos"
 with 	articulos 'Los' 'los' 'tus',
	nombre_m 'ojo',
	nombre_mp 'ojos',
	nombre_f 'vista',
	genero G_MASCULINO+G_PLURAL,
	descripcion "Tus ojos no te duelen. Estás bastante seguro de 
	    que la oscuridad no se debe a una ceguera, sino a una 
	    ausencia total de luz.",
	antes [;
	 Examinar: rfalse;
	 Abrir: "Aunque te resulta difícil de creer, tienes los ojos
	    completamente abiertos.";
	 Cerrar: "No habría diferencia en esta oscuridad.";
	 Tocar: <<Examinar self>>;
	 default: "Mejor dejar tus ojos tranquilos. No parecen servir
	    de mucho ahora, pero tal vez los necesites más tarde.";
	],
	esta_en CeldaOscura1 CeldaOscura2,
 has 	oculto;


Object 	Suelo "suelo"
 with 	! No pongo propiedad nombre para no confundir al parser, ya que ya
! existe otro objeto llamado suelo, que es obj_abajo. En la celda
! capturo la acción examinar obj_abajo y la redirijo a este objeto.
	descripcion [;
	    switch (jugador.estado) 
	    {
	     TIRADO_AL_PRINCIPIO:
		if (self hasnt general)
	     	{
		    give self general;
		    "Extiendes una mano y pesadamente cae sobre algo
		    húmedo y duro. Durante unos minutos la dejas
		    descansar así, haciendo esfuerzos por adivinar
		    dónde puedes encontrarte y qué ha sido de ti.";
		}
		"Palpas de nuevo el suelo, llegando al mismo
		resultado. Es fría y húmeda piedra.";
	     DE_PIE_AL_PRINCIPIO, JUNTO_A_LAS_PAREDES, JUNTO_AL_POZO:
		if (self hasnt general)
	     	{
		    give self general;
		    "Te agachas para tocar el suelo, y lo encuentras 
		    húmedo y duro, como una losa de superficie 
		    irregular. Rastreas una pequeña zona pero no hay
		    nada sobre él. Estás seguro de que no hay nada
		    sobre el suelo en toda la celda.";
		}
		"De nuevo te agachas para tocar el suelo y cerciorarte
		de que no hay nada sobre él.";
	     ATADO_A_LA_TABLA:
		print "Esforzando el cuello, consigues echar un 
		    vistazo al suelo sobre el que yaces. ";
		if (comida in localizacion)
		{
		    if (comida has general)
			print "Han puesto a tu lado otro trozo de comida
			gelatinosa como el que tiraste al
			    pozo. También puedes ver ";
		    else  print "A tu lado está tu trozo de comida 
			gelatinosa. También puedes ver ";
		}
		else print "Puedes ver ";
		"el brocal del pozo al que estuviste a punto de caer.";
	     default: "El suelo es de piedra, cubierta de un limo
		resbaladizo. En su centro hay un gran pozo.";
	    }
	],
	antes [;
	 Examinar: self.descripcion(); rtrue;
	 Tocar: <<Examinar self>>;
	 Oler: "El suelo huele a humedad.";
	 Coger, Atacar: <<Excavar>>;
	 Ir: if (pozo in localizacion) "No puedes escalar por las
	    lisas paredes del pozo. Si realmente quieres bajar, tu
	    única posibilidad es saltar al pozo.";
	    "A tus pies sólo hay sólida piedra.";
	 default: "En tu febril obsesión por encontrar sentido a esta
	    situación ya no sabes qué intentar y pruebas ideas
	    absurdas.";
	],
 has 	oculto escenario;

Object techo "techo"
 with	antes [;
	 Examinar:
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    	"No puedes ver el techo, pero tienes la intuición
	    	de que está increíblemente alto.";
	    if (jugador.estado==ATADO_A_LA_TABLA)
	    {
	    	if (self hasnt general)
	    	{
		    give self general;
		    move pendulo to localizacion;
		    "El techo está realmente alto, a unos 10 metros 
		    sobre tu cabeza, y parece estar excavado en la 
		    roca, excepto por unas compuertas metálicas 
		    justamente sobre ti. Al examinar éstas con más 
		    detenimiento descubres con horror que justamente 
		    en su centro, sobre tu vertical, hay un gran 
		    péndulo que se balancea de un lado a otro.";
	    	}
	    	"El lejano techo sirve de soporte para el péndulo 
		que se balancea sobre ti.";
	    }
	    "El techo parece excavado en la roca, excepto por unas
	    compuertas centrales. Descubres ahora que en ellas había
	    un dibujo, una representación del tiempo pero en su mano,
	    en lugar de la clásica guadaña, estaba el hilo del que
	    pendía el péndulo.";
	 Tocar:
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    	"Extiendes las manos hacia lo alto, esperando tocar el
	    	techo, pero no encuentras nada.";
	    "El techo es inalcanzable.";
	default: "El techo es algo inaccesible por completo.";
       	],
 has 	oculto escenario;
	    
! Las paredes son bastante complejas, ya que este único objeto tiene
! diferente comportamiento según la fase del juego. Al principio están
! a oscuras y no se ven. Más tarde pueden examinarse. Al final se
! ponen en movimiento para aplastar al jugador
Object 	paredes "paredes"
 with 	nombre_f 'pared' 'piedra' 'plancha' 'esquina',
	nombre_fp 'paredes' 'planchas',
	nombre_m 'muro' 'hierro' 'metal',
	descripcion [;
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    {
	    	if ((camison in jugador)||(camison has general))
	    	    "Palpas la pared en una pequeña área. Es fría y 
		    lisa. Podrías recorrer el perímetro de la celda sin 
		    separarte de la pared, para hacerte una idea de sus 
		    dimensiones, pero sin un punto de referencia 
		    probablemente terminarías dando vueltas, pasando una 
		    y otra vez por los mismos puntos sin darte cuenta. 
		    Si pudieras hacer alguna marca en la pared, que te 
		    sirviera de referencia, examinarías el perímetro más 
		    confiado.";
	    	LaVueltaAlRuedo();
	    }
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Ahora puedes observar la verdadera forma de tu
		recinto, y compruebas que te habías equivocado
		bastante en tus estimaciones. Las paredes parecen
		grandes planchas de hierro con junturas en algunos
		puntos. Su superficie está embadurnada groseramente
		con toda clase de emblemas horrorosos y repulsivos,
		nacidos de la superstición sepulcral de los
		frailes.";
	    if (jugador.estado==LIBERADO_DE_TABLA)
		"Las paredes están calientes al tacto, y se hallan
		recubiertas de toda clase de emblemas horrorosos y
		repulsivos, nacidos de la superstición sepulcral de
		los frailes.";
	    if (jugador.estado==EN_CELDA_MENGUANTE)
	    {
		if (self hasnt general)
		{
		    give self general;
		    "Las paredes están ahora al rojo vivo. Intentas 
		    evitar el contacto con ellas, pero la celda está 
		    cambiando de forma, pasando de cuadrada a 
		    romboidal. Dos de las esquinas son agudas, las 
		    otras dos son obtusas, y los ángulos se acentúan 
		    cada vez más. Dentro de poco las paredes te 
		    aplastarán, si no optas por terminar con tu 
		    agonía antes lanzándote al pozo.";
		}
		"Las paredes al rojo se acercan inexorablemente.";
	    }
	],
	antes [;
	    if ((jugador.estado==ATADO_A_LA_TABLA)
		&&(accion~=##Examinar))
		"No puedes acceder a las paredes mientras 
		permanezcas atado de esta forma.";
	    if ((jugador.estado==EN_CELDA_MENGUANTE)
		&&(accion~=##Examinar or ##Oler))
	    	"No puedes tocar las paredes. Están al rojo vivo.";
		
	 Oler: "Tienen un acre olor metálico.";
	 Atacar:
	    "Preso de una desesperación insuperable golpeas la pared 
	    con todas tus fuerzas, que no son ya muchas. Los muros 
	    te devuelven una cacofonía de resonancias metálicas, 
	    cuyo eco tarda mucho en extinguirse. Parece que las 
	    paredes son paneles de metal, contra los que nada puedes 
	    hacer.";
	 Abrir: "No descubres ninguna juntura en la pared que te
	    permita practicar una abertura. Y de todas formas no
	    podrías hacer nada sin herramienta y en tu estado de
	    agotamiento.";
	 Marcar:
	    if (jugador.estado==JUNTO_A_LAS_PAREDES)
	    "Intentas hacer una muesca con la uña en la pared, pero 
		entonces compruebas su extraordinaria dureza. Es 
		imposible hacer una marca sin un cuchillo, y por 
		desgracia parece que los inquisidores se han quedado 
		con el tuyo. Tendrás que pensar en otra forma de 
		señalar tu localización.";
	    "Ya no tiene sentido hacer marcas en la pared.";
	],
	estado 1,
	daemon [;
	    self.estado++;
	    switch(self.estado)
	    {
	     4: ParedesInicianMovimiento();
	     5: "Te parece que las paredes se han movido.";
	     6:
		if (self hasnt general)
	     	{
 		    give self general;
		    "No cabe duda, la celda está cambiando, pasando 
		    lentamente de forma cuadrada a romboidal, como 
		    si sus cuatro esquinas fuesen articuladas y un 
		    potente mecanismo estuviese empujando dos de 
		    ellas hacia adentro.";
		}
		"La celda se está deformando, como si sus cuatro
		esquinas fuesen articuladas y un potente mecanismo
		estuviera empujando dos de ellas hacia adentro.";
	     7: "Las esquina más próxima a ti ya tiene solo cuarenta 
		y cinco grados, intentas alejarte de esa esquina, 
		pero el pozo está en tu camino.";
	     8: "Las paredes despiden un calor que se empieza a hacer
		insoportable.";
	     9,10,11:
		"El ángulo de la esquina ya es de tan sólo ",
		    (numero) (12-self.estado)*5, " grados.";
	     12:
		if (tabla hasnt general)
		{
		    remove tabla;
 		    "Las paredes tropiezan con la tabla a la que 
		    habías sido atado, pero el mecanismo de empuje 
		    de las planchas parece estar justamente a los 
		    lados de la tabla, por lo que ésta se astilla 
		    con estrépito, y las astillas arden al contacto 
		    con las abrasadoras paredes. Tú serás lo próximo 
		    en ser aplastado.";
		}
		self.estado=13;
		"Las paredes tropiezan con la tabla a la que habías
		sido atado. Ya que la has movido del sitio previsto,
		los mecanismos que comprimen los muros no están
		alineados con ella, y de momento encuentran una fuerte
		resistencia que no pueden vencer.";
	     13:
		banderafin=1;
		"La proximidad de las paredes te produce ya horribles
		quemaduras, pero la tortura no dura mucho. Enseguida
		la espantosa compresión termina con tu vida y pronto
		no eres más que una mancha carbonizada. Ya no puedes
		oír el ruido de voces humanas, la explosión y el
		huracán de trompetas que a continuación tiene lugar en
		tu celda, cuando las tropas francesas que han entrado
		en Toledo llegan, demasiado tarde, para rescatarte.";
	     14: "Entre espantosos crujidos, la tabla empieza a
		ceder.";
	     15: "La tabla es finalmente aplastada por las paredes y
		sus astillas se carbonizan inmediatamente. Has ganado
		unos segundos, pero pese a todo tú serás lo
		próximo en ser aplastado.";
	     16: banderafin=2;
		"Pero he aquí un ruido de voces humanas. Una
		explosión, un huracán, un poderoso rugido semejante al
		de mil truenos. Los muros de fuego se echan hacia
		atrás precipitadamente. Un brazo alargado te coge del
		tuyo cuando ya desfalleciente te precipitabas en el
		abismo. Es el brazo del general Lasalle. Las tropas
		francesas han entrado en Toledo. La inquisición se
		halla en poder de sus enemigos.";
	    }
	],
	esta_en CeldaOscura2 CeldaPendulo,
 has 	escenario femenino nombreplural oculta;

Object negrura "negrura"
 with 	nombre 'negrura' 'tiniebla' 'tinieblas' 'oscuridad'
	    'impenetrable' 'alrededor' 'atmosfera' 'lugar'
	    'habitacion' 'celda' 'aire' 'noche' 'eterna',
	antes [;
	    Examinar: <<Mirar>>;
	    Oler: <<Oler>>;
	    default:
		"El agotamiento y la tensión te
	    	hacen concebir ideas absurdas.";
	],
	esta_en CeldaOscura1 CeldaOscura2,
 has 	escenario femenino oculta;

!================================================================
! El objeto jugador
!
! Proporciona una descripción variable, por si quiere examinarse a sí
! mismo, y también intercepta algunas acciones según el estado.
!
Object 	preso "ti mismo" CeldaOscura1
 with 	descripcion [;
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    {
	    	if (camison has puesto)
	    	{
	    	    if (self hasnt general) 
	    	    {
		    	give self general;
		    	"Te palpas en la oscuridad y encuentras que 
		    	todas tus pertenencias han desaparecido, como 
		    	era de esperar. Incluso tu traje ha sido 
		    	sustituido por un camisón.";
	    	    }
		    "Te palpas de nuevo, pero no encuentras nada. Al menos
		    conservas todos tus miembros.";
	    	}
	    	"Estás desnudo, tiritando de frío y terror.";
	    }
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Te hallas acostado cuan largo eres sobre una especie
		de armazón de madera muy bajo. Estás atado con una
		larga tira que parece de cuero. Enrollase en torno a
		tus miembros y a tu cuerpo, dejando únicamente libres
		tu cabeza y tu brazo izquierdo, y una zona del pecho.";
	    "Tu forma física no es muy buena. Las privaciones y
	    tormentos sufridos han dejado su mella.";
	],
	cantidad 0,       ! Todo PJ debe tener esta propiedad
	estado 1,
	pensamientos 1,
	hablo false,
	grito false,
	reaccionar_antes [;
	 Salir:
	    if (self.estado==TIRADO_AL_PRINCIPIO)
	    {
	    	self.estado=DE_PIE_AL_PRINCIPIO;
	    	"Una idea repentina te asalta y acelera tu sangre en
	    	torrentes hacia tu corazón. De un solo movimiento te
	    	levantas sobre tus pies. Desatinadamente extiendes tus
	    	brazos por encima de tu cabeza y en todas direcciones. No
	    	sientes nada. Sin embargo, tiemblas ante la idea de dar un
	    	paso, pues te da miedo tropezar con los muros de tu
	    	tumba.";
	    }
	    if (self.estado==ATADO_A_LA_TABLA)
	    {
		if (correa in jugador)
		{
		    if (ratas.estado~=RATAS_ROYENDO)
		    	"Estás atado a una tabla por unas fuertes 
			correas que te impiden moverte.";
		    "Espera, las ratas aún están royendo tus
		    ataduras.";
		}
		print "Te levantas de golpe, ahuyentando a las ratas.^";
		return JugadorLiberado();
	    }
	    
	    "¡Salir! La idea te atormenta. Si tan sólo supieras 
	    cómo.";
	 Saltar:
	    switch(self.estado)
	    {
	     TIRADO_AL_PRINCIPIO:
		<<Salir>>;
	     ATADO_A_LA_TABLA:
		if (correa in jugador)
		    "Las correas te impiden todo movimiento.";
		<<Salir>>;
	     LIBERADO_DE_TABLA:
		"El techo está demasiado alto.";
	     default:
	    	"Saltas con la vana esperanza de tocar el techo, 
		pero no tocas nada. La celda en que te hallas debe 
		de ser de grandes dimensiones.";
	    }
	 Hablar:
	    if (self.Hablo==false)
	    {
		self.Hablo=true;
	    	"Por un momento hablas solo. Pero el sonido de tu propia
	    	voz, amplificado por las resonancias de la enorme cavidad
	    	en que te hallas, te asusta y te hace consciente de tu
	    	penoso estado mental.";
	    }
	    "Murmuras otra vez para tus adentros.";
	 Gritar:
	    if (self.Grito==false)
	    {
		self.Grito=true;
	    	"Gritas tratando de atraer la atención de alguien. 
		La resonancia de la cavidad en que te hallas es 
		extraordinaria y el eco de tu grito tarda un minuto 
		en extinguirse. Pero nada más oyes después. Imaginas 
		a tus verdugos disfrutando con esta situación.";
	    }
	    "No vas a dar de nuevo esa satisfacción a tus verdugos.";
	 DarPalmada:
	    if (self.estado<ATADO_A_LA_TABLA)
	    	"Das una palmada, esperando no sabes muy bien qué. 
		Su eco tarda casi un minuto en desaparecer. Esto 
		debe de significar que el techo está muy alto y las 
		paredes son muy lisas.";
	    if (self.estado==ATADO_A_LA_TABLA)
		"No es posible aplaudir con una sola mano.";
	    "Das una palmada que las paredes y el techo de devuelven
	    amplificadas y multiplicadas. Después vuelve el
	    silencio.";
	    
	 Pensar:
	    switch(self.estado)
	    {
	     TIRADO_AL_PRINCIPIO, DE_PIE_AL_PRINCIPIO:
	    	switch (jugador.pensamientos++) 
	    	{
	     	 1: "Tratas de recordar los procedimientos 
		    inquisitoriales y, partiendo de ésto, procuras 
		    deducir tu posición verdadera. Ha sido 
		    pronunciada la sentencia, y desde entonces ha 
		    transcurrido un largo intervalo de tiempo. No 
		    obstante no puedes estar muerto. A pesar de 
		    todas las ficciones literarias, esa idea es 
		    absolutamente incompatible con la existencia 
		    real.";
	     	 2: "Sobre estos calabozos contabanse cosas 
		    extrañas. Tú siempre habías creído que eran 
		    fábulas, pero sin embargo eran tan extraños que 
		    sólo podían repetirse en voz baja. ¿Debes morir 
		    de hambre, en este subterráneo mundo de 
		    tinieblas, o qué muerte más terrible te 
		    espera?";
	     	 3: "Conoces bien el carácter de tus jueces y no 
		    puedes dudar que el resultado de tu encierro 
		    será la muerte, y una muerte de amargura 
		    escogida. En qué consistirá y cuál será la hora 
		    de su ejecución es lo único que te aturde.";
	     	 4: "Esfuerzas una vez más tu agotado cerebro, 
		    tratando inútilmente de anticipar la suerte que 
		    te han reservado los inquisidores.";
		 default: "Se te ocurre que tal vez deberías caminar
		    para hacerte una idea del tamaño de tu celda.";
		    
	    	}
	     JUNTO_A_LAS_PAREDES:
		"Piensas en una forma de marcar tu situación, pero no
		se te ocurre nada.";
	     JUNTO_AL_POZO:
		"Tal vez lo más sensato sea alejarse del pozo.";
	     ATADO_A_LA_TABLA:
		if (correa in localizacion)
		    "Tratas de pensar cómo cortar las correas, pero no
		    tienes nada salvo tus dientes.";
		"No hay tiempo de pararse a pensar ahora que te has
		liberado de las correas. El péndulo sigue bajando
		inexorablemente.";
	     EN_CELDA_MENGUANTE:
		if (paredes.estado<6)
		    "No se te ocurre nada para salir de esta
		    situación. Sólo te queda esperar al próximo
		    movimiento de tus verdugos.";
		if (paredes.estado>15)
		    "Estabas seguro de que la tabla detendría las
		    paredes. Ya no se te ocurre qué mas
		    hacer. Empiezas a aceptar tu inevitable derrota.";
	    	"Esfuerzas tu cerebro tratando de pensar una solución a la
	    	terrible situación en que te hallas. Ya has burlado a tus
	    	verdugos dos veces ¿serás capaz de volver a hacerlo?";
	    }
	],
	antes [;
	    if ((self.estado~=ATADO_A_LA_TABLA)&&(accion~=##Examinar))
		"Eso no tiene sentido.";
	 Atacar, Retorcer,IrAmbiguo:
	    "Cuanto más te mueves, más se aprietan las correas.";
	],
 has 	animado propio;

Object  camison "camisón de estamena" preso
 with 	nombre_m 'traje' 'camison',
	nombre_f 'ropa',
	adjetivos 'estamena',
	genero G_MASCULINO,
	descripcion [;
	    if (jugador.estado==TIRADO_AL_PRINCIPIO)
	    	"Tus ropas han sido sustituidas por un vulgar camisón
		de estamena.";
	    if (jugador.estado~=ATADO_A_LA_TABLA)
		"Es el camisón con que te han vestido los
		inquisidores.";
	    if (self has general)
	    {
		give self ~general;
		print   "Has recuperado tu camisón. Evidentemente es 
		    el mismo que habías arrojado al pozo pues está 
		    aún húmedo. No puedes dejar de advertir el 
		    refinamiento de este nuevo castigo. ";
	    }
		"El camisón se halla aprisionado por una tira como de
		cuero que da varias vueltas alrededor de tus miembros
		y tu cuerpo.";
	],
	antes [;
	 Desatar: "No hay nudos en la ropa.";
	 Atar: "Tu camisón no es lo bastante largo y flexible como 
	    para poder anudarlo.";
	 Oler: "Tu ropa huele espantosamente a sudor. O bien llevas
	    aquí más tiempo del que creías o bien te han dado la ropa
	    de otro ajusticiado. Lo último te parece más probable.";
	 Atacar, Cortar:
	    "Intentas arrancar una tira de tu traje, pero la tela es 
	    más recia de lo que creías y apenas te quedan ya 
	    fuerzas.";
	 Tocar: print "Es una tela áspera y recia";
	    if (self has general)
		print " y está empapada";
	    ".";
	 Desvestir:
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"No puedes quitarte la ropa. Estás aprisionado por 
		la tira de cuero que se enrolla por todo tu cuerpo.";
	 Lanzar:
	    if (self has puesto) "Tendrías que quitarte", (lo) self, "
		antes.";
	],
	despues [;
	 Desvestir: "Te quitas el camisón, que era todo tu
	    abrigo. Inmediatamente empiezas a tiritar.";
	 Vestir: "El abrigo que te produce esta prenda es el único
	    placer físico que has experimentado en los últimos días.";
	 Dejar:
	    if (pozo in localizacion) <<Lanzar self pozo>>;

	    "Depositas en el suelo tu camisón."; 

	],
 has 	prenda puesto;


!================================================================
! FASE 2 Junto al pozo
!================================================================
! Esta localidad podría haberse codificado como parte de
! CeldaOscura1. Realmente la única razón para separarla ha sido poder
! darle otra propiedad "inicial".
!
Object CeldaOscura2 "En las tinieblas"
class CeldaOscura
 with 	inicial
	    "^^Cuando despiertas, al apoyarte para ponerte en pie,
	    tocas con la mano un trozo de algo
	    gelatinoso. Probablemente alguien lo ha depositado aquí
	    mientras dormías.",
	descripcion 
	    "Las tinieblas a tu alrededor son tan densas como antes.",
	anduvo 1,
	no_puedes_ir
	    "Es imposible saber dónde está el norte o el sur en esta 
	    prisión. Si quieres explorar la celda, todo lo más que 
	    puedes hacer es caminar al azar.",
	antes [;
	 IrAmbiguo:
	    switch(self.anduvo++) 
	    {
	     1:
	    	move pozo to localizacion;
	    	jugador.estado=JUNTO_AL_POZO;
	    	"Decides continuar tus pesquisas, aunque realmente 
		no acabas de encontrarles ningún sentido. Caminas de 
		nuevo alejándote de la pared, con la intención de 
		cruzar la celda, cuando el resbaladizo suelo te hace 
		caer. Entonces descubres algo realmente extraño. 
		Aunque tu barbilla descansa en el suelo, tus labios 
		y nariz están suspendidos en el vacío. Parece que 
		estás asomado a un pozo y sólo un azar 
		extraordinario te ha librado de caer en él. De modo 
		que esta era la muerte que te tenían reservada.";
	     2:
		print "Tanteando el suelo en cada paso, temeroso de 
		    los innumerables pozos que tu imaginación 
		    multiplica en la celda, retrocedes hasta la 
		    pared.^^Un extraño olor que te recuerda al de 
		    los hospitales parece provenir ahora del lugar 
		    donde estabas antes.^";
		return JugadorGrogui();
	    }
	];


	    
Object -> comida "trozo de algo gelatinoso"
 with 	nombre_corto "trozo de gelatina",
	nombre_m 'trozo' 'gelatinoso' 'algo',
	nombre_f 'gelatina' 'comida',
	genero G_MASCULINO,
	articulo "un",
	descripcion [;
	    self.nombre_corto="comida";
	    self.genero=G_FEMENINO;
	    self.articulo="un trozo de";
	    if (self hasnt general)
	    {
		if (jugador.estado<ATADO_A_LA_TABLA)
		    "Es grasiento al tacto. Tal vez sea comida.";
		"Es un trozo de gelatina amarillenta. Probablemente
		sea comida.";
	    }
	    "Es el trozo de comida que te han dejado los inquisidores
	    para incrementar tu sed.";
	],
	antes [;
	 Tocar: <<Examinar self>>;
	 Oler: "Huele como si fuera comestible. Parece que después de
	    todo no planean matarte de hambre.";
	 Comer, Probar:
	    if (self hasnt general)
	    {
	    	give self general;
	    	"Tu debilidad puede más que tus escrúpulos y das un 
		bocado al trozo de gelatina. Está terriblemente 
		salada y tu sed se incrementa atrozmente, mientras 
		que tu hambre apenas resulta disminuida. Qué ingenuo 
		fuiste al esperar un rasgo de humanidad de tus 
		verdugos.";
	    }
	    "El hambre te tortura, pero comer esta inmundicia sería
	    peor aún para ti.";
	 Dejar, Lanzar:
	    if ((accion==##lanzar)&&(otro==pozo)) rfalse;
	    if (pozo in localizacion) <<Lanzar self pozo>>;
	    if (self has general)
	    	"Disgustado por la burla de que eres objeto, estás a 
		punto de lanzar el trozo de gelatina. Pero después 
		reflexionas y piensas que tal vez pueda serte útil 
		para sobrevivir unos minutos más, llegado el caso.";
	    "Mejor no perderlo ahora que lo has encontrado. Tal vez
	    sea comestible.";
	],
	despues [;
	 Coger:
	    if (ratas.estado==RATAS_COMIENDO or RATAS_TERMINANDO)
	     	"Consigues arrebatarle la comida a la rata.";
	],
 has 	comestible;

! Al pozo pueden tirarse cosas. Aunque no sirve para nada, da realismo
! al juego. Cuando el jugador se aleja del pozo, se pasa a la siguente
! fase del juego. Si pasan varios turnos y no se aleja, el pozo
! emanará un gas y se avanzará de todas formas a la siguiente fase
Object pozo "pozo"
 with 	nombre 'pozo' 'abismo' 'brocal',
	descripcion [;
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    {
	    	if (self hasnt general)
	    	{
		    give self general;
		    "Evidentemente no puedes ver nada, pero al palpar 
		    los bordes del pozo tropiezas con una pequeña piedra 
		    que cae a su interior. Durante algunos segundos 
		    prestas atención a sus rebotes. Choca en su caída 
		    contra las paredes del pozo. Lúgubremente se hunde 
		    por último en el agua, despertando ecos estridentes.";
	    	}
	    	"La oscuridad es total. La vista no te sirve aquí para
	    	averiguar la profundidad del pozo.";
	    }
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Fuerzas el cuello para ver el pozo que tienes
		cerca. Desde aquí no puedes ver su profundidad, pero
		sí puedes observar que no parece haber más pozos en la
		celda.";
	    "Te asomas al pozo y ves en el fondo el reflejo plateado 
	    del agua, lo que te permite estimar su profundidad. No 
	    es probable que sobrevivieras a una caída, y menos aún si
	    el agua no es profunda, dato que ignoras.";
	],
	describir "Estás junto a un pozo de dimensiones
	    desconocidas.",
	reaccionar_antes [;
	 Saltar: <<Entrar self>>;
	 Oler:
	   print "El olor a humedad de la celda se acentúa aún más
		debido a la cercanía del pozo";
	    
	    if ((self.estado>4)&&(self.estado<7))
	     " y ahora se ha sumado un extraño olor que te recuerda al
		de los hospitales.";
	    ".";
	],
	antes [;
	 BuscarEn: "Es imposible ver nada en la celda, menos aún en el
	    interior del pozo.";
	 Coger, Empujar, Tirar, EmpujarDir, Girar, Retorcer:
	    "Deliras.";
	 Entrar, Meterse:
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"No puedes moverte de la tabla a la que estás atado.";
	    banderafin=1;
	    print "Incapaz de soportar un minuto más la tensión 
		nerviosa a la que te ves sometido, decides terminar 
		con esto de una vez por todas. Saltas al pozo y tras 
		una interminable caída, llegas finalmente al fondo 
		del pozo. La pequeña cantidad de agua no sirve para 
		evitar el fatal aplastamiento";
	    if (paredes.estado>6) print ". Mientras agonizas, 
		escuchas un gran estrépito en tu celda, un ruido de 
		voces humanas, un huracán de trompetas, cuando las 
		tropas francesas que han entrado en Toledo detienen 
		la infernal maquinaria para liberarte. Han llegado 
		demasiado tarde";
	    
	    @piracy ?sigue;
	    ".^^Lo último que ven tus ojos es una pequeña inscripción
	    fosforescente en la pared del pozo: ~Zak McKracken estuvo
	    aquí.~";
	    .sigue;
	    ".";
	 SaltarSobre:
	    if (jugador.estado<ATADO_A_LA_TABLA)
	    	"No tienes idea de las dimensiones del pozo y no vas a
	    	intentar ese salto en las tinieblas. Sería mortal con
	    	seguridad.";
	    if (jugador.estado==EN_CELDA_MENGUANTE)
		"En tu estado de agotamiento no te ves capaz de saltar
		por encima del pozo. Y ahora, debido a la deformación
		de la celda tampoco puedes bordearlo. De todas formas
		en el otro lado estarías exactamente igual que en
		éste.";
	    "No tiene sentido saltar por encima del pozo, cuando
	    puedes bordearlo perfectamente. Pero tampoco tiene sentido
	    bordearlo cuando lo que hay al otro lado es exactamente
	    igual a lo que hay en éste.";
	 RecibirLanzamiento, Recibir:
	    move uno to pozo;
	    switch(uno) 
	    {
	     comida:
		give comida general;
		"Dejas caer el trozo de comida al pozo y escuchas
		atentamente. Unos segundos más tarde oyes el chapoteo
		de la gelatina al llegar al fondo, y después un
		inesperado bullicio, como si las aguas hirvieran por
		unos instantes. Tal vez hay algo vivo ahí abajo.";
	     camison:
		give camison general;
		ArrancarReloj(self,2);
		"Dejas caer tu ropa al pozo. Quedas escuchando un rato
		pero no oyes nada. Tal vez se ha quedado enganchada en
		la pared, tal vez la tela ha hecho de paracaídas y
		esté aún cayendo.";
	     tabla:
		"La tabla desaparece por la boca del pozo, sus golpes
		contra las paredes, amplificados por las
		reverberaciones en su interior producen un estrépito
		espantoso, que te impide escuchar claramente el
		impacto con el agua. El silencio tarda unos minutos en
		retornar.";
	     default:
		"¿De dónde has sacado eso? [BUG]";
	    }
	],
	tiempo_restante 2,
	tiempo_agotado [;
	    "^Escuchas un suave chapoteo casi imperceptible. Parece que
	    tu camisón ha tocado fondo al fin. Después, te parece
	    escuchar un suave rumor en el agua, como si tu ropa
	    flotara y algo le estuviera dando pequeños tirones.";
	],
	estado 1,
	cada_turno [;
	    switch (self.estado++) 
	    {
	     2: "No estás muy cómodo tan cerca del pozo. Temes
		resbalar y caer dentro.";
	     4: "Un extraño olor proviene del pozo.";
	     7: JugadorGrogui();
	     13: move ratas to localizacion;
		"Un ruido leve atrae tu atención. Miras al suelo y ves
		algunas enormes ratas que lo cruzan. Han salido del
		pozo.";
	    }
	],
 has 	estatico recipiente;


!================================================================
! FASE 3: ATADO A LA TABLA
! ================================================================

Object CeldaPendulo 
 with	nombre_corto [;
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"En una gran celda metálica (atado a una tabla)";
	    if (jugador.estado==LIBERADO_DE_TABLA)
		"En una gran celda metálica";
	    if (jugador.estado==EN_CELDA_MENGUANTE)
		"En una gran celda metálica (cuyo tamaño se reduce a
		ojos vista)";
	],
	irrelevante 'ojo' 'ojos' 'mano' 'manos' 'brazo' 'brazos' 'pie'
	    'pies' 'pierna' 'piernas' 'compuerta' 'compuertas' 'espalda',
	inicial "El sueño te abandona lentamente. Abres los ojos.^^ 
	    Te hallas de nuevo en posición horizontal, sobre una 
	    superficie que parece de madera. Sientes una presión 
	    alrededor de todo tu cuerpo, excepto en un brazo y la 
	    cabeza. Pero la celda está ahora iluminada por una 
	    claridad sulfurosa cuyo origen no puedes encontrar, que 
	    te permite examinarla con más detalle.",
	descripcion [;
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Desde el lugar en que yaces puedes contemplar las
		paredes y el techo de tu prisión. Con un pequeño
		esfuerzo también puedes ver el suelo.";
	    if (jugador.estado==LIBERADO_DE_TABLA)
		"Las paredes de tu celda despiden un fulgor
		sobrenatural.";
	    "Las paredes al rojo se acercan inexorablemente, 
	    dejándote como únicas alternativas la muerte por 
	    aplastamiento o el salto al pozo, que sería igualmente 
	    fatal.";
	],
	antes [;
	    if (uno==obj_abajo) return EjecutarRutinas(suelo,antes);
	    if (uno==obj_arriba) return EjecutarRutinas(techo, antes);
	 Excavar:
	    if (self.estado==ATADO_A_LA_TABLA)
		"Arañas el suelo con tu mano libre, pero sólo logras
		hacerte sangrar las uñas.";
	    "Intentas cavar con tus manos en la fría piedra, pero
	    sólo logras hacerte sangrar las uñas.";
	 Escuchar:
	    if (pendulo in localizacion)
	    {
	    	if (pendulo hasnt general) 
	    	{
	    	    if ((ratas.estado>RATAS_APARECIENDO)&&
		    	(ratas.estado<RATAS_NO_HAY))
		    	"Sólo escuchas los ocasionales chillidos de 
			las ratas.";
	    	    if (ratas.estado==RATAS_MERODEANDO or RATAS_ESPERANDO)
		    	"Escuchas los diminutos pasos de las ratas.";
	    	    "No oyes nada, salvo el latir de tu agitado 
		    corazón.";
	    	}
	    	"No tienes lugar en tu mente para otro sonido que el 
		espantoso silbido del péndulo.";
	    }
	    if (jugador.estado==EN_CELDA_MENGUANTE)
		"Oyes un sordo retumbar que parece provenir de las
		paredes.";
	    "Sólo escuchas los diminutos pasos de las ratas.";
	 Oler:
	    if (~~uno)
	    	"Percibes el característico olor del moho y la 
		tierra, junto con otro olor más acre, como de hierro 
		caliente.";
	 IrAmbiguo:
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Estás atado a una tabla por una correa que te impide
		todo desplazamiento.";
	    if (jugador.estado==LIBERADO_DE_TABLA)
		"Ahora que puedes ver toda la celda no tiene sentido
		hacer más exploraciones. No hay salida posible.";
	    "Ya estás en la parte más ancha de la celda. De aquí sólo
	    puedes ir hacia el pozo o hacia las paredes. Ambos
	    destinos fatales.";
	],
	no_puedes_ir [;
	    if (jugador.estado==ATADO_A_LA_TABLA)
		"Estás atado por una correa que te impide todo
		desplazamiento.";
	    "No hay salidas en este lugar.";
	],
	estado 1,
	daemon [;
	    self.estado++;
	    if (self.estado==5)
	    {
		move pendulo to localizacion;
		pendulo.estado=7;
		if (techo hasnt general)
		{
		    give techo general;
		    "Hace ya un rato que escuchas un sonido sibilante 
		    proveniente del techo. Ahora es mucho más fuerte. 
		    Levantas la cabeza y descubres horrorizado que 
		    justamente en la vertical de tu pecho está oscilando 
		    un enorme péndulo, cuyo extremo inferior está 
		    formado por una media luna de brillante acero. Los 
		    cuernos están dirigidos hacia arriba y el filo 
		    inferior, evidentemente, afilado como una navaja 
		    barbera. Todo ello silba moviendose en el espacio. Y 
		    en cada nueva oscilación el péndulo desciende un 
		    poco más.";
		}
	    }
	],
 has 	luz;

! Las ratas tienen una propiedad cada_turno que las hace bastante
! animadas, a pesar de que no tienen atributo animado
Object 	ratas "ratas"
 with	nombre 'rata' 'ratas',
	descripcion [;
	    switch(self.estado)
	    {
	     RATAS_APARECIENDO:
		"Han salido del pozo y puedes ver sus pequeños bigotes
		olfateando el aire.";
	     RATAS_OLIENDO:
		"Parecen agitadas por el olor de tu comida.";
	     RATAS_ACERCANDOSE:
		"Están muy cerca de ti.";
	     RATAS_COMIENDO,RATAS_TERMINANDO:
		"Una rata está comiendo tu trozo de gelatina.";
	     RATAS_ALEJANDOSE: "Se alejan, una vez agotada tu comida.";
	     RATAS_DESAPARECIDAS: "Se han ido por el pozo.";
	     RATAS_NO_HAY:
		"Ya no hay ratas aquí. Una vez han dado cuenta de tu 
		comida han desaparecido por donde han venido.";
	     RATAS_MERODEANDO:
		"Las ratas merodean por el suelo, atraídas por el olor
		de tu comida pero sin atreverse a quitártela.";
	     RATAS_ROYENDO:
		"Las ratas están mordiendo tus correas con avidez.";
	     RATAS_ESPERANDO:
		"Las ratas dan vueltas a tu alrededor confiando en 
		que aparezca más comida.";
	     RATAS_HAN_HUIDO:
		"Ya no hay ratas aquí. Han huido al pozo cuando
		se produjo el retumbar.";
	    }
	],
	estado 1,
	cada_turno [;
	    if (comida in jugador) self.estado=9;
	    if (comida in correa) self.estado=10;
	    switch(self.estado)
	    {
	     RATAS_APARECIENDO:
		self.estado++; "Las ratas se acercan.";
	     RATAS_OLIENDO:
		self.estado++;
		"Las ratas han detectado la comida que tienes a tu 
		lado.";
	     RATAS_ACERCANDOSE:
		self.estado++;
		move comida to ratas;
		"Una rata se acerca más y comienza a comer el trozo 
		de gelatina que tienes junto a tu mano izquierda.";
	     RATAS_COMIENDO: self.estado++;
		"La rata sigue comiendo con avidez y rechaza con
		chillidos a las otras ratas que intentan acercarse.";
	     RATAS_TERMINANDO:
		remove comida;
		self.estado++;
		"La rata ha terminado tu comida y se va.";
	     RATAS_ALEJANDOSE:
		self.estado++;
		give self oculto;
		"Escuchas unos pequeños chapoteos. Las ratas se han
		ido por el pozo.";
	     RATAS_DESAPARECIDAS:
		self.estado++;
 	     RATAS_NO_HAY:
	     RATAS_MERODEANDO:
		switch(random(15))
	     	{
		 1: "Una rata más osada que las demás salta sobre ti
		    para intentar quitarte la comida, pero te liberas
		    de ella con una sacudida.";
		 2: "Algunas ratas chillan de excitación por el olor
		    de tu comida.";
		 3: "Una rata cruza rápidamente sobre ti, pero no
		    consigue quitarte la comida.";
		 4: "Una rata mordisquea por un momento tu correa,
		    pero abandona rápidamente.";
		}
	     10: self.estado++;
		remove comida;
		"Una masa de ratas se agita sobre ti. Por suerte sólo
		buscan el cuero de las correas que te sujetan. ";
	     RATAS_ROYENDO:
		remove correa;
		self.estado++;
		"Las ratas han terminado su trabajo y no han dejado 
		rastro de tus correas. Te dejan tranquilo pero 
		continúan cerca de ti.";
	     RATAS_ESPERANDO:
		switch(random(30))
		{
		 1,2,3,4:"Un par de ratas se pelean.";
		 5,6,7:"Una de las ratas se va por el pozo.";
		 9:"Una rata tropieza contra la pared y se aleja
		    chillando.";
		 10: "Una rata se sube a tu pie. Te liberas de ella de
		    una patada.";
		}
	    }
	],
	vida [;
	 Dar:
	    if (uno==comida)
	    {
		remove comida;
		ratas.estado=RATAS_ESPERANDO;
		"Lanzas la comida a las ratas, que se agolpan en una
		masa agitada disputándose el trozo de gelatina. En
		poco tiempo han dado cuenta de ella y merodean a la
		espera de más.";
	    }
	 Mostrar:
	    if (uno==comida)
		"Las ratas chillan de excitación a la vista del trozo
		de gelatina.";
	    if (uno==correa)
		"Alguna rata olisquea con curiosidad la correa, 
		esperando que sea algo de comer, pero no parece 
		interesarle el sabor del cuero.";
	],	    
	antes [;
	 Coger, Atacar:
	    if (self.estado<RATAS_COMIENDO)
		"Aún no están lo suficientemente cerca.";
	    if (self.estado==RATAS_COMIENDO or RATAS_TERMINANDO)
		"Coges a la rata que tienes más cerca de la mano, la
		cual da un chillido y se libera de tu agarre, para
		volver poco después a continuar su festín.";
	    if (self.estado<RATAS_MERODEANDO)
		"Ya están demasiado lejos.";
	    if (self.estado==RATAS_MERODEANDO)
		"No pasan lo suficientemente cerca de tu mano como
		para que puedas coger una.";
	    if (self.estado<=RATAS_ROYENDO)
	    	"Coges una rata con tu mano libre, pero el animal te
		da un mordisco y se escabulle.";
	    if (self.estado==RATAS_ESPERANDO)
	    {
		if (jugador.estado==ATADO_A_LA_TABLA)
		{
		    print "Te levantas repentinamente tratando de 
			atrapar una rata por sorpresa, pero sus 
			reflejos son muy rápidos. Evidentemente 
			estos animales han sobrevivido aquí a muchos 
			ajusticiados antes que tú.^";
		    return JugadorLiberado();
		}
		"Las ratas son muy escurridizas. Eres incapaz de
		atrapar una.";
	    }
	    "No hay más ratas por aquí.";
	 DejarSalir:
	    if (uno==comida) 
	    {
		move comida to jugador;
		"Consigues arrebatarle el trozo de gelatina a la
		rata.";
	    }
	],
has femenino nombreplural animado recipiente abierto;		
		

! El pendulo baja poco a poco a traves de cada_turno
Object pendulo "péndulo"
 with  	nombre_m 'pendulo' 'oscilacion' 'oscilante' 'afilado' 'silbato',
	nombre_f 'cuchilla' 'afilada',
	estado 0,
	descripcion [;
	    switch(self.estado) 
	    {
	     1,2,3: "El péndulo se balancea en lo alto del techo, pero
		parece que la longitud de su cable está aumentando
		poco a poco.";
	     4,5,6,7,8:
		if (self hasnt general){
		    give self general;
		    "Cuando vuelves a mirar al péndulo descubres 
		    horrorizado que está mucho más cerca, y que su 
		    extremo inferior está formado por una media luna 
		    de brillante acero. Los cuernos están dirigidos 
		    hacia arriba y el filo inferior, evidentemente, 
		    afilado como una navaja barbera. Todo ello silba 
		    moviendose en el espacio. Y en cada nueva 
		    oscilación el péndulo desciende un poco más.";
	     	}
		"La cuchilla del péndulo avanza lenta pero 
		inexorablemente hacia su cometido, con un silbido 
		enloquecedor.";
	     9,10,11,12,13,14,15:
		"La cuchilla está ya a menos de ", (numero)
		    (17-self.estado)*5, " centímetros de tu
			pecho.";
	     16: if (camison has puesto)
		 "La cuchilla ha cortado ya tu camisón. En la 
		 próxima oscilación segará tu corazón.";
		"La cuchilla ha cortado ya la piel del pecho. En la
		próxima oscilación segará tu corazón.";
	    }
	],
	cada_turno [;
	    switch(self.estado++) 
	    {
	     6: if (self has general)
		 "Te había parecido escuchar un sonido sibilante
		 producido por el péndulo. Ahora lo oyes mucho más
		 cerca.";
	     9,10,11,12,13,14,15:
		"La cuchilla del péndulo está ya a menos de ",
		    (numero) (17-self.estado)*5, " centímetros de 
		    tu pecho, y sigue bajando.";
	     16: if (camison has puesto)
		 "La cuchilla ha cortado ya tu camisón. En la 
		 próxima oscilación segará tu corazón.";
		"La cuchilla ha cortado ya la piel del pecho. En la
		próxima oscilación segará tu corazón.";
	     17: banderafin=1;
		if (correa notin localizacion)
		    "Ya es demasiado tarde. El espantoso
		    silbido del péndulo y un agudo dolor en el pecho
		    es lo último que percibes.";
		"Cuando ves al péndulo dirigirse silbando a toda
		velocidad hacia tu pecho, haces un pequeño esfuerzo
		por elevarte, para que el corte sea mortal de
		necesidad y tu agonía finalice de una vez por
		todas. El espantoso silbido y un agudo dolor es lo
		último que percibes.";
	    }
	],
 has 	escenario;

Object tabla "tabla" CeldaPendulo
 with 	nombre 'tabla' 'cama' 'potro' 'madera' 'tablon',
	describir [;
	    if (jugador.estado~=ATADO_A_LA_TABLA)
		"A un lado está la tabla a la que estabas atado.";
	    rtrue;
	],
	antes [;
	    if ((jugador.estado==ATADO_A_LA_TABLA)
		&& (accion~=##Tocar))
		"No puedes, estás atado a ella.";
	 Tocar: "Es muy lisa y dura.";
	 Coger: "La tabla es muy pesada para tus exiguas fuerzas.";
	 MirarDebajo: "No puedes levantarla, pero estás seguro de que
	    debajo no hay nada que pueda ayudarte.";
	 BuscarEn: "No hay nada sobre la tabla.";
	 Atacar: "Tus intentos son completamente estériles. La tabla
	    parece hecha de una madera extraordinariamente dura.";
	 Empujar, Tirar:
	    if (self has general)
		"La tabla está encajada en la esquina y no puedes
		sacarla de ahí.";
	    "Si empujas la tabla hacia el pozo, probablemente caerá en
	    su interior. El pozo es demasiado ancho. Si la empujas
	    hacia la pared, quedará encajada en la esquina y no podrás
	    sacarla de ahí. Te paras a pensar qué puede ser más
	    conveniente.";
	 EmpujarDir:
	    if (otro in Brujula)
		"No tienes idea de dónde está el
	    	norte o el sur.";
	    if (self has general)
		"La tabla está encajada en la esquina y no puedes
		sacarla de ahí.";
	    if (otro==paredes)
	    {
	     	give tabla general;
		if (paredes.estado>5)
		{
		    paredes.estado=13;
		    "Con un gran esfuerzo empujas la tabla hasta 
		    encajarla en la esquina. Esta situación parece 
		    no haber sido prevista en el mecanismo que 
		    empuja las paredes, ya que momentáneamente su 
		    avance se detiene, aunque el retumbar sube cada 
		    vez más de volumen.";
		}
		"Empujas la tabla con gran esfuerzo hasta encajarla en
		la esquina de la celda.";
	    }
	    if (otro==pozo)
	    {
		accion=##Recibir;
		ejecutarRutinas(pozo, antes);
	    }
	],
	descripcion [;
	    print "La tabla a la que permaneciste atado hasta hace 
		poco es de madera muy oscura y aparentemente muy 
		dura";
	    if (paredes.estado>14)
		", pero no va a soportar la presión de las paredes.";
	    ".";
	],
 has 	femenino estatico;

Object correa "correas" CeldaPendulo
 with 	nombre_f 'correa' 'tira' 'cuerda' 'atadura',
	nombre_fp 'correas' 'tiras' 'cuerdas' 'ataduras',
	nombre_m 'nudo',
	nombre_mp 'nudos',
	adjetivos 'cuero',
	descripcion [;
	    if (ratas.estado~=RATAS_ROYENDO)
		"Los inquisidores han hecho un buen trabajo. Con estas
		ataduras no serías capaz de liberarte ni siquiera en
		el caso de que estuvieras en plena forma. Menos aún en
		la situación actual. Las correas dejan libre una zona
		de tu pecho.";
	    "No puedes ver las correas, están sepultadas por un mar de
	    ratas.";
	],
	reaccionar_antes [;
	 Desatar: "Con la mano libre intentas deshacer los nudos de
	    las correas que te sujetan, pero te resulta absolutamente
	    imposible.";
	],
	listarse "unas correas (que te impiden moverte)",
	antes [;
	 Coger: "No puedes coger las correas mientras estén
	    aprisionandote.";
	 Dejar: "Ojalá fuera tan sencillo liberarse de estas
	    correas.";
	 Cortar: "No tienes con qué cortarlas, salvo tus dientes, pero
	    la situación de la cabeza te impide hacerlo.";
	 Comer: "Por más que fuerzas el cuello, te resulta imposible
	    morder las correas.";
	 Atacar, Tirar, Empujar, Girar:
	    "Las correas son muy resistentes y cuanto más tiras
	    de ellas, más se aprietan.";
	 Recibir, FrotarContra:
	    if (uno==comida)
	    {
		print "Embadurnas las correas que te sujetan con la 
		    gelatina y esperas unos instantes";
		move comida to correa;
		if (ratas.estado==RATAS_MERODEANDO)
		    ". Enseguida un par de ratas se suben sobre ti y 
		    comienzan a roer tus ataduras. ¡El truco ha dado 
		    resultado! Pronto todas las ratas están sobre 
		    ti.";
		else ".";
	    }
	    "Eso no tiene sentido.";
	],
 has 	nombreplural femenino;
	    
Object pecho "pecho" CeldaPendulo
 with 	nombre 'pecho',
	descripcion [;
	    print "Las correas que rodean todo tu cuerpo dejan libre
	    	el área del pecho";
	    if (pendulo has general)
		" ¡justamente en la zona situada en la trayectoria 
		del péndulo!";
	    else ".";
	],
	antes [;
	 Examinar: rfalse;
	 Recibir:
 	    if ((uno==comida)&&(ratas.estado==RATAS_MERODEANDO))
	    {
		remove comida;
		ratas.estado=RATAS_ALEJANDOSE;
		"Dejas el trozo de comida sobre tu
		pecho. Inmediatamente una rata salta sobre él y se lo
		lleva lejos, donde lo devora sin ser molestada.";
	    }
	    "Eso no tiene sentido.";
	 FrotarContra:
	    if (uno==comida)
	    {
		banderafin=1;
		"Frotas la gelatina contra tu pecho. Inmediatamente un
		par de ratas saltan sobre ti atraídas por el fuerte
		olor de este alimento, y comienzan a morderte en el
		pecho. Con tu mano libre tratas de ahuyentarlas, pero
		cada vez más ratas se suman al festín. Has elegido una
		forma de morir más espantosa aún que la que habían
		ideado para ti tus verdugos.";
	    }
	 default: "Eso no tiene sentido.";
	],
 has 	oculto soporte;


Object emblemas "emblemas horrorosos"
with nombre 'emblema' 'emblemas' 'horrorosos' 'repulsivos' 'demonio'
	    'demonios' 'imagenes' 'esqueletos' 'esqueleto' 'colores'
	    'color' 'contorno' 'contornos' 'monstruosidad',
	descripcion "Figuras de demonios con amenazantes gestos, con
	    formas de demonios y otras imágenes del horror más
	    realista llenan en toda su extensión las paredes. Los
	    contornos de estas monstruosidades aparecen
	    suficientemente claros, pero los colores parecen manchados
	    y estropeados por efecto de la humedad del ambiente.",
 has 	escenario nombreplural;

	
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! El inicio del juego
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
[Inicializar;
    
    CambiarJugador(preso);
    localizacion=celdaoscura1;
    box "Cuando, por último, me desataron y pude sentarme,"
       	"noté que perdía el conocimiento. La sentencia, la"
       	"espantosa sentencia de muerte, fue la ultima frase"
       	"claramente acentuada que llego a mis oídos. Luego,"
       	"el sonido de las voces de los inquisidores me pareció"
       	"que se apagaba en el indefinido zumbido de un sueño."
       	"Y el Universo fue solo noche, silencio, inmovilidad."
       	""
       	"             -Edgar Allan Poe ~El pozo y el péndulo~";
    print "^^";
    Pause();
    print "Un largo e indescriptible período de tiempo transcurrió, 
	durante el cual te viste acosado por multitud de pesadillas 
	entremezcladas con la sensación de estar siendo transportado 
	y depositado, resultándote imposible discernir lo soñado de 
	lo real. Después, la simple conciencia de tu existencia sin 
	pensamiento, sensación que duro mucho. Luego, bruscamente, 
	el pensamiento de nuevo, un temor que te producía 
	escalofríos y un esfuerzo ardiente por comprender tu 
	verdadero estado.^^";
    print "No has abierto los ojos hasta el momento. Pero sientes 
	que estás tendido de espaldas y sin ataduras. Tienes una 
	gran impaciencia por hacer uso de tus ojos, pero no te 
	atreves. Tienes miedo de la primera mirada sobre las cosas 
	que te rodean. No es que te aterrorice contemplar cosas 
	horribles, sino que te aterra la idea de no ver nada.^^";
    Pause();
    Cls();
];


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! El jugador consigue tantear todo el perímetro de la habitación
[ LaVueltaAlRuedo;
    print "Con tu ropa en el suelo como punto de referencia, 
	inicias confiado la exploración de la pared. El terreno es
	húmedo y resbaladizo. Tambaleándote, caminas durante un buen
	rato. Cuando ya llevas contados unos cien pasos, y empiezas a
	pensar que te has perdido, tropiezas de nuevo con tu ropa en
	el suelo. De modo que el perímetro de tu prisión es de unos
	cincuenta metros, sin embargo has tropezado con unos cuantos
	ángulos, lo que te impide conjeturar la forma de la
	cueva. Porque no hay duda de que esto es una cueva.^^
	Agotado por el esfuerzo, caes dormido.^^";
    move camison to CeldaOscura2;
    Pause();
    CLS();
    JugadorA(CeldaOscura2);
    jugador.estado=JUNTO_A_LAS_PAREDES;
    rtrue;
];

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! El jugador se queda grogui y despierta bajo el péndulo
[ JugadorGrogui;
    print "^Un sueño invencible se apodera de ti. Probablemente el 
	pozo ha exhalado algún tipo de narcótico. Los inquisidores 
	ya se han dado cuenta de que has descubierto el pozo y 
	probablemente van a prepararte un nuevo tipo de agonía. Te 
	duermes con un sueño profundo parecido a la muerte.^^";
    Pause();
    CLS();
    jugador.estado=ATADO_A_LA_TABLA;
    move camison to jugador;
    give camison puesto;
    move comida to CeldaPendulo;
    give comida oculto;
    move pozo to CeldaPendulo;
    move correa to jugador;
    PararReloj(pozo);
    ArrancarDaemon(CeldaPendulo);
    pozo.estado=8;
    JugadorA(CeldaPendulo);
    rtrue;
];    

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! El jugador ha conseguido levantarse de la tabla
[ JugadorLiberado;
    jugador.estado=LIBERADO_DE_TABLA;
    give ratas oculto;
    move tabla to localizacion;
    remove pendulo;
    PararDaemon(CeldaPendulo);
    ArrancarDaemon(paredes);
    if (techo has general)
    	print "^Tan pronto como te apartas de la trayectoria del 
	    péndulo, éste es izado a toda velocidad, desapareciendo 
	    por las compuertas del techo. Has conseguido burlar una 
	    vez más a tus verdugos ¿qué nueva tortura te estarán 
	    preparando?^^";
    else print "^Un ruido en el techo llama tu atención. Al mirar 
	hacia arriba descubres que te has librado de una muerte 
	horrible. ¡Un enorme péndulo rematado con una afilada 
	cuchilla estaba oscilando sobre la tabla a la que estabas 
	atado!^^En vista de que su plan ha fracasado, el péndulo es 
	izado a toda velocidad. ¿Qué nueva tortura te prepararán 
	ahora?^^";
    <<Mirar>>;
];

! La celda se aplasta
[ ParedesInicianMovimiento;
    jugador.estado=EN_CELDA_MENGUANTE;
    ratas.estado=RATAS_HAN_HUIDO;
    if (tabla has general) paredes.estado=13;
    "De pronto un espantoso aullido metálico hace temblar toda tu
    celda, como el quejido de un animal fabuloso herido. Seguidamente
    un grave retumbar sacude el aire de la prisión, atravesándote de
    lado a lado. Todas las ratas huyen despavoridas por el pozo.";
];

!================================================================
! Extensiones y modificaciones a la gramática
!================================================================
[ DarPalmadaSub;
    "Aplaudes entusiasmado. ~Gracias, gracias...~ dice el
    autor. [BUG]";
];

[ GritarSub;
    "¡¡¡Yeaargh!!! [BUG]";
];

[ NadaDeUsarSub;
    "Tratas de encontrar un uso para ", (el) uno, " pero tu mente no 
	acierta con la acción concreta.";
];


[ RespirarSub;
    respiracion++;
    if (respiracion<5)
	"Tomas aire con ansia, tratando de oxigenar tu cerebro para
	clarificar tus ideas.";
    "Sufres un pequeño mareo debido a la hiperventilación.";
];

[ MarcarSub;
    "No tiene sentido hacer una marca en ", (el) uno, ".";
];

[ EcharseSub;
    "Aunque estás realmente agotado, tu estado de excitación te impide
    ponerte a descansar.";
];

[ DesatarSub;
    "Qué idea tan absurda.";
];

[ FrotarContraSub;
    if (uno notin jugador)
	"Para eso debes coger ", (el) uno, " antes.";
    if (EjecutarRutinas(uno, antes)) rtrue;
    if(EjecutarRutinas(otro, antes)) rtrue;
    print "Frotas ", (el) uno;
    if (uno==otro)
	print " contra sí mismo";
    else print " contra ", (el) otro;
    " sin lograr ningún resultado aparente.";
];

[ ConjuroSub;
    "En estos momentos desearías que las acusaciones de brujería que
    te han traído aquí fuesen ciertas. Por desgracia no sabes cómo
    lanzar conjuros.";
];

[ AyudaSub;
    "PIENSA.";
];

Verb 'ayuda' 'help'
    *					-> Ayuda;

Verb 'aplaude'
    *					-> DarPalmada;
VerboIrregular "aplaudir" with imperativo 'aplaude';

Extend 'da' first
    * 'palmada'/'palmas'		-> DarPalmada
    * 'una' 'palmada'			-> DarPalmada;
Extend only 'grita' replace 
    *	topic				-> Gritar;

! Eliminados de un plumazo los verbos de conversación
Extend 'habla' replace
    * topic				-> Hablar;
Extend 'pregunta' replace
    * topic				-> Hablar;
Extend 'di' replace
    * topic				-> Hablar;

Verb 'usa' 'emplea' 'utiliza'
    * 'razon'				-> Pensar
    * 'la' 'razon'			-> Pensar
    * noun topic			-> NadaDeUsar;

Extend 'pon' first
    * noun				-> Vestir;

Verb 'respira'
    *					-> Respirar;

Verb 'marca'
    * noun				-> Marcar;

Verb 'haz'
    * 'marca' 'en' noun			-> Marcar
    * 'una' 'marca' 'en' noun		-> Marcar;
VerboIrregular "hacer la marca" with imperativo 'haz';

Verb 'sigue' 'avanza' 'retrocede' 'muevete' 'explora' 'alejate'
    *					-> IrAmbiguo;

Verb 'tirate' = 'metete';
VerboIrregular "tirar" with imperativo 'tirate';

Extend 'echate' first
    * 					-> Echarse;

Verb 'desata' 
    * noun				-> Desatar;

Extend 'frota'
    * noun 'con' noun			-> FrotarContra reverse
    * noun 'contra'/'sobre'/'en' noun	-> FrotarContra;

Verb 'unta' 'embadurna' = 'frota';
Verb 'levanta' = 'coge';
Verb 'muerde' = 'come';
VerboIrregular "morder" with imperativo 'muerde';

Verb 'xyzzy'
    *					-> Conjuro;

Extend 'lanza' first
    * 'conjuro'				-> Conjuro;

Verb 'arrastra'='empuja';

Extend 'empuja'
    * noun 'a//' noun			-> EmpujarDir;


!----------------------------------------------------------------
! Funciones de utilidad
[ Pause i width;
    width = 0->33; if (width == 0) width = 80;
    spaces (width - 18);
    font off;print "[ Pulsa Espacio ]"; font on;
    do { @read_char 1 0 0 i; } until (i==32 or 10 or 13);
    CLS();
];

[ CLS ;
    @erase_window -1;
];