;FLAGS
;FLAG 1 (*First turn of game*)
;FLAG 2 (*Is PM Time?*)
;FLAG 3 (*one of bonus flags for being thorough in room 2-window*)
;FLAG 4 (*Safe is closed*)
;FLAG 5 (*marks south across bridge msg.*)
;FLAG 6 (*Presentable*)
;FLAG 7 (*Package has been delivered*)
;FLAG 8 (vitality flag
;FLAG 9 nutrisim dispensor
;FLAG 10 (*Temporary*)
;FLAG 11 (peanuts spring
;FLAG 12 (*1 of bonus flags--check 3d photo*)
;FLAG 13 (*SPIDER*)
;FLAG 14 (*Music*)
;FLAG 15 (*SPIDER SHOOTS*)
;FLAG 16 (*DENEBIAN FLAG*)
;FLAG 17 *big opporutniy with super    
;FLAG 18 (*MUSIC IS SCOTCHED*)
;FLAG 19 (*Temp phone call flag*)
;FLAG 20 (*Moment of judgement*)
;FLAG 21 --chit for denebian
;FLAG 22 --chit for clean floor
;FLAG 23 --Chit for presentability (don't confuse with 6)
;FLAG 24 --clothed
;FLAG 25 --armed/bipolar
;FLAG 26 --temp door warning flag
;FLAG 27 --has pen
;FLAG 28 --to prevent overall recurrancesuper
;FLAG 29 --apology has happened
;FLAG 30 --delivery of food synth           
;FLAG 31 --KNOWS HOW TO FLENZ?
;FLAG 32 --Denebian wants to know what to flenz
;FLAG 33 --read reminder on front door, first time you go for the
          ;front door
;FLAG 34 --ASSASSIN permenent flag
;FLAG 35 --temp phone ring
;FLAG 36 --bonus call
;FLAG 37 --he is on phone... with grace
;FLAG 38 --warned diggs at busstop
;FLAG 39 --entering elevator from hallway
;FLAG 40 --entering elevator from lobby
;FLAG 41 --this is for 8 30 skybus   
;FLAG 42 --perm flag for first sidewalk event
;FLAG 43 --defines first time you go north at bridge... mari
;FLAG 44 --window of chase opportunity-anyall pupose
;FLAG 45 --Quarter till bus arrival flag
;FLAG 46 --you're calling super about fooderizer
;FLAG 47 --YOU HAVE STUNNED THE SABOTEUR INSURING WIN!
;FLAG 48 --shouldn't wear blacks bi polar
;FLAG 49 --default package delivery
;Flag 50 --drop gun flag
;Flag 51 --drop em all
;Flag 52 --sets up judgement in incinerator room
;the following flags are chits for judgement there
;Flag 53 --appearance
;Flag 54 --armed
;Flag 55 --Denebian
;Flag 56 --there's a fight, lot
;Flag 57 --ask kid structure, set up insect
;Flag 58 --gave shield to kid
;Flag 59 --you're hiding
;Flag 60 --pour water, first time
;Flag 61 --got probe reverse with next
;flag 62 --kid still has hoverboard
;Flag 63 --sabateur
;FLAG 64 --denebian changes in fear
;Flag 65 --kid returns shield
;Flag 66 --dogmatic arrives
;Flag 67 --set up for conversation in lot
;flag 68 --bobbi shares thoughts about dome
;flag 69 --diggs approaches at pavillion
;Flag 70 --you have brought diggs evidence
;Flag 71 --you've told diggs about dome
;Flag 72 --ate hotdog, for better and worse
;flag 73 --first flenz
;flag 74 --first unflenz
;flag 75 --holocaust has commenced
;flag 76 --called mari about injured boy
;flag 77 --got glimpse of lot at alley
;flag 78 --*bonus flag, made phone call, any*
;FLAG 79 --spotted self going out roof
;VARIABLE 1 (Time in seconds)
;VARIABLE 2 (*Time in minutes*)        
;VARIABLE 3 (Time in hours)    
;VARIABLE 4 (Seconds per more)
;VARIABLE 5 (*Decrements vitality*)
;VARIABLE 6 number of sims in packet
;VARIABLE 7 count till package is delivered
;VARIABLE 8 impressing landlord
;VARIABLE 9 amount of water in cup
;VARIABLE 10 how many times you can die
;VARIABLE 11 earns bonus, gets hints
;#DEFINE {maximum seconds per move} 20
;COUNTERS
;COUNTER 1 (*Delivery man's patience*)
;COUNTER 2 (*AFTER MASS TAKEN COUNT TILL SPIDER COMES*)
;COUNTER 3 --counts in the arrival of landlord
;COUNTER 4 --how long he has to ask about fooderizer
;COUNTER 5 --marks off how long super takes to get fooderizer
;COUNTER 6 --door nudge counter
;COUNTER 7 --chance to catch people he should follow
;COUNTER 8 --USED ON ANY HAIL, how long before you hit right talk
;COUNTER 9 --police and bus counter
;COUNTER 10 --WINDOW OF OP ON INSECT ENCOUNTER
;Counter 11 --bus window of op northbound 8:30
;Counter 12 --chance to show diggs goods

COMMAND ANY
FirstVisitToRoom
Chance 4          ;every once in a while
PrintMessage 81     ;been through this before
Delay 5             ;it makes him mull
ClearScreen
END_COMMAND

COMMAND ANY
AtLocation 2     ;in the room
IsClosed 204     ;window closed 
Chance 5       ;ten percent chance
PrintMessage 97  ;its stuffy
Delay 3        
ClearScreen
END_COMMAND

COMMAND ANY
FlagOFF 26      ;door flag--permanent bi-polar
AtLocation 2    ;his apt. main room
IsOpen 231      ;the door
NOT Present 301 ;it's not during the super
NOT Present 240 ;or the delivery man scene
TurnFlagON 26   ;mark door open
TurnCounterON 6 ;start count
END_COMMAND

COMMAND ANY
AtLocation 2       ;if in room
CounterEquals 6 3  ;three turns have passed
PrintMessage 72    ;raised in barn?
Delay 3
ClearScreen
END_COMMAND

COMMAND ANY
FlagOFF 7 (*Package delivery flag*)
SetVariableTo 7 0 (*Initialize condition*)
TurnFlagON 7 (*count has begun*)
END_COMMAND

COMMAND ANY
FlagON 7
AddToVariable 7 1 (*One/per/turn*)
END_COMMAND

;revise--the following need super to come to room--build cms

COMMAND ANY
FlagON 20                ;marks judgement points for super
FlagOFF 21     
Present 302              ;denebian
PrintMessage 65          ;didn't know you had pet, disapproval
BlankLine
SubtractFromVariable 8 1 ;from brownie points
TurnFlagON 21
END_COMMAND

COMMAND ANY
FlagON 20
FlagOFF 22               ;chit for tidiness 
Present 244              ;peanuts
Present 248              ;more peanuts 
PrintMessage 66          ;super eyes mess
BlankLine
SubtractFromVariable 8 2 ;one less brownie poin
TurnFlagON 22
END_COMMAND

COMMAND ANY
FlagON 20
FlagOFF 23               ;moment of tidiness,poss redun flg
FlagOFF 6                ;true neatness flag, now off
PrintMessage 67          ;eyes your disarray
BlankLine 
SubtractFromVariable 8 1 ;less b p
TurnFlagON 23
END_COMMAND

COMMAND ANY
FlagON 20
FlagOFF 24               
NOT IsWearing 200        ;you're naked 
NOT IsWearing 228
NOT IsWearing 230
NOT IsWearing 239
PrintMessage 68          ;and you know it now
BlankLine
SubtractFromVariable 8 1
TurnFlagON 24
END_COMMAND

COMMAND ANY
FlagON 20
FlagOFF 25
IsCarrying 222           ;armed
 OR
IsCarrying 229
 OR
IsCarrying 212
PrintMessage 69          ;makes super nervous
BlankLine
SubtractFromVariable 8 2
TurnFlagON 25
END_COMMAND

COMMAND ANY
FlagON 20
FlagOFF 27
IsSomewhere 241          ;you didn't return pen
SubtractFromVariable 8 1
TurnFlagON 27
END_COMMAND

;these commands involve the landlord's trip to get new machine
;COUNTER 5 is the jiffy, if he apologized and scored well

COMMAND ANY
FlagON 46  ;you've called for super
CounterEquals 5 6
PrintMessage 75
BlankLine
DescribeThing 250
PutInCurrentRoom 250
TurnCounterOFF 5
Delay 10
ClearScreen
PlusScore 50
END_COMMAND

COMMAND ANY
FlagON 29
FlagOFF 30
CounterEquals 5 6   
PrintMessage 75    ;super w synth
DescribeThing 250
PutInCurrentRoom 250
AddToVariable 2 5
TurnCounterOFF 5
END_COMMAND

COMMAND ANY
CounterEquals 5 12  ;wait twelve turns
PrintMessage 75     ;here's supe with synth
BlankLine
SendToRoom 250 2
AddToVariable 2 10
TurnFlagON 30
TurnCounterOFF 5
END_COMMAND

COMMAND ANY
FlagOFF 8 (*vitality flag*)
SetVariableTo 5 25 (*INITIALIZE LOW*)
TurnFlagON 8 (*He's going*)
END_COMMAND

COMMAND ANY
FlagOFF 9 (*Empty dispensor*)
SetVariableTo 6 4 (*Is Now as full as the broke machine allows*)
SetVariableTo 9 8 (*There are five sips in the cup*)
TurnFlagON 9 (*And running*)
END_COMMAND

COMMAND ANY
FlagON 8 (*Vitality*)
SubtractFromVariable 5 1 (*Natural wear rate*)
END_COMMAND

COMMAND ANY
LoadWeightGT 30
SubtractFromVariable 5 1 (*Wear for lugging heavy*)
END_COMMAND

COMMAND ANY
VariableEquals 5 8 (*He's mucho low on energy*)
PrintMessage 20 (*Feeling weak*)
BlankLine
END_COMMAND

COMMAND ANY
VariableEquals 5 3 (*Right near the eand*)
PrintMessage 21
BlankLine
Delay 3
END_COMMAND

COMMAND ANY
VariableLT 5 1   ;energy at zip
VariableGT 10 3  ;youve had 3 chances 
PrintMessage 22  ;you're dead
BlankLine
PrintMessage 51  ;this time it's over
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND ANY
VariableLT 5 1 (*No steam*)
PrintMessage 22 (*Tough breaks*)
BlankLine
PrintMessage 114
BlankLine
GoToRoom 2
SetVariableTo 5 20  ;free boost
SubtractFromVariable 2 5
AddToVariable 10 1  ;only return to timeline x times
DoneWithTurn
END_COMMAND
 
COMMAND ANY
FlagOFF 49         ;default package delivery
IsNowhere 242      ;the package undelivered
VariableEquals 3 7 ;it's eight oclock
VariableGT 2 30     ;five after
SendToRoom 242 4
TurnFlagON 49
END_COMMAND

COMMAND ANY
AtLocation 4        ;in hall
IsNowhere 242
VariableGT 7 20 ;delivery is due
PrintMessage 93     ;he steps out of nowhere
BlankLine
PutInCurrentRoom 240
DescribeThing 240   ;delivery man
PrintMessage 25     ;gives you pen
BlankLine            
GetIt 241           ;done
TurnFlagON 11
TurnCounterON 1
DoneWithTurn
END_COMMAND

COMMAND ANY
FlagOFF 10 (*No delivery yet*)
VariableEquals 7 20 (*We've waited twenty turns*)
SendToRoom 240 4 (*Delivery man to hall*)
SendToRoom 270 2 ;knocking
TurnFlagON 10 (*Delivery is history*)
END_COMMAND

COMMAND ANY
FlagOFF 1 (*first turn of game--initialize*)             
TurnFlagOFF 2 (*Is PM time*)
SetVariableTo 1 0 (*Set time to six 45AM*)
SetVariableTo 2 45
SetVariableTo 3 6
TurnFlagON 1 (*No longer first turn*)   
END_COMMAND

COMMAND ANY
RandomVariable 4 20 (*Turns can take nearly a minute*)
AddVariables 1 4 (*Add this to regular increments*)
END_COMMAND

COMMAND ANY
VariableGT 1 59            ;turns seconds to minutes 
SubtractFromVariable 1 60
AddToVariable 2 1
END_COMMAND

COMMAND ANY
VariableGT 2 59            ;minutes to hours
SubtractFromVariable 2 60
AddToVariable 3 1
END_COMMAND

COMMAND ANY
VariableGT 3 12            ;AM to PM
SubtractFromVariable 3 12
ToggleFlag 2
END_COMMAND

COMMAND ANY
CounterEquals 1 3 (*During the Delivery*)
PrintMessage 27 (*Player told*)
SendToRoom 301 4 (*Super is in hall watching*)
BlankLine
END_COMMAND

COMMAND ANY
CounterEquals 1 5 (*Player has two turns with to impress*)
PrintMessage 28 (*He watches with interest*)
SendToRoom 301 24 (*Then leaves for stairsaft room*)
BlankLine
PrintMessage 29 (*One last glimpse*)
BlankLine
END_COMMAND

COMMAND ANY
CounterEquals 1 7     ;seven turns into delivery encounter
PrintMessage 73       ;delivery man gives up
BlankLine
PutInCurrentRoom 242  ;he leaves package and pen
Destroy 240           ;he leaves
TurnFlagOFF 11
TurnCounterOFF 1
END_COMMAND

COMMAND ANY
AtLocation 14       ;alley
NOT VerbIsDirection ;your not leaving
FlagOFF 77
DescribeThing 248   ;glimpse spider and super
BlankLine
TurnFlagON 77       ;only once
END_COMMAND

;SPIDER DELETE 

COMMAND ANY
Present 304 ;or other creature
IsCarrying 214 ;and he's got the cred-card
SwapLocations 214 215 ;it will get zapped
END_COMMAND

COMMAND ANY
Present 302 ;denebian
Present 304  ;insect
PrintMessage 139
BlankLine
SwapLocations 302 243  
END_COMMAND

COMMAND ANY
AtLocation 17
CounterEquals 10 3
PrintMessage 59
BlankLine
TurnFlagON 56 ;it's fighting time
TurnCounterOFF 10
END_COMMAND

COMMAND ANY
FlagON 56
Present 317  ;bobbi
FlagOFF 58   ;doesn't have shield
SwapLocations 317 318
END_COMMAND

COMMAND ANY
Present 304 ;insect
Chance 33 ;chance of shooting
TurnFlagON 15 ;a shot is taken
PrintMessage 40 ;describe this shot
Chance 60 ; chance of taking hit
PrintMessage 41 ; that was a close one
TurnFlagOFF 15 ;its history
END_COMMAND

COMMAND ANY
FlagON 15
FlagON 59     ;is hiding
 OR
IsWearing 224
PrintMessage 133 ;doesn't hit, cause your hidden
BlankLine
TurnFlagOFF 15
END_COMMAND

COMMAND ANY
FlagON 15
VariableGT 10 3
PrintMessage 55
BlankLine
PrintMessage 51
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND ANY
FlagON 15
PrintMessage 55     ;it wouldseem you're dead
BlankLine
PrintMessage 114    ;pulled out of timeline
BlankLine
Destroy 304         ;the insect
AddToVariable 5 20  ;bonus vitality
AddToVariable 10 1  ;chances at rebirth
SubtractFromVariable 2 2 ;you gain two min.
AddToVariable 10 1
TurnFlagOFF 57      ;so it can reoccur
TurnFlagOFF 56      ;that's the fight flag        
TurnFlagOFF 15
DoneWithTurn
END_COMMAND

COMMAND ANY
Present 317
Present 252  ;this can only be if kid survived fight shielded
 OR
Present 251
FlagOFF 65  
PrintMessage 142
BlankLine
GetIt 224
TurnFlagON 65
END_COMMAND

COMMAND ANY
NOT VerbIsDirection
AtLocation 10
 OR
AtLocation 11
 OR
AtLocation 12
 OR
AtLocation 15
 OR
AtLocation 18
VariableLT 3 9
VariableLT 2 30
PutInCurrentRoom 303
END_COMMAND

COMMAND ANY
AtLocation 10
Present 314
DescribeThing 314
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 15 ;confluence
VariableGT 2 30
VariableEquals 3 7
FlagOFF 41
PrintMessage 105
BlankLine
PrintMessage 99
BlankLine
PutInCurrentRoom 312 ;northbound skybus
PutInCurrentRoom 307 ;diggs
SwapLocations 209 207  ;oooh, the note changes
TurnFlagON 41
TurnCounterON 11
END_COMMAND

COMMAND ANY
AtLocation 15
CounterEquals 11 4  ;three turns to respond
PrintMessage 104
BlankLine
SwapLocations 312 275
Destroy 307
TurnCounterOFF 11
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 15
FlagOFF 45
VariableGT 2 45
VariableEquals 3 7
PrintMessage 105
BlankLine
PutInCurrentRoom 313
TurnFlagON 45
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 17   ;west end lot
Present 302     ;denebian
Present 317     ;bobbi
FlagOFF 68
PrintMessage 154
BlankLine
TurnFlagON 68
END_COMMAND

COMMAND ANY
AtLocation 10
FlagOFF 50
IsCarrying 212   ;sudmaas pistol
 OR
IsCarrying 222   ;kendall laser
PrintMessage 124
BlankLine
PutInCurrentRoom 316  ;cops
TurnFlagON 50
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 10
FlagOFF 48
IsWearing 228   ;blacks
PrintMessage 121 ;cops surround, demand ID
BlankLine
PutInCurrentRoom 316
TurnFlagON 48
DoneWithTurn
END_COMMAND

COMMAND ANY
VerbIsDirection
Present 316        ;cops present
PrintMessage 128   ;you try to leave scene 
BlankLine
PrintMessage 114
BlankLine
GoToRoom 9  
SubtractFromVariable 2 5
AddToVariable 10 1
DoneWithTurn
END_COMMAND

COMMAND ANY
NOT VerbIsDirection
AtLocation 10
 OR
AtLocation 11
 OR
AtLocation 15
 OR 
AtLocation 21
IsSomewhere 237  ;its time is present
NOT Present 237
PutInCurrentRoom 237
END_COMMAND

COMMAND ANY
AtLocation 15
FlagOFF 66
Chance 20
DescribeThing 311
BlankLine
PutInCurrentRoom 311
TurnFlagON 66
END_COMMAND

COMMAND ANY
NOT VerbIsDirection
AtLocation 16
 OR
AtLocation 17
PutInCurrentRoom 267  ;weeds
PutInCurrentRoom 268  ;structures
END_COMMAND

COMMAND ANY
AtLocation 21
Present 307           ;diggs
FlagOFF 69
PrintMessage 149
BlankLine
TurnFlagON 69
TurnCounterON 12
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 21
CounterEquals 12 6
PrintMessage 148
BlankLine
Destroy 307
TurnCounterOFF 12
END_COMMAND

;win files

COMMAND ANY
AtLocation 21    ;pavillion
FlagON 47        ;saboteur has been properly stopped  
FlagON 6         ;you are presentable
FlagON 62        ;scored probe
FlagON 70        ;showed evidence of struggles
FlagON 71        ;told diggs where gate is
FlagON 72        ;ate hotdog, only difference
VariableGT 2 58  ;it's eight
IsWearing 228    ;blacks
PrintMessage 147 ;you're lined up
BlankLine
GoToRoom 28
WinGame
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 21    ;pavillion
FlagON 47        ;saboteur has been properly stopped  
FlagON 6         ;you are presentable
FlagON 62        ;scored probe
FlagON 70        ;showed evidence of struggles
FlagON 71        ;told diggs where gate is
VariableGT 2 58  ;it's eight
IsWearing 228    ;blacks
PrintMessage 147 ;you're lined up
BlankLine
GoToRoom 27
WinGame
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 21    ;pavillion
FlagON 47        ;saboteur has been properly stopped  
FlagON 6         ;you are presentable
VariableGT 2 58  ;it's eight
IsWearing 228    ;blacks
PrintMessage 147 ;you're lined up
BlankLine
GoToRoom 29      ;no win/win
WinGame
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 21   ;tranquil pavillion
VariableGT     2 58
DescribeThing 315  ;glimpse of assassin
PrintMessage 140
BlankLine
PrintMessage 119  ;flash, boom
BlankLine
GoToRoom 22     ;pavillion chaos
DoneWithTurn
END_COMMAND

;default 8:00 ending setup

COMMAND ANY
VariableGT 3 7
FlagOFF 75
NOT AtLocation 21   ;pavillion
 OR
NOT AtLocation 25   ;gardens
PrintMessage 120
BlankLine
TurnFlagON 75
SendToRoom 314 10
END_COMMAND

COMMAND ANY
AtLocation 24     ;room at bottom stairs
FlagOFF 52        ;perm
Present 301       ;supe
PrintMessage 116  ;super notes your arrival
BlankLine
SetVariableTo 8 4 ;impressing landlord
TurnFlagON 52
END_COMMAND

COMMAND ANY
AtLocation 24
Present 301     ;super at incinerator
FlagOFF 53
FlagOFF 6       ;not presentable
PrintMessage 67
BlankLine
SubtractFromVariable 8 1
TurnFlagON 53
END_COMMAND

COMMAND ANY
AtLocation 24
Present 301
FlagOFF 54
IsCarrying 212  ;sudmaas
 OR
IsCarrying 222  ;kendall
 OR
IsCarrying 229  ;rifle mockup
PrintMessage 69
BlankLine
SubtractFromVariable 8 1
TurnFlagON 54
END_COMMAND

COMMAND ANY
AtLocation 24
Present 301
Present 302      ;denebian
FlagOFF 55
PrintMessage 65
BlankLine
SubtractFromVariable 8 1
TurnFlagON 55
END_COMMAND

COMMAND ANY
AtLocation 25        ;gardens
FlagOFF 63           ;permflag
VariableEquals 3 7   ;it's time
VariableGT 2 54
DescribeThing 315    ;saboteur
BlankLine            ;up to something                       
PrintMessage 141     
PutInCurrentRoom 315 
BlankLine
TurnFlagON 63
DoneWithTurn
END_COMMAND

COMMAND ANY
Present 315   ;saboteur
Chance 50     ;he's determined
TurnFlagON 15 ;a shot is taken
PrintMessage 143 ;describe this shot
Chance 60 ; chance of taking hit
PrintMessage 144 ; that was a close one
TurnFlagOFF 15 ;its history
END_COMMAND

COMMAND ANY
FlagON 15
IsWearing 224   ;shield
PrintMessage 42
BlankLine
TurnFlagOFF 15
END_COMMAND

COMMAND ANY
FlagON 15
PrintMessage 145
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 2
FlagOFF 36
VariableGT 11 6    ;you've been thorough at outset of game
PrintMessage 90    ;phone rings
BlankLine          
SendToRoom 263 2
TurnFlagON 36      ;the bonus hint call
END_COMMAND

COMMAND ANY
AtLocation 31
FlagOFF 79
VariableLT 7 7  ;you've hit roof immediately
PrintMessage 161 
TurnFlagON 79
END_COMMAND

COMMAND SAY TIME
FlagOFF 2            
VariableLT 2 10
PrintMessage 3
DoneWithTurn
END_COMMAND

COMMAND SAY TIME
FlagOFF 2
PrintMessage 1
DoneWithTurn
END_COMMAND

COMMAND SAY TIME
FlagON 2
VariableLT 2 10
PrintMessage 4
DoneWithTurn
END_COMMAND

COMMAND SAY TIME
FlagON 2
PrintMessage 2
DoneWithTurn
END_COMMAND

COMMAND SAY NICK    
FlagOFF 4
Present 220
Delay 3
PrintMessage 8
SwapLocations 220 238
ShowContents 238
Tone 660 700
PlusScore 50
TurnFlagON 4
DoneWithTurn
END_COMMAND

COMMAND SAY THIRD FLOOR
AtLocation 8
PrintMessage 101
BlankLine
GoToRoom 4
SendToRoom 255 4
DoneWithTurn
END_COMMAND

COMMAND SAY MIRRORED LOBBY
AtLocation 8
PrintMessage 101
BlankLine
GoToRoom 9
SendToRoom 255 9
DoneWithTurn
END_COMMAND

COMMAND TELL TIME
Present 202 (*Wristwatch*)
ReDirectTo SAY TIME
END_COMMAND

COMMAND TELL TIME
Present 237 (*Clocktower*)
ReDirectTo SAY TIME
END_COMMAND

COMMAND TELL DIGGS ABOUT STRUCTURE
Present 307
FlagOFF 71
PrintMessage 151
BlankLine
Tone 660 700
PlusScore 50
TurnFlagON 71
DoneWithTurn
END_COMMAND

COMMAND TELL DIGGS ABOUT ANY
AtLocation 15
Present 307
Present 275
PrintMessage 152
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TELL DIGGS ABOUT ANY
AtLocation 21
Present 307
NOT ObjectPresent
ObjectIsNumber 218
 OR
ObjectIsNumber 251
 OR
ObjectIsNumber 252
 OR
ObjectIsNumber 300
 OR
ObjectIsNumber 304
PrintMessage 35
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TELL SUPER ANY
FlagON 46
NOT ObjectIsNumber 232
PrintMessage 5
TurnFlagOFF 46
DoneWithTurn
END_COMMAND

COMMAND TELL SUPER ANY
NOT AtLocation 24 
Present 301
PrintMessage 134
BlankLine
SendToRoom 301 24
DoneWithTurn
END_COMMAND

COMMAND TELL SUPERINTENDANT ABOUT FOODERIZER
RedirectTo ASK SUPERINTENDANT ABOUT FOODERIZER
END_COMMAND

COMMAND READ WATCH
Present 202            
ReDirectTo SAY TIME
END_COMMAND

COMMAND READ TOWER
Present 237              
ReDirectTo SAY TIME
END_COMMAND

COMMAND READ ANY
AtLocation 2
NOUNPresent
AddToVariable 11 1
END_COMMAND

COMMAND EXAMINE WATCH
Present 202             
DescribeThing 202              
BlankLine
ReDirectTo SAY TIME
END_COMMAND

COMMAND EXAMINE TOWER
Present 237             
DescribeThing 237             
BlankLine
ReDirectTo SAY TIME
END_COMMAND

COMMAND EXAMINE STRUCTURES
AtLocation 2   ;main room
IsOpen 204     ;window
DescribeThing 268 
BlankLine
ShowContents 17
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EXAMINE STRUCTURES
AtLocation 14
 OR
AtLocation 19
DescribeThing 268
BlankLine
ShowContents 17
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EXAMINE GROUND
AtLocation 14
DescribeThing 260 ;sets of prints and marks in alley
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
IsOpen 225        ;closet door
FlagOFF 6         ;he's not presentable 
IsWearing 239     ;wet clothes
DescribeThing 227 ;mirror intro
BlankLine         ; 
PrintMessage 48   ;you look like drowned rat
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
IsOpen 225
FlagOFF 6
IsWearing 264
 OR
IsWearing 265
DescribeThing 227
BlankLine
PrintMessage 43
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
FlagOFF 6
DescribeThing 227
BlankLine
PrintMessage 43
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
FlagON 6
IsWearing 228
DescribeThing 227
BlankLine
PrintMessage 44
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
FlagON 6
IsWearing 230
DescribeThing 227
BlankLine
PrintMessage 45
DoneWithTurn
END_COMMAND

COMMAND EXAMINE MIRROR
FlagON 6
NOT IsWearing 228
NOT IsWearing 230
DescribeThing 227
BlankLine
PrintMessage 19
DoneWithTurn
END_COMMAND

COMMAND EXAMINE KID
Present 317
FlagOFF 62
DescribeThing 317
BlankLine
PrintMessage 82
BlankLine
DoneWithTurn
END_COMMAND

;part of bonus wins hint prcess

COMMAND EXAMINE ANY
AtLocation 2
NOUNPresent
AddToVariable 11 1
END_COMMAND

COMMAND EXAMINE ANY
AtLocation 2
IsOpen 231
NOUNIsLocated 4
PrintMessage 31
DoneWithTurn
END_COMMAND

COMMAND STRAIGHTEN PAINTING
PrintMessage 7
PutInCurrentRoom 220
DoneWithTurn
END_COMMAND

COMMAND SHOWER
AtLocation 25  ;gardens
FlagOFF 6      ;needs it
PrintMessage 155
BlankLine
DropEverything
RemoveEverything
TurnFlagON 6
AddToVariable 1 30
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND SHOWER
AtLocation 3
FlagOFF 6
IsWearing 200
PrintMessage 9
BlankLine
PrintMessage 10
SwapLocations 200 239
AddToVariable 2 20
DoneWithTurn
END_COMMAND

COMMAND SHOWER
AtLocation 3
FlagOFF 6
IsWearing 228
 OR
IsWearing 230
PrintMessage 111
BlankLine
TurnFlagON 6
AddToVariable 2 20
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND SHOWER
AtLocation 3
FlagOFF 6
PrintMessage 9
BlankLine
TurnFlagON 6
AddToVariable 2 20
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND SHOWER
FlagON 6
PrintMessage 12
DoneWithTurn
END_COMMAND

COMMAND SHOWER
PrintMessage 11
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OPEN FLENZER
Present 201
DescribeThing 100
BlankLine
ShowContents 100
DoneWithTurn
END_COMMAND

COMMAND OPEN CLOSET
FlagOFF 38    ;hasn't had memory
Present 225   ;he's where closet it
IsClosed 225  ;and yes its closed
Chance 40     ;not bad odds
PrintMessage 98 ;plants memory of jungle camp
BlankLine
OpenIt 225
ShowContents 225
DoneWithTurn
END_COMMAND

COMMAND OPEN CLOSET
Present 225
IsClosed 225
PrintMessage 14
BlankLine
OpenIt 225
ShowContents 225
DoneWithTurn
END_COMMAND

COMMAND OPEN WINDOW      
Present 204
AtLocation 2   ;main room
IsClosed 204     ;window
FlagOFF 3
DescribeThing 205
BlankLine
OpenIt 204
TurnFlagON 3
DoneWithTurn
END_COMMAND

COMMAND OPEN WINDOW
Present 204
OpenIt 204
PrintMessage 14
ShowContents 204
DoneWithTurn
END_COMMAND

COMMAND OPEN DRESSER
Present 217
OpenIt 217
PrintMessage 14
ShowContents 217
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
AtLocation 2
FlagOFF 33
DescribeThing 231
Delay 8
TurnFlagON 33
END_COMMAND

COMMAND OPEN DOOR
AtLocation 2
FlagOFF 17
FlagON 10
NOT IsWearing 200
NOT IsWearing 228
NOT IsWearing 230
NOT IsWearing 239
PrintMessage 46
BlankLine
DoneWithTurn
END_COMMAND 

COMMAND OPEN DOOR
AtLocation 2
FlagON 17           ;this must remain on so this event will not recur
FlagOFF 20          ;this flag represents the timeof judgement
FlagOFF 28
OpenIt 231
PrintMessage 61
BlankLine
PutInCurrentRoom 301 
Destroy 270         ;knocking
SetVariableTo 8 5
TurnFlagON 20
TurnFlagON 28
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
AtLocation 2
FlagON 10
FlagOFF 11
OpenIt 231
PrintMessage 14
BlankLine
DescribeThing 240
PrintMessage 25
SendToRoom 241 1
PutInCurrentRoom 240
Destroy 270          ;knocking
TurnFlagOFF 10
TurnFlagON 11
TurnCounterON 1
DoneWithTurn
END_COMMAND

COMMAND OPEN PACKAGE
FlagOFF 11 (*Package trap*)
Present 242 (*Package*)
PrintMessage 34 (*peanuts spring out*)
BlankLine
PutInCurrentRoom 244 ;peanuts
OpenIt 242
TurnFlagON 11
DoneWithTurn
END_COMMAND

COMMAND CLOSE DOOR
FlagON 26
AtLocation 2
CloseIt 231
PrintMessage 54
TurnFlagOFF 26
TurnCounterOFF 6
DoneWithTurn
END_COMMAND

COMMAND CLOSE SAFE
Present 238
PrintMessage 15
SwapLocations 238 220
TurnFlagOFF 4
DoneWithTurn
END_COMMAND

COMMAND REMOVE RUMPLED SUIT
IsWearing 200
RemoveIt 200
RelocateAll 1 200
PrintMessage 19
DoneWithTurn
END_COMMAND

COMMAND REMOVE UNIFORM
IsWearing 228
RemoveIt 228
RelocateAll 1 228
PrintMessage 19
DoneWithTurn
END_COMMAND

COMMAND REMOVE NONDESCRIPT SUIT
IsWearing 230
RemoveIt 230
RelocateAll 1 230
PrintMessage 19
DoneWithTurn
END_COMMAND

COMMAND REMOVE SOGGY CLOTHES
IsWearing 239
RemoveIt 239
RelocateAll 1 239
PrintMessage 19
BlankLine
TurnFlagON 6
DoneWithTurn
END_COMMAND

COMMAND RELOAD DISPENSOR
Present 250
Present 233
PrintMessage 77
BlankLine
DoneWithTurn
END_COMMAND

COMMAND RELOAD DISPENSOR
Present 250
Present 234
PrintMessage 76
BlankLine
AddToVariable 6 6
SwapLocations 234 233
DoneWithTurn
END_COMMAND

COMMAND REFILL CUP
Present 236
Present 250
PrintMessage 76
SwapLocations 236 235
DoneWithTurn
END_COMMAND
 
COMMAND PUT ON RUMPLED SUIT  
Present 200
PrintMessage 17
DoneWithTurn
END_COMMAND

COMMAND PUT ON SOGGY CLOTHES
Present 239
PrintMessage 17
DoneWithTurn
END_COMMAND

COMMAND PUT ON UNIFORM
Present 228
IsWearing 200
 OR 
IsWearing 230
 OR
IsWearing 239
PrintMessage 47
DoneWithTurn
END_COMMAND

COMMAND PUT ON UNIFORM          
Present 228
PrintMessage 16
WearIt 228
RelocateAll 228 1
AddToVariable 2 2
DoneWithTurn
END_COMMAND

COMMAND PUT ON NONDESCRIPT SUIT
Present 230
IsWearing 200
 OR 
IsWearing 228
 OR
IsWearing 239
PrintMessage 47
DoneWithTurn
END_COMMAND

COMMAND PUT ON NONDESCRIPT SUIT
Present 230
PrintMessage 16
WearIt 230
RelocateAll 230 1
AddToVariable 2 1
DoneWithTurn
END_COMMAND

COMMAND PUT ON ENERGY SHIELD
Present 224
IsWearing 200
 OR
IsWearing 228
 OR
IsWearing 230
PrintMessage 18
AddToVariable 2 2
DoneWithTurn
END_COMMAND

COMMAND EAT HOTDOG
Present 262     ;the dog
FlagOFF 72
PrintMessage 106
BlankLine
Destroy 262
AddToVariable 5 50
TurnFlagON 72
DoneWithTurn
END_COMMAND

COMMAND EAT HOTDOG
Present 262     ;the dog
PrintMessage 106
BlankLine
Destroy 262
AddToVariable 5 50
DoneWithTurn
END_COMMAND

COMMAND EAT DISPENSOR
Present 233
VariableEquals 6 0
SwapLocations 233 234
DescribeThing 234
DoneWithTurn
END_COMMAND

COMMAND EAT DISPENSOR
Present 233
GetIt 233
PrintMessage 23
AddToVariable 5 12
SubtractFromVariable 6 1
DoneWithTurn
END_COMMAND

COMMAND EAT DISPENSOR
Present 234
DescribeThing 234
DoneWithTurn
END_COMMAND

COMMAND SIGN CREDCARD
Present 240
PrintMessage 26
DoneWithTurn
END_COMMAND

COMMAND SIGN MAN
ReDirectTo SIGN CREDCARD
END_COMMAND

COMMAND DROP PISTOL
Present 316  ;cops
FlagOFF 51
IsCarrying 212
IsCarrying 222
PrintMessage 106
PrintMessage 126
BlankLine
Destroy 212
TurnFlagON 51
DoneWithTurn
END_COMMAND

COMMAND DROP PISTOL
Present 316  ;cops
IsCarrying 212
PrintMessage 106
PrintMessage 125
BlankLine
Destroy 212
TurnFlagON 51
DoneWithTurn
END_COMMAND

COMMAND DROP LASER
Present 316
FlagOFF 51
IsCarrying 212
IsCarrying 222
PrintMessage 106
PrintMessage 126
BlankLine
Destroy 222
TurnFlagON 51
DoneWithTurn
END_COMMAND

COMMAND DROP LASER
Present 316
IsCarrying 222
PrintMessage 106
PrintMessage 125
BlankLine
Destroy 222
DoneWithTurn
END_COMMAND

COMMAND RETURN SHIELD TO KID
Present 317   ;bobbi
Present 224
PrintMessage 87
BlankLine
Destroy 224
TurnFlagON 58  ;bobbi now has shield
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND RETURN PEN              
FlagON 11
Present 240
PrintMessage 30
PutInCurrentRoom 242
Destroy 240
Destroy 241
SendToRoom 301 24
TurnFlagOFF 11
TurnCounterOFF 1
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND RETURN CREDCARD
Present 316 ;security wants ID
Present 212 ;weapons
 OR
Present 222
Present 214 ;credcard
 OR
Present 221
PrintMessage 127 ;id good, weapons bad
BlankLine
PrintMessage 114
GoToRoom 9
SubtractFromVariable 2 5
AddToVariable 10 1
DoneWithTurn
END_COMMAND

COMMAND RETURN CREDCARD
Present 316 ;Security wants ID
Present 214 ;credcard
 OR
Present 221 ;backup
PrintMessage 122  ;go back and get new clothes
BlankLine
Destroy 316
GoToRoom 9  ;if you go back out, it happens all over
DoneWithTurn
END_COMMAND

COMMAND RETURN CREDCARD
Present 316 ;Security wants ID
Present 215 ;busted credcard
NOT Present 221
PrintMessage 123  ;ixnay on that               
BlankLine
PrintMessage 114
GoToRoom 9  ;if you go back out, it happens all over
SubtractFromVariable 2 2
AddToVariable 10 1
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 4
PrintMessage 33
BlankLine
END_COMMAND

COMMAND NORTH
AtLocation 9
PrintMessage 62
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 11 ;bridge
FlagOFF 43   ;perm event flag
PrintMessage 102 ;mari asks about kid
BlankLine
GetIt 211
GoToRoom 15
TurnFlagON 43
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 19   ;side street
VariableLT 2 44 ;not yet a quarter till
PrintMessage 135
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 19
FlagON 62
PrintMessage 62
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 19  ;now that it's open
FlagOFF 62
IsCarrying 214
 OR
IsCarrying 221
DescribeThing 20  ;the shop
BlankLine
PrintMessage 136
BlankLine
GetIt 253         ;probe
TurnFlagON 62
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 19
DescribeThing 20 ;probe shop
BlankLine
PrintMessage 64 ;no credcard no luck
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH
AtLocation 31    ;rooftop
PrintMessage 157
BlankLine
DoneWithTurn
END_COMMANE

COMMAND EAST
AtLocation 31
PrintMessage 158
BlankLine
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 31
PrintMessage 159
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 31
PrintMessage 160
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 2
IsClosed 231
PrintMessage 32
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 2
IsOpen 231
PrintMessage 33
BlankLine
GoToRoom 4
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 10
DescribeThing 271
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 16
DescribeThing 259
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST
AtLocation 17
Present 317
FlagON 61   ;you borrowed board
DescribeThing 254
BlankLine
Destroy 317
END_COMMAND

COMMAND EAST
AtLocation 17
Present 317
FlagOFF 61   ;you forgot to borrow board
DescribeThing 254
BlankLine
Destroy 317
Destroy 269
END_COMMAND

COMMAND WEST
AtLocation 4
IsLocked 247
PrintMessage 62
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 4
IsClosed 247
PrintMessage 63
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 4
PrintMessage 33
GoToRoom 2
CloseIt 247
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 14  ;alley
DescribeThing 259
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST
AtLocation 16
FlagOFF 67
PrintMessage 153
BlankLine
TurnFlagON 67
END_COMMAND

COMMAND SOUTH
AtLocation 7
PrintMessage 62
BlankLine
DoneWithTurn
END_COMMAND

COMMAND SOUTH
AtLocation 15
Present 275   ;the crash has happened
Present 307
FlagON 38     ;you've warned diggs
SendToRoom 307 21 ;diggs to pavilion
END_COMMAND

COMMAND SOUTH
AtLocation 11   ;bridge
FlagOFF 5
PrintMessage 6
BlankLine
TurnFlagON 5
END_COMMAND

COMMAND SOUTH
AtLocation 21
DescribeThing 26
DoneWithTurn
END_COMMAND

COMMAND SOUTHEAST
AtLocation 10
DescribeThing 30
Delay 30
ClearScreen
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SOUTHWEST
AtLocation 10    ;sidewalk
Chance 70      
PrintMessage 36  ;youre carried to underground
Delay 12
ClearScreen
GoToRoom 18
DoneWithTurn
END_COMMAND

COMMAND PUSH FOODERIZER
AtLocation 5
FlagON 18
PrintMessage 58
DoneWithTurn
END_COMMAND

COMMAND PUSH FOODERIZER
AtLocation 5   ;in kitchen
FlagOFF 18
FlagON 14
PrintMessage 52
Destroy 246
TurnFlagOFF 14
TurnFlagON 18
TurnCounterOFF 3
DoneWithTurn
END_COMMAND

COMMAND PUSH FOODERIZER    
AtLocation 5
FlagOFF 14 (*Music is initiated*)
AtLocation 5
PrintMessage 37 (*Breakfast is served*)
BlankLine 
PrintMessage 38 (*The radio comes on*)
PutInCurrentRoom 216 (*Tray*)
PutInCurrentRoom 246 ;broadcast
TurnFlagON 14 (*music ongoes*)
DoneWithTurn
END_COMMAND

COMMAND PUSH ELEVATOR
AtLocation 4
PrintMessage 100 ;push button, door opens, enter, elevator starts
GoToRoom 8       ;elevator
DoneWithTurn
END_COMMAND

COMMAND PUSH ELEVATOR
AtLocation 9
PrintMessage 100 ;push button, door opens, enter, elevator starts
GoToRoom 8       ;elevator
DoneWithTurn
END_COMMAND

COMMAND SHOOT INSECT WITH LASER
Present 304
IsCarrying 222
PrintMessage 88
BlankLine
SwapLocations 304 252    ;insect and heap
SubtractFromVariable 5 6
TurnFlagOFF 6
TurnFlagOFF 56
DoneWithTurn
END_COMMAND

COMMAND SHOOT INSECT WITH PISTOL
Present 304
IsCarrying 212
PrintMessage  88
SwapLocations 304 252
SubtractFromVariable 5 6
TurnFlagOFF 6
TurnFlagOFF 56
DoneWithTurn
END_COMMAND

COMMAND SHOOT SABOTEUR WITH LASER
Present 315
IsCarrying 222
PrintMessage 146
BlankLine
EndGame
DoneWithTurn
END_COMMAND

COMMAND SHOOT SABOTEUR WITH PISTOL
Present 315
IsCarrying 212
PrintMessage 146
BlankLine
EndGame
DoneWithTurn
END_COMMAND

COMMAND SHOOT ANY WITH RIFLE
IsCarrying 229
PrintMessage 24
BlankLine 
DoneWithTurn
END_COMMAND

COMMAND STUN INSECT
Present 304
IsCarrying 222
Delay 5
PrintMessage 89
SwapLocations 304 251
TurnFlagOFF 56
DoneWithTurn
END_COMMAND

COMMAND STUN SABOTEUR
Present 315
IsCarrying 222
Delay 3
PrintMessage 106
BlankLine
SwapLocations 315 256
TurnFlagON 47
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND POUR WATER ON MASS
Present 235
Present 243
FlagOFF 60
PrintMessage 49 ;you pour water on it
BlankLine
DescribeThing 302
BlankLine
PrintMessage 50
GetIt 201
SwapLocations 235 236
Destroy 243
PutInCurrentRoom 302
TurnFlagON 60
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND POUR WATER ON MASS
Present 235
Present 243
PrintMessage 49 ;you pour water on it
BlankLine
SwapLocations 235 236
Destroy 243
PutInCurrentRoom 302
DescribeThing 302
DoneWithTurn
END_COMMAND

COMMAND DRINK WATER
Present 235
SwapLocations 235 236
PrintMessage 56
AddToVariable 5 10
DoneWithTurn
END_COMMAND

COMMAND SIP WATER       
Present 235
VariableEquals 9 0
SwapLocations 235 236
DescribeThing 236
DoneWithTurn
END_COMMAND

COMMAND SIP WATER
Present 235
PrintMessage 57
AddToVariable 5 8
SubtractFromVariable 9 1
DoneWithTurn
END_COMMAND

COMMAND ASK DENEBIAN ABOUT FLENZER
FlagOFF 31
Present 201
Present 302
PrintMessage 80
TurnFlagON 31
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT FOODERIZER
FlagON 18
FlagON 46    ;this is holocall
PrintMessage 115
BlankLine
TurnCounterON 5  ;the jiffy, but no judgement
Tone 660 700
TurnFlagOFF 46
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT FOODERIZER
FlagON 18
FlagON 20
VariableGT 8 3
PrintMessage 70
GoToRoom 5
Destroy 301
TurnFlagOFF 20
TurnCounterON 5  ;the jiffy
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT FOODERIZER
FlagON 18
FlagON 20
VariableLT 8 4
PrintMessage 71
Destroy 301
TurnFlagOFF 20
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT STRUCTURES
AtLocation 24
Present 301
VariableGT 8 2 ;held his own through judgement
FlagON 29      ;apology has occurred
PrintMessage 129
BlankLine
ChangePassageway 1 16  ;now there is a way between
UnlockIt 213
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT STRUCTURES
AtLocation 24
Present 301
VariableGT 8 2 ;held his own through judgement
PrintMessage 117  ;yeah, its out there, but no go
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT STRUCTURES
AtLocation 24
PrintMessage 112
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ASK KID ABOUT STRUCTURE
Present 317
FlagOFF 57          ;it can only happen once
PrintMessage 130
BlankLine
Delay 12
PrintMessage 131
BlankLine
DescribeThing 304
PutInCurrentRoom 304  ;metal bug
TurnCounterON 10   ;chance to hide, and give bobbi shield
TurnFlagON 57      
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND ASK SUPERINTENDANT ABOUT GRAY DOOR
ReDirectTo ASK SUPERINTENDANT ABOUT STRUCTURES
END_COMMAND

COMMAND APOLOGIZE TO SUPERINTENDANT FOR DAMAGE
IsSomewhere 249
Present 301
FlagOFF 29
PrintMessage 74
TurnFlagON 29
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND FLENZ ANY
Present 201
FlagOFF 31
PrintMessage 79
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FLENZ ANY
Present 201
NOUNPresent
NOUNIsMovable
NOT NOUNIsCreature
FlagOFF 73        ;first flenz
FlagON 31
PrintMessage 83
BlankLine
SendNOUNToRoom 100
TurnFlagON 73
DoneWithTurn
END_COMMAND

COMMAND FLENZ ANY
Present 201
FlagON 31
FlagON 73
NOUNPresent
NOUNIsMovable
PrintMessage 106
BlankLine
SendNOUNToRoom 100
DoneWithTurn
END_COMMAND

COMMAND FLENZ ANY
Present 201
NOUNPresent
NOT NOUNIsMovable
 OR
NOUNIsCreature
FlagON 31
PrintMessage 84
DoneWithTurn
END_COMMAND

COMMAND UNFLENZ ANY
AtLocation 21     ;at pavillion
Present 307       ;diggs
FlagOFF 70
NOUNIsLocated 100 ;you have it in the flenzer
PutNounInCurrentRoom  ;you unflenz it
PrintMessage 106   ;verbthenoun
BlankLine
PrintMessage 150   ;fascinating says diggs
BlankLine
TurnFlagON 70      ;you've scored
TurnCounterOFF 12
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND UNFLENZ ANY
Present 201
FlagOFF 74
NOUNIsLocated 100
PutNOUNInCurrentRoom
PrintMessage 85
BlankLine
TurnFlagON 74
DoneWithTurn
END_COMMAND

COMMAND UNFLENZ ANY
Present 201
FlagON 74
NOUNIsLocated 100
PutNOUNInCurrentRoom
PrintMessage 106
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ANSWER PHONE
AtLocation 2
FlagON 36   ;Dr. Grace calls
TurnFlagON 37
DescribeThing 305
BlankLine
Destroy 263      ;that's the ringing
PrintMessage 91  ;she warns about murder attempts
BlankLine
PrintMessage 92
DoneWithTurn
END_COMMAND

COMMAND CALL WOMAN
Present 226
IsSomewhere 318
FlagOFF 76
DescribeThing 306
BlankLine
TurnFlagON 76
DoneWithTurn
END_COMMAND

COMMAND CALL SUPERINTENDANT
Present 226
NOT Present 301
FlagOFF 17  ;not involved with him
PrintMessage 110
BlankLine
TurnFlagON 46 ;this is phone call
DoneWithTurn
END_COMMAND

COMMAND CALL ANY
Present 226
PrintMessage 60
DoneWithTurn
END_COMMAND

COMMAND CALL ANY
PrintMessage 11
DoneWithTurn
END_COMMAND

COMMAND LISTEN TO BROADCAST 
AtLocation 2
 OR
AtLocation 3
 OR
AtLocation 5
IsSomewhere 246
RandomMessage 94 96
AddToVariable 2 5
DoneWithTurn
END_COMMAND

COMMAND CRAWL UNDER END
IsWearing 228  ;blacks
Present 259
GoToRoom 16
PrintMessage 113
BlankLine
TurnFlagOFF 6            ;you're messy
SwapLocations 228 265  ;dirty clothes
DoneWithTurn
END_COMMAND

COMMAND CRAWL UNDER END
IsWearing 230  ;nondescript suit
Present 259
GoToRoom 16
PrintMessage 113
BlankLine
TurnFlagOFF 6            ;you're messy
SwapLocations 230 264   ;dirty clothes
DoneWithTurn
END_COMMAND

COMMAND CRAWL UNDER END
Present 259
GoToRoom 16
PrintMessage 113
BlankLine
DoneWithTurn
END_COMMAND

COMMAND CRAWL UNDER END
AtLocation 16  ;utility lot
PrintMessage 108
BlankLine
GoToRoom 14
DoneWithTurn
END_COMMAND

COMMAND BOARD SKYBUS
Present 312
IsCarrying 214
 OR
IsCarrying 221
VariableGT 10 3
PrintMessage 13
BlankLine
PrintMessage 51
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND BOARD SKYBUS
Present 312   ;half past northbound
IsCarrying 214
 OR
IsCarrying 221   ;one or other credcard
PrintMessage 13  ;ahhh, unlucky thirteen
BlankLine
PrintMessage 114
BlankLine
SubtractFromVariable 2 10  ;lose five minutes
GoToRoom 10      ;back to your street
AddToVariable 10 1  ;so many chances...
TurnFlagOFF 41
DoneWithTurn
END_COMMAND

COMMAND BOARD SKYBUS
Present 313        ;express bus
IsCarrying 214     ;credcards 
 OR
IsCarrying 221
PrintMessage 107   ;you ride and dismount
BlankLine
GoToRoom 21        ;at pavillion 
SetVariableTo 2 55 
DoneWithTurn
END_COMMAND

COMMAND BOARD SKYBUS
Present 312
 OR
Present 313  ;but, apparently no credcard
PrintMessage 53
BlankLine
END_COMMAND

COMMAND HIDE
AtLocation 17
FlagOFF 59
Present 304  ;insect
PrintMessage 132 
BlankLine
TurnFlagON 59
DoneWithTurn
END_COMMAND

COMMAND WARN DIGGS ABOUT SKYBUS
AtLocation 15     ;at confluence
FlagOFF 38
Present 307       ;diggs
Present 312       ;half hourly bus
PrintMessage 109  ;you warn
BlankLine         
PrintMessage 103  ;he heeds and watches w you
SwapLocations 312 275 ;while bus crashes
TurnFlagON 38
TurnCounterOFF 11
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND JUMP RAIL
AtLocation 10
IsCarrying 269
FlagON 6   ;is presentable
PrintMessage 138
BlankLine
GoToRoom 21
TurnFlagOFF 6
SetVariableTo 2 50 ;minutes to spare
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND JUMP RAIL
AtLocation 10
IsCarrying 269
PrintMessage 138
BlankLine
GoToRoom 21
SetVariableTo 2 50 ;minutes to spare
Tone 660 700
DoneWithTurn
END_COMMAND

COMMAND JUMP RAIL
AtLocation 10
VariableGT 10 3
PrintMessage 106
BlankLine
DescribeThing 13
BlankLine
PrintMessage 51
BlankLine
KillPlayer
DoneWithTurn
END_COMMAND

COMMAND JUMP RAIL
AtLocation 10
PrintMessage 106
BlankLine
DescribeThing 13
BlankLine
PrintMessage 114
BlankLine
SubtractFromVariable 2 15
GoToRoom 4
AddToVariable 10 1
DoneWithTurn
END_COMMAND

COMMAND BORROW HOTDOG
Present 311    ;dogmatic
IsCarrying 214
 OR
IsCarrying 221
PrintMessage 106
BlankLine
GetIt 262
DoneWithTurn
END_COMMAND

COMMAND BORROW HOVERBOARD
Present 317
FlagOFF 61
FlagON 58 ;you gave shield to kid
IsSomewhere 251
 OR
IsSomewhere 252
PrintMessage 137
BlankLine
GetIt 269
TurnFlagON 61
Tone 660 700
PlusScore 50
DoneWithTurn
END_COMMAND

COMMAND BORROW HOVERBOARD
Present 317
FlagOFF 61
PrintMessage 156
BlankLine
DoneWithTurn
END_COMMAND